企业管理

开发平台：
Visual Basic

i-：源码内容
							VERSION 5.00
Object = "{BEEECC20-4D5F-4F8B-BFDC-5D9B6FBDE09D}#1.0#0"; "vsflex8.ocx"
Object = "{831FDD16-0C5C-11D2-A9FC-0000F8754DA1}#2.0#0"; "mscomctl.ocx"
Begin VB.Form ZB_Frmzflzjg 
   Caption         =   "总分类帐"
   ClientHeight    =   7755
   ClientLeft      =   315
   ClientTop       =   390
   ClientWidth     =   11190
   Icon            =   "帐簿_总分类帐查询结果.frx":0000
   KeyPreview      =   -1  'True
   LinkTopic       =   "Form1"
   MDIChild        =   -1  'True
   ScaleHeight     =   7755
   ScaleWidth      =   11190
   WindowState     =   2  'Maximized
   Begin VB.CommandButton Cmd_CancelPrint 
      Caption         =   "取消打印(&C)"
      Height          =   405
      Left            =   9750
      TabIndex        =   11
      Top             =   720
      Visible         =   0   'False
      Width           =   1155
   End
   Begin VB.Timer Timer1 
      Enabled         =   0   'False
      Interval        =   1
      Left            =   7620
      Top             =   90
   End
   Begin VB.PictureBox Pic_Title 
      Height          =   1185
      Left            =   0
      Picture         =   "帐簿_总分类帐查询结果.frx":1042
      ScaleHeight     =   1125
      ScaleWidth      =   11535
      TabIndex        =   0
      Top             =   570
      Width           =   11595
      Begin VB.ComboBox Combo_QueryCcode 
         Height          =   300
         Left            =   1770
         Style           =   2  'Dropdown List
         TabIndex        =   8
         Top             =   780
         Width           =   3915
      End
      Begin VB.ComboBox Combo_AccFormat 
         Height          =   300
         Left            =   7560
         Style           =   2  'Dropdown List
         TabIndex        =   4
         Top             =   780
         Width           =   1725
      End
      Begin VB.Label Lab_TitleText 
         BackStyle       =   0  'Transparent
         ForeColor       =   &H00000000&
         Height          =   225
         Index           =   1
         Left            =   7620
         TabIndex        =   10
         Top             =   180
         Width           =   1395
      End
      Begin VB.Label Lab_TitleMess 
         BackStyle       =   0  'Transparent
         Caption         =   "外币名称:"
         Height          =   225
         Index           =   2
         Left            =   6720
         TabIndex        =   9
         Top             =   210
         Width           =   915
      End
      Begin VB.Label Lab_TitleMess 
         AutoSize        =   -1  'True
         BackStyle       =   0  'Transparent
         Caption         =   "科目名称:"
         Height          =   180
         Index           =   1
         Left            =   960
         TabIndex        =   7
         Top             =   840
         Width           =   810
      End
      Begin VB.Label TsLabel 
         AutoSize        =   -1  'True
         BackStyle       =   0  'Transparent
         Caption         =   "帐页格式:"
         Height          =   180
         Index           =   7
         Left            =   6720
         TabIndex        =   5
         Top             =   840
         Width           =   810
      End
      Begin VB.Label TsLabel 
         BackColor       =   &H80000018&
         BackStyle       =   0  'Transparent
         Caption         =   "总分类帐"
         BeginProperty Font 
            Name            =   "宋体"
            Size            =   14.25
            Charset         =   134
            Weight          =   700
            Underline       =   0   'False
            Italic          =   0   'False
            Strikethrough   =   0   'False
         EndProperty
         ForeColor       =   &H00000000&
         Height          =   330
         Index           =   4
         Left            =   600
         TabIndex        =   1
         Top             =   180
         Width           =   1425
      End
   End
   Begin VSFlex8Ctl.VSFlexGrid CxbbGrid 
      Height          =   6885
      Left            =   0
      TabIndex        =   2
      Top             =   1770
      Width           =   11715
      _cx             =   5080
      _cy             =   5080
      Appearance      =   1
      BorderStyle     =   1
      Enabled         =   -1  'True
      BeginProperty Font {0BE35203-8F91-11CE-9DE3-00AA004BB851} 
         Name            =   "宋体"
         Size            =   9
         Charset         =   134
         Weight          =   400
         Underline       =   0   'False
         Italic          =   0   'False
         Strikethrough   =   0   'False
      EndProperty
      MousePointer    =   0
      BackColor       =   16777215
      ForeColor       =   -2147483640
      BackColorFixed  =   12632256
      ForeColorFixed  =   -2147483630
      BackColorSel    =   -2147483635
      ForeColorSel    =   -2147483634
      BackColorBkg    =   -2147483636
      BackColorAlternate=   16777215
      GridColor       =   -2147483633
      GridColorFixed  =   -2147483632
      TreeColor       =   -2147483632
      FloodColor      =   192
      SheetBorder     =   -2147483642
      FocusRect       =   1
      HighLight       =   1
      AllowSelection  =   -1  'True
      AllowBigSelection=   -1  'True
      AllowUserResizing=   0
      SelectionMode   =   0
      GridLines       =   1
      GridLinesFixed  =   2
      GridLineWidth   =   1
      Rows            =   50
      Cols            =   10
      FixedRows       =   1
      FixedCols       =   1
      RowHeightMin    =   0
      RowHeightMax    =   0
      ColWidthMin     =   0
      ColWidthMax     =   0
      ExtendLastCol   =   0   'False
      FormatString    =   ""
      ScrollTrack     =   0   'False
      ScrollBars      =   3
      ScrollTips      =   0   'False
      MergeCells      =   0
      MergeCompare    =   0
      AutoResize      =   -1  'True
      AutoSizeMode    =   0
      AutoSearch      =   0
      AutoSearchDelay =   2
      MultiTotals     =   -1  'True
      SubtotalPosition=   1
      OutlineBar      =   0
      OutlineCol      =   0
      Ellipsis        =   0
      ExplorerBar     =   0
      PicturesOver    =   0   'False
      FillStyle       =   0
      RightToLeft     =   0   'False
      PictureType     =   0
      TabBehavior     =   0
      OwnerDraw       =   0
      Editable        =   0
      ShowComboButton =   1
      WordWrap        =   0   'False
      TextStyle       =   0
      TextStyleFixed  =   0
      OleDragMode     =   0
      OleDropMode     =   0
      DataMode        =   0
      VirtualData     =   -1  'True
      DataMember      =   ""
      ComboSearch     =   3
      AutoSizeMouse   =   -1  'True
      FrozenRows      =   0
      FrozenCols      =   0
      AllowUserFreezing=   0
      BackColorFrozen =   0
      ForeColorFrozen =   0
      WallPaperAlignment=   9
      AccessibleName  =   ""
      AccessibleDescription=   ""
      AccessibleValue =   ""
      AccessibleRole  =   24
   End
   Begin MSComctlLib.Toolbar SzToolbar 
      Align           =   1  'Align Top
      Height          =   555
      Left            =   0
      TabIndex        =   3
      Top             =   0
      Width           =   11190
      _ExtentX        =   19738
      _ExtentY        =   979
      ButtonWidth     =   820
      ButtonHeight    =   926
      AllowCustomize  =   0   'False
      Appearance      =   1
      Style           =   1
      ImageList       =   "ImageList1"
      _Version        =   393216
      BeginProperty Buttons {66833FE8-8583-11D1-B16A-00C0F0283628} 
         NumButtons      =   13
         BeginProperty Button1 {66833FEA-8583-11D1-B16A-00C0F0283628} 
            Caption         =   "设置"
            Key             =   "ymsz"
            ImageKey        =   "sz"
         EndProperty
         BeginProperty Button2 {66833FEA-8583-11D1-B16A-00C0F0283628} 
            Caption         =   "打印"
            Key             =   "dy"
            ImageKey        =   "dy"
         EndProperty
         BeginProperty Button3 {66833FEA-8583-11D1-B16A-00C0F0283628} 
            Caption         =   "预览"
            Key             =   "yl"
            ImageKey        =   "yl"
         EndProperty
         BeginProperty Button4 {66833FEA-8583-11D1-B16A-00C0F0283628} 
            Caption         =   "连打"
            Key             =   "lxdy"
            ImageKey        =   "lxdy"
         EndProperty
         BeginProperty Button5 {66833FEA-8583-11D1-B16A-00C0F0283628} 
            Style           =   3
         EndProperty
         BeginProperty Button6 {66833FEA-8583-11D1-B16A-00C0F0283628} 
            Caption         =   "查询"
            Key             =   "cx"
            ImageKey        =   "cx"
         EndProperty
         BeginProperty Button7 {66833FEA-8583-11D1-B16A-00C0F0283628} 
            Style           =   3
         EndProperty
         BeginProperty Button8 {66833FEA-8583-11D1-B16A-00C0F0283628} 
            Caption         =   "明细"
            Key             =   "mxz"
            ImageKey        =   "mx"
         EndProperty
         BeginProperty Button9 {66833FEA-8583-11D1-B16A-00C0F0283628} 
            Style           =   3
         EndProperty
         BeginProperty Button10 {66833FEA-8583-11D1-B16A-00C0F0283628} 
            Caption         =   "刷新"
            Key             =   "sx"
            ImageKey        =   "sx"
         EndProperty
         BeginProperty Button11 {66833FEA-8583-11D1-B16A-00C0F0283628} 
            Style           =   3
         EndProperty
         BeginProperty Button12 {66833FEA-8583-11D1-B16A-00C0F0283628} 
            Caption         =   "帮助"
            Key             =   "bz"
            ImageKey        =   "bz"
         EndProperty
         BeginProperty Button13 {66833FEA-8583-11D1-B16A-00C0F0283628} 
            Caption         =   "退出"
            Key             =   "fh"
            ImageKey        =   "tc"
         EndProperty
      EndProperty
      BorderStyle     =   1
      Begin MSComctlLib.ImageList ImageList1 
         Left            =   6600
         Top             =   0
         _ExtentX        =   1005
         _ExtentY        =   1005
         BackColor       =   -2147483643
         ImageWidth      =   16
         ImageHeight     =   16
         MaskColor       =   12632256
         _Version        =   393216
         BeginProperty Images {2C247F25-8591-11D1-B16A-00C0F0283628} 
            NumListImages   =   35
            BeginProperty ListImage1 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":35106
               Key             =   "sz"
            EndProperty
            BeginProperty ListImage2 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":354A0
               Key             =   "dy"
            EndProperty
            BeginProperty ListImage3 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3583A
               Key             =   "yl"
            EndProperty
            BeginProperty ListImage4 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":35BD4
               Key             =   "xg"
            EndProperty
            BeginProperty ListImage5 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":35F6E
               Key             =   "zh"
            EndProperty
            BeginProperty ListImage6 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":36308
               Key             =   "sh"
            EndProperty
            BeginProperty ListImage7 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":366A2
               Key             =   "bc"
            EndProperty
            BeginProperty ListImage8 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":36A3C
               Key             =   "fq"
            EndProperty
            BeginProperty ListImage9 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":36DD6
               Key             =   "bz"
            EndProperty
            BeginProperty ListImage10 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":37170
               Key             =   "tc"
            EndProperty
            BeginProperty ListImage11 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3750A
               Key             =   "bcgs"
            EndProperty
            BeginProperty ListImage12 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":378A4
               Key             =   "mrlk"
            EndProperty
            BeginProperty ListImage13 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":37C3E
               Key             =   "xsxm"
            EndProperty
            BeginProperty ListImage14 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":37FD8
               Key             =   "first"
            EndProperty
            BeginProperty ListImage15 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":38372
               Key             =   "prev"
            EndProperty
            BeginProperty ListImage16 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3870C
               Key             =   "next"
            EndProperty
            BeginProperty ListImage17 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":38AA6
               Key             =   "last"
            EndProperty
            BeginProperty ListImage18 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":38E40
               Key             =   "xx"
            EndProperty
            BeginProperty ListImage19 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":391DA
               Key             =   "define"
            EndProperty
            BeginProperty ListImage20 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":39574
               Key             =   "exec"
            EndProperty
            BeginProperty ListImage21 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3990E
               Key             =   "xz"
            EndProperty
            BeginProperty ListImage22 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":39CA8
               Key             =   "sc"
            EndProperty
            BeginProperty ListImage23 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3A042
               Key             =   "sx"
            EndProperty
            BeginProperty ListImage24 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3A3DC
               Key             =   "cx"
            EndProperty
            BeginProperty ListImage25 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3A776
               Key             =   "zd"
            EndProperty
            BeginProperty ListImage26 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3AB10
               Key             =   "dz"
            EndProperty
            BeginProperty ListImage27 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3AEAA
               Key             =   "ph"
            EndProperty
            BeginProperty ListImage28 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3B244
               Key             =   "fz"
            EndProperty
            BeginProperty ListImage29 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3B5DE
               Key             =   "dw"
            EndProperty
            BeginProperty ListImage30 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3B978
               Key             =   "hf"
            EndProperty
            BeginProperty ListImage31 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3BD12
               Key             =   "pz"
            EndProperty
            BeginProperty ListImage32 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3C0AC
               Key             =   "check"
            EndProperty
            BeginProperty ListImage33 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3C446
               Key             =   "zz"
            EndProperty
            BeginProperty ListImage34 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3C7E0
               Key             =   "mx"
            EndProperty
            BeginProperty ListImage35 {2C247F27-8591-11D1-B16A-00C0F0283628} 
               Picture         =   "帐簿_总分类帐查询结果.frx":3CB7A
               Key             =   "lxdy"
            EndProperty
         EndProperty
      End
      Begin MSComctlLib.Toolbar GsToolbar 
         Height          =   525
         Left            =   9510
         TabIndex        =   6
         Top             =   0
         Width           =   1665
         _ExtentX        =   2937
         _ExtentY        =   926
         ButtonWidth     =   1455
         ButtonHeight    =   926
         AllowCustomize  =   0   'False
         Appearance      =   1
         Style           =   1
         ImageList       =   "ImageList1"
         _Version        =   393216
         BeginProperty Buttons {66833FE8-8583-11D1-B16A-00C0F0283628} 
            NumButtons      =   2
            BeginProperty Button1 {66833FEA-8583-11D1-B16A-00C0F0283628} 
               Caption         =   "保存格式"
               Key             =   "bcgs"
               ImageKey        =   "bcgs"
            EndProperty
            BeginProperty Button2 {66833FEA-8583-11D1-B16A-00C0F0283628} 
               Caption         =   "默认列宽"
               Key             =   "hfmrgs"
               ImageKey        =   "mrlk"
            EndProperty
         EndProperty
      End
   End
End
Attribute VB_Name = "ZB_Frmzflzjg"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
'*********************************************************************
'*    模 块 名 称 :总分类帐
'*    功 能 描 述 :本功能用于查询某科目的总分类帐
'*                 并且能够进行立体联查明细帐数据。
'*    程序员姓名  : 张建忠
'*    最后修改人  :奚俊峰
'*    最后修改时间:2001.12.29
'*    备        注:
'*********************************************************************
Dim ReportTitle As String                '报表主标题
Dim Bln_CancelPrint As Boolean           '用户是否取消打印
Dim Bln_Printing As Boolean              '用户是否正在打印
'以下为固定使用变量
Dim Dyymctbl As New DY_Dyymsz            '打印页面窗体变量
Dim GridCode As String                   '显示网格网格代码
Dim GridInf() As Variant                 '整个网格设置信息
Dim Tsxx As String                       '系统提示信息
Dim Qslz As Long                         '网格隐藏(非操作显示)列数
Dim Sjhgd As Double                      '网格数据行高度
Dim Sfxshjwg As Boolean                  '是否显示合计网格
Dim GridBoolean() As Boolean             '网格列信息(布尔型)
Dim GridStr()  As String                 '网格列信息(字符型)
Dim GridInt() As Integer                 '网格列信息(整型)
Dim Szzls As Integer                     '数组总列数(网格列数-1)
Dim Bln_Stop As Boolean                  '停止输出查询结果
Private Sub Form_Activate()
    Me.HelpContextID = "0116001"
End Sub
Private Sub Form_Resize()                '根据窗体大小来调整网格,标题栏大小
    On Error Resume Next
    With CxbbGrid
        .Width = Me.Width - 160
        .Height = Me.Height - .Top - 400
    End With
    With Pic_Title
        .Width = Me.Width - 160
    End With
    
    GsToolbar.Left = Me.Width - GsToolbar.Width - 140
End Sub
Private Sub Form_Load()                                                   '窗体装入
    
    Me.HelpContextID = "0116001"
    
    '调入打印页面设置窗体
    XtReportCode = "Cwzz_zflz"
    Load Dyymctbl
    ReportTitle = "总 分 类 帐"
    
    '调整标题栏及网格、格式工具条位置
    Pic_Title.Left = 40
    Pic_Title.Top = SzToolbar.Top + SzToolbar.Height - 10
    CxbbGrid.Left = Pic_Title.Left
    CxbbGrid.Top = Pic_Title.Top + Pic_Title.Height + 20
    
    '调 入 网 格
    GridCode = "Cwzz_zflz"
    Call BzWgcsh(CxbbGrid, GridCode, GridInf(), GridBoolean(), GridInt(), GridStr())
    
    Qslz = GridInf(1)
    Sjhgd = GridInf(2)
    Sfxshjwg = GridInf(7)
    Szzls = CxbbGrid.Cols - 1
    
    '填充查询年度
    CxbbGrid.TextMatrix(0, Sydz("001", GridStr(), Szzls)) = Trim(Str(Xtyear)) + "年"
    CxbbGrid.TextMatrix(0, Sydz("002", GridStr(), Szzls)) = Trim(Str(Xtyear)) + "年"
    
    '帐页格式
    Call FillCombo(Combo_AccFormat, "Cwzz_zygs", "", 0)
    
    '调整标题位置
    SetTitlePos tsLabel(4)
    
    
End Sub
Private Sub Form_Unload(Cancel As Integer)                                  '窗体卸载
    '如果用户正在连续打印帐页,则不能关闭窗体
    If Bln_Printing Then
        Cancel = 1
    End If
    '卸载条件窗体
    ZB_Frmzflztj.UnloadCheck.Value = 1
    Unload ZB_Frmzflztj
    '卸载打印页面设置窗体
    Unload Dyymctbl
End Sub
Private Sub GsToolbar_ButtonClick(ByVal Button As MSComctlLib.Button)       '网格格式调整
    Select Case Button.Key
    Case "bcgs"                                          '保存表格格式
        Call Bcwggs(CxbbGrid, GridCode, GridStr)
    Case "hfmrgs"                                        '恢复默认格式
        Call Hfmrgs(CxbbGrid, GridCode, GridStr)
    Case "szxsxm"                                        '设置显示项目
        Call Szxsxm(CxbbGrid, GridCode)
    End Select
End Sub
Private Sub SzToolbar_ButtonClick(ByVal Button As MSComctlLib.Button)
    '如果用户正在连续打印帐页,则不能执行其他功能
    If Bln_Printing Then
        Exit Sub
    End If
    
    Select Case Button.Key
    Case "ymsz"                                          '页面设置
        Dyymctbl.Show 1
    Case "yl"                                            '预 览
        Call bbyl(True)
    Case "dy"                                            '打 印
        Call bbyl(False)
    Case "lxdy"                                          '连 打
        Call Sub_Lxdy
    Case "cx"                                            '查 询
        If Trim(Combo_QueryCcode.Text) <> "" Then
            ZB_Frmzflztj.LrText(0).Text = Trim(Mid(Combo_QueryCcode.Text, 1, InStr(1, Combo_QueryCcode.Text, " ") - 1))
        End If
        ZB_Frmzflztj.Show 1
    Case "mxz"                                           '明细帐
        Call Sub_Lcmxz
    Case "sx"                                            '刷 新
        Combo_QueryCcode_Click
    Case "bz"                                            '帮 助
        Call F1bz
    Case "fh"                                            '退 出
        Unload Me
    End Select
End Sub
Private Sub Timer1_Timer()                                 '在窗体激活后调入查询程序
    Dim RecTemp As New ADODB.Recordset          '临时使用动态集
    Dim Str_QueryCondi As String                '用户录入查询条件
    
    Timer1.Enabled = False
    
    With ZB_Frmzflztj
        
        Str_QueryCondi = " where 1=1 "
        For Jsqte = 1 To 3
            Select Case Jsqte
            Case 1   '科目号范围(起始科目号)
                Str_QueryCondi = Str_QueryCondi & " and CCode>='" & Trim(.LrText(0).Text) & "'"
            Case 2   '科目号范围(终止科目号)
                If Trim(.LrText(1).Text) <> "" Then
                    Str_QueryCondi = Str_QueryCondi & " and CCode<='" & Trim(.LrText(1).Text) & "'"
                End If
                
            Case 3   '科目级次范围(起始科目级次-终止科目级次)
                Str_QueryCondi = Str_QueryCondi & " and CodeLevel>=" & Val(.LrText(2).Text) & " and CodeLevel<=" & Val(.LrText(3).Text)
            End Select
        Next Jsqte
        
        '判断是否仅限于末级科目查询
        If .Chk_EndFlag.Value = 1 Then
            Str_QueryCondi = Str_QueryCondi & " and EndFlag='1'"
        End If
        
    End With
    
    '根据查询科目范围填充科目列表框
    Sqlstr = "SELECT Ccode,Cname From Cwzz_AccCode" & Str_QueryCondi & " Order By Ccode"
    Set RecTemp = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
    
    Combo_QueryCcode.Clear
    Do While Not RecTemp.EOF
        Combo_QueryCcode.AddItem Trim(RecTemp.Fields("Ccode")) + " " + Trim(RecTemp.Fields("Cname") & "")
        RecTemp.MoveNext
    Loop
    
    If Combo_QueryCcode.ListCount <> 0 Then
        Combo_QueryCcode.Text = Combo_QueryCcode.List(0)
    End If
    
End Sub
Private Sub Combo_QueryCcode_Click()                                      '用户点击科目列表框
    Timer1.Enabled = False
    Xt_Wait.Show
    Xt_Wait.Refresh
    CxbbGrid.Redraw = True
    
    '加快显示速度
    CxbbGrid.Redraw = False
    
    '生成查询结果
    Call Sub_Query
    
    CxbbGrid.Redraw = True
    
    Xt_Wait.Hide
End Sub
Private Sub Sub_Query()                                    '生成查询结果
    Dim RecTemp As New ADODB.Recordset          '临时使用动态集
    Dim Rec_AccSum As New ADODB.Recordset       '科目总帐动态集
    Dim Str_Ccode As String                     '查询科目
    Dim Sqlstr As String                        '查询字符串
    Dim Coljsq As Long                          '网格列计数器
    Dim Jsqte As Long                           '临时动态计数器
    Dim Int_Year As Integer                     '查询会计年度
    Dim Bln_IncluNotBook As Boolean             '是否包含未记帐凭证
    Dim Bln_EndFlag As Boolean                  '判断当前科目是否为末级科目
    Dim Int_DqPeriod As Integer                 '查询进行当前会计期间
    
    Dim Dbl_Qcyete#, Dbl_Qcslte#, Dbl_Qcwbte#   '期初金额,数量,外币
    Dim Dbl_Jejfhj#, Dbl_Jedfhj#, Dbl_Sljfhj#, Dbl_Sldfhj#, Dbl_Wbjfhj#, Dbl_Wbdfhj# '本期合计(金额,数量,外币)
    Dim Dbl_Jejflj#, Dbl_Jedflj#, Dbl_Sljflj#, Dbl_Sldflj#, Dbl_Wbjflj#, Dbl_Wbdflj# '截止累计(金额,数量,外币)
    Dim Dbl_Qmyete#, Dbl_Qmslte#, Dbl_Qmwbte#   '期末金额,数量,外币
    '以下为用户自定义部分[
    
    '清除原查询数据
    CxbbGrid.Rows = CxbbGrid.FixedRows
    
    '得到当前查询科目,并判断是否为末级科目
    If Trim(Combo_QueryCcode.Text) <> "" Then
        Str_Ccode = Trim(Mid(Combo_QueryCcode.Text, 1, InStr(1, Combo_QueryCcode.Text, " ") - 1))
    Else
        Exit Sub
    End If
    Sqlstr = "SELECT EndFlag,AccFormat,ForeignFlag,ForeignCurrName From Cwzz_AccCode Left JOIN Gy_ForeignCurrency ON" & _
    " Cwzz_AccCode.ForeignCurrCode = Gy_ForeignCurrency.ForeignCurrCode Where Ccode='" & Str_Ccode & "'"
    Set RecTemp = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
    If Not RecTemp.EOF Then
        Bln_EndFlag = RecTemp.Fields("EndFlag")
        Combo_AccFormat.Text = Trim(RecTemp.Fields("AccFormat") & "")
        If RecTemp.Fields("ForeignFlag") Then
            Lab_TitleMess(2).Visible = True
            Lab_TitleText(1).Caption = Trim(RecTemp.Fields("ForeignCurrName") & "")
        Else
            Lab_TitleMess(2).Visible = True
            Lab_TitleText(1).Caption = ""
        End If
    End If
    
    '得到查询年度,并判断是否包含未记帐凭证
    With ZB_Frmzflztj
        
        Int_Year = Xtyear
        
        '是否包含未记帐凭证
        If .Chk_NotBook.Value = 1 Then
            Bln_IncluNotBook = True
        Else
            Bln_IncluNotBook = False
        End If
        
    End With
    
    '初始化各种值
    Dbl_Qcyete = 0
    Dbl_Qcslte = 0
    Dbl_Qcwbte = 0
    
    Dbl_Jejfhj = 0
    Dbl_Jedfhj = 0
    Dbl_Sljfhj = 0
    Dbl_Sldfhj = 0
    Dbl_Wbjfhj = 0
    Dbl_Wbdfhj = 0
    
    Dbl_Jejflj = 0
    Dbl_Jedflj = 0
    Dbl_Sljflj = 0
    Dbl_Sldflj = 0
    Dbl_Wbjflj = 0
    Dbl_Wbdflj = 0
    
    Jsqte = CxbbGrid.FixedRows - 1
    
    '1.读出上年结转余额(数量,外币,金)
    Sqlstr = "SELECT * From Cwzz_AccSum Where Ccode='" & Str_Ccode & "' And Year=" & Int_Year & " And Period=1"
    Set RecTemp = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
    If Not RecTemp.EOF Then
        Dbl_Qcyete = RecTemp.Fields("Qcye")
        Dbl_Qcslte = RecTemp.Fields("Qcsl")
        Dbl_Qcwbte = RecTemp.Fields("Qcwb")
    End If
    
    CxbbGrid.AddItem ""
    Jsqte = Jsqte + 1
    
    CxbbGrid.TextMatrix(Jsqte, Sydz("004", GridStr(), Szzls)) = "上年结转"
    
    '输出余额
    Call Sub_OutBalance(Jsqte, Bln_EndFlag, Dbl_Qcyete, Dbl_Qcslte, Dbl_Qcwbte)
    
    
    '2.读出所有会计期间记账数据
    Sqlstr = "SELECT * From Cwzz_AccSum Where Ccode='" & Str_Ccode & "' And Year=" & Int_Year
    Set Rec_AccSum = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
    
    '3.如果包含未记帐凭证查询,则读出本年度所有未记帐凭证各会计期间合计数据
    If Bln_IncluNotBook Then
        Sqlstr = "SELECT Period,SUM(Jfje) AS Jfjehj, SUM(Dfje) AS Dfjehj, SUM(Jfsl) AS Jfslhj, SUM(Dfsl) AS Dfslhj," & _
        " SUM(Wbjfje) AS Wbjfjehj, SUM(Wbdfje) AS Wbdfjehj From Cwzz_V_AccVouch WHERE BookFlag=0 And Ccode like '" & Str_Ccode & "%' And Year=" & Int_Year & _
        " GROUP BY Year, Period"
        Set RecTemp = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
    End If
    
    '4.将各会计期间科目合计数据写入网格,同时计算本年累计,余额将其写入网格
    For Int_DqPeriod = 1 To 12
        
        '本期合计数据清零
        Dbl_Jejfhj = 0
        Dbl_Jedfhj = 0
        Dbl_Sljfhj = 0
        Dbl_Sldfhj = 0
        Dbl_Wbjfhj = 0
        Dbl_Wbdfhj = 0
        
        With Rec_AccSum
            If .RecordCount <> 0 Then
                .MoveFirst
                .Find "Period =" & Int_DqPeriod
                If Not .EOF Then
                    Dbl_Jejfhj = Dbl_Jejfhj + .Fields("Mjje")
                    Dbl_Jedfhj = Dbl_Jedfhj + .Fields("Mdje")
                    Dbl_Sljfhj = Dbl_Sljfhj + .Fields("Mjsl")
                    Dbl_Sldfhj = Dbl_Sldfhj + .Fields("Mdsl")
                    Dbl_Wbjfhj = Dbl_Wbjfhj + .Fields("Mjwb")
                    Dbl_Wbdfhj = Dbl_Wbdfhj + .Fields("Mdwb")
                    
                    Dbl_Jejflj = Dbl_Jejflj + .Fields("Mjje")
                    Dbl_Jedflj = Dbl_Jedflj + .Fields("Mdje")
                    Dbl_Sljflj = Dbl_Sljflj + .Fields("Mjsl")
                    Dbl_Sldflj = Dbl_Sldflj + .Fields("Mdsl")
                    Dbl_Wbjflj = Dbl_Wbjflj + .Fields("Mjwb")
                    Dbl_Wbdflj = Dbl_Wbdflj + .Fields("Mdwb")
                End If
            End If
        End With
        
        '判断是否包含未记帐凭证
        If Bln_IncluNotBook Then
            With RecTemp
                If .RecordCount <> 0 Then
                    .MoveFirst
                    .Find "Period =" & Int_DqPeriod
                    If Not .EOF Then
                        Dbl_Jejfhj = Dbl_Jejfhj + Val(.Fields("Jfjehj") & "")
                        Dbl_Jedfhj = Dbl_Jedfhj + Val(.Fields("Dfjehj") & "")
                        Dbl_Sljfhj = Dbl_Sljfhj + Val(.Fields("Jfslhj") & "")
                        Dbl_Sldfhj = Dbl_Sldfhj + Val(.Fields("Dfslhj") & "")
                        Dbl_Wbjfhj = Dbl_Wbjfhj + Val(.Fields("Wbjfjehj") & "")
                        Dbl_Wbdfhj = Dbl_Wbdfhj + Val(.Fields("Wbdfjehj") & "")
                        
                        Dbl_Jejflj = Dbl_Jejflj + Val(.Fields("Jfjehj") & "")
                        Dbl_Jedflj = Dbl_Jedflj + Val(.Fields("Dfjehj") & "")
                        Dbl_Sljflj = Dbl_Sljflj + Val(.Fields("Jfslhj") & "")
                        Dbl_Sldflj = Dbl_Sldflj + Val(.Fields("Dfslhj") & "")
                        Dbl_Wbjflj = Dbl_Wbjflj + Val(.Fields("Wbjfjehj") & "")
                        Dbl_Wbdflj = Dbl_Wbdflj + Val(.Fields("Wbdfjehj") & "")
                    End If
                End If
            End With
        End If
        
        '随时计算期末余额
        
        Dbl_Qcyete = Dbl_Qcyete + Dbl_Jejfhj - Dbl_Jedfhj
        Dbl_Qcslte = Dbl_Qcslte + Dbl_Sljfhj - Dbl_Sldfhj
        Dbl_Qcwbte = Dbl_Qcwbte + Dbl_Wbjfhj - Dbl_Wbdfhj
        
        '如果本期合计数据不为零则输出本月合计,本年累计,期末余额
        If Dbl_Jejfhj <> 0 Or Dbl_Jedfhj <> 0 Or Dbl_Sljfhj <> 0 Or Dbl_Sldfhj <> 0 Or Dbl_Wbjfhj <> 0 Or Dbl_Wbdfhj <> 0 Then
            CxbbGrid.AddItem ""
            Jsqte = Jsqte + 1
            Call Sub_OutPeriodSum(Jsqte, Bln_EndFlag, Int_DqPeriod, Dbl_Jejfhj, Dbl_Jedfhj, Dbl_Sljfhj, Dbl_Sldfhj, Dbl_Wbjfhj, Dbl_Wbdfhj)
            
            '输出余额
            Call Sub_OutBalance(Jsqte, Bln_EndFlag, Dbl_Qcyete, Dbl_Qcslte, Dbl_Qcwbte)
            
            CxbbGrid.AddItem ""
            Jsqte = Jsqte + 1
            Call Sub_OutYearSum(Jsqte, Bln_EndFlag, Int_DqPeriod, Dbl_Jejflj, Dbl_Jedflj, Dbl_Sljflj, Dbl_Sldflj, Dbl_Wbjflj, Dbl_Wbdflj)
        End If
        
    Next Int_DqPeriod
    
    '重置网格行高
    For Jsqte = CxbbGrid.FixedRows To CxbbGrid.Rows - 1
        CxbbGrid.RowHeight(Jsqte) = Sjhgd
    Next Jsqte
    
End Sub
Private Sub Combo_AccFormat_Click()                    '用户选择不同帐页格式
    Dim Int_Coljsq As Integer         '网格列临时计数器
    
    '为了加快显示速度
    CxbbGrid.Redraw = False
    
    For Int_Coljsq = Qslz To CxbbGrid.Cols - 1
        CxbbGrid.ColHidden(Int_Coljsq) = True
    Next Int_Coljsq
    
    Select Case Combo_AccFormat
    Case "金额式"
        CxbbGrid.ColHidden(Sydz("001", GridStr(), Szzls)) = False      '月
        CxbbGrid.ColHidden(Sydz("002", GridStr(), Szzls)) = False      '日
        CxbbGrid.ColHidden(Sydz("003", GridStr(), Szzls)) = False      '凭证字号
        CxbbGrid.ColHidden(Sydz("004", GridStr(), Szzls)) = False      '摘要
        CxbbGrid.ColHidden(Sydz("005", GridStr(), Szzls)) = False      '借方.借方
        CxbbGrid.ColHidden(Sydz("009", GridStr(), Szzls)) = False      '贷方.贷方
        CxbbGrid.ColHidden(Sydz("013", GridStr(), Szzls)) = False      '方向.方向
        CxbbGrid.ColHidden(Sydz("014", GridStr(), Szzls)) = False      '余额.余额
        
    Case "外币金额式"
        CxbbGrid.ColHidden(Sydz("001", GridStr(), Szzls)) = False      '月
        CxbbGrid.ColHidden(Sydz("002", GridStr(), Szzls)) = False      '日
        CxbbGrid.ColHidden(Sydz("003", GridStr(), Szzls)) = False      '凭证字号
        CxbbGrid.ColHidden(Sydz("004", GridStr(), Szzls)) = False      '摘要
        CxbbGrid.ColHidden(Sydz("007", GridStr(), Szzls)) = False      '借方.外币
        CxbbGrid.ColHidden(Sydz("008", GridStr(), Szzls)) = False      '借方.金额
        CxbbGrid.ColHidden(Sydz("011", GridStr(), Szzls)) = False      '贷方.外币
        CxbbGrid.ColHidden(Sydz("012", GridStr(), Szzls)) = False      '贷方.金额
        CxbbGrid.ColHidden(Sydz("013", GridStr(), Szzls)) = False      '方向.方向
        CxbbGrid.ColHidden(Sydz("016", GridStr(), Szzls)) = False      '余额.外币
        CxbbGrid.ColHidden(Sydz("017", GridStr(), Szzls)) = False      '余额.金额
        
    Case "数量金额式"
        CxbbGrid.ColHidden(Sydz("001", GridStr(), Szzls)) = False      '月
        CxbbGrid.ColHidden(Sydz("002", GridStr(), Szzls)) = False      '日
        CxbbGrid.ColHidden(Sydz("003", GridStr(), Szzls)) = False      '凭证字号
        CxbbGrid.ColHidden(Sydz("004", GridStr(), Szzls)) = False      '摘要
        CxbbGrid.ColHidden(Sydz("006", GridStr(), Szzls)) = False      '借方.数量
        CxbbGrid.ColHidden(Sydz("008", GridStr(), Szzls)) = False      '借方.金额
        CxbbGrid.ColHidden(Sydz("010", GridStr(), Szzls)) = False      '贷方.数量
        CxbbGrid.ColHidden(Sydz("012", GridStr(), Szzls)) = False      '贷方.金额
        CxbbGrid.ColHidden(Sydz("013", GridStr(), Szzls)) = False      '方向.方向
        CxbbGrid.ColHidden(Sydz("015", GridStr(), Szzls)) = False      '余额.数量
        CxbbGrid.ColHidden(Sydz("017", GridStr(), Szzls)) = False      '余额.金额
        
    Case "数量外币式"
        CxbbGrid.ColHidden(Sydz("001", GridStr(), Szzls)) = False      '月
        CxbbGrid.ColHidden(Sydz("002", GridStr(), Szzls)) = False      '日
        CxbbGrid.ColHidden(Sydz("003", GridStr(), Szzls)) = False      '凭证字号
        CxbbGrid.ColHidden(Sydz("004", GridStr(), Szzls)) = False      '摘要
        CxbbGrid.ColHidden(Sydz("006", GridStr(), Szzls)) = False      '借方.数量
        CxbbGrid.ColHidden(Sydz("007", GridStr(), Szzls)) = False      '借方.外币
        CxbbGrid.ColHidden(Sydz("008", GridStr(), Szzls)) = False      '借方.金额
        CxbbGrid.ColHidden(Sydz("010", GridStr(), Szzls)) = False      '贷方.数量
        CxbbGrid.ColHidden(Sydz("011", GridStr(), Szzls)) = False      '贷方.外币
        CxbbGrid.ColHidden(Sydz("012", GridStr(), Szzls)) = False      '贷方.金额
        CxbbGrid.ColHidden(Sydz("013", GridStr(), Szzls)) = False      '方向.方向
        CxbbGrid.ColHidden(Sydz("015", GridStr(), Szzls)) = False      '余额.数量
        CxbbGrid.ColHidden(Sydz("016", GridStr(), Szzls)) = False      '余额.外币
        CxbbGrid.ColHidden(Sydz("017", GridStr(), Szzls)) = False      '余额.金额
        
    End Select
    CxbbGrid.Redraw = True
End Sub
Private Sub Sub_OutBalance(Jsqte As Long, Bln_EndFlag As Boolean, Dbl_Qcyete#, Dbl_Qcslte#, Dbl_Qcwbte#)          '输出余额
    If Dbl_Qcyete = 0 Then
        CxbbGrid.TextMatrix(Jsqte, Sydz("013", GridStr(), Szzls)) = "平"          '期初方向
        If Bln_EndFlag And Dbl_Qcslte <> 0 Then
            CxbbGrid.TextMatrix(Jsqte, Sydz("015", GridStr(), Szzls)) = Dbl_Qcslte
        End If
        If Bln_EndFlag And Dbl_Qcwbte <> 0 Then
            CxbbGrid.TextMatrix(Jsqte, Sydz("016", GridStr(), Szzls)) = Dbl_Qcwbte
        End If
    Else
        If Dbl_Qcyete > 0 Then
            CxbbGrid.TextMatrix(Jsqte, Sydz("013", GridStr(), Szzls)) = "借"
            CxbbGrid.TextMatrix(Jsqte, Sydz("014", GridStr(), Szzls)) = Dbl_Qcyete
            CxbbGrid.TextMatrix(Jsqte, Sydz("017", GridStr(), Szzls)) = Dbl_Qcyete
            If Bln_EndFlag And Dbl_Qcslte <> 0 Then
                CxbbGrid.TextMatrix(Jsqte, Sydz("015", GridStr(), Szzls)) = Dbl_Qcslte
            End If
            If Bln_EndFlag And Dbl_Qcwbte <> 0 Then
                CxbbGrid.TextMatrix(Jsqte, Sydz("016", GridStr(), Szzls)) = Dbl_Qcwbte
            End If
        Else
            CxbbGrid.TextMatrix(Jsqte, Sydz("013", GridStr(), Szzls)) = "贷"
            CxbbGrid.TextMatrix(Jsqte, Sydz("014", GridStr(), Szzls)) = -Dbl_Qcyete
            CxbbGrid.TextMatrix(Jsqte, Sydz("017", GridStr(), Szzls)) = -Dbl_Qcyete
            If Bln_EndFlag And Dbl_Qcslte <> 0 Then
                CxbbGrid.TextMatrix(Jsqte, Sydz("015", GridStr(), Szzls)) = -Dbl_Qcslte
            End If
            If Bln_EndFlag And Dbl_Qcwbte <> 0 Then
                CxbbGrid.TextMatrix(Jsqte, Sydz("016", GridStr(), Szzls)) = -Dbl_Qcwbte
            End If
        End If
    End If
End Sub
Private Sub Sub_OutPeriodSum(Jsqte As Long, Bln_EndFlag As Boolean, Int_DqPeriod%, Dbl_Jejfhj#, Dbl_Jedfhj#, Dbl_Sljfhj#, Dbl_Sldfhj#, Dbl_Wbjfhj#, Dbl_Wbdfhj#) '输出本月合计
    CxbbGrid.TextMatrix(Jsqte, Sydz("001", GridStr(), Szzls)) = Mid(Trim(Str(100 + Int_DqPeriod)), 2, 2)
    CxbbGrid.TextMatrix(Jsqte, Sydz("004", GridStr(), Szzls)) = "本月合计"
    If Dbl_Jejfhj <> 0 Then                                                        '本月借方金额合计
        CxbbGrid.TextMatrix(Jsqte, Sydz("005", GridStr(), Szzls)) = Dbl_Jejfhj
        CxbbGrid.TextMatrix(Jsqte, Sydz("008", GridStr(), Szzls)) = Dbl_Jejfhj
    End If
    If Dbl_Jedfhj <> 0 Then                                                        '本月贷方金额合计
        CxbbGrid.TextMatrix(Jsqte, Sydz("009", GridStr(), Szzls)) = Dbl_Jedfhj
        CxbbGrid.TextMatrix(Jsqte, Sydz("012", GridStr(), Szzls)) = Dbl_Jedfhj
    End If
    
    '只有末级科目才显示数量和外币
    If Bln_EndFlag Then
        If Dbl_Sljfhj <> 0 Then                                                     '本月借方数量合计
            CxbbGrid.TextMatrix(Jsqte, Sydz("006", GridStr(), Szzls)) = Dbl_Sljfhj
        End If
        If Dbl_Sldfhj <> 0 Then                                                     '本月贷方数量合计
            CxbbGrid.TextMatrix(Jsqte, Sydz("010", GridStr(), Szzls)) = Dbl_Sldfhj
        End If
        If Dbl_Wbjfhj <> 0 Then                                                     '本月借方外币合计
            CxbbGrid.TextMatrix(Jsqte, Sydz("007", GridStr(), Szzls)) = Dbl_Wbjfhj
        End If
        If Dbl_Wbdfhj <> 0 Then                                                     '本月贷方外币合计
            CxbbGrid.TextMatrix(Jsqte, Sydz("011", GridStr(), Szzls)) = Dbl_Wbdfhj
        End If
    End If
End Sub
Private Sub Sub_OutYearSum(Jsqte As Long, Bln_EndFlag As Boolean, Int_DqPeriod%, Dbl_Jejflj#, Dbl_Jedflj#, Dbl_Sljflj#, Dbl_Sldflj#, Dbl_Wbjflj#, Dbl_Wbdflj#) '输出本年累计
    CxbbGrid.TextMatrix(Jsqte, Sydz("001", GridStr(), Szzls)) = Mid(Trim(Str(100 + Int_DqPeriod)), 2, 2)
    CxbbGrid.TextMatrix(Jsqte, Sydz("004", GridStr(), Szzls)) = "本年累计"
    If Dbl_Jejflj <> 0 Then                                                        '本年借方金额累计
        CxbbGrid.TextMatrix(Jsqte, Sydz("005", GridStr(), Szzls)) = Dbl_Jejflj
        CxbbGrid.TextMatrix(Jsqte, Sydz("008", GridStr(), Szzls)) = Dbl_Jejflj
    End If
    If Dbl_Jedflj <> 0 Then                                                        '本年贷方金额累计
        CxbbGrid.TextMatrix(Jsqte, Sydz("009", GridStr(), Szzls)) = Dbl_Jedflj
        CxbbGrid.TextMatrix(Jsqte, Sydz("012", GridStr(), Szzls)) = Dbl_Jedflj
    End If
    
    '只有末级科目才显示数量和外币
    If Bln_EndFlag Then
        If Dbl_Sljflj <> 0 Then                                                     '本年借方数量累计
            CxbbGrid.TextMatrix(Jsqte, Sydz("006", GridStr(), Szzls)) = Dbl_Sljflj
        End If
        If Dbl_Sldflj <> 0 Then                                                     '本年贷方数量累计
            CxbbGrid.TextMatrix(Jsqte, Sydz("010", GridStr(), Szzls)) = Dbl_Sldflj
        End If
        If Dbl_Wbjflj <> 0 Then                                                     '本年借方外币累计
            CxbbGrid.TextMatrix(Jsqte, Sydz("007", GridStr(), Szzls)) = Dbl_Wbjflj
        End If
        If Dbl_Wbdflj <> 0 Then                                                     '本年贷方外币累计
            CxbbGrid.TextMatrix(Jsqte, Sydz("011", GridStr(), Szzls)) = Dbl_Wbdflj
        End If
    End If
End Sub
Private Sub Sub_Lcmxz()                                '联查科目明细帐
    Dim Str_Ccode As String          '查询科目
    
    '如果科目为空或用户定位网格月份为空则不进行查询
    If Trim(Combo_QueryCcode.Text) <> "" And Trim(CxbbGrid.TextMatrix(CxbbGrid.Row, Sydz("001", GridStr(), Szzls))) <> "" Then
        Str_Ccode = Trim(Mid(Combo_QueryCcode.Text, 1, InStr(1, Combo_QueryCcode.Text, " ") - 1))
    Else
        Exit Sub
    End If
    '联查明细帐
    If Trim(Str_Ccode) <> "" Then
        ZB_Frmkmmxztj.Combo_Kjqj(0).Text = Mid(Trim(Str(10000 + Xtyear)), 2, 4) + "." + Trim(CxbbGrid.TextMatrix(CxbbGrid.Row, Sydz("001", GridStr(), Szzls)))   '起始会计期间
        ZB_Frmkmmxztj.Combo_Kjqj(1).Text = Mid(Trim(Str(10000 + Xtyear)), 2, 4) + "." + Trim(CxbbGrid.TextMatrix(CxbbGrid.Row, Sydz("001", GridStr(), Szzls)))   '终止会计期间
        ZB_Frmkmmxztj.LrText(0).Text = Str_Ccode                                                                                                                 '查询科目
        ZB_Frmkmmxztj.LrText(1).Text = Str_Ccode                                                                                                                 '查询科目
        ZB_Frmkmmxztj.Chk_NotBook.Value = ZB_Frmzflztj.Chk_NotBook.Value      '是否包含未记帐凭证
        ZB_Frmkmmxzjg.Timer1.Enabled = True                                   '激活查询明细帐过程
        ZB_Frmkmmxzjg.Show
        ZB_Frmkmmxzjg.SetFocus
    End If
End Sub
Private Sub bbyl(bbylte As Boolean)                    '报表打印预览
    Dim Bbzbt$, Bbxbt() As String, bbxbtzzxs() As Integer, Bbxbtgs As Integer
    Dim Bbbwh() As String, Bbbwhzzxs() As Integer, Bbbwhgs As Integer
    Bbxbtgs = 1                                          '报 表 小 标 题 行 数
    Bbbwhgs = 0                                          '报 表 表 尾 行 数
    ReDim Bbxbt(1 To Bbxbtgs)
    ReDim bbxbtzzxs(1 To Bbxbtgs)
    If Bbbwhgs <> 0 Then
        ReDim Bbbwh(1 To Bbbwhgs)
        ReDim Bbbwhzzxs(1 To Bbbwhgs)
    End If
    Bbzbt = ReportTitle
    Bbxbt(1) = Space(2) + "科目名称：" + Me.Combo_QueryCcode.Text
    bbxbtzzxs(1) = 0                                    '报表行组织形式(0-居左 1-居中 2-居右)
    Call Scyxsjb(CxbbGrid)                               '生成报表数据
    Call Scdybb(Dyymctbl, Bbzbt, Bbxbt(), bbxbtzzxs(), Bbxbtgs, Bbbwh(), Bbbwhzzxs(), Bbbwhgs, bbylte)
    If Not bbylte Then
        Unload DY_Tybbyldy
    End If
End Sub
Private Sub Sub_Lxdy()                                 '帐页连续打印(帐页每批尽量少选)
    Dim Bbzbt$, Bbxbt() As String, bbxbtzzxs() As Integer, Bbxbtgs As Integer
    Dim Bbbwh() As String, Bbbwhzzxs() As Integer, Bbbwhgs As Integer
    Dim Jsqte As Integer
    Dim YAnswer As Integer
    
    '用户确认是否开始连续打印帐页
    Tsxx = "请确认是否开始连续打印帐页？"
    YAnswer = Xtxxts(Tsxx, 2, 2)
    If YAnswer <> 1 Then
        Exit Sub
    End If
    
    '初始化连续打印状态
    Cmd_CancelPrint.Visible = True
    Cmd_CancelPrint.SetFocus
    Cmd_CancelPrint.Refresh
    Bln_CancelPrint = False
    Bln_Printing = True
    
    '循环输出打印作业
    For Jsqte = 0 To Combo_QueryCcode.ListCount - 1
        Combo_QueryCcode.Text = Combo_QueryCcode.List(Jsqte)
        Bbxbtgs = 1                                          '报 表 小 标 题 行 数
        Bbbwhgs = 0                                          '报 表 表 尾 行 数
        ReDim Bbxbt(1 To Bbxbtgs)
        ReDim bbxbtzzxs(1 To Bbxbtgs)
        If Bbbwhgs <> 0 Then
            ReDim Bbbwh(1 To Bbbwhgs)
            ReDim Bbbwhzzxs(1 To Bbbwhgs)
        End If
        Bbzbt = ReportTitle
        Bbxbt(1) = Space(2) + "科目名称：" + Me.Combo_QueryCcode.Text
        bbxbtzzxs(1) = 1                                     '报表行组织形式(0-居左 1-居中 2-居右)
        Call Scyxsjb(CxbbGrid)                               '生成报表数据
        Call Scdybb(Dyymctbl, Bbzbt, Bbxbt(), bbxbtzzxs(), Bbxbtgs, Bbbwh(), Bbbwhzzxs(), Bbbwhgs, False, True)
        Unload DY_Tybbyldy
        DoEvents
        If Bln_CancelPrint Then
            Bln_Printing = False
            Exit Sub
        End If
    Next Jsqte
    Bln_Printing = False
End Sub
Private Sub Cmd_CancelPrint_Click()                    '取消帐页连续打印
    Bln_CancelPrint = True
    Cmd_CancelPrint.Visible = False
End Sub

						