企业管理

开发平台：
Visual Basic

i-：源码内容
							VERSION 5.00
Object = "{D76D7128-4A96-11D3-BD95-D296DC2DD072}#1.0#0"; "VSOCX7.OCX"
Begin VB.Form ZB_Frmzflztj 
   BorderStyle     =   1  'Fixed Single
   Caption         =   "总分类帐查询"
   ClientHeight    =   2205
   ClientLeft      =   45
   ClientTop       =   330
   ClientWidth     =   4665
   Icon            =   "帐簿_总分类帐查询条件.frx":0000
   KeyPreview      =   -1  'True
   LinkTopic       =   "Form2"
   MaxButton       =   0   'False
   MinButton       =   0   'False
   ScaleHeight     =   2205
   ScaleWidth      =   4665
   StartUpPosition =   2  '屏幕中心
   Begin VB.Frame Fra_MyReport 
      Height          =   2145
      Left            =   4710
      TabIndex        =   14
      Top             =   0
      Width           =   3195
      Begin VB.CommandButton Cmd_Save 
         Caption         =   "保存(&S)"
         Height          =   300
         Left            =   750
         TabIndex        =   16
         Top             =   1770
         Width           =   1120
      End
      Begin VB.CommandButton Cmd_Delete 
         Caption         =   "删除(&D)"
         Height          =   300
         Left            =   1980
         TabIndex        =   15
         Top             =   1770
         Width           =   1120
      End
      Begin VSFlex8Ctl.VSFlexGrid vsFlx_MyReport 
         Height          =   1515
         Left            =   60
         TabIndex        =   17
         Top             =   180
         Width           =   3075
         _ExtentX        =   5424
         _ExtentY        =   2672
         Appearance      =   1
         BorderStyle     =   1
         Enabled         =   -1  'True
         BeginProperty Font {0BE35203-8F91-11CE-9DE3-00AA004BB851} 
            Name            =   "宋体"
            Size            =   9
            Charset         =   134
            Weight          =   400
            Underline       =   0   'False
            Italic          =   0   'False
            Strikethrough   =   0   'False
         EndProperty
         MousePointer    =   0
         BackColor       =   -2147483643
         ForeColor       =   -2147483640
         BackColorFixed  =   -2147483633
         ForeColorFixed  =   -2147483630
         BackColorSel    =   -2147483635
         ForeColorSel    =   -2147483634
         BackColorBkg    =   -2147483636
         BackColorAlternate=   -2147483643
         GridColor       =   -2147483633
         GridColorFixed  =   -2147483632
         TreeColor       =   -2147483632
         FloodColor      =   192
         SheetBorder     =   -2147483642
         FocusRect       =   1
         HighLight       =   1
         AllowSelection  =   -1  'True
         AllowBigSelection=   -1  'True
         AllowUserResizing=   0
         SelectionMode   =   0
         GridLines       =   1
         GridLinesFixed  =   2
         GridLineWidth   =   1
         Rows            =   50
         Cols            =   10
         FixedRows       =   1
         FixedCols       =   1
         RowHeightMin    =   0
         RowHeightMax    =   0
         ColWidthMin     =   0
         ColWidthMax     =   0
         ExtendLastCol   =   0   'False
         FormatString    =   ""
         ScrollTrack     =   0   'False
         ScrollBars      =   3
         ScrollTips      =   0   'False
         MergeCells      =   0
         MergeCompare    =   0
         AutoResize      =   -1  'True
         AutoSizeMode    =   0
         AutoSearch      =   0
         MultiTotals     =   -1  'True
         SubtotalPosition=   1
         OutlineBar      =   0
         OutlineCol      =   0
         Ellipsis        =   0
         ExplorerBar     =   0
         PicturesOver    =   0   'False
         FillStyle       =   0
         RightToLeft     =   0   'False
         PictureType     =   0
         TabBehavior     =   0
         OwnerDraw       =   0
         Editable        =   0   'False
         ShowComboButton =   -1  'True
         WordWrap        =   0   'False
         TextStyle       =   0
         TextStyleFixed  =   0
         OleDragMode     =   0
         OleDropMode     =   0
         DataMode        =   0
         VirtualData     =   -1  'True
      End
   End
   Begin VB.CommandButton QdCommand 
      Caption         =   "确定(&O)"
      Height          =   300
      Left            =   1080
      TabIndex        =   6
      Top             =   1800
      Width           =   1120
   End
   Begin VB.CommandButton QxCommand 
      Caption         =   "取消(&C)"
      Height          =   300
      Left            =   2280
      TabIndex        =   7
      Top             =   1800
      Width           =   1120
   End
   Begin VB.CommandButton Cmd_MyReport 
      Caption         =   "我的报表>>"
      Height          =   300
      Left            =   3480
      TabIndex        =   8
      Top             =   1800
      Width           =   1120
   End
   Begin VB.CheckBox UnloadCheck 
      Caption         =   "卸载窗体"
      Height          =   615
      Left            =   8250
      TabIndex        =   11
      Top             =   720
      Visible         =   0   'False
      Width           =   825
   End
   Begin VB.Frame Fra_Query 
      ForeColor       =   &H00FF0000&
      Height          =   1665
      Left            =   60
      TabIndex        =   9
      Top             =   30
      Width           =   4545
      Begin VB.TextBox LrText 
         Height          =   300
         Index           =   2
         Left            =   1020
         TabIndex        =   2
         Text            =   "2"
         Top             =   570
         Width           =   1545
      End
      Begin VB.TextBox LrText 
         Height          =   300
         Index           =   3
         Left            =   2850
         TabIndex        =   3
         Text            =   "3"
         Top             =   570
         Width           =   1545
      End
      Begin VB.CheckBox Chk_EndFlag 
         Caption         =   "仅显示明细科目"
         BeginProperty DataFormat 
            Type            =   4
            Format          =   "yyyy-MM-dd"
            HaveTrueFalseNull=   0
            FirstDayOfWeek  =   0
            FirstWeekOfYear =   0
            LCID            =   2052
            SubFormatType   =   8
         EndProperty
         Height          =   225
         Left            =   180
         TabIndex        =   4
         Top             =   990
         Width           =   2445
      End
      Begin VB.CommandButton Ydcommand1 
         Height          =   300
         Index           =   1
         Left            =   4080
         Picture         =   "帐簿_总分类帐查询条件.frx":1042
         Style           =   1  'Graphical
         TabIndex        =   13
         Top             =   210
         Visible         =   0   'False
         Width           =   300
      End
      Begin VB.CommandButton Ydcommand1 
         Height          =   300
         Index           =   0
         Left            =   2250
         Picture         =   "帐簿_总分类帐查询条件.frx":13CC
         Style           =   1  'Graphical
         TabIndex        =   12
         Top             =   210
         Visible         =   0   'False
         Width           =   300
      End
      Begin VB.CheckBox Chk_NotBook 
         Caption         =   "是否包含未记帐凭证"
         Height          =   285
         Left            =   180
         TabIndex        =   5
         Top             =   1260
         Width           =   2145
      End
      Begin VB.TextBox LrText 
         Height          =   300
         Index           =   0
         Left            =   1020
         TabIndex        =   0
         Text            =   "0"
         Top             =   210
         Width           =   1245
      End
      Begin VB.TextBox LrText 
         Height          =   300
         Index           =   1
         Left            =   2850
         TabIndex        =   1
         Text            =   "1"
         Top             =   210
         Width           =   1245
      End
      Begin VB.Label Label1 
         AutoSize        =   -1  'True
         Caption         =   "科目级次:"
         Height          =   180
         Index           =   3
         Left            =   180
         TabIndex        =   18
         Top             =   630
         Width           =   810
      End
      Begin VB.Line Line1 
         Index           =   2
         X1              =   2580
         X2              =   2820
         Y1              =   720
         Y2              =   720
      End
      Begin VB.Image Image1 
         Height          =   480
         Left            =   2880
         Picture         =   "帐簿_总分类帐查询条件.frx":1756
         Top             =   1020
         Width           =   480
      End
      Begin VB.Line Line1 
         Index           =   0
         X1              =   2580
         X2              =   2820
         Y1              =   360
         Y2              =   360
      End
      Begin VB.Label Label1 
         AutoSize        =   -1  'True
         Caption         =   "科目范围:"
         Height          =   180
         Index           =   0
         Left            =   180
         TabIndex        =   10
         Top             =   270
         Width           =   810
      End
   End
End
Attribute VB_Name = "ZB_Frmzflztj"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
'****************************************************************
'*    模 块 名 称 :总分类帐查询条件
'*    功 能 描 述 :
'*    程序员姓名  :张建忠
'*    最后修改人  : 奚俊峰
'*    最后修改时间:2001/12/30
'*    备        注:程序中所有依实际情况自定义部分均用[>>  <<]括起
'****************************************************************
Dim Dbl_DefaultWidth As Double           '条件窗体默认宽度
'以下为固定使用变量(网格)
Dim Cxnrrec As New ADODB.Recordset       '显示查询内容动态集
Dim Dyymctbl As New DY_Dyymsz            '打印页面窗体变量
Dim GridCode As String                   '显示网格网格代码
Dim GridInf() As Variant                 '整个网格设置信息
Dim Tsxx As String                       '系统提示信息
Dim Qslz As Long                         '网格隐藏(非操作显示)列数
Dim Sjhgd As Double                      '网格数据行高度
Dim GridBoolean() As Boolean             '网格列信息(布尔型)
Dim GridStr()  As String                 '网格列信息(字符型)
Dim GridInt() As Integer                 '网格列信息(整型)
Dim Szzls As Integer                     '数组总列数(网格列数-1)
Dim Lng_Dqwgh As Long                    '系统当前刚刚离开网格行
'以下为固定使用变量(文本框)
Dim Textvar() As Variant                 '存储变体型文本框信息
Dim Textboolean() As Boolean             '存储布尔型文本框信息
Dim Textint() As Integer                 '存储整型文本框信息
Dim Textstr() As String                  '存储字符型文本框信息
Dim Max_Text_Index As Integer            '最大录入文本框索引值
Dim TextGroupCode As String              '文本框录入分组编码
Dim TextValiLock As Boolean              '文本框失去焦点是否进行有效性控制判断
Dim TextValiJudgeLock() As Boolean       '文本框录入有效性判断控制锁
Dim CurTextIndex As Integer              '当前文本框索引值
Dim TextChangeLock As Boolean            '文本框内容变换控制锁
Dim Bln_Cancel As Boolean                '取消按钮信息传递
Private Sub Cmd_MyReport_Click()         '用户点击我的报表按钮
    If Fra_MyReport.Visible Then
        Fra_MyReport.Visible = False
        Me.Width = Dbl_DefaultWidth
    Else
        Fra_MyReport.Visible = True
        Me.Width = Fra_MyReport.Left + Fra_MyReport.Width + 100
    End If
    
    '条件窗体居于屏幕中心
    Me.Move (Screen.Width - Me.Width) / 2
    
End Sub
Private Sub Form_KeyPress(KeyAscii As Integer)   '控 制 焦 点 转 移
    Dim jdzygs As Integer                         '控件焦点转移个数
    jdzygs = 30
    Select Case KeyAscii
    Case vbKeyReturn
        If Kjjdzy(jdzygs) Then
            KeyAscii = 0
        End If
    Case 39           '屏蔽"'"
        KeyAscii = 0
    End Select
End Sub
Private Sub Form_Load()
    
    '以下为文本框处理程序
    
    TextGroupCode = "Cwzz_zflz"
    Call Drwbkxx(TextGroupCode, Textvar(), Textboolean(), Textint(), Textstr())  '读入文本框录入信息
    Call Wbkcsh
    
    '保存条件窗体默认宽度,隐藏我的报表栏
    Dbl_DefaultWidth = Me.Width
    Fra_MyReport.Visible = False
    
    '调 入 网 格
    GridCode = "Cwzz_myreport"
    Call BzWgcsh(vsFlx_MyReport, GridCode, GridInf(), GridBoolean(), GridInt(), GridStr())
    
    Qslz = GridInf(1)
    Sjhgd = GridInf(2)
    Szzls = vsFlx_MyReport.Cols - 1
    
    '填 充 网 格
    Call Cxnrtcwg
    
    '[>>科目级次范围默认为1-1
    LrText(2).Text = 1
    LrText(3).Text = 1
    '[<<完毕
    
End Sub
Private Sub Cxnrtcwg()                               '查 询 内 容 填 充 网 格
    Dim Sqlstr As String
    Dim Jsqte As Long
    
    vsFlx_MyReport.Redraw = False
    
    '查询连接串
    Sqlstr = "SELECT Distinct QueryName FROM Cwzz_MyReport Where Czybm='" & Xtczybm & "' And QueryCode='" & TextGroupCode & "'"
    Set Cxnrrec = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
    With Cxnrrec
        vsFlx_MyReport.Clear 1
        vsFlx_MyReport.Rows = .RecordCount + vsFlx_MyReport.FixedRows
        If .EOF And .BOF Then
            vsFlx_MyReport.Redraw = True
            Exit Sub
        End If
        Jsqte = vsFlx_MyReport.FixedRows
        Do While Not .EOF
            If Jsqte >= vsFlx_MyReport.Rows Then
                vsFlx_MyReport.AddItem ""
            End If
            
            vsFlx_MyReport.TextMatrix(Jsqte, Sydz("001", GridStr(), Szzls)) = Trim(.Fields("QueryName"))
            
            vsFlx_MyReport.RowHeight(Jsqte) = Sjhgd
            .MoveNext
            Jsqte = Jsqte + 1
        Loop
    End With
    
    vsFlx_MyReport.Redraw = True
End Sub
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
    If UnloadCheck.Value <> 1 Then
        Cancel = 1
        Me.Hide
    End If
End Sub
Private Sub QdCommand_Click()                                   '确 定
    '录入条件有效性判断
    If Not Lrtjyxxpd Then
        Exit Sub
    End If
    Me.Hide
    
    '激活查询过程
    ZB_Frmzflzjg.Timer1.Enabled = True
    
End Sub
Private Sub QxCommand_Click()                                    '取消
    Me.Hide
End Sub
Private Function Lrtjyxxpd() As Boolean                          '用户录入条件有效性判断
    Dim Jsqte As Integer
    Lrtjyxxpd = False
    
    '对需要进行事后判断的文本框录入内容进行有效性判断 (固定不变)
    For Jsqte = 0 To Max_Text_Index
        If Textint(Jsqte, 9) = 0 Or Textint(Jsqte, 9) = 2 Then
            If Not TextYxxpd(Jsqte) Then
                Exit Function
            End If
        End If
    Next Jsqte
    
    '[>>以下为依据实际情况自定义部分
    
    '查询科目号范围应由小到大
    If Trim(LrText(0).Text) > Trim(LrText(1).Text) And Trim(LrText(1).Text) <> "" Then
        Tsxx = "查询科目范围应由小到大!"
        Call Xtxxts(Tsxx, 0, 4)
        LrText(0).SetFocus
        Exit Function
    End If
    
    '查询科目级次应为1-6,且级次范围应由小到大
    If Not (Val(LrText(2).Text) >= 1 And Val(LrText(2).Text) <= 6) Then
        Tsxx = "查询科目级次应在1-6之间!"
        Call Xtxxts(Tsxx, 0, 4)
        LrText(2).SetFocus
        Exit Function
    End If
    
    If Not (Val(LrText(3).Text) >= 1 And Val(LrText(3).Text) <= 6) Then
        Tsxx = "查询科目级次应在1-6之间!"
        Call Xtxxts(Tsxx, 0, 4)
        LrText(3).SetFocus
        Exit Function
    End If
    
    If Val(LrText(2).Text) > Val(LrText(3).Text) Then
        Tsxx = "查询科目级次范围应由小到大!"
        Call Xtxxts(Tsxx, 0, 4)
        LrText(2).SetFocus
        Exit Function
    End If
    
    '<<]以上为依据实际情况自定义部分
    
    Lrtjyxxpd = True
End Function
Private Sub vsFlx_MyReport_Click()                                          '显示用户点击查询报表
    Dim Sqlstr As String
    Dim Rec_MyReport As New ADODB.Recordset     '我的报表动态集
    Dim Jsqte As Integer                        '临时动态计数器
    
    If vsFlx_MyReport.Row < vsFlx_MyReport.FixedRows Then
        Exit Sub
    End If
    
    '查询连接串
    Sqlstr = "SELECT Value FROM Cwzz_MyReport Where Czybm='" & Xtczybm & "' And QueryCode='" & TextGroupCode & "' And QueryName='" & Trim(vsFlx_MyReport.TextMatrix(vsFlx_MyReport.Row, Sydz("001", GridStr(), Szzls))) & "' Order By I_ID"
    Set Rec_MyReport = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
    
    Jsqte = 1
    
    On Error Resume Next
    
    With Rec_MyReport
        Do While Not .EOF
            Select Case Jsqte
            Case 1           '起始科目编码
                LrText(0).Text = Trim(.Fields("Value"))
            Case 2           '终止科目编码
                LrText(1).Text = Trim(.Fields("Value"))
            Case 3           '起始科目级次
                LrText(2).Text = Trim(.Fields("Value"))
            Case 4           '终止科目级次
                LrText(3).Text = Trim(.Fields("Value"))
            Case 5           '仅限于明细科目
                Chk_EndFlag.Value = Int(.Fields("Value"))
            Case 6           '是否包含未记帐凭证
                Chk_NotBook.Value = Int(.Fields("Value"))
            End Select
            Jsqte = Jsqte + 1
            .MoveNext
        Loop
    End With
End Sub
Private Sub Cmd_Delete_Click()                                              '删除当前报表查询条件
    Dim Yhanswer As Integer
    If vsFlx_MyReport.Row < vsFlx_MyReport.FixedRows Then
        Exit Sub
    End If
    Tsxx = "请确认是否删除当前记录?"
    Yhanswer = Xtxxts(Tsxx, 2, 2)
    If Yhanswer = 2 Then
        Exit Sub
    End If
    
    '[以下需自定义部分
    Cw_DataEnvi.DataConnect.Execute ("Delete FROM Cwzz_MyReport Where Czybm='" & Xtczybm & "' And QueryCode='" & TextGroupCode & "' And QueryName='" & Trim(vsFlx_MyReport.TextMatrix(vsFlx_MyReport.Row, Sydz("001", GridStr(), Szzls))) & "'")
    '以上为自定义部分]
    
    vsFlx_MyReport.RemoveItem vsFlx_MyReport.Row
    
End Sub
Private Sub Cmd_Save_Click()   '保存报表查询条件
    Dim tCode As String
    Dim tReturn As String
    
    tCode = Trim(vsFlx_MyReport.TextMatrix(vsFlx_MyReport.Row, Sydz("001", GridStr(), Szzls)))
    
    tReturn = InputBox("请输入我的报表名称:", "报表名称", tCode)
    If Trim(tReturn) = "" Then Exit Sub
    
    SaveReport tReturn
End Sub
'************以下为文本框录入处理程序(固定不变部分)*************'
Private Sub Wbklrwbcl(Index As Integer)    '文本框录入事后处理程序
    
    '以下为依据实际情况自定义部分[
    
    '在此填写文本框录入事后处理程序
    
    ']以上为依据实际情况自定义部分
End Sub
Private Sub LrText_Change(Index As Integer)
    
    '屏蔽程序改变控制
    If TextChangeLock Then
        Exit Sub
    End If
    
    TextValiJudgeLock(Index) = False    '打开有效性判断锁
    
    '限制字段录入长度
    
    TextChangeLock = True  '加锁(防止执行Lrtext_Change)
    Select Case Textint(Index, 1)
    Case 8           '金额型
        Call Sjgskz(LrText(Index), Xtjezws - Xtjexsws - 1, Xtjexsws)
    Case 9           '数量型
        Call Sjgskz(LrText(Index), Xtslzws - Xtslxsws - 1, Xtslxsws)
    Case 10          '单价型
        Call Sjgskz(LrText(Index), Xtdjzws - Xtdjxsws - 1, Xtdjxsws)
    Case Else        '其他小数类型控制
        If Textint(Index, 6) <> 0 Or Textint(Index, 7) <> 0 Then
            Call Sjgskz(LrText(Index), Textint(Index, 6), Textint(Index, 7))
        End If
    End Select
    TextChangeLock = False '解锁
End Sub
Private Sub LrText_GotFocus(Index As Integer)                                                 '文本框得到焦点,显示相应信息
    Call TextShow(Index)
    CurTextIndex = Index
    LrText(Index).SelStart = Len(LrText(Index))
End Sub
Private Sub LrText_KeyDown(Index As Integer, KeyCode As Integer, Shift As Integer)            '字段按F2键提供帮助
    Select Case KeyCode
    Case vbKeyF2
        Call Text_Help(Index)
    End Select
End Sub
Private Sub LrText_KeyPress(Index As Integer, KeyAscii As Integer)                            '文本框录入事中控制
    Call InputFieldLimit(LrText(Index), Textint(Index, 1), KeyAscii)
End Sub
Private Sub LrText_LostFocus(Index As Integer)                                                '文本框失去焦点进行有效性判断及相应处理
    If Textint(Index, 9) = 0 Or Textint(Index, 9) = 1 Then '事中判断
        Call TextYxxpd(Index)
    End If
End Sub
Private Sub Ydcommand1_MouseDown(Index As Integer, Button As Integer, Shift As Integer, X As Single, Y As Single)     '按钮提供帮助
    Call Text_Help(Index)
End Sub
Private Sub Text_Help(Index As Integer)                                                       '录入字段帮助
    If Not Textboolean(Index, 1) Then
        Exit Sub
    End If
    TextValiJudgeLock(Index) = True
    
    '先进行有效性判断
    If Not TextYxxpd(CurTextIndex) Then
        Exit Sub
    End If
    
    Call Drbmhelp(Textint(Index, 2), Textstr(Index, 4), Trim(LrText(Index).Text))
    
    If Len(Xtfhcs) <> 0 Then
        If Textint(Index, 3) = 1 Then
            LrText(Index).Text = Xtfhcsfz
            LrText(Index).Tag = Xtfhcs
        Else
            LrText(Index).Text = Xtfhcs
            LrText(Index).Tag = Xtfhcsfz
        End If
        
    End If
    TextValiJudgeLock(Index) = False
    LrText(Index).SetFocus
End Sub
Private Sub TextShow(Index As Integer)        '文本框得到焦点,显示相应信息
    
    '填写文本框得到焦点,进行相应信息处理程序
    
End Sub
Private Sub Wbkcsh()                          '录入文本框初始化
    Dim Jsqte As Integer
    
    '最大录入文本框索引值
    Max_Text_Index = Textvar(1)
    
    ReDim TextValiJudgeLock(Max_Text_Index)
    For Jsqte = 0 To Max_Text_Index
        
        If Len(Trim(Textstr(Jsqte, 1))) <> 0 Then
            If Textboolean(Jsqte, 1) Then
                If Jsqte <> 0 And Not Textboolean(Jsqte, 3) Then
                    Load Ydcommand1(Jsqte)
                End If
                Ydcommand1(Jsqte).Visible = True
                Ydcommand1(Jsqte).Move LrText(Jsqte).Left + LrText(Jsqte).Width, LrText(Jsqte).Top
            End If
            TextChangeLock = True
            LrText(Jsqte).Text = ""
            LrText(Jsqte).Tag = ""
            If Textint(Jsqte, 5) <> 0 Then
                LrText(Jsqte).MaxLength = Textint(Jsqte, 5)
            End If
            
            TextChangeLock = False
        End If
        TextValiJudgeLock(Jsqte) = True
    Next Jsqte
End Sub
Private Function TextYxxpd(Index As Integer) As Boolean           '文本框有效性判断
    Dim Sqlstr As String
    Dim Findrec As ADODB.Recordset
    If TextValiJudgeLock(Index) Then    '文本框内容未曾改变不进行有效性判断
        TextYxxpd = True
        Exit Function
    End If
    If Trim(LrText(Index)) = "" Then
        LrText(Index).Tag = ""
        Call Wbklrwbcl(Index)
        TextValiJudgeLock(Index) = True
        TextYxxpd = True
        Exit Function
    End If
    Select Case Textint(Index, 4)
    Case 1      '编码型
        Sqlstr = Trim(Textstr(Index, 5))
        Sqlstr = Replace(Sqlstr, "@", "'" + Trim(LrText(Index).Text) + "'")
        Set Findrec = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
        If Findrec.EOF Then
            Call Xtxxts(Trim(Textstr(Index, 6)), 0, 1)
            LrText(Index).SetFocus
            Exit Function
        Else
            Select Case Textint(Index, 3)
            Case 0
                If Len(Trim(Textstr(Index, 2))) <> 0 Then
                    LrText(Index).Text = Trim(Findrec.Fields(Trim(Textstr(Index, 2))))
                End If
                If Len(Trim(Textstr(Index, 3) & "")) <> 0 Then
                    LrText(Index).Tag = Trim(Findrec.Fields(Trim(Textstr(Index, 3))))
                End If
            Case 1
                If Len(Trim(Textstr(Index, 3) & "")) <> 0 Then
                    LrText(Index).Text = Trim(Findrec.Fields(Trim(Textstr(Index, 3))))
                End If
                If Len(Trim(Textstr(Index, 2))) <> 0 Then
                    LrText(Index).Tag = Trim(Findrec.Fields(Trim(Textstr(Index, 2))))
                End If
            End Select
        End If
    Case 2      '日期型
        If IsDate(LrText(Index).Text) Then
            LrText(Index).Text = Format(LrText(Index).Text, "yyyy-mm-dd")
        Else
            Tsxx = "非法公历日期!(格式:" + Format(Date, "yyyy-mm-dd") + ")"
            Call Xtxxts(Tsxx, 0, 1)
            LrText(Index).SetFocus
            Exit Function
        End If
    Case 3      '其他类型
        
    End Select
    TextValiJudgeLock(Index) = True
    TextYxxpd = True
End Function
Private Sub SaveReport(sReport As String)
    Dim Rec_MyReport As New ADODB.Recordset     '我的报表动态集
    Dim Yhanswer As Integer
    Dim Jsqte As Integer                        '临时动态计数器
    Dim Sqlstr As String
    
    Yhanswer = 0
    
    '查询连接串
    Sqlstr = "SELECT Distinct QueryName FROM Cwzz_MyReport Where Czybm='" & Xtczybm & "' And QueryCode='" & TextGroupCode & "' And QueryName='" & Trim(sReport) & "'"
    Set Rec_MyReport = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
    With Rec_MyReport
        If Not .EOF Then
            Tsxx = "已有此报表名称,是否覆盖?"
            Yhanswer = Xtxxts(Tsxx, 2, 2)
            If Yhanswer <> 1 Then
                Exit Sub
            End If
        End If
        
        On Error GoTo Swcwcl
        Cw_DataEnvi.DataConnect.BeginTrans
        
        If Yhanswer = 1 Then
            Sqlstr = "Delete FROM Cwzz_MyReport Where Czybm='" & Xtczybm & "' And QueryCode='" & TextGroupCode & "' And QueryName='" & Trim(sReport) & "'"
            Cw_DataEnvi.DataConnect.Execute (Sqlstr)
        End If
        If .State = 1 Then .Close
        .Open "Select * From Cwzz_MyReport Where 1=2", Cw_DataEnvi.DataConnect, adOpenDynamic, adLockOptimistic
        
        For Jsqte = 1 To 6
            .AddNew
            .Fields("Czybm") = Xtczybm
            .Fields("QueryCode") = TextGroupCode
            .Fields("QueryName") = sReport
            
            Select Case Jsqte
            Case 1           '起始会计期间
                .Fields("Value") = Trim(LrText(0).Text)
            Case 2           '终止会计期间
                .Fields("Value") = Trim(LrText(1).Text)
            Case 3           '科目类型
                .Fields("Value") = Trim(LrText(2).Text)
            Case 4
                .Fields("Value") = Trim(LrText(3).Text)
            Case 5
                .Fields("Value") = Trim(Chk_EndFlag.Value)
            Case 6           '是否包含未记帐凭证
                .Fields("Value") = Trim(Chk_NotBook.Value)
            End Select
            
            .Update
        Next Jsqte
    End With
    
    Cw_DataEnvi.DataConnect.CommitTrans
    
    '在网格中添加报表名称(非覆盖)
    If Yhanswer <> 1 Then
        With vsFlx_MyReport
            .AddItem ""
            .TextMatrix(.Rows - 1, 0) = Trim(sReport)
        End With
    End If
    
    Tsxx = "报表查询条件保存完毕!"
    Call Xtxxts(Tsxx, 0, 4)
    Exit Sub
    
Swcwcl:
    Cw_DataEnvi.DataConnect.RollbackTrans
    Tsxx = "存盘过程中出现未知错误,程序自动恢复保存前状态!"
    Call Xtxxts(Tsxx, 0, 1)
    Exit Sub
End Sub

						