企业管理

开发平台：
Visual Basic

˪-i㦥：源码内容
							VERSION 5.00
Begin VB.Form Note_FrmNoteEndorse 
   BorderStyle     =   3  'Fixed Dialog
   Caption         =   "应收票据背书"
   ClientHeight    =   4725
   ClientLeft      =   45
   ClientTop       =   330
   ClientWidth     =   5940
   HelpContextID   =   20403
   Icon            =   "应收票据_背书.frx":0000
   KeyPreview      =   -1  'True
   LinkTopic       =   "Form1"
   MaxButton       =   0   'False
   MinButton       =   0   'False
   ScaleHeight     =   4725
   ScaleWidth      =   5940
   ShowInTaskbar   =   0   'False
   StartUpPosition =   1  'CenterOwner
   Begin VB.Frame Frame1 
      Caption         =   "背书方式"
      Height          =   975
      Index           =   1
      Left            =   4020
      TabIndex        =   13
      Top             =   240
      Width           =   1725
      Begin VB.OptionButton OptType 
         Caption         =   "冲销应付帐款"
         Height          =   255
         Index           =   0
         Left            =   210
         TabIndex        =   11
         Top             =   270
         Value           =   -1  'True
         Width           =   1455
      End
      Begin VB.OptionButton OptType 
         Caption         =   "其它"
         Height          =   255
         Index           =   1
         Left            =   240
         TabIndex        =   12
         Top             =   570
         Width           =   735
      End
   End
   Begin VB.Frame Frame1 
      Height          =   4215
      Index           =   0
      Left            =   60
      TabIndex        =   15
      Top             =   30
      Width           =   5805
      Begin VB.CommandButton Ydcommand1 
         Height          =   300
         Index           =   3
         Left            =   3660
         Picture         =   "应收票据_背书.frx":1042
         Style           =   1  'Graphical
         TabIndex        =   26
         Top             =   1560
         Visible         =   0   'False
         Width           =   300
      End
      Begin VB.TextBox LrText 
         Height          =   300
         Index           =   5
         Left            =   1260
         TabIndex        =   5
         Text            =   "5"
         Top             =   2370
         Width           =   2415
      End
      Begin VB.TextBox LrText 
         Height          =   300
         Index           =   2
         Left            =   1260
         TabIndex        =   2
         Text            =   "2"
         Top             =   1140
         Width           =   2415
      End
      Begin VB.CommandButton Ydcommand1 
         Height          =   300
         Index           =   7
         Left            =   3660
         Picture         =   "应收票据_背书.frx":13CC
         Style           =   1  'Graphical
         TabIndex        =   16
         Top             =   3210
         Visible         =   0   'False
         Width           =   300
      End
      Begin VB.TextBox LrText 
         Height          =   300
         Index           =   7
         Left            =   1260
         TabIndex        =   7
         Text            =   "7"
         Top             =   3210
         Width           =   2415
      End
      Begin VB.CommandButton Ydcommand1 
         Height          =   300
         Index           =   4
         Left            =   4530
         Picture         =   "应收票据_背书.frx":1756
         Style           =   1  'Graphical
         TabIndex        =   14
         Top             =   1950
         Visible         =   0   'False
         Width           =   300
      End
      Begin VB.TextBox LrText 
         Height          =   300
         Index           =   8
         Left            =   1260
         TabIndex        =   8
         Text            =   "8"
         Top             =   3630
         Width           =   3285
      End
      Begin VB.TextBox LrText 
         Height          =   300
         Index           =   4
         Left            =   1260
         TabIndex        =   4
         Text            =   "4"
         Top             =   1950
         Width           =   3285
      End
      Begin VB.TextBox LrText 
         Enabled         =   0   'False
         Height          =   300
         Index           =   1
         Left            =   1260
         TabIndex        =   1
         Text            =   "1"
         Top             =   690
         Width           =   2415
      End
      Begin VB.TextBox LrText 
         Height          =   300
         Index           =   6
         Left            =   1260
         TabIndex        =   6
         Text            =   "6"
         Top             =   2790
         Width           =   2415
      End
      Begin VB.TextBox LrText 
         Enabled         =   0   'False
         Height          =   300
         Index           =   0
         Left            =   1260
         TabIndex        =   0
         Text            =   "0"
         Top             =   270
         Width           =   2415
      End
      Begin VB.TextBox LrText 
         Height          =   300
         Index           =   3
         Left            =   1260
         TabIndex        =   3
         Text            =   "3"
         Top             =   1560
         Width           =   2415
      End
      Begin VB.Label Label1 
         AutoSize        =   -1  'True
         Caption         =   "背书日期:"
         Height          =   195
         Index           =   0
         Left            =   270
         TabIndex        =   25
         Top             =   1620
         Width           =   765
      End
      Begin VB.Label Label1 
         AutoSize        =   -1  'True
         Caption         =   "票面金额:"
         Height          =   195
         Index           =   11
         Left            =   270
         TabIndex        =   24
         Top             =   750
         Width           =   765
      End
      Begin VB.Label Label1 
         AutoSize        =   -1  'True
         Caption         =   "票据编号:"
         Height          =   195
         Index           =   2
         Left            =   270
         TabIndex        =   23
         Top             =   330
         Width           =   765
      End
      Begin VB.Label Label1 
         AutoSize        =   -1  'True
         Caption         =   "背书金额:"
         Height          =   195
         Index           =   1
         Left            =   270
         TabIndex        =   22
         Top             =   2850
         Width           =   765
      End
      Begin VB.Label Label1 
         AutoSize        =   -1  'True
         Caption         =   "被背书单位:"
         Height          =   195
         Index           =   3
         Left            =   270
         TabIndex        =   21
         Top             =   2040
         Width           =   945
      End
      Begin VB.Label Label1 
         AutoSize        =   -1  'True
         Caption         =   "摘要:"
         Height          =   195
         Index           =   4
         Left            =   270
         TabIndex        =   20
         Top             =   3690
         Width           =   405
      End
      Begin VB.Label Label1 
         AutoSize        =   -1  'True
         Caption         =   "背书科目:"
         Height          =   195
         Index           =   5
         Left            =   270
         TabIndex        =   19
         Top             =   3270
         Width           =   765
      End
      Begin VB.Label Label1 
         AutoSize        =   -1  'True
         Caption         =   "币别:"
         Height          =   195
         Index           =   6
         Left            =   270
         TabIndex        =   18
         Top             =   1200
         Width           =   405
      End
      Begin VB.Label Label1 
         AutoSize        =   -1  'True
         Caption         =   "记帐汇率:"
         Height          =   195
         Index           =   7
         Left            =   270
         TabIndex        =   17
         Top             =   2430
         Width           =   765
      End
   End
   Begin VB.CommandButton QxCommand 
      Caption         =   "取消(&C)"
      Height          =   300
      Left            =   4745
      TabIndex        =   10
      Top             =   4350
      Width           =   1120
   End
   Begin VB.CommandButton QdCommand 
      Caption         =   "确定(&O)"
      Height          =   300
      Left            =   3540
      TabIndex        =   9
      Top             =   4350
      Width           =   1120
   End
End
Attribute VB_Name = "Note_FrmNoteEndorse"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
'******************************************************************
'*    模 块 名 称 :应收票据背书
'*    功 能 描 述 :
'*    程序员姓名  :姜冬梅
'*    最后修改人  :姜冬梅
'*    最后修改时间:2001/12/06
'*    备        注:程序中所有依实际情况自定义部分均用[>>  <<]括起
'******************************************************************
Dim Tsxx As String                       '系统信息提示
Dim Bln_ConVertFlag As Boolean           '币种折算方式
Dim Dbl_AccRate As Double                '币种记帐汇率
Dim Dbl_Bbje As Double                   '本币金额
'以下为固定使用变量(文本框)
Dim Textvar() As Variant                 '存储变体型文本框信息
Dim Textboolean() As Boolean             '存储布尔型文本框信息
Dim Textint() As Integer                 '存储整型文本框信息
Dim Textstr() As String                  '存储字符型文本框信息
Dim Max_Text_Index As Integer            '最大录入文本框索引值
Dim TextGroupCode As String              '文本框录入分组编码
Dim TextValiLock As Boolean              '文本框失去焦点是否进行有效性控制判断
Dim TextValiJudgeLock() As Boolean       '文本框录入有效性判断控制锁
Dim CurTextIndex As Integer              '当前文本框索引值
Dim TextChangeLock As Boolean            '文本框内容变换控制锁
Dim Bln_Cancel As Boolean                '取消按钮信息传递
Private Sub Form_KeyPress(KeyAscii As Integer)   '控 制 焦 点 转 移(Fixed)
    
    Dim jdzygs As Integer                         '控件焦点转移个数
    jdzygs = 10
    Select Case KeyAscii
        Case vbKeyReturn
            If Kjjdzy(jdzygs) Then
                KeyAscii = 0
            End If
        Case 39           '屏蔽"'"
            KeyAscii = 0
    End Select
End Sub
Private Sub Form_Load()
   
    '以下为文本框处理程序(Fixed)
    TextGroupCode = "Ar_NoteEndorse"
    Call Drwbkxx(TextGroupCode, Textvar(), Textboolean(), Textint(), Textstr())  '读入文本框录入信息
    Call Wbkcsh
   
    '[>>初始化查询条件默认值
    Call ShowBill
    '<<]
   
End Sub
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)          '查询条件窗体卸载
    '查询条件窗体卸载时判断是否因为结果窗体卸载,如是则卸载,否则隐藏
    Unload Me
End Sub
Private Sub QdCommand_Click()                                   '确 定
    '录入条件有效性判断(Fixed)
    If Not Lrtjyxxpd Then
        Exit Sub
    End If
    If SaveBill = True Then
    '<<]
        Xtfhcs = "1"
        Unload Me
    End If
End Sub
Private Sub QxCommand_Click()                                    '取消(Fixed)
    Xtfhcs = "0"
    Unload Me
End Sub
Private Function Lrtjyxxpd() As Boolean                          '用户录入条件有效性判断
 
    Dim jsqte As Integer
    Lrtjyxxpd = False
 
    '对需要进行事后判断的文本框录入内容进行有效性判断 (Fixed)
    For jsqte = 0 To Max_Text_Index
        If Textint(jsqte, 9) = 0 Or Textint(jsqte, 9) = 2 Then
            If Not TextYxxpd(jsqte) Then
                Exit Function
            End If
        End If
    Next jsqte
   
    '[>>以下为依据实际情况自定义部分
 
    '<<]以上为依据实际情况自定义部分
 
    Lrtjyxxpd = True
End Function
'*************以下为文本框录入处理程序(固定不变部分)*************'
Private Sub Wbklrwbcl(Index As Integer)    '文本框录入事后处理程序
  
    '以下为依据实际情况自定义部分[
  
    '在此填写文本框录入事后处理程序
    '如果背书方式为冲应付款，则自动取该供应商对应的科目
    If Index = 4 Then
        If OptType(0).Value = True And LrText(4).Text <> "" And LrText(7).Text = "" Then
            LrText(7).Text = Fun_InputCodeSupplier(LrText(4).Tag, 0)        '背书科目
        End If
    End If
    Select Case Index
         Case 5             '记帐汇率
            TextChangeLock = True
            '2.如果用户选择币种为本位币则汇率必须为1，否则汇率不能为零
            If Trim(LrText(3).Tag) = XtSCurrCode Then
                LrText(5).Text = 1
            Else
                Call Sub_GetAccRate(LrText(3).Tag, Bln_ConVertFlag, Dbl_AccRate)    '取外币记帐汇率
                If Dbl_AccRate <> 0 Then
                    LrText(5).Text = Dbl_AccRate
                Else
                    LrText(5).Text = ""
                End If
            End If
            TextChangeLock = False
    End Select
   
    ']以上为依据实际情况自定义部分
  
End Sub
Private Sub LrText_Change(Index As Integer)
    
    '屏蔽程序改变控制
    If TextChangeLock Then
        Exit Sub
    End If
    
    TextValiJudgeLock(Index) = False    '打开有效性判断锁
    
    '限制字段录入长度
          
    TextChangeLock = True  '加锁(防止执行Lrtext_Change)
     
    Select Case Textint(Index, 1)
        Case 8, 11      '金额型
            Call Sjgskz(LrText(Index), Xtjezws - Xtjexsws - 1, Xtjexsws)
        Case 9, 12      '数量型
            Call Sjgskz(LrText(Index), Xtslzws - Xtslxsws - 1, Xtslxsws)
        Case 10          '单价型
            Call Sjgskz(LrText(Index), Xtdjzws - Xtdjxsws - 1, Xtdjxsws)
        Case Else        '其他小数类型控制
            If Textint(Index, 6) <> 0 Or Textint(Index, 7) <> 0 Then
                Call Sjgskz(LrText(Index), Textint(Index, 6), Textint(Index, 7))
            End If
    End Select
        
    TextChangeLock = False '解锁
End Sub
Private Sub LrText_GotFocus(Index As Integer)                                                 '文本框得到焦点,显示相应信息
    
    Call TextShow(Index)
    CurTextIndex = Index
    LrText(Index).SelStart = Len(LrText(Index))
End Sub
Private Sub LrText_KeyDown(Index As Integer, KeyCode As Integer, Shift As Integer)            '字段按F2键提供帮助
    
    Select Case KeyCode
        Case vbKeyF2
            Call Text_Help(Index)
    End Select
End Sub
Private Sub LrText_KeyPress(Index As Integer, KeyAscii As Integer)                            '文本框录入事中控制
    Call InputFieldLimit(LrText(Index), Textint(Index, 1), KeyAscii)
End Sub
Private Sub LrText_LostFocus(Index As Integer)                                                '文本框失去焦点
  '显示相应信息但不能进行有效性判断
  Call Wbklrwbcl(Index)
End Sub
Private Sub Ydcommand1_MouseDown(Index As Integer, Button As Integer, Shift As Integer, x As Single, y As Single)     '按钮提供帮助
    Call Text_Help(Index)
End Sub
Private Sub Text_Help(Index As Integer)                                                       '录入字段帮助
    If Not Textboolean(Index, 1) Then
        Exit Sub
    End If
     
    '调用帮助
    Call Drbmhelp(Textint(Index, 2), Textstr(Index, 4), Trim(LrText(Index).Text))
  
    '根据设置选择显示编码和名称,并进行存储
    If Len(Xtfhcs) <> 0 Then
        If Textint(Index, 3) = 1 Then
            LrText(Index).Text = Xtfhcsfz
            LrText(Index).Tag = Xtfhcs
        Else
            LrText(Index).Text = Xtfhcs
            LrText(Index).Tag = Xtfhcsfz
        End If
    End If
   
    LrText(Index).SetFocus
End Sub
Private Sub TextShow(Index As Integer)        '文本框得到焦点,显示相应信息
  '填写文本框得到焦点,进行相应信息处理程序
   
End Sub
Private Sub Wbkcsh()                          '录入文本框初始化
  
    Dim jsqte As Integer
  
    '最大录入文本框索引值
    Max_Text_Index = Textvar(1)
  
    ReDim TextValiJudgeLock(Max_Text_Index)
    For jsqte = 0 To Max_Text_Index
         
        If Len(Trim(Textstr(jsqte, 1))) <> 0 Then
            If Textboolean(jsqte, 1) Then
                If jsqte <> 0 And Not Textboolean(jsqte, 3) Then
                    Load Ydcommand1(jsqte)
                End If
                Ydcommand1(jsqte).Visible = True
                Ydcommand1(jsqte).Move LrText(jsqte).Left + LrText(jsqte).Width, LrText(jsqte).Top
            End If
            TextChangeLock = True
            LrText(jsqte).Text = ""
            LrText(jsqte).Tag = ""
            If Textint(jsqte, 5) <> 0 Then
                LrText(jsqte).MaxLength = Textint(jsqte, 5)
            End If
            TextChangeLock = False
        End If
        If Textboolean(jsqte, 5) = False Then
            LrText(jsqte).Enabled = False
        End If
        TextValiJudgeLock(jsqte) = True
    Next jsqte
End Sub
Private Function TextYxxpd(Index As Integer) As Boolean           '文本框有效性判断
    Dim Sqlstr As String
    Dim Findrec As ADODB.Recordset
  
    '文本框内容未曾改变不进行有效性判断
    If TextValiJudgeLock(Index) Then
        TextYxxpd = True
        Exit Function
    End If
  
    '文本框内容为空认为有效,并清空其Tag值
    If Trim(LrText(Index)) = "" Then
        LrText(Index).Tag = ""
        Call Wbklrwbcl(Index)
        TextValiJudgeLock(Index) = True
        TextYxxpd = True
        Exit Function
    End If
  
    '可在此加入不做有效性判断的理由
  
    Select Case Textint(Index, 4)
        Case 1      '编码型
            Sqlstr = Trim(Textstr(Index, 5))
            Sqlstr = Replace(Sqlstr, "@", "'" + Trim(LrText(Index).Text) + "'")
            Set Findrec = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
            If Findrec.EOF Then
                Call Xtxxts(Trim(Textstr(Index, 6)), 0, 1)
                LrText(Index).SetFocus
                Exit Function
            Else
                Select Case Textint(Index, 3)
                    Case 0
                        If Len(Trim(Textstr(Index, 2))) <> 0 Then
                            LrText(Index).Text = Trim(Findrec.Fields(Trim(Textstr(Index, 2))))
                        End If
                        If Len(Trim(Textstr(Index, 3) & "")) <> 0 Then
                            LrText(Index).Tag = Trim(Findrec.Fields(Trim(Textstr(Index, 3))))
                        End If
                    Case 1
                        If Len(Trim(Textstr(Index, 3) & "")) <> 0 Then
                            LrText(Index).Text = Trim(Findrec.Fields(Trim(Textstr(Index, 3))))
                        End If
                        If Len(Trim(Textstr(Index, 2))) <> 0 Then
                            LrText(Index).Tag = Trim(Findrec.Fields(Trim(Textstr(Index, 2))))
                        End If
                End Select
            End If
        Case 2      '日期型
            If IsDate(LrText(Index).Text) Then
                LrText(Index).Text = Format(LrText(Index).Text, "yyyy-mm-dd")
                If Val(Mid(LrText(Index), 1, 4)) < 1900 Then
                    LrText(Index).Text = "1900" + Mid(LrText(Index), 5, 6)
                End If
            Else
                Tsxx = "非法公历日期!(格式:" + Format(Date, "yyyy-mm-dd") + ")"
                Call Xtxxts(Tsxx, 0, 1)
                LrText(Index).SetFocus
                Exit Function
            End If
        Case 3      '其他类型
    End Select
    
    '如果有效则加锁,用户不改变内容则不再进行有效性判断
    TextValiJudgeLock(Index) = True
    '调用文本框事后处理程序
    Call Wbklrwbcl(Index)
  
    '有效性判断通过则返回True
    TextYxxpd = True
   
End Function
Private Sub ShowBill()
    '调入用户查询结果动态集,并定位该单据
    Sqlstr = "SELECT dbo.RP_Note.*, dbo.Gy_ForeignCurrency.ForeignCurrName AS ForeignCurrName " & _
            "FROM dbo.Gy_ForeignCurrency INNER JOIN  dbo.RP_Note ON " & _
            "dbo.Gy_ForeignCurrency.ForeignCurrCode = dbo.RP_Note.ForeignCurrCode where NoteId='" & XT_BillID & "'"
    Set RecTemp = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
    LrText(0).Text = RecTemp.Fields("NoteCode")
    LrText(1).Text = RecTemp.Fields("YbSsJe") + Val(RecTemp.Fields("YbInterest") & "") '票面+利息
    LrText(3).Text = Xtrq
    LrText(2).Tag = RecTemp.Fields("ForeignCurrCode")
    LrText(2).Text = RecTemp.Fields("ForeignCurrName")
    Call Sub_GetAccRate(LrText(2).Tag, Bln_ConVertFlag, Dbl_AccRate)    '取外币记帐汇率，和汇兑方式
    LrText(5).Text = Dbl_AccRate
End Sub
Private Function SaveBill()                   '存储背书数据
    Dim Rec_Bill As New ADODB.Recordset
    Dim jsqte As Integer
    Dim Int_Kjyear As Integer                 '会计年度
    Dim Int_Period As Integer                 '会计期间
    Dim JE As Double                          '背书金额
    
    '保存其它应付单用变量
    Dim BillCode As String                   '其它应付单单据代码
    Dim OtherBillCode As String              '其它应付单编码
    Dim OtherBillId As Integer               '其它应付单ID
    Dim RecTemp As New ADODB.Recordset
    SaveBill = False
    '一.============先对单据内容进行有效性判断==============='
  
    '先进行字段不能为空或不能为零有效性判断(Fixed)
    For jsqte = 0 To Max_Text_Index
        If Textint(jsqte, 8) = 1 Then     '字段不能为空
            If Len(Trim(LrText(jsqte).Text)) = 0 Then
                Tsxx = Textstr(jsqte, 7) & "不能为空!"
                Call Xtxxts(Tsxx, 0, 1)
                LrText(jsqte).SetFocus
                Exit Function
            End If
        Else
            If Textint(jsqte, 8) = 2 Then   '字段不能为零
                If Val(Trim(LrText(jsqte).Text)) = 0 Then
                    Tsxx = Textstr(jsqte, 7) & "不能为零!"
                    Call Xtxxts(Tsxx, 0, 1)
                    LrText(jsqte).SetFocus
                    Exit Function
                End If
            End If
        End If
    Next jsqte
    
  
    '[>>
        '1.判断单据日期是否有效,如有效同时记录会计年度和会计期间
    If Not Fun_GetPeriod(CDate(Format(LrText(3).Text, "yyyy-mm-dd")), Int_Kjyear, Int_Period) Then
        LrText(3).SetFocus
        Exit Function
    End If
        '2.判断汇率
    If Trim(LrText(2).Tag) <> XtSCurrCode Then
       If Val(LrText(5).Text) = 0 Then
          Tsxx = "汇率不能为零!"
          Call Xtxxts(Tsxx, 0, 1)
          LrText(5).SetFocus
          Exit Function
       End If
    Else
       LrText(5).Text = 1
    End If
    
    '<<]
    Sqlstr = "SELECT * From Rp_Note where NoteId='" & XT_BillID & "'"
    Set RecTemp = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
    
   '2.开始存盘
    
    On Error GoTo Swcwcl
    Cw_DataEnvi.DataConnect.BeginTrans
    
    Sqlstr = "SELECT * From Rp_Note where NoteId='" & XT_BillID & "'"
    Set RecTemp = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
    '增加一张付款结算单
    If OptType(0).Value = True Then                                   '按冲销应付款方式背书
 
        Sqlstr = "Select * from RP_Note Where NoteId='" & XT_BillID & "'"
        Set RecTemp = Cw_DataEnvi.DataConnect.Execute(Sqlstr)
    
        BillCode = "0304"   '付款结算单编号
        OtherBillCode = CreatBillCode(BillCode, True) '
        OtherBillId = CreatBillID(BillCode)
    
        If Rec_Bill.State = 1 Then Rec_Bill.Close
        Rec_Bill.Open "Select * From Rp_CloseBill Where 1=2", Cw_DataEnvi.DataConnect, adOpenDynamic, adLockOptimistic
        With Rec_Bill
            .AddNew
            .Fields("CloseBillID") = OtherBillId                                      '单据ID
            .Fields("BillCode") = OtherBillCode                                       '单据编号
            .Fields("SourceBillCode") = Trim(LrText(0).Text)                          '形成该应收单的单据号
            .Fields("BillDate") = CDate(LrText(3).Text)                               '单据日期
            .Fields("ForeignCurrCode") = Trim(LrText(2).Tag)                          '币别编码
            .Fields("YbSsJe") = Val(LrText(6).Text)                                   '背书金额
            .Fields("AccRate") = Val(LrText(5).Text)                                  '汇率
            If Bln_ConVertFlag Then
                .Fields("BbSsJe") = Val(Format(Val(LrText(6).Text) / Val(LrText(5).Text), "##." + String(Xtjexsws, "0")))
            Else
                .Fields("BbSsJe") = Val(Format(Val(LrText(6).Text) * Val(LrText(5).Text), "##." + String(Xtjexsws, "0")))
            End If
            
            .Fields("PsCode") = LrText(4).Tag                                         '背书单位编码
        
            .Fields("DeptCode") = RecTemp.Fields("DeptCode")                          '部门编码
            .Fields("PersonCode") = RecTemp.Fields("PersonCode")                      '经办人编码
            .Fields("Digest") = Trim((LrText(8).Text) & "") & "应收票据背书" & Trim(LrText(0).Text)                           '摘要"
            .Fields("Maker") = Xtczy                                                  '制单人
            
            '系统自动保存应付帐款科目
            .Fields("AccCodeArAp") = LrText(7).Tag
            '应收票据科目
            If .Fields("BillItemCode") = "01" Then
                .Fields("AccCode") = Fun_GetInputCode("AR_CommNoteAccCode")           '商业承兑汇票科目
            Else
                .Fields("AccCode") = Fun_GetInputCode("AR_BankNoteAccCode")           '银行承兑汇票科目
            End If
            
            '后台处理
            .Fields("RPFlag") = "AP"                                                  '应付标识
            .Fields("KJYear") = Int_Kjyear                                            '会计年度
            .Fields("Period") = Int_Period                                            '会计期间
            .Fields("BillItemCode") = "90"                                            '单据类型编码
            .Fields("VouchId") = 0                                                    '凭证关联标识
            .Fields("IfBuildVouch") = 1   '目的是该付款结算单在“选择应付单做凭证时不被选中”是否生成凭证
            .Fields("OverStatus") = 0
            .Update
        End With
    End If
    
    '写入变动单据表
    If Rec_Bill.State = 1 Then Rec_Bill.Close
    Rec_Bill.Open "Select * From Rp_NoteClose Where 1=2", Cw_DataEnvi.DataConnect, adOpenDynamic, adLockOptimistic
    With Rec_Bill
        .AddNew
        .Fields("NoteId") = XT_BillID                      '单据号
        .Fields("CloseDate") = CDate(LrText(3).Text)       '背书日期
        .Fields("EndorseCusCode") = Trim(LrText(4).Tag)    '背书单位
        .Fields("ForeignCurrCode") = Trim(LrText(2).Tag)   '原币编码
        .Fields("YbCash") = Val(Trim(LrText(6).Text))      '原币背书金额
        .Fields("AccRate") = Val(Trim(LrText(5).Text))     '记帐汇率
        .Fields("PsCode") = RecTemp.Fields("PsCode")       '客户编码
        .Fields("Digest") = Trim(LrText(8).Text)           '备注
        If Bln_ConVertFlag Then                            '本币背书金额
            .Fields("BbCash") = Val(Format(Val(LrText(6).Text) / Val(LrText(5).Text), "##." + String(Xtjexsws, "0")))
        Else
            .Fields("BbCash") = Val(Format(Val(LrText(6).Text) * Val(LrText(5).Text), "##." + String(Xtjexsws, "0")))
        End If
        .Fields("DeptCode") = Trim(RecTemp.Fields("DeptCode") & "")       '部门编码
        .Fields("PersonCode") = Trim(RecTemp.Fields("PersonCode") & "")   '经办人编码
        .Fields("AccCodeNote") = Trim(RecTemp.Fields("AccCode") & "")     '应收票据科目
        .Fields("AccCode") = LrText(7).Tag                                '背书科目编码
        
        
        '系统名
        .Fields("RPFlag") = "Ar"
        
        '单据所属的会计期间
        .Fields("KjYear") = Int_Kjyear
        .Fields("Period") = Int_Period
        
        '单据类型
        .Fields("BillItemCode") = "43"
        
        
        '票据利息科目
        .Fields("AccCodeInterest") = Fun_GetInputCode("AR_NoteIntAccCode")  '承兑利息科目
        
        '票据费用科目
        .Fields("AccCodeExpense") = Fun_GetInputCode("AR_NoteFareAccCode")
        .Fields("BillIDAp") = OtherBillId
        .Update
        
        '系统读出单据ID写入Lab_BillID
    End With
    
    
            
    Cw_DataEnvi.DataConnect.CommitTrans
    Tsxx = "保存完毕！"
    SaveBill = True
    Call Xtxxts(Tsxx, 0, 4)
    Exit Function
Swcwcl:       '数据存盘时出现错误
    Cw_DataEnvi.DataConnect.RollbackTrans
    Tsxx = "存盘过程中出现未知错误,程序自动恢复保存前状态!"
    Call Xtxxts(Tsxx, 0, 1)
    Exit Function
        
End Function

						