企业管理

开发平台：
Visual Basic

：源码内容
							VERSION 5.00
Begin VB.Form YF_FrmAccountC 
   BorderStyle     =   1  'Fixed Single
   Caption         =   "预算分析查询条件"
   ClientHeight    =   2640
   ClientLeft      =   45
   ClientTop       =   330
   ClientWidth     =   3420
   Icon            =   "预算分析_科目查询条件.frx":0000
   KeyPreview      =   -1  'True
   LinkTopic       =   "Form2"
   MaxButton       =   0   'False
   MinButton       =   0   'False
   ScaleHeight     =   2640
   ScaleWidth      =   3420
   StartUpPosition =   2  '屏幕中心
   Begin VB.Frame Frame1 
      Caption         =   "比较日期"
      Height          =   1035
      Index           =   1
      Left            =   60
      TabIndex        =   8
      Top             =   1110
      Width           =   3285
      Begin VB.ComboBox Combo_SelYear 
         Height          =   300
         Left            =   105
         Style           =   2  'Dropdown List
         TabIndex        =   2
         Top             =   225
         Width           =   3075
      End
      Begin VB.ComboBox Combo_CompDate 
         Height          =   300
         Left            =   105
         Style           =   2  'Dropdown List
         TabIndex        =   3
         Top             =   615
         Width           =   3075
      End
   End
   Begin VB.Frame Frame1 
      Caption         =   "分析日期"
      Height          =   1005
      Index           =   0
      Left            =   60
      TabIndex        =   7
      Top             =   30
      Width           =   3285
      Begin VB.ComboBox Combo_Type 
         Height          =   300
         Left            =   90
         Style           =   2  'Dropdown List
         TabIndex        =   0
         Top             =   210
         Width           =   3075
      End
      Begin VB.ComboBox Combo_BaseDate 
         Height          =   300
         Left            =   90
         Style           =   2  'Dropdown List
         TabIndex        =   1
         Top             =   585
         Width           =   3075
      End
   End
   Begin VB.CommandButton QdCommand 
      Caption         =   "确定(&O)"
      Height          =   300
      Left            =   1020
      TabIndex        =   4
      Top             =   2250
      Width           =   1120
   End
   Begin VB.CommandButton QxCommand 
      Caption         =   "取消(&C)"
      Height          =   300
      Left            =   2225
      TabIndex        =   5
      Top             =   2250
      Width           =   1120
   End
   Begin VB.CheckBox UnloadCheck 
      Caption         =   "卸载窗体"
      Height          =   615
      Left            =   3900
      TabIndex        =   6
      Top             =   1920
      Visible         =   0   'False
      Width           =   825
   End
   Begin VB.Label Lbl_Comment 
      Height          =   525
      Left            =   120
      TabIndex        =   9
      Top             =   2850
      Visible         =   0   'False
      Width           =   1245
   End
End
Attribute VB_Name = "YF_FrmAccountC"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
'****************************************************************
'*    模 块 名 称 : 预算分析科目查询条件
'*    功 能 描 述 :
'*    程序员姓名  : 魏永生
'*    最后修改人  :
'*    最后修改时间:2002/1/21
'*    备        注:程序中所有依实际情况自定义部分均用[>>  <<]括起
'****************************************************************
    
Dim Int_Curr_year As Integer            '分析期年
Dim Int_Curr_month1 As Integer          '分析期开始月
Dim Int_Curr_month2 As Integer          '分析期结束月
Dim Int_Comp_year As Integer            '比较期年
Dim Int_Comp_month1 As Integer          '比较期开始月
Dim Int_Comp_month2 As Integer          '比较期结束月
Dim Tsxx As String                      '系统信息提示
Private UsedYear() As String            '已使用年数据，如：UsedYear(0)="1999",UsedYear(1)="2000"
Private iHowManyYears As Integer        '已使用的年数
Private iMaxMonth As Integer            '最大使用月份
Private Sub Form_KeyPress(KeyAscii As Integer)   '控 制 焦 点 转 移
    Dim jdzygs As Integer                         '控件焦点转移个数
    jdzygs = 6
    Select Case KeyAscii
    Case vbKeyReturn
        If Kjjdzy(jdzygs) Then
            KeyAscii = 0
        End If
    Case 39                                 '屏蔽"'"
        KeyAscii = 0
    End Select
End Sub
Private Sub Form_Load()
    
    Set Frm_AnalysisC = YF_FrmAccountC
    Str_ReportSubTitle = ""
    
    Call GetUsedYear
    Call GetUsedMonth
    '填充
    Call FillCombo(Combo_Type, "cwfx_AccountC", "", 0)
    Call FillMonth(Combo_BaseDate, Xtyear)
    Call FillYear(Combo_SelYear)
    If Combo_SelYear.ListIndex <> -1 Then
        Combo_CompDate.Enabled = True
        Call FillMonth(Combo_CompDate, Combo_SelYear.Text)
    End If
    
    
    
End Sub
                                     
Private Sub FillThisYear(PastComb As ComboBox)
    With PastComb
        .Clear
        .AddItem Xtyear
        .Text = Xtyear
    End With
End Sub
Private Sub FillYear(PastComb As ComboBox)
    Dim i As Integer
    With PastComb
        .Clear
        .AddItem ""
        For i = 0 To iHowManyYears
            .AddItem UsedYear(i)
        Next
        .Text = Xtyear
    End With
End Sub
Private Sub FillMonth(PastComb As ComboBox, ByVal PastYear As String)
    Dim i As Integer
    With PastComb
        .Clear
        If iMaxMonth < 1 Then Exit Sub
        .AddItem ""
        For i = 1 To iMaxMonth
            .AddItem PastYear & "." & Format(i, "00")
        Next
        .Text = Xtyear & "." & Format(Xtmm, "00")
    End With
End Sub
Private Sub FillThreeMonth(PastComb As ComboBox, ByVal PastYear As String)
    Dim i As Integer
    With PastComb
        .Clear
        If iMaxMonth < 1 Then Exit Sub
        .AddItem ""
        For i = 1 To 4
            .AddItem PastYear & "." & Format(((i - 1) * 3 + 1), "00") & "-" & PastYear & "." & Format((i * 3), "00")
        Next
    End With
End Sub
Private Sub GetUsedYear()
    '由Form_Load 调用,得到此帐套已使用的年度，存于UsedYear()数据中
    Dim temRs As New ADODB.Recordset
    Dim strSql As String
    Dim i As Integer
    strSql = "SELECT DISTINCT kjyear AS cYear FROM gy_kjrlb"
    Set temRs = Cw_DataEnvi.DataConnect.Execute(strSql)
    iHowManyYears = temRs.RecordCount - 1
    ReDim UsedYear(iHowManyYears)
    With temRs
        Do Until .EOF
            UsedYear(i) = !cYear
            i = i + 1
            .MoveNext
        Loop
    End With
    If temRs.State = adStateOpen Then temRs.Close
    Set temRs = Nothing
End Sub
Private Sub GetUsedMonth()
    '由Form_Load 调用,得到此帐套已使用的最大月份，存于iMaxMonth数据中
    
    Dim temRs As New ADODB.Recordset
    Dim strSql As String
    Dim i As Integer
    strSql = "SELECT Max(period) AS cMonth FROM gy_kjrlb"
    Set temRs = Cw_DataEnvi.DataConnect.Execute(strSql)
    With temRs
        If Not (.EOF And .BOF) Then
            iMaxMonth = !cMonth
        End If
    End With
    If temRs.State = adStateOpen Then temRs.Close
    Set temRs = Nothing
End Sub
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
    If UnloadCheck.Value <> 1 Then
        Cancel = 1
        Me.Hide
    End If
End Sub
Private Sub QdCommand_Click()                                   '确 定
    '录入条件有效性判断
    If Not Lrtjyxxpd Then
        Exit Sub
    End If
    Me.Hide
    
    Set Frm_AnalysisC = YF_FrmAccountC
    
    Lbl_Comment.Caption = "分析期间:" & Combo_BaseDate.Text & "      比较期间:" & _
    IIf(Len(Combo_CompDate.Text) <> 0, Combo_CompDate.Text, Combo_SelYear.Text)
    
    '激活查询过程
    YF_FrmAnalysis.Timer1.Enabled = True
    YF_FrmAnalysis.SetFocus
    
End Sub
Private Sub QxCommand_Click()                                    '取消
    Me.Hide
End Sub
Private Function Lrtjyxxpd() As Boolean                          '用户录入条件有效性判断
    
    Lrtjyxxpd = False
    
    
    '[>>以下为依据实际情况自定义部分
    If Combo_BaseDate.ListIndex < 1 Then
        Xtxxts "请选择分析期间!", 0, 1
        Lrtjyxxpd = False
        Combo_BaseDate.SetFocus
        Exit Function
    End If
    
    If Combo_SelYear.ListIndex > 0 And Combo_Type.ListIndex <> 2 Then
        If Combo_CompDate.ListIndex < 1 Then
            Xtxxts "请选择比较期间!", 0, 1
            Lrtjyxxpd = False
            Combo_CompDate.SetFocus
            Exit Function
        End If
    End If
    '<<]以上为依据实际情况自定义部分
    
    Lrtjyxxpd = True
End Function
Private Sub Combo_SelYear_Click()
    If Combo_SelYear.ListIndex = 0 Then
        Combo_CompDate.Enabled = False
        Combo_CompDate.Clear
        Exit Sub
    End If
    Select Case Combo_Type.ListIndex
    Case 0
        Combo_CompDate.Enabled = True
        Call FillMonth(Combo_CompDate, Combo_SelYear.Text)
    Case 1
        Combo_CompDate.Enabled = True
        Call FillThreeMonth(Combo_CompDate, Combo_SelYear.Text)
    Case 2
        Combo_CompDate.Enabled = False
    End Select
End Sub
Private Sub Combo_Type_Click()
    Select Case Combo_Type.ListIndex
    Case 0
        Call FillMonth(Combo_BaseDate, Xtyear)
        If Combo_SelYear.ListIndex <> -1 Then
            Combo_CompDate.Enabled = True
            Call FillMonth(Combo_CompDate, Combo_SelYear.Text)
        End If
    Case 1
        Call FillThreeMonth(Combo_BaseDate, Xtyear)
        If Combo_SelYear.ListIndex <> -1 Then
            Combo_CompDate.Enabled = True
            Call FillThreeMonth(Combo_CompDate, Combo_SelYear.Text)
        End If
    Case 2
        Call FillThisYear(Combo_BaseDate)
        Combo_CompDate.Clear
        Combo_CompDate.Enabled = False
    End Select
End Sub

						