企业管理

开发平台：
Visual Basic

：源码内容
							VERSION 5.00
Object = "{D76D7128-4A96-11D3-BD95-D296DC2DD072}#1.0#0"; "VSOCX7.OCX"
Begin VB.Form CL_EndCheckOut 
   BorderStyle     =   1  'Fixed Single
   Caption         =   "期末结帐"
   ClientHeight    =   4800
   ClientLeft      =   45
   ClientTop       =   330
   ClientWidth     =   5325
   HelpContextID   =   130408
   Icon            =   "处理_期末结帐.frx":0000
   LinkTopic       =   "Form1"
   MaxButton       =   0   'False
   MinButton       =   0   'False
   ScaleHeight     =   4800
   ScaleWidth      =   5325
   StartUpPosition =   2  '屏幕中心
   Begin VB.Timer Timer1 
      Enabled         =   0   'False
      Interval        =   1
      Left            =   2670
      Top             =   0
   End
   Begin VB.OptionButton Opt_Hfqmjz 
      Caption         =   "恢复期末结帐"
      Height          =   255
      Left            =   1320
      TabIndex        =   7
      Top             =   4410
      Width           =   1425
   End
   Begin VB.OptionButton Opt_Qmjz 
      Caption         =   "期末结帐"
      Height          =   255
      Left            =   150
      TabIndex        =   6
      Top             =   4410
      Value           =   -1  'True
      Width           =   1095
   End
   Begin VB.CommandButton Com_Qx 
      Cancel          =   -1  'True
      Caption         =   "取消(&C)"
      Height          =   300
      Left            =   4080
      TabIndex        =   1
      Top             =   4380
      Width           =   1120
   End
   Begin VB.CommandButton Com_Qmjz 
      Caption         =   "确认(&O)"
      Height          =   300
      Left            =   2850
      TabIndex        =   0
      Top             =   4380
      Width           =   1120
   End
   Begin VSFlex8Ctl.VSFlexGrid CxbbGrid 
      Height          =   3795
      Left            =   120
      TabIndex        =   3
      Top             =   450
      Width           =   5085
      _ExtentX        =   8969
      _ExtentY        =   6694
      Appearance      =   1
      BorderStyle     =   1
      Enabled         =   -1  'True
      BeginProperty Font {0BE35203-8F91-11CE-9DE3-00AA004BB851} 
         Name            =   "宋体"
         Size            =   9
         Charset         =   134
         Weight          =   400
         Underline       =   0   'False
         Italic          =   0   'False
         Strikethrough   =   0   'False
      EndProperty
      MousePointer    =   0
      BackColor       =   -2147483643
      ForeColor       =   0
      BackColorFixed  =   -2147483633
      ForeColorFixed  =   -2147483630
      BackColorSel    =   16777152
      ForeColorSel    =   -2147483640
      BackColorBkg    =   -2147483636
      BackColorAlternate=   -2147483643
      GridColor       =   -2147483633
      GridColorFixed  =   -2147483632
      TreeColor       =   33023
      FloodColor      =   192
      SheetBorder     =   -2147483642
      FocusRect       =   1
      HighLight       =   1
      AllowSelection  =   0   'False
      AllowBigSelection=   0   'False
      AllowUserResizing=   0
      SelectionMode   =   1
      GridLines       =   1
      GridLinesFixed  =   2
      GridLineWidth   =   1
      Rows            =   50
      Cols            =   10
      FixedRows       =   1
      FixedCols       =   1
      RowHeightMin    =   0
      RowHeightMax    =   0
      ColWidthMin     =   0
      ColWidthMax     =   0
      ExtendLastCol   =   0   'False
      FormatString    =   ""
      ScrollTrack     =   0   'False
      ScrollBars      =   0
      ScrollTips      =   0   'False
      MergeCells      =   0
      MergeCompare    =   0
      AutoResize      =   -1  'True
      AutoSizeMode    =   0
      AutoSearch      =   0
      MultiTotals     =   -1  'True
      SubtotalPosition=   0
      OutlineBar      =   0
      OutlineCol      =   0
      Ellipsis        =   0
      ExplorerBar     =   0
      PicturesOver    =   0   'False
      FillStyle       =   0
      RightToLeft     =   0   'False
      PictureType     =   0
      TabBehavior     =   0
      OwnerDraw       =   0
      Editable        =   0   'False
      ShowComboButton =   -1  'True
      WordWrap        =   0   'False
      TextStyle       =   0
      TextStyleFixed  =   0
      OleDragMode     =   0
      OleDropMode     =   0
      DataMode        =   0
      VirtualData     =   -1  'True
   End
   Begin VB.Label Lbl_labTitle 
      AutoSize        =   -1  'True
      Caption         =   "当前会计期间:"
      Height          =   240
      Left            =   180
      TabIndex        =   5
      Top             =   120
      Width           =   1170
   End
   Begin VB.Label Lbl_labText 
      AutoSize        =   -1  'True
      Caption         =   "Label1"
      Height          =   240
      Left            =   1440
      TabIndex        =   4
      Top             =   120
      Width           =   1170
   End
   Begin VB.Label Label1 
      AutoSize        =   -1  'True
      Caption         =   "数据正在处理中..."
      ForeColor       =   &H000000FF&
      Height          =   210
      Left            =   3270
      TabIndex        =   2
      Top             =   120
      Visible         =   0   'False
      Width           =   1530
   End
End
Attribute VB_Name = "CL_EndCheckOut"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
'**************************************************************************
'*    模 块 名 称 :期末结帐
'*    功 能 描 述 :
'*    程序员姓名  :杨波
'*    最后修改人  :白凤英
'*    最后修改时间:2001/12/10
'*    备        注:程序中所有依实际情况自定义部分均用[>>  <<]括起
'**************************************************************************
Dim mKjYear As Integer                   '调用年度
Dim mKjMonth As Integer                  '调用月份
Dim FindMonth As Integer                 '查询月份
Dim DyLock As Boolean
Dim Dqrow As Integer
'以下为固定使用变量
Dim ReportTitle As String                '报表主标题
Dim Dyymctbl As New DY_Dyymsz            '打印页面窗体变量
Dim GridCode As String                   '显示网格网格代码
Dim GridInf() As Variant                 '整个网格设置信息
Dim Tsxx As String                       '系统提示信息
Dim Qslz As Long                         '网格隐藏(非操作显示)列数
Dim Sjhgd As Double                      '网格数据行高度
Dim Sfxshjwg As Boolean                  '是否显示合计网格
Dim GridBoolean() As Boolean             '网格列信息(布尔型)
Dim GridStr()  As String                 '网格列信息(字符型)
Dim GridInt() As Integer                 '网格列信息(整型)
Dim Szzls As Integer                     '数组总列数(网格列数-1)
Dim Jsqte%
Private Sub Sub_Qmjz()      '期末结帐
    Dim Rectemp As New ADODB.Recordset
    Dim RecTempFz As New ADODB.Recordset
    Dim Rec_Query As Recordset
    Dim Msg As Integer
    Dim Now_year As Integer
    Dim Now_period As Integer
    Dim mPeriod As Integer
    Dim mYear As Integer
    Dim Zfstr As String
    Dim SqlStr As String
  
    Now_year = PGKjYear
    Now_period = PGNowmon
    
    If Now_period = Val(CxbbGrid.TextMatrix(CxbbGrid.Rows - 1, Sydz("001", GridStr(), Szzls))) Then
        mPeriod = 1
        mYear = PGKjYear + 1
    Else
        mPeriod = Now_period + 1
        mYear = PGKjYear
    End If
        
    '系统集成时，库房未记帐时核算不能记帐
    If Xt_XtJc Then
        Set Rectemp = Cw_DataEnvi.DataConnect.Execute("select * from gy_kjrlb where kjyear=" & Now_year & " and period=" & Now_period)
        If Not Rectemp.EOF Then
            If Not Rectemp.Fields("kfjzbz") Then
                Tsxx = "库存管理系统未结帐,不允许核算系统结帐!"
                Call Xtxxts(Tsxx, 0, 4)
                Exit Sub
            End If
        End If
    End If
    
    '操作日期大于等于单据录入的最大日期
    SqlStr = "select max(chalkdate) as maxdate from chhs_list a where kjyear=" & Now_year & " and period=" & Now_period
    Set Rectemp = Cw_DataEnvi.DataConnect.Execute(SqlStr)
    If Not Rectemp.EOF Then
        If Xtrq < Rectemp.Fields("maxdate") Then
            Tsxx = "操作日期必须>=单据记帐日期 " + Format(CStr(Rectemp.Fields("maxdate")), "yyyy-mm-dd")
            Call Xtxxts(Tsxx, 0, 4)
            Exit Sub
        End If
    End If
    
    '判断是否全部期末处理完毕
    SqlStr = "SELECT WhName,EndDealFlagChhs from GY_WareHouse Where ChhsUseFlag=1 ORDER BY WhCode "
    Set Rectemp = Cw_DataEnvi.DataConnect.Execute(SqlStr)
    
    Zfstr = ""
    Do While Not Rectemp.EOF
        If Not Rectemp.Fields("EndDealFlagChhs") Then
            If Zfstr = "" Then
                Zfstr = Trim(Rectemp.Fields("WhName"))
            Else
                Zfstr = Zfstr + "、" + Trim(Rectemp.Fields("WhName"))
            End If
        End If
        Rectemp.MoveNext
    Loop
        
    If Zfstr <> "" Then
        Tsxx = "仓库 (" + Zfstr + ") 未进行期末处理!"
        Call Xtxxts(Tsxx, 0, 1)
        Exit Sub
    End If
  
    '判断上月是否结帐
    If Now_period = 1 Then
        SqlStr = "SELECT * FROM GY_Kjrlb WHERE Kjyear=" & Now_year - 1 & " order by period desc "
        Set Rectemp = Cw_DataEnvi.DataConnect.Execute(SqlStr)
        If Not Rectemp.EOF Then
            If Not Rectemp.Fields("Chhsjzbz") Then
                Tsxx = "上月未结帐!"
                Call Xtxxts(Tsxx, 0, 1)
                Exit Sub
            End If
        End If
    Else
        SqlStr = "SELECT * FROM GY_Kjrlb WHERE Kjyear=" & Now_year & " and period=" & Now_period - 1
        Set Rectemp = Cw_DataEnvi.DataConnect.Execute(SqlStr)
        If Not Rectemp.EOF Then
            If Not Rectemp.Fields("Chhsjzbz") Then
                Tsxx = "上月未结帐!"
                Call Xtxxts(Tsxx, 0, 1)
                Exit Sub
            End If
        End If
    End If
    
    Tsxx = "是否进行期末结帐?"
    Msg = Xtxxts(Tsxx, 1, 2)
    If Not Msg = 6 Then Exit Sub
    
    Label1.Visible = True
    Label1.Refresh
    SqlStr = "SELECT Chhsjzbz from GY_Kjrlb WHERE Kjyear='" & Now_year & "' and Period='" & Now_period & "'"
    Set Rectemp = Cw_DataEnvi.DataConnect.Execute(SqlStr)
    If Rectemp.Fields("Chhsjzbz") Then
        Tsxx = "期末已经结帐,不能再次结帐!"
        Label1.Visible = False
        Call Xtxxts(Tsxx, 0, 4)
        Exit Sub
    End If
 
    Cw_DataEnvi.DataConnect.BeginTrans
    
    '调整期末结存,生成下月期初
    If RecTempFz.State = 1 Then RecTempFz.Close
    RecTempFz.Open "SELECT * FROM Chhs_Mate where 1=2", Cw_DataEnvi.DataConnect, adOpenDynamic, adLockBatchOptimistic
    
    If Rectemp.State = 1 Then Rectemp.Close
    Rectemp.Open "SELECT * FROM Chhs_Mate WHERE Kjyear=" & Now_year & " and Period=" & Now_period, Cw_DataEnvi.DataConnect, adOpenDynamic, adLockBatchOptimistic
    
    Do While Not Rectemp.EOF
    
        '期末结存
        Rectemp.Fields("EndQuan") = Val(Rectemp.Fields("StartQuan")) + Val(Rectemp.Fields("InQuan")) - Val(Rectemp("OutQuan"))
        Rectemp.Fields("EndMoney") = Val(Rectemp.Fields("StartMoney")) + Val(Rectemp.Fields("InMoney")) - Val(Rectemp("OutMoney"))
        If Not Rectemp.Fields("EndQuan") = 0 Then
            Rectemp.Fields("EndPrice") = Format(Val(Rectemp.Fields("EndMoney")) / Val(Rectemp.Fields("EndQuan")), "###." + String(Xtdjxsws, "0"))
        Else
            Rectemp.Fields("EndPrice") = 0
        End If
        Rectemp.Fields("EndDiff") = Val(Rectemp.Fields("StartDiff")) + Val(Rectemp.Fields("JfDiff")) - Val(Rectemp("DfDiff"))
        Rectemp.UpdateBatch
        
        '生成下月期初
        RecTempFz.AddNew
        RecTempFz.Fields("WhCode") = Trim(Rectemp.Fields("WhCode"))
        RecTempFz.Fields("MNumber") = Trim(Rectemp.Fields("MNumber"))
        RecTempFz.Fields("StartQuan") = Val(Rectemp.Fields("EndQuan"))
        RecTempFz.Fields("StartPrice") = Val(Rectemp.Fields("EndPrice"))
        RecTempFz.Fields("StartMoney") = Val(Rectemp.Fields("EndMoney"))
        RecTempFz.Fields("StartDiff") = Val(Rectemp.Fields("EndDiff"))
        RecTempFz.Fields("kjyear") = mYear
        RecTempFz.Fields("period") = mPeriod
        RecTempFz.UpdateBatch
        Rectemp.MoveNext
    Loop
    
    '汇总下月的红字回冲单
    SqlStr = "SELECT WhCode, MNumber, SUM(InQuan) AS InQuan,SUM(InMoney)  AS InMoney," & _
             "SUM(JfDiff) AS JfDiff,SUM(DfDiff) AS DfDiff " & _
             "FROM Chhs_List WHERE Period =" & mPeriod & "and Kjyear=" & mYear & _
             " GROUP BY WhCode, MNumber"
    Set Rec_Query = Cw_DataEnvi.DataConnect.Execute(SqlStr)
    Do While Not Rec_Query.EOF
        If RecTempFz.State = 1 Then RecTempFz.Close
        SqlStr = "SELECT * FROM Chhs_Mate WHERE Kjyear=" & mYear & " and Period=" & mPeriod & _
                 " and WhCode='" & Trim(Rec_Query.Fields("WhCode")) & "'" & _
                 " AND  MNumber ='" & Trim(Rec_Query.Fields("MNumber")) & "'"
        RecTempFz.Open SqlStr, Cw_DataEnvi.DataConnect, adOpenDynamic, adLockBatchOptimistic
        If Not RecTempFz.EOF Then
            RecTempFz.Fields("InQuan") = Val(Rec_Query.Fields("InQuan"))
            RecTempFz.Fields("InMoney") = Val(Rec_Query.Fields("InMoney"))
            If Rec_Query.Fields("InQuan") <> 0 Then
                RecTempFz.Fields("InPrice") = Format(Val(Rec_Query.Fields("InMoney")) / Val(Rec_Query.Fields("InQuan")), "##0." + String(Xtdjxsws, "0"))
            End If
            RecTempFz.Fields("JfDiff") = Val(Rec_Query.Fields("JfDiff"))
            RecTempFz.Fields("DfDiff") = Val(Rec_Query.Fields("DfDiff"))
            RecTempFz.UpdateBatch
        Else
            RecTempFz.AddNew
            RecTempFz.Fields("WhCode") = Trim(Rec_Query.Fields("WhCode"))
            RecTempFz.Fields("MNumber") = Trim(Rec_Query.Fields("MNumber"))
            RecTempFz.Fields("kjyear") = mYear
            RecTempFz.Fields("period") = mPeriod
            RecTempFz.Fields("InQuan") = Val(Rec_Query.Fields("InQuan"))
            RecTempFz.Fields("InMoney") = Val(Rec_Query.Fields("InMoney"))
            If Rec_Query.Fields("InQuan") <> 0 Then
                RecTempFz.Fields("InPrice") = Format(Val(Rec_Query.Fields("InMoney")) / Val(Rec_Query.Fields("InQuan")), "##0." + String(Xtdjxsws, "0"))
            End If
            RecTempFz.Fields("JfDiff") = Val(Rec_Query.Fields("JfDiff"))
            RecTempFz.Fields("DfDiff") = Val(Rec_Query.Fields("DfDiff"))
            RecTempFz.UpdateBatch
        End If
        Rec_Query.MoveNext
    Loop
    
    '结帐标志
    SqlStr = "Update Gy_Kjrlb SET Chhsjzbz=1 WHERE Kjyear=" & Now_year & " and Period=" & Now_period
    Cw_DataEnvi.DataConnect.Execute (SqlStr)
    
    '清除仓库期末结帐标志
    SqlStr = "Update Gy_Warehouse SET EndDealFlagChhs=0 WHERE chhsuseflag=1"
    Cw_DataEnvi.DataConnect.Execute (SqlStr)
  
    Cw_DataEnvi.DataConnect.CommitTrans
    
    Label1.Visible = False
    
    Call Sub_Query
    Call Sub_Opt
    
    Tsxx = "期末结帐完毕!"
    Call Xtxxts(Tsxx, 0, 4)
    
    Set Rectemp = Nothing
    Set RecTempFz = Nothing
    
End Sub
Private Sub Sub_HfQmjz()      '恢复期末结帐
    Dim Rectemp As New ADODB.Recordset
    Dim RecTempFz As New ADODB.Recordset
    Dim Msg As Integer
    Dim Now_year As Integer
    Dim Now_period As Integer
    Dim Hf_year As Integer
    Dim Hf_period As Integer
    Dim Pre_Period As Integer
    Dim SqlStr As String
  
    Now_year = PGKjYear
    Now_period = PGNowmon
    
    Hf_year = PGPrevKjYear
    Hf_period = PGPrevKjMon
    
    '判断是否全部期末处理完毕
    Set Rectemp = Cw_DataEnvi.DataConnect.Execute("SELECT WhCode,EndDealFlagChhs FROM GY_WareHouse Where chhsuseflag=1 ORDER BY WhCode")
    Do While Not Rectemp.EOF
        If Rectemp.Fields("EndDealFlagChhs") Then
            Tsxx = "仓库(" + Trim(Rectemp.Fields("WhCode")) + ")已进行当前月份期末处理!"
            Call Xtxxts(Tsxx, 0, 4)
            Exit Sub
        End If
        Rectemp.MoveNext
    Loop
    
    '判断是否记帐
    Set Rectemp = Cw_DataEnvi.DataConnect.Execute("SELECT ChalkitupMan FROM GY_InoutMain WHERE kjyear=" & Now_year & " and Period=" & Now_period & " and ChalkitupMan<>''")
    If Not Rectemp.EOF Then
        Tsxx = "当前月份单据已记帐!"
        Call Xtxxts(Tsxx, 0, 4)
        Exit Sub
    End If
    
    '判断库房管理系统是否已结帐
    Set Rectemp = Cw_DataEnvi.DataConnect.Execute("SELECT Kfjzbz FROM GY_Kjrlb WHERE kfjzbz=1 and kjyear=" & Now_year & " and Period=" & Now_period)
    If Not Rectemp.EOF Then
        Tsxx = "库房管理系统 " + CStr(Now_year) + "." + CStr(Now_period) + " 已结帐,不允许恢复 " + CStr(Hf_year) + "." + CStr(Hf_period) + " 的期末结帐!"
        Call Xtxxts(Tsxx, 0, 4)
        Exit Sub
    End If
  
    Tsxx = "是否进行恢复期末结帐?"
    Msg = Xtxxts(Tsxx, 1, 2)
    If Not Msg = 6 Then Exit Sub
    
    Label1.Visible = True
    Label1.Refresh
 
    Cw_DataEnvi.DataConnect.BeginTrans
    '会计日历表标记
    Cw_DataEnvi.DataConnect.Execute ("UPDATE GY_Kjrlb SET Chhsjzbz=0 WHERE Kjyear=" & Hf_year & " AND Period=" & Hf_period)
    
    '仓库期末结帐标志
    SqlStr = "Update Gy_Warehouse SET EndDealFlagChhs=1 WHERE chhsuseflag=1"
    Cw_DataEnvi.DataConnect.Execute (SqlStr)
    
    '删除当前月期初
    Cw_DataEnvi.DataConnect.Execute ("DELEte Chhs_Mate WHERE Kjyear=" & Now_year & " and Period=" & Now_period)
    
    '清除恢复月份期末结存
    Cw_DataEnvi.DataConnect.Execute ("UPDATE Chhs_Mate Set EndQuan=0,EndPrice=0,EndMoney=0,EndDiff=0 WHERE Kjyear=" & Hf_year & " and Period=" & Hf_period)
        
    Cw_DataEnvi.DataConnect.CommitTrans
  
    Label1.Visible = False
    
    Call Sub_Query
    Call Sub_Opt
    
    Tsxx = "期末结帐恢复完毕!"
    Call Xtxxts(Tsxx, 0, 4)
  
End Sub
Private Sub Com_Qmjz_Click()
  
    If Opt_Qmjz.Value Then
        If Not Month(Xtrq) = PGNowmon Then
            Tsxx = "操作日期不在当前会计期间(" + Trim(Str(PGKjYear)) + "." + Trim(Str(PGNowmon)) + ")之内,请重新登录!"
            Call Xtxxts(Tsxx, 0, 1)
            Exit Sub
        End If
        Call Sub_Qmjz
    Else
        Call Sub_HfQmjz
    End If
  
End Sub
Private Sub Com_Qx_Click()
    Unload Me
  
End Sub
Private Sub Form_Load()                                                   '窗体装入
  
    '调 入 网 格
    GridCode = "Chhs_EndCheckOut"
    Call BzWgcsh(CxbbGrid, GridCode, GridInf(), GridBoolean(), GridInt(), GridStr())
    
    Qslz = GridInf(1)
    Sjhgd = GridInf(2)
    Sfxshjwg = GridInf(7)
    Szzls = CxbbGrid.Cols - 1
    CxbbGrid.AllowUserResizing = flexResizeNone
    
    CxbbGrid.SelectionMode = flexSelectionByRow
    CxbbGrid.BackColorSel = &HFFFFC0
    DyLock = True
    Dqrow = 0
    
End Sub
Private Sub Sub_Query()      '填充网格
 
    Dim Rectemp As New ADODB.Recordset
    Dim Dqrow As Long
    Dim SqlStr As String
    
    Lbl_labText = Str(PGKjYear) + "." + Str(PGNowmon)
    With CxbbGrid
    
        .Rows = .FixedRows
        
        Set Rectemp = Cw_DataEnvi.DataConnect.Execute("select Period,Qsrq,Zzrq,Chhsjzbz from GY_kjrlb where kjyear=" & Me.Dyear & " order by kjyear ,Period")
        Do While Not Rectemp.EOF
            .AddItem ""
            .RowHeight(.Rows - 1) = Sjhgd
            .TextMatrix(.Rows - 1, Sydz("001", GridStr(), Szzls)) = Trim(Rectemp.Fields("Period"))
            .TextMatrix(.Rows - 1, Sydz("002", GridStr(), Szzls)) = Format(Trim(Rectemp.Fields("Qsrq")), "yyyy-mm-dd")
            .TextMatrix(.Rows - 1, Sydz("003", GridStr(), Szzls)) = Format(Trim(Rectemp.Fields("Zzrq")), "yyyy-mm-dd")
            .TextMatrix(.Rows - 1, Sydz("004", GridStr(), Szzls)) = Trim(Rectemp.Fields("chhsjzbz"))
            Rectemp.MoveNext
        Loop
        .Enabled = False
    
    End With
 
    Set Rectemp = Nothing
 
End Sub
Private Sub Opt_Hfqmjz_Click()
    
    If DyLock Then Exit Sub
    
    With CxbbGrid
        If Dqrow - 1 > 0 Then
            .Select Dqrow - 1, 0, Dqrow - 1, .Cols - 1
        End If
    End With
End Sub
Private Sub Opt_Qmjz_Click()
    
    If DyLock Then Exit Sub
    
    With CxbbGrid
       If Dqrow > 0 Then
            .Select Dqrow, 0, Dqrow, .Cols - 1
        End If
    End With
End Sub
Private Sub Timer1_Timer()
    Timer1.Enabled = False
   
    '加快显示速度
    CxbbGrid.Redraw = False
    '生成查询结果
    Call Sub_Query
    Call Sub_Opt
    CxbbGrid.Redraw = True
    
End Sub
Private Sub Sub_Opt()           '恢复状态
    DyLock = True
    
    Lbl_labText = Str(PGKjYear) + "." + Str(PGNowmon)
    With CxbbGrid
    
        If Me.Dmonth = Val(.TextMatrix(.Rows - 1, Sydz("001", GridStr(), Szzls))) Then
            If .TextMatrix(.Rows - 1, .Cols - 1) = True Then
                Opt_Qmjz.Enabled = False
                Opt_Hfqmjz.Enabled = True
                Opt_Hfqmjz.Value = True
            Else
                Opt_Qmjz.Enabled = True
                Opt_Hfqmjz.Enabled = True
                Opt_Qmjz.Value = True
            End If
        Else
            If .TextMatrix(.FixedRows, .Cols - 1) = False Then
                Opt_Qmjz.Enabled = True
                Opt_Hfqmjz.Enabled = False
                Opt_Qmjz.Value = True
            Else
                Opt_Qmjz.Enabled = True
                Opt_Hfqmjz.Enabled = True
                Opt_Qmjz.Value = True
            End If
        End If
    
        If .Rows > .FixedRows Then
            If Me.Dmonth = Val(.TextMatrix(.Rows - 1, Sydz("001", GridStr(), Szzls))) Then
                Dqrow = .Rows - 1
            Else
                Dqrow = .Findrow("False", 0, .Cols - 1)
            End If
        End If
        
        If Dqrow > 0 Then
            .Select Dqrow, 0, Dqrow, .Cols - 1
        End If
    End With
    
    DyLock = False
    
End Sub
Public Property Get Dyear() As Variant
    Dyear = mKjYear
End Property
Public Property Let Dyear(ByVal vNewValue As Variant)
    mKjYear = vNewValue
End Property
Public Property Get Dmonth() As Variant
    Dmonth = mKjMonth
End Property
Public Property Let Dmonth(ByVal vNewValue As Variant)
    mKjMonth = vNewValue
End Property

						