开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 多媒体 > DVD > 查看源码
intdrv.S
资源名称：8202s_8281s_050405_dvd_622.rar　[点击查看]
上传用户：caisangzi8
上传日期：2013-10-25
资源大小：15756k
文件大小：28k
源码类别：

DVD

开发平台：

C/C++

intdrv.S：源码内容
  1. //
  2. // FILE
  3. // intdrv.S
  4. //
  5. // DESCRIPTION
  6. // interrupt service routines.
  7. //
  9. #include "ver.h"
  10. #include "regdef.h"
  11. #include "regmapa.h"
  12. #include "intdef.h"
  13. #include "pu8560.h"
  14. #include "user_init.h"
  15. #include "set.h"
  17. #define RGST_BASE    0xbffe8000
  18. #define TASK_ENTRY    4
  20. //#define SPURIOUS_PANIC
  22. #define SUPPORT_INTR_SW0
  23. #define SUPPORT_INTR_SW1
  24. #define SUPPORT_INTR_HW2
  25. #define SUPPORT_INTR_HW3
  26. #define SUPPORT_INTR_HW4
  27. #define SUPPORT_INTR_HW5
  29. #ifndef DVDRELEASE
  30. #define SUPPORT_UART0_FIFO
  31. #endif
  33. #define INTR_UART0_VECTOR   intr_uart0_null
  34. #define INTR_UART1_VECTOR   intr_uart1_null
  36. #ifdef  SUPPORT_UART0_FIFO
  37. #undef  INTR_UART0_VECTOR
  38. #define INTR_UART0_VECTOR   intr_uart0_fifo
  39. #endif
  40. #ifdef  SUPPORT_UART1_FIFO
  41. #undef  INTR_UART1_VECTOR
  42. #define INTR_UART1_VECTOR   intr_uart1_fifo
  43. #endif
  45. #define ERET(r)             
  46.         .set    noreorder;      
  47.         jr      r;              
  48.         rfe;                    
  49.         .set    reorder
  51. /*
  52. ** FUNCTION
  53. ** __exception_arise
  54. **
  55. ** DESCRIPTION
  56. ** first exception-handler
  57. ** 1. check C0_CAUSE for exception_cause [IP7-IP0]
  58. */
  59.                 .global    __exception_arise
  60.                 .ent    __exception_arise
  61. __exception_arise:
  62.                 mfc0    k0, C0_CAUSE            // load C0_CAUSE
  63.                 li      k1, EXCCODE_Int<<2    
  64.                 andi    k0, (0x001f<<2)         // extract exception-code field
  65.                                                 // .EEE-EE..
  66.                                                 // CP0_CAUSE[6:2]
  67.                 beq     k1, k0, __exception_chk_intr
  69. #ifndef DVDRELEASE                
  70.                 li      k1, EXCCODE_Sys<<2    
  71.                 beq     k1, k0, __exception_chk_syscall
  72. #endif
  73.                 
  74.                 li      k1, EXCCODE_RI<<2
  75.                 beq     k1, k0, __exception_chk_ri
  76.                 li      k1, EXCCODE_Bp<<2
  77.                 beq     k1, k0, __exception_chk_bp
  78.                 li      k1, EXCCODE_CpU<<2
  79.                 beq     k1, k0, __exception_chk_cpu        
  80.                 li      k1, EXCCODE_Ov<<2
  81.                 beq     k1, k0, __exception_chk_ov
  82.                 li      k1, EXCCODE_AdEL<<2
  83.                 beq     k1, k0, __exception_chk_adel
  84.                 li      k1, EXCCODE_AdES<<2
  85.                 beq     k1, k0, __exception_chk_ades
  87. __exception_chk_ri:
  88. __exception_chk_bp:
  89. __exception_chk_cpu:
  90. __exception_chk_ov:
  91. __exception_chk_adel:
  92. __exception_chk_ades:
  93.                 la      k0, exception_panic
  94.                 b       __panic_service
  96. __exception_mmu:
  97.                 la      k0, exception_mmu
  98.                 b       __panic_service
  99.     
  101. //
  102. // __exception_chk_intr:
  103. //
  104. // checking IP7-0
  105. // currently the external interrupt are all wired
  106. // into IntreqN[0] (IntreqN[5:0]), and that is mapped
  107. // into IP2.  Since there are no other interrupt enabled,
  108. // we simple jump to exception_intr
  109. //
  110. __exception_chk_intr:
  111.                 mfc0    k0, C0_CAUSE
  112. __exception_chk_intr7:
  113.                 andi    k1, k0, CAUSE_IP2            /* INT_GRP_0 */
  114.                 bnez    k1, check_inthw0_sources
  116.                 andi    k1, k0, CAUSE_IP3            /* INT_GRP_1 */
  117.                 bnez    k1, check_inthw1_sources
  119. #ifdef  SUPPORT_INTR_HW2
  120.                 andi    k1, k0, CAUSE_IP4          
  121.                 bnez    k1, check_inthw2_sources
  122. #endif
  124. #ifdef  SUPPORT_INTR_HW3
  125.                 andi    k1, k0, CAUSE_IP5         
  126.                 bnez    k1, check_inthw3_sources
  127. #endif
  129. #ifdef  SUPPORT_INTR_HW4
  130.                 andi    k1, k0, CAUSE_IP6        
  131.                 bnez    k1, check_inthw4_sources
  132. #endif
  134. #ifdef  SUPPORT_INTR_HW5
  135.                 andi    k1, k0, CAUSE_IP7       
  136.                 bnez    k1, check_inthw5_sources
  137. #endif
  139. #ifdef  SUPPORT_INTR_SW0
  140.                 andi    k1, k0, CAUSE_IP0      
  141.                 bnez    k1, check_intsw0_sources
  142. #endif
  144. #ifdef  SUPPORT_INTR_SW1
  145.                 andi    k1, k0, CAUSE_IP1      
  146.                 bnez    k1, check_intsw1_sources
  147. #endif
  149.                 b         __exception_leave
  150.         
  151. #ifdef  SUPPORT_INTR_SW0
  152. check_intsw0_sources:
  153.                 li      k0, 0
  154.                 la      k1, intr_sw0
  155.                 b        __interrupt_service
  156. #endif
  158. #ifdef  SUPPORT_INTR_SW1
  159. check_intsw1_sources:
  160.                 li      k0, 0
  161.                 la      k1, intr_sw1
  162.                 b        __interrupt_service
  163. #endif
  165. #ifdef  SUPPORT_INTR_HW2
  166. check_inthw2_sources:
  167.                 li      k0, 0
  168.                 la      k1, intr_hw2
  169.                 b        __interrupt_service
  170. #endif
  172. #ifdef  SUPPORT_INTR_HW3
  173. check_inthw3_sources:
  174.                 li      k0, 0
  175.                 la      k1, intr_hw3
  176.                 b        __interrupt_service
  177. #endif
  179. #ifdef  SUPPORT_INTR_HW4
  180. check_inthw4_sources:
  181.                 li      k0, 0
  182.                 la      k1, intr_hw4
  183.                 b        __interrupt_service
  184. #endif
  186. #ifdef  SUPPORT_INTR_HW5
  187. check_inthw5_sources:
  188.                 li      k0, 0
  189.                 la      k1, intr_hw5
  190.                 b        __interrupt_service
  191. #endif
  193. __exception_leave:
  194.                 mfc0    k0, C0_EPC
  195.                 ERET(k0)
  196.                 .end    __exception_arise
  199. /*
  200. ** ENTRY HW0 bit
  201. ** check_inthw0_sources:
  202. */
  203. check_inthw0_sources:
  204.                 li      k0, RGST_BASE                   // load register-file-base
  205.                 lw      k1, RF_INTR_MASKED_FLAG(k0)     // k1 = int-flag-0
  206.                 beqz    k1, __exception_leave
  208.                 andi    k0, k1, INTR_FIELD_END          // 10: field_end interrupt
  209.                 bnez    k0, __entry_field_end           // 
  210. #ifdef SPHE8202
  211.                 andi    k0, k1, INTR_SRV_INT0           // 1: SRVINT0
  212.                 bnez    k0, __entry_srv0
  213. #endif
  214.                 andi    k0, k1, INTR_DECERR             // 15: dec-err
  215.                 bnez    k0, __entry_decerr
  217.                 andi    k0, k1, INTR_PIC_END            // 5: v_pic_end interrupt
  218.                 bnez    k0, __entry_pic_end
  220.                 andi    k0, k1, INTR_FIELD_START        // 9: field_start interrupt
  221.                 bnez    k0, __entry_field_start         // 
  223.                 andi    k0, k1, INTR_TIMER0             // 12: timer0 interrupt
  224.                 bnez    k0, __entry_timer0
  226.                 andi    k0, k1, INTR_TIMER1             // 13: timer1 interrupt
  227.                 bnez    k0, __entry_timer1
  229. #if defined(SPHE1000) && defined(SUPPORT_USB)
  230.                 andi    k0, k1, INTR_USB             // 13: timer1 interrupt
  231.                 bnez    k0, __entry_usb
  232. #endif
  234.                 andi    k0, k1, INTR_H_PIO_INT          // 8: h_pio_int interrupt
  235.                 bnez    k0, __entry_h_pio
  236. #ifdef SPHE1000
  237. andi k0, k1, INTR_DISPATCH_MIPZ // 1: DISPATCH MIPZ
  238. bnez k0, __entry_srv0
  239. #else
  240. #ifndef SPHE8202
  241.                 andi    k0, k1, INTR_SRV_INT0           // 1: SRVINT0
  242.                 bnez    k0, __entry_srv0
  243. #endif
  244.                 andi    k0, k1, INTR_SRV_INT1           // 2: SRVINT1
  245.                 bnez    k0, __entry_srv1
  247.                 andi    k0, k1, INTR_SRV_INT2           // 3: SRVINT2
  248.                 bnez    k0, __entry_srv2 
  250.                 andi    k0, k1, INTR_SRV_INT3           // 4: SRVINT3
  251.                 bnez    k0, __entry_srv3 
  252. #endif
  254.                 andi    k0, k1, INTR_DSP_INT            // 0: dsp interrupt
  255.                 bnez    k0, __entry_dsp
  256.                         
  257.                 andi    k0, k1, INTR_UART0_INT          // 6: UART0
  258.                 bnez    k0, __entry_uart0
  260.                 andi    k0, k1, INTR_UART1_INT          // 7: UART1
  261.                 bnez    k0, __entry_uart1
  263.                 // this interrupts is FATAL-ERROR
  264.                 andi    k0, k1, INTR_RI_WATCHDOG
  265.                 bnez    k0, __entry_ri_watchdog
  267. #ifdef    SPURIOUS_PANIC
  268.                 b       spurious_panic
  269. #endif
  270.                 // clear this spurious int-flag (#0) and leave
  271.                 li      k0, RGST_BASE
  272.                 sw      k1, RF_INTR_FLAG(k0)
  273.                 b       __exception_leave
  275. /*
  276. ** spurious_panic
  277. */
  278. spurious_panic:
  279.                 la      k0, intr_panic                  // intr_panic(intr_flag, epc)
  280.                 b       __panic_service
  282. __entry_lswitch_intr:
  283.                 la      k0, intr_ls_watchdog
  284.                 b       __panic_service
  286. __entry_sdctrl:
  287. #ifdef SPHE8202
  288. #ifndef DVDRELEASE//terry,2004/4/13 01:43PM
  289.                 li      k0, RGST_BASE
  290.                 sw      k1, RF_INTR1_FLAG(k0)           // disable 
  291.                 lw      k1, (0x350+4*7)(k0)             // k1: signature
  292.                 li      k0, 5<<4
  293.                 andi    k1, ((0x0f)<<4)
  294.                 beq     k0, k1, intr_sd_leave
  295.                 li      k0, 6<<4
  296.                 beq     k0, k1, intr_sd_leave
  297.                 li      k1, 0
  298. #endif                
  299. #endif
  300.                 la      k0, intr_sd
  301.                 b       __panic_service
  303. #ifdef SPHE8202
  304. #ifndef DVDRELEASE//terry,2004/4/13 01:43PM
  305. intr_sd_leave:
  306.                 li      k0, RGST_BASE
  307.                 sw      zero, RF_SDCTRL_INT(k0)
  308.                 b       __exception_leave
  309. #endif                
  310. #endif
  312. __entry_ri_watchdog:
  313.                 la      k0, intr_ri_watchdog
  314.                 b       __panic_service
  316. __entry_watchdog:
  317.                 la      k0, intr_watchdog
  318.                 b       __panic_service
  321. /*
  322. ** ENTRY
  323. ** check_inthw1_sources:
  324. */
  325. check_inthw1_sources:
  326.                 li      k0, RGST_BASE                   // load register-file-base
  327.                 lw      k1, RF_INTR1_MASKED_FLAG(k0)    // k1 = int-flag-1
  328.                 beqz    k1, __exception_leave
  329.                 
  330. #ifdef SPHE1000
  331. andi k0, k1, INTR1_PCI0
  332. bnez k0, __entry_risc0
  333. #else
  334.                 andi    k0, k1, INTR1_RISC_INT0         // 12: RISCINT4
  335.                 bnez    k0, __entry_risc0
  337.                 andi    k0, k1, INTR1_RISC_INT1         // 11: RISCINT1
  338.                 bnez    k0, __entry_risc1
  340.                 andi    k0, k1, INTR1_RISC_INT2         // 10: RISCINT2
  341.                 bnez    k0, __entry_risc2
  343.                 andi    k0, k1, INTR1_RISC_INT3         // 9: RISCINT3
  344.                 bnez    k0, __entry_risc3
  345.                 
  346.                 andi    k0, k1, INTR1_RISC_INT4         // 12: RISCINT4
  347.                 bnez    k0, __entry_risc4
  348. #endif
  349.                 
  350.                 andi    k0, k1, INTR1_TIMERW
  351.                 bnez    k0, __entry_watchdog            // WATCHDOG
  353.                 andi    k0, k1, INTR1_TIMER2A
  354.                 bnez    k0, __entry_timer2a             // TIMER2a
  356.                 andi    k0, k1, INTR1_TIMER2B
  357.                 bnez    k0, __entry_timer2b             // TIMER2b
  359.                 andi    k0, k1, INTR1_TIMER3A
  360.                 bnez    k0, __entry_timer3a             // TIMER3a
  362.                 andi    k0, k1, INTR1_TIMER3B
  363.                 bnez    k0, __entry_timer3b             // TIMER3b
  365.                 // these interrupts are FATAL-ERROR
  366.                 andi    k0, k1, INTR1_LSWITCH_INTR_FLAG
  367.                 bnez    k0, __entry_ri_watchdog         // WATCHDOG
  368.                 
  369. #ifdef    SPHE8202
  370.                 andi    k0, k1, INTR1_USB
  371.                 bnez    k0, __entry_usb                 // USB
  372. #endif                
  373.                 andi    k0, k1, INTR1_SD
  374.                 bnez    k0, __entry_sdctrl              // SDRAM controller
  376. #ifdef    SPURIOUS_PANIC
  377.                 b        spurious_panic
  378. #endif
  380.                 // clear other unknown interrupt flags and leave
  381.                 li        k0, RGST_BASE            
  382.                 sw        k1, RF_INTR1_FLAG(k0)
  383.                 b        __exception_leave
  386. //
  387. // interrupt vectors #0
  388. //
  389. __entry_field_end:
  390.                 la        k1, intr_field_end
  391.                 b        __interrupt_service
  393. __entry_field_start:
  394.                 la        k1, intr_field_start
  395.                 b        __interrupt_service
  397. __entry_pic_end:
  398.                 la        k1, intr_pic_end
  399.                 b        __interrupt_service
  401. __entry_timer0:
  402. #ifdef DVDRELEASE
  403.                 la        k1, intr_timer0
  404.                 b        __interrupt_service
  405. #else
  406.                 la        k1, intr_timer0
  407.                 b        __taskX_service
  408. #endif
  410. __entry_h_pio:
  411.                 la        k1, intr_host_pio
  412.                 b        __interrupt_service
  414. __entry_timer1:
  415.                 la        k1, intr_timer1
  416.                 b        __interrupt_service
  418. __entry_decerr:
  419.                 la        k1, intr_decerr
  420.                 b        __interrupt_service
  422. __entry_uart0:
  423.                 la        k1, INTR_UART0_VECTOR
  424.                 b        __interrupt_service
  426. __entry_uart1:
  427.                 la        k1, INTR_UART1_VECTOR
  428.                 b        __interrupt_service
  430. #if defined(SPHE1000) && defined(SUPPORT_USB)
  431. __entry_usb:    la        k1, uhci_USBISR
  432. b  __interrupt_service
  433. #endif
  435. __entry_srv3:
  436. #ifdef DVD_SERVO
  437.                 la        k1, ServoDecoderISR_4
  438. #endif
  439.                 b        __interrupt_service
  441. __entry_srv2:
  442. #ifdef DVD_SERVO
  443.                 la        k1, ServoDecoderISR_3
  444. #endif
  445.                 b        __interrupt_service
  447. __entry_srv1:
  448. #ifdef DVD_SERVO
  449.                 la        k1, ServoDecoderISR_2
  450. #endif
  451.                 b        __interrupt_service
  452.                 
  453. __entry_srv0:
  454. #ifdef DVD_SERVO
  455.                 la        k1, ServoDecoderISR_1
  456. #endif
  457. #ifdef SPHE1000
  458. la        k1, intr_dispatch_mipz
  459. #endif
  460.                 b        __interrupt_service
  462. __entry_dsp:
  463.                 la        k1,dsp_intr
  464.                 b        __interrupt_service
  466. //
  467. // interrupt vectors #1
  468. //
  469. __entry_risc4:
  470.                 la        k1, intr_risc4
  471.                 b        __interrupt_service
  473. __entry_risc3:
  474.                 la        k1, intr_risc3
  475.                 b        __interrupt_service
  477. __entry_risc2:
  478.                 la        k1, intr_risc2
  479.                 b        __interrupt_service
  481. __entry_risc1:
  482.                 la        k1, intr_risc1
  483.                 b        __interrupt_service
  484.                 
  485. __entry_risc0:
  486.                 la        k1, intr_risc0
  487.                 b        __interrupt_service
  489. __entry_timer2a:
  490.                 la        k1, intr_timer2a
  491.                 b        __interrupt1_service
  493. __entry_timer2b:
  494.                 la        k1, intr_timer2b
  495.                 b        __interrupt1_service
  497. __entry_timer3a:
  498.                 la        k1, intr_timer3a
  499.                 b        __interrupt1_service
  501. __entry_timer3b:
  502.                 la        k1, intr_timer3b
  503.                 b        __interrupt1_service
  504. #ifdef    SPHE8202
  505. __entry_usb:
  506.                 la        k1, uhci_USBISR
  507.                 b        __interrupt1_service
  508. #endif
  510. /*
  511. ** SAVE_REG/LOAD_REG
  512. */
  513. #include "regloc.h"
  515. #define    SAVE_REG(a,b,c)        sw    a, 4*b(c)
  516. #define    LOAD_REG(a,b,c)        lw    a, 4*b(c)
  518. /*
  519. ** INTR_SAVE_REG
  520. ** save AT/v0~v1/a0~a3/t0~t9/s6/gp/ra/EPC registers
  521. */
  522. #define INTR_SAVE_REG()     
  523.         subu    sp, +4*REGLOCi_NUM;     
  524.         .set noat;                      
  525.         SAVE_REG(AT, REGLOCi_AT, sp);   
  526.         .set at;                        
  527.         SAVE_REG(v0, REGLOCi_v0, sp);   
  528.         SAVE_REG(v1, REGLOCi_v1, sp);   
  529.         mfc0    v0, C0_EPC;             
  530.         SAVE_REG(a0, REGLOCi_a0, sp);   
  531.         SAVE_REG(a1, REGLOCi_a1, sp);   
  532.         SAVE_REG(a2, REGLOCi_a2, sp);   
  533.         SAVE_REG(a3, REGLOCi_a3, sp);   
  534.         SAVE_REG(t0, REGLOCi_t0, sp);   
  535.         SAVE_REG(t1, REGLOCi_t1, sp);   
  536.         SAVE_REG(t2, REGLOCi_t2, sp);   
  537.         SAVE_REG(t3, REGLOCi_t3, sp);   
  538.         SAVE_REG(t4, REGLOCi_t4, sp);   
  539.         SAVE_REG(t5, REGLOCi_t5, sp);   
  540.         SAVE_REG(t6, REGLOCi_t6, sp);   
  541.         SAVE_REG(t7, REGLOCi_t7, sp);   
  542.         SAVE_REG(t8, REGLOCi_t8, sp);   
  543.         SAVE_REG(t9, REGLOCi_t9, sp);   
  544.         SAVE_REG(s6, REGLOCi_s6, sp);   
  545.         SAVE_REG(gp, REGLOCi_gp, sp);   
  546.         SAVE_REG(ra, REGLOCi_ra, sp);   
  547.         SAVE_REG(v0, REGLOCi_EPC, sp); 
  550. /*
  551. ** INTR_LOAD_REG
  552. ** load AT/v0~v1/a0~a3/t0~t9/s6/gp/ra registers
  553. ** load EPC to k1
  554. */
  555. #define INTR_LOAD_REG()     
  556.         .set noat;                      
  557.         LOAD_REG(AT, REGLOCi_AT, sp);   
  558.         .set at;                        
  559.         LOAD_REG(v0, REGLOCi_v0, sp);   
  560.         LOAD_REG(v1, REGLOCi_v1, sp);   
  561.         LOAD_REG(a0, REGLOCi_a0, sp);   
  562.         LOAD_REG(a1, REGLOCi_a1, sp);   
  563.         LOAD_REG(a2, REGLOCi_a2, sp);   
  564.         LOAD_REG(a3, REGLOCi_a3, sp);   
  565.         LOAD_REG(t0, REGLOCi_t0, sp);   
  566.         LOAD_REG(t1, REGLOCi_t1, sp);   
  567.         LOAD_REG(t2, REGLOCi_t2, sp);   
  568.         LOAD_REG(t3, REGLOCi_t3, sp);   
  569.         LOAD_REG(t4, REGLOCi_t4, sp);   
  570.         LOAD_REG(t5, REGLOCi_t5, sp);   
  571.         LOAD_REG(t6, REGLOCi_t6, sp);   
  572.         LOAD_REG(t7, REGLOCi_t7, sp);   
  573.         LOAD_REG(t8, REGLOCi_t8, sp);   
  574.         LOAD_REG(t9, REGLOCi_t9, sp);   
  575.         LOAD_REG(s6, REGLOCi_s6, sp);   
  576.         LOAD_REG(gp, REGLOCi_gp, sp);   
  577.         LOAD_REG(ra, REGLOCi_ra, sp);   
  578.         LOAD_REG(k1, REGLOCi_EPC, sp);  
  579.         addiu    sp, +4*REGLOCi_NUM;
  582. #define TASK_LOAD_REG(r)       
  583.         .set noat;                      
  584.         LOAD_REG(k1, REGLOC_EPC, r);    
  585.         LOAD_REG(AT, REGLOC_AT, r);     
  586.         LOAD_REG(v0, REGLOC_v0, r);     
  587.         LOAD_REG(v1, REGLOC_v1, r);     
  588.         LOAD_REG(a0, REGLOC_a0, r);     
  589.         LOAD_REG(a1, REGLOC_a1, r);     
  590.         LOAD_REG(a2, REGLOC_a2, r);     
  591.         LOAD_REG(a3, REGLOC_a3, r);     
  592.         LOAD_REG(t0, REGLOC_t0, r);     
  593.         LOAD_REG(t1, REGLOC_t1, r);     
  594.         LOAD_REG(t2, REGLOC_t2, r);     
  595.         LOAD_REG(t3, REGLOC_t3, r);     
  596.         LOAD_REG(t4, REGLOC_t4, r);     
  597.         LOAD_REG(t5, REGLOC_t5, r);     
  598.         LOAD_REG(t6, REGLOC_t6, r);     
  599.         LOAD_REG(t7, REGLOC_t7, r);     
  600.         LOAD_REG(s0, REGLOC_s0, r);     
  601.         LOAD_REG(s1, REGLOC_s1, r);     
  602.         LOAD_REG(s2, REGLOC_s2, r);     
  603.         LOAD_REG(s3, REGLOC_s3, r);     
  604.         LOAD_REG(s4, REGLOC_s4, r);     
  605.         LOAD_REG(s5, REGLOC_s5, r);     
  606.         LOAD_REG(s6, REGLOC_s6, r);     
  607.         LOAD_REG(s7, REGLOC_s7, r);     
  608.         LOAD_REG(t8, REGLOC_t8, r);     
  609.         LOAD_REG(t9, REGLOC_t9, r);     
  610.         LOAD_REG(gp, REGLOC_gp, r);     
  611.         LOAD_REG(sp, REGLOC_sp, r);     
  612.         LOAD_REG(fp, REGLOC_fp, r);     
  613.         LOAD_REG(ra, REGLOC_ra, r);     
  614.         .set at
  616. /*
  617. ** __interrupt_service:
  618. **
  619. ** when entering this point:
  620. **    k0: interrupt_flag (to be cleared)
  621. **    k1: interrupt routine
  622. **
  623. ** save only caller-saved registers
  624. ** AT
  625. ** v0/v1
  626. ** a0/a1/a2/a3
  627. ** t0/t1/t2/t3/t4/t5/t6/t7/t8/t9
  628. ** s6 (load with register-pointer)
  629. ** gp (load with global-pointer)
  630. ** ra
  631. */
  632.                 .global __interrupt_service
  633.                 .ent    __interrupt_service
  634. __interrupt_service:
  636.                 INTR_SAVE_REG()
  638.                 lw      gp, s_gp                        /* setup $gp                    */
  639.                 li      s6, RGST_BASE                   /* load global pointer (s6)     */
  640.                 lw      v0, RF_INTR_FLAG(s6)            /* load interrupt flag in v0    */
  641.                 sw      k0, RF_INTR_FLAG(s6)            /* clear interrupt flag         */
  643. __interruptXXX:
  644. #ifdef  DVDRELEASE
  645.                 jalr    k1                              /* call to service routine      */
  646. #else
  647.                 move    a0, k1
  648.                 addiu   sp, -8
  650.                 lw      v0, RF_INTR_MASK(s6)
  651.                 lw      v1, RF_INTR1_MASK(s6)
  652.                 sw      v0, 4(sp)
  653.                 sw      v1, 0(sp)
  654.                 li      v0, INTR_RI_WATCHDOG
  655. #ifdef ENABLE_SDRAM_OV_RANGE_INTR
  656.                 li      v1, INTR1_SD|INTR1_LSWITCH_INTR_FLAG|INTR1_TIMERW
  657. #else
  658.                 li      v1, INTR1_LSWITCH_INTR_FLAG|INTR1_TIMERW
  659. #endif
  661.                 sw      v0, RF_INTR_MASK(s6)
  662.                 sw      v1, RF_INTR1_MASK(s6)
  664.                 // enable interrupt
  665.                 mfc0    v1, C0_STATUS     
  666.                 ori     v1, STATUS_IEc
  667.                 mtc0    v1, C0_STATUS
  668.                 jalr    a0
  670.                 // disable interrupt
  671.                 mfc0    v1, C0_STATUS     
  672.                 ori     v1, STATUS_IEc
  673.                 xori    v1, STATUS_IEc
  674.                 mtc0    v1, C0_STATUS
  676.                 // restore mask
  677.                 lw      v0, 4(sp)
  678.                 lw      v1, 0(sp)
  679.                 sw      v0, RF_INTR_MASK(s6)
  680.                 sw      v1, RF_INTR1_MASK(s6)
  681.                 addiu   sp, 8
  682. #endif
  684.                 INTR_LOAD_REG()
  685.                 ERET(k1)
  686.                 .end    __interrupt_service
  689. /*
  690. ** __interrupt1_service:
  691. **
  692. ** when entering this point:
  693. **    k0: interrupt_flag (to be cleared)
  694. **    k1: interrupt routine
  695. **
  696. ** save only caller-saved registers
  697. ** AT
  698. ** v0/v1
  699. ** a0/a1/a2/a3
  700. ** t0/t1/t2/t3/t4/t5/t6/t7/t8/t9
  701. ** s6 (load with register-pointer)
  702. ** gp (load with global-pointer)
  703. ** ra
  704. */
  706.                 .global __interrupt1_service
  707.                 .ent    __interrupt1_service
  708. __interrupt1_service:
  710.                 INTR_SAVE_REG()
  712.                 lw      gp, s_gp                    /* setup $gp                    */
  713.                 li      s6, RGST_BASE                /* load global pointer (s6)        */
  714.                 lw      v0, RF_INTR1_FLAG(s6)        /* load interrupt flag in v0    */
  715.                 sw      k0, RF_INTR1_FLAG(s6)        /* clear interrupt flag            */
  716.                 b       __interruptXXX
  717. #if 0
  718.                 jalr    k1                            /* call to service routine        */
  720.                 INTR_LOAD_REG()
  721.                 ERET(k1)
  722. #endif
  723.                 .end    __interrupt1_service
  727. /*
  728. ** __taskX_service:
  729. **
  730. ** when entering this point:
  731. **    k0: interrupt_flag (to be cleared)
  732. **    k1: interrupt routine
  733. **
  734. ** save ALL registers
  735. ** fp/ra
  736. */
  737. #ifndef DVDRELEASE
  738.                 .extern task_state;
  739.                 .global __taskX_service
  740.                 .ent    __taskX_service
  741. __taskX_service:
  742.                 sw      t0, -4(sp)
  744.                 la      t0, task_state
  745.                 lw      t0, TASK_ENTRY(t0)    /* task_table_entry        */
  747.                 SAVE_REG(v0, REGLOC_v0, t0)
  748.                 SAVE_REG(v1, REGLOC_v1, t0)
  749.         
  750.                 move    v0, t0
  751.                 lw      t0, -4(sp)
  753.                 .set    noat
  754.                 SAVE_REG(AT, REGLOC_AT, v0)
  755.                 .set    at
  757.                 mfc0    v1, C0_EPC        /* load EPC in v1        */
  758. __taskX_service2:
  759.                 SAVE_REG(a0, REGLOC_a0, v0)
  760.                 SAVE_REG(a1, REGLOC_a1, v0)
  761.                 SAVE_REG(a2, REGLOC_a2, v0)
  762.                 SAVE_REG(a3, REGLOC_a3, v0)
  763.                 SAVE_REG(t0, REGLOC_t0, v0)
  764.                 SAVE_REG(t1, REGLOC_t1, v0)
  765.                 SAVE_REG(t2, REGLOC_t2, v0)
  766.                 SAVE_REG(t3, REGLOC_t3, v0)
  767.                 SAVE_REG(t4, REGLOC_t4, v0)
  768.                 SAVE_REG(t5, REGLOC_t5, v0)
  769.                 SAVE_REG(t6, REGLOC_t6, v0)
  770.                 SAVE_REG(t7, REGLOC_t7, v0)
  771.                 SAVE_REG(s0, REGLOC_s0, v0)
  772.                 SAVE_REG(s1, REGLOC_s1, v0)
  773.                 SAVE_REG(s2, REGLOC_s2, v0)
  774.                 SAVE_REG(s3, REGLOC_s3, v0)
  775.                 SAVE_REG(s4, REGLOC_s4, v0)
  776.                 SAVE_REG(s5, REGLOC_s5, v0)
  777.                 SAVE_REG(s6, REGLOC_s6, v0)
  778.                 SAVE_REG(s7, REGLOC_s7, v0)
  779.                 SAVE_REG(t8, REGLOC_t8, v0)
  780.                 SAVE_REG(t9, REGLOC_t9, v0)
  781.                 SAVE_REG(gp, REGLOC_gp, v0)
  782.                 SAVE_REG(sp, REGLOC_sp, v0)
  783.                 SAVE_REG(fp, REGLOC_fp, v0)
  784.                 SAVE_REG(ra, REGLOC_ra, v0)
  786.                 SAVE_REG(v1, REGLOC_EPC, v0)    /* save EPC            */
  788.                 lw      gp, s_gp                /* reload gp                */
  789.                 li      s6, RGST_BASE           /* load global pointer S6   */
  790.                 sw      k0, RF_INTR_FLAG(s6)    /* clear interrupt flag     */
  791.                 jalr    k1                      /* call to service routine  */
  793.                 la      k0, task_state
  794.                 lw      k0, TASK_ENTRY(k0)      /* task_table_entry         */
  796.                 TASK_LOAD_REG(k0)               /* load reg from k0 and write EPC to k1 */
  797.                 ERET(k1)
  798.                 .end    __taskX_service
  800. #endif
  801. /*
  802. ** __panic_service
  803. **
  804. ** when entering this point:
  805. **    k0: interrupt routine
  806. **
  807. ** NOTE:
  808. **   1. save ALL registers
  809. **   2. no return
  810. */
  811.                 .ent    __panic_service
  812. __panic_service:
  814. #ifndef DVDRELEASE
  815.                 la    k1, task_state
  816.                 lw    k1, TASK_ENTRY(k1)            /* load task_table_entry */
  818.                 SAVE_REG(v0, REGLOC_v0, k1)
  819.                 SAVE_REG(v1, REGLOC_v1, k1)
  820.         
  821.                 mfc0 v1, C0_EPC                     /* load EPC in v1        */
  822.                 move v0, k1
  824.                 lw   zero, 0(v1)                    /* load in d-cache      */
  825.                 lw   zero, 16(v1)                   /* load in d-cache      */
  826.                 lw   zero, 32(v1)                   /* load in d-cache      */
  827.                 lw   zero, 48(v1)                   /* load in d-cache      */
  829.                 .set    noat
  830.                 SAVE_REG(AT, REGLOC_AT, v0)
  831.                 .set    at
  832.                 SAVE_REG(a0, REGLOC_a0, v0)
  833.                 SAVE_REG(a1, REGLOC_a1, v0)
  834.                 SAVE_REG(a2, REGLOC_a2, v0)
  835.                 SAVE_REG(a3, REGLOC_a3, v0)
  836.                 SAVE_REG(t0, REGLOC_t0, v0)
  837.                 SAVE_REG(t1, REGLOC_t1, v0)
  838.                 SAVE_REG(t2, REGLOC_t2, v0)
  839.                 SAVE_REG(t3, REGLOC_t3, v0)
  840.                 SAVE_REG(t4, REGLOC_t4, v0)
  841.                 SAVE_REG(t5, REGLOC_t5, v0)
  842.                 SAVE_REG(t6, REGLOC_t6, v0)
  843.                 SAVE_REG(t7, REGLOC_t7, v0)
  844.                 SAVE_REG(s0, REGLOC_s0, v0)
  845.                 SAVE_REG(s1, REGLOC_s1, v0)
  846.                 SAVE_REG(s2, REGLOC_s2, v0)
  847.                 SAVE_REG(s3, REGLOC_s3, v0)
  848.                 SAVE_REG(s4, REGLOC_s4, v0)
  849.                 SAVE_REG(s5, REGLOC_s5, v0)
  850.                 SAVE_REG(s6, REGLOC_s6, v0)
  851.                 SAVE_REG(s7, REGLOC_s7, v0)
  852.                 SAVE_REG(t8, REGLOC_t8, v0)
  853.                 SAVE_REG(t9, REGLOC_t9, v0)
  854.                 SAVE_REG(gp, REGLOC_gp, v0)
  855.                 SAVE_REG(sp, REGLOC_sp, v0)
  856.                 SAVE_REG(fp, REGLOC_fp, v0)
  857.                 SAVE_REG(ra, REGLOC_ra, v0)
  858.                 SAVE_REG(v1, REGLOC_EPC, v0)        /* save EPC            */
  860. #endif
  861.                 lw      gp, s_gp                    // reload gp
  862.                 li      s6, RGST_BASE               // load global pointer s6
  863.                 jalr    k0                          // jump to target
  864.                 // no return
  865.                 .end    __panic_service
  868. #ifndef DVDRELEASE
  869. //
  870. // SYSCALL handler
  871. //
  872. __exception_chk_syscall:
  873.                 la      k0, task_state
  874.                 lw      k0, TASK_ENTRY(k0)        // k0: task_table_entry
  876.                 // save at/v0/v1 into task-table
  877.                 .set    noat
  878.                 SAVE_REG(v0, REGLOC_v0, k0)
  879.                 SAVE_REG(v1, REGLOC_v1, k0)
  880.                 move v0, k0
  881.                 SAVE_REG(AT, REGLOC_AT, v0)
  882.                 .set    at
  884.                 //
  885.                 // call to task-switching routine
  886.                 //
  887.                 // v0/v1/at saved
  888.                 // k0: flag
  889.                 // k1: intr-vect
  890.                 // v1: EPC
  891.                 //
  892.                 mfc0    v1, C0_EPC              // load EPC in v1
  893.                 li      k0, 0                   // FLAG: 0
  894.                 la      k1, intr_timer0         // INTR: timer0
  895.                 addiu   v1, 4                   // v1=v1+4
  896.                 b       __taskX_service2
  897. #endif