DVD

开发平台：
C/C++

dvdL.ldp：源码内容
							/*
*  History
*  Terry,2004/2/6 05:38PM
*/
#include "set.h"
#include "user_init.h"
#include "load.h"
#include "memmap0.h"
/*
** FILE
** dvdL.ld
** DESCRIPTION
** linker script for dvd system (in little-endian mode)
**
** ****************
** EMU-type0
**
** ROM      88000000
**          00400000
** SDRAM    80000000
**
** ****************
** EMU-type1 & ASIC-type0
**
** ROM      88000000 (granuate A)
**          80000000 (granuate ABC)
** SDRAM    80000000
*/
/*
** this file is VERY IMPORTANT for all systems. please keep
** every thing simple here for cleaness.
*/
#include "input_lib.h"
#define TO080(y)    (0x080000000+1024*(y))
#define TO180(y)	(0x180000000+1024*(y))
#define K(y)        (1024*(y))
//data ram,terry,2004/7/26 02:51PM
#define TO_DR(x,y)  (0x0bfff0000+1024*(y)+x)  
//stack pointer
#include "stack.ldp"
SECTIONS
{
/*===========================================================================
* SDRAM 1 ,code ,rom data
*=============================================================================*/
    /*
    * iop driver
    */
    .drv_iop :
    {
        _text_drv_iop = .;
        .       = ALIGN(16);
        *iop.o    (.rodata)
    } > sdram_drv_iop
    /*
    * iop standby driver
    */
    .drv_iop_rst :
    {
        .       = ALIGN(16);
        *ioprom.o    (.rodata)
    } > sdram_iop_rst
    /*
    * mpeg driver
    */
    .ramdrv1 :
    {
        _text_drv = .;
        .       = ALIGN(16);
        *rwdk.o     (.text*)
#ifndef UNLOAD_ROMCODE
#ifdef LOAD_MPEG
        *mpegsys*.o (.text*)
        *supdrv*.o  (.text*)        //terry,2004/2/4 04:22PM
        
#if !defined(BBK_DVD)&&!defined(NINTAUS_DVD) ||defined(NIN_612_4M) //terry,2003/12/17 06:18PM
        *setup_ui1.o (.text*)
#endif
#endif
#endif
    } > sdram_drv1
    /*
    * jpeg driver
    */
    .ramdrv2 :
    {
        .       = ALIGN(16);
#ifndef UNLOAD_ROMCODE
#ifdef LOAD_JPEG
        *jpegtest.o (.rodata)
        *jpegtest.o (.text*)
#endif
#endif
    } > sdram_drv2
    /*
    *  navigation
    */
    .drv_dvd :
    {
        _text_drv_dvd = .;
#if !defined(UNLOAD_ROMCODE)
#ifdef LOAD_NAV
        *nav.o      (.text*)
        *pgc.o      (.text*)
        *user_if.o  (.text*)
        *ncmd.o     (.text*)
        *ncmd_exe.o (.text*)
        *vts.o      (.text*)
        *vmg.o      (.text*)
        *preview.o  (.rodata)
        *preview.o  (.text*)
        *psd.o      (.rodata)
        *psd.o      (.text*)
        *v11.o      (.rodata)
        *v11.o      (.text*)
        *svcd.o     (.rodata)
        *svcd.o     (.text*)
        *cdg.o      (.rodata)
        *cdg.o      (.text*)
        *gf2m_c.o   (.text*)
        *rs2420.o   (.text*)
        *rs42.o     (.rodata)
        *rs42.o     (.text*)
        *navif.o    (.text*)
        *book.o     (.text*)
        *srv0.o     (.text*)
        *srv1.o     (.text*)
#if !defined(NINTAUS_DVD)&& !defined(HUAJIA_DVD)&& !defined(GBM_DVD)&& !defined(MINTON_DVD)||defined(NIN_612_4M) 
        *prvdrv.o   (.text*)
        *int_decerr.o (.text*)
        *supdec*.o   (.text*)
        *slowback.o (.text*)
//        *cd.o       (.text*)    
        *cdfunc.o   (.text*)
    #if  !defined(PMP_DVD)       
        *mainproc.o (.text*)
        *sysmain2.o (.text*)
    #endif //#if !defined(PMP_DVD)    
        *dvdpe.o    (.text*)
//        *audhw.o    (.text*)//nono 2004-6-22 18:40 for WHEN JPEG PLAYING, setting SPDIF item will reset.
//        *cderr.o    (.text*)        
        *repeat.o   (.text*)
                
        //cannot reduce rom code,        
        *css-des.o  (.text*)   
        *css-auth.o (.rodata)
        *css-auth.o (.text*)
        *dvdauth.o  (.text*)
        *dvdioctl.o (.text*)
#endif//!defined(NINTAUS_DVD)
#ifdef DVDRELEASE   
        *viddec.o   (.rodata)
        *int_fld.o  (.text*)
        *int_pend.o (.text*)
        *genint.o   (.text*)
#endif
#endif
#endif
        .       = ALIGN(16);
    } > sdram_dvd
    /*
    * boot-strap
    */
    .boot_flash :
    {
        *boot_flashs.o (.text*)
        *boot_flashs.o (.rodata)
        *boot_flash.o  (.text*)
        *boot_flash.o  (.rodata)
        *boot_emuio.o  (.text*)
        *boot_emuio.o  (.rodata)
        *boot_uart.o   (.text*)
        *boot_uart.o   (.rodata)
        *boot_sio.o    (.text*)
        *boot_sio.o    (.rodata)
        .       = ALIGN(16);
		_text_rombin_start = .;
    } > sdram_flash
    .drv_cdrom :
    {
        _text_drv_cdrom = .;
#ifndef UNLOAD_ROMCODE
        *flash.o       (.text*)
        *flash.o       (.rodata)
#ifdef LOAD_CDROM
        *ThumbNav.o    (.rodata)
        *ThumbNav.o    (.text*)
        *fsNAV.o       (.rodata)
    #ifndef PMP_DVD
        *fsGUI.o       (.text*)
        *fsGUI.o       (.rodata)
    #endif
    #ifndef SUPPORT_MP4_SUBTITLE
        *fsNAV.o       (.text*)
        *fs_nav_upgrade.o      (.text*)
        *fs_nav_upgrade.o      (.rodata)        
    #endif        
        *udf.o         (.text*)
        *udf.o         (.rodata)
        *fs9660.o      (.text*)
        *fs9660.o      (.rodata)
        *fsCDDA.o   (.rodata)//nono 4-9-1 12:01 move from sdram_drv1
        *fsCDDA.o   (.text*)
        *NESInit.o     (.text*)
//        *nesif.o       (.text*)
//        *nesif.o       (.rodata)
        *fsFile.o      (.rodata)
        *fsFile.o      (.text*)
        *fsGUIX.o      (.text*)
#endif
#ifdef LOAD_AP
//nono 2004-10-10 13:20 move here from "drv_ap1".
#if !defined(BBK_DVD)&&!defined(NINTAUS_DVD)||defined(NIN_612_4M)  //terry,2003/12/17 06:18PM      
       *graph.o        (.rodata)
       *graph.o        (.text*)
       *atapi_if.o     (.text*)
#endif
#endif//#ifdef LOAD_AP
#if defined(LOAD_AP_OTHER)&&!defined(DVD_AUDIO)&&!defined(DVD_ESP_2S)//nono 2004-10-16 16:23
        *cderr.o    (.text*)        
#endif//LOAD_AP_OTHER
#endif
        .       = ALIGN(16);
    } > sdram_cdrom
    .drv_ap1 :
    {
       _text_drv_ap = .;
#ifndef UNLOAD_ROMCODE
    #ifdef LOAD_AP
        
       *ircmd.o        (.rodata)
       *ircmd.o        (.text*)
       *ir_parser.o    (.rodata)
       *ir_parser.o    (.text*)
       *ir_drv.o       (.text*)
       *disp.o         (.rodata)
       *disp.o         (.text*)
       *polling.o      (.text*)
       *sound_if.o     (.text*)
        #ifndef SUPPORT_MP4_SUBTITLE       
       *audif.o        (.text*)
       *audif.o        (.rodata)
        #endif
       
        #ifndef SUPPORT_MIDI
       *osd1.o         (.text*)
        #endif
        #if !defined( ENLARGE_SDRAM_CS_AND_OSD_SIZE )
       *vfd.o          (.rodata)
       *vfd.o          (.text*)
            #if !defined(NINTAUS_DVD)||defined(NIN_612_4M) 
       *setup.o        (.rodata)
            #endif//#if !defined(NINTAUS_DVD)
        
            #if defined(SUPPORT_MP4)||defined(SUPPORT_ID3)||defined(SUPPORT_OSDID3) //linrc 2004-11-08 10:57
       *fs_message_show.o   (.rodata)
       *fs_message_show.o   (.text)
            #endif
            #if !defined(BBK_DVD)&&!defined(NINTAUS_DVD)||defined(NIN_612_4M)  //terry,2003/12/17 06:18PM      
       *safe.o         (.rodata)
       *safe.o         (.text*)
       *prog.o         (.rodata)       
            #endif
            
        #endif
    #endif
    
    #ifdef LOAD_SERVO
       *Servo.o        (.text*)
       *Servo.o        (.rodata)
       *DecUtil.o      (.text*)
       *DecUtil.o      (.rodata)
       *IdeMain.o      (.text*)
       *IdeMain.o      (.rodata)
       *DecInit.o      (.text*)
       *DecISR.o       (.text*)
       *DecISR.o       (.rodata*)
       *Atapicmd.o     (.text*)
       *Atapicmd.o     (.rodata)
       *DecUpdt.o      (.text*)
       *DecUpdt.o      (.rodata)
       *DSPCode.o      (.text*)
       *SUtil.o        (.text*)
       *Servoset.o     (.text*)
       *TimerISR.o     (.text*)
       *DecExUtil.o    (.text*)
       *DecExUtil.o    (.rodata)
       *ServoSet.o     (.text*)
       *ServoSet.o     (.rodata*)
       *SrvCom.o       (.text*)
    #endif
    #ifdef LOAD_AP_OTHER //terry,2004/4/13 09:36PM
       *avd.o          (.text*)
       *timer.o        (.text*)
       *ircode.o       (.rodata)
       *osdutil.o      (.rodata)
       *font_offset.o  (.rodata)
       *sound.o        (.rodata)
       *sysmain2.o     (.rodata)       
       *estd.o         (.text) 
       *supset.o       (.text) 
       *cvdogt.o       (.text) 
       *sup.o          (.text) 
     
       *memcfg.o       (.text) 
       *util.o         (.text) 
       *nav_util.o     (.text)
       *read.o         (.text)
       *score.o        (.text)
       *kernel.o       (.text)
       *ninf.o         (.text)
       *_Xdivdi3.o     (.text)
       *setvideo.o     (.text)
//       *hwif.o         (.text)//cause 8200 standby fail.2004-4-30 11:32
       *cd.o       (.text*)
    #endif
       
#endif
       .        = ALIGN(16);
    } > sdram_ap1
    .drv_ap2 :
    {
        _text_drv_ap2 = .;
#ifndef UNLOAD_ROMCODE
#ifdef LOAD_AP
       *setup.o        (.text*)
       *intdrv.o        (.text*)      
       *prog.o          (.text*) 
#endif
#endif
       .        = ALIGN(16);
    } > sdram_ap2
    .drv_ap3 :
    {
        .       = ALIGN(16);
#ifndef UNLOAD_ROMCODE
#ifdef LOAD_AP
/*       *prog.o         (.text*)*/
/*       *sound.o        (.text*)*/
#endif
#endif
    } > sdram_ap3
    .drv_srvdp :
    {
        _text_drv_srvdp = .;
#ifndef UNLOAD_ROMCODE
       *DSPCode.o      (.rodata)
#endif
    } > sdram_srvdp
    .drv_free :
    {
        _text_drv_free = .;
#ifndef UNLOAD_ROMCODE
    #ifdef LOAD_AP
        #ifndef SUPPORT_JPEG_MIC //terry,2004/1/7 07:12PM
            #if  !defined(PMP_DVD)&&!defined(BBK_DVD)&&!defined(NINTAUS_DVD)&&!defined(GBM_CARD_READER)||defined(NIN_612_4M)  //nono 4-2-2 15:15 
       *osd1.o         (.rodata)
            #endif       
       *search.o       (.text*)
       *search.o       (.rodata)
       *macro.o        (.text*)
       *macro.o        (.rodata)
       *image.o        (.text*)
       *iop.o          (.text*)
       *cderr.o        (.text*)
       *cderr.o        (.rodata)
       *hostx.o        (.text*)
       *hostx.o        (.rodata)
       *dsp3_if.o      (.text*)
       *dsp3_if.o      (.rodata)
       *fs9660_util.o  (.text*)
       *fsNav_util.o   (.text*)
       *fsGUI_util.o   (.text*)
       *fsGUIShowFont.c (.text*)    // 2004/02/01 yltseng
       *framebuf*.o     (.text*)
       *sound.o        (.text*)
       *fs.o           (.text*)
       *fs.o           (.rodata)
       *vpp_728.o      (.text*)
            #ifdef DVDRELEASE
       *jpegeffect.o   (.rodata)
       *jpegeffect.o   (.text*)
       //*jpegeffect_help.o   (.rodata)
       //*jpegeffect_help.o   (.text*)
       *lbaif.o        (.rodata)
       *lbaif.o        (.text*)
       *supintr.o      (.text*)
       *viddec.o       (.text*)      
                #ifdef LOAD_MP4     // 2004/12/16 yltseng
        *viddec_mp4.o   (.text*)
                #endif
                
       *time.o         (.text*)
       *time.o         (.rodata)
       *vpp_728.o      (.rodata)
       *sp8200tv.o     (.text*)
       *sp8200tv.o     (.rodata)
                #ifdef SUPPORT_MJPEG
        *mjpeg.o	(.rodata)
        *mjpeg.o	(.text*)
                #endif
            #endif
        #endif
    #endif
    
#endif
    } > sdram_free
    .drv_mp4 :
    {
        _text_drv_mp4 = .;
#ifndef UNLOAD_ROMCODE
    #ifdef LOAD_MP4
        *mp4vid.o       (.text*)
        *mp4vid.o       (.rodata)
        *mp4vid.o       (.bss)
        *mp4vid.o       (COMMON)
        *mp4vid.o       (.sbss)
        *mp4vid.o       (.scommon)       
        *avi_if.o       (.text*)
        *avi_if.o       (.rodata)
    #endif
#endif
    } > sdram_mp4
    .drv_wma :
    {
        _text_drv_wma = .;
#ifndef UNLOAD_ROMCODE
#ifdef LOAD_WMA
       *asfheader.o    (.text*)
       *asfheader.o    (.rodata)
       *asfdata.o      (.text*)
       *asfdata.o      (.rodata)
       *asfheader.o	   (COMMON)
       *asfdata.o      (.scommon)
#endif
#endif
    } > sdram_wma
/*===========================================================================
// ROM 1
//===========================================================================*/
    /*
    ** .rom1: text image
    **
    ** this section keeps all the text-section rom image.
    ** the order of first few files is to ensure there will
    ** not be any cache trashing.  don't modify it unless
    ** you know what you are doing.
    **
    */
    .rom1 :
    {
#ifndef  LOAD_OTHER
        /* normal */
        MIPS/init0.o    (.text*)         /* boot code */
#ifndef DVDRELEASE
        *viddec.o   (.text*)
        *viddec.o   (.rodata)
        *intdrv.o   (.text*)        
        *int_fld.o      (.text*)
        *int_pend.o     (.text*)
        *genint.o       (.text*)
#endif
        
        
/*        *srv*.o         (.text*)*/
        *               (.text*)
        MIPS/crt0.o     (.text*)         /* c runtime code */
#else
        /* download all code to SDRAM */
        MIPS/init0.o    (.text*)         /* boot code            */
        MIPS/rominit.o  (.text*)         /* data/bss init code   */
        MIPS/crt0.o     (.text*)         /* c runtime code       */
        *reset.o        (.text*)         /* reset routine        */
        *sysmain.o      (.text*)         /* c main-routine       */
        *lexra.o        (.text*)        
        *dsp3_config.o  (.text*)
        *bitop.o        (.text*)
        *dtsrom.o       (.rodata)
        *intdrv.o       (.text*)      
        
        *emuio.o        (.text*)
        
        *uart0fifo.o    (.text*)        
        *other.o        (.text*)
        *sdram.o        (.text*)
        *sio.o          (.text*)
        *sio.o          (.rodata*)
        *uart1null.o     (.text*)
        
        *hwcpu*.o       (.text*)
        *crt0.o         (.rodata*)
        *init0.o        (.rodata*)        
#endif
        . = ALIGN(16);
    } > rom
/*===========================================================================
 SDRAM 2, global var.
===========================================================================*/
    /*
    ** .ram1: DATA section
    **
    ** this section is the virtual mapping of data-sections.
    ** data section is for initialized read/write variables.
    ** we have to store the initial value of these variables
    ** somewhere(.rom1_2).  during building the binary image
    ** we will dumping .ram1 content to .rom1_2
    **
    */
    .ram1 :
    {
        _data           = .;        /* beginning of data segment */
        *              (.data)
        _gp             = .;        /* $gp global pointer, _gp for crt0.S to load */
        *              (.sdata)
        *              (.lit8)
        *              (.lit4)
        *              (.lita)
        _edata      = .;            /* end of data area (to be copied from ROM) */
        .       = ALIGN(16);
    } > sdram_cs
/*===========================================================================
 ROM 2
===========================================================================*/
    /*
    ** .rom1_2: padding section for DATA initialization
    */
    .rom1_2 :
    {
        _data_ps = .;
        .       += SIZEOF(.ram1);
        _data_pe  = .;
        .       = ALIGN(16);
    } > rom
    /*
    ** .rom2: constant data
    */
    .rom2 :
    {
        /* CONSTANT DATA (read-only) */
#ifndef  LOAD_OTHER
        *               (.rdata)
        *               (.rodata)
#else
        /* only load these essential data to ROM */
        MIPS/rominit.o  (.rodata)
        MIPS/crt0.o     (.rodata)
        *reset.o        (.rodata)
        *sysmain.o      (.rodata)
        *lexra.o        (.rodata)
        //*memcfg.o       (.rodata)
        *dsp3_config.o  (.rodata)
        *bitop.o        (.rodata)
/*        MIPS/title.o    (.rodata)*/
#endif
        .               = ALIGN(16);
    } > rom
	.rom3 :
    {
        MIPS/title.o    (.rodata)
        .               = ALIGN(16);
    } > rom_title
/*===========================================================================
// SDRAM 3
//===========================================================================*/
    .ram_jpeg :
    {
        *jpegtest.o		(.bss)
        *jpegtest.o		(COMMON)
		*mjpeg.o	(.bss)
		*mjpeg.o	(COMMON)
		//*mjpeg.o	(.sbss)
		//*mjpeg.o	(.scommon)		
/*
        // These datas are moved to sdram_mp4 section
        *mp4vid.o		(.bss)
        *mp4vid.o		(COMMON)
        *mp4vid.o		(.sbss)
        *mp4vid.o		(.scommon)
*/
        //*asfheader.o  (COMMON)
        //*asfheader.o	(.scommon)
        //*asfdata.o    (.scommon)
        .       = ALIGN(16);
    } > sdram_jpeg
    .drv_other :
    {
        _text_other = .;
#ifdef  LOAD_OTHER
        *       (.text*)
        *       (.rodata)
#endif
        .       = ALIGN(16);
    } > sdram_other
    /*
    ** .ramf
    ** fast un-initialized variable storage.
    **
    */
    .ramF :
    {
        MIPS/databuf.o  (.bss)
        MIPS/databuf.o  (COMMON)
        .       = ALIGN(16);
    } > sdram_cs
    /*
    ** .ram2: un-initialized data
    */
    .ram2 :
    {
        _bstart     = .;
        *       (.sbss)
        *       (.scommon)
        *       (.bss)
        *       (COMMON)
        .       = ALIGN(16);
        _bend       = .;
    } > sdram_cs
    .rel :
    {
        *       (.rel.dyn)
    } > garbage
    _etext = ADDR(.rom1) + SIZEOF(.rom1) + SIZEOF(.rom2);  /* end of ROM image */
    _stextf = _etext + SIZEOF(.ram1);
    _tt_gb_size = SIZEOF(.ram1) + SIZEOF(.ram2) + SIZEOF(.ramF);
    .udf_buf :
    {
        _udf_work_buf = .;
        . += K(UDF_WORK_BUF_SIZE);
        _udf_work_buf_end = .;
    } > sdram_udfbuf
#if !defined( SDRAM_16Mb_Mode ) || !defined( SUPPORT_FILE_SYSTEM_MODE )		// 2004/06/12 yltseng
    #if !defined(FAT_FILE_MODE)&&!defined(FILE_MODE_WRITE)//liweihua 2004-10-20 17:25//sunzhh 2004-12-30
    _fs9660_buf     = TO080(FS9660YA);
#endif
#endif
#ifdef USE_NAV_BUF
    wb_buf          = TO080(N_NAVYA);
#endif
#ifndef SDRAM_16Mb_Mode
    decomp_fnTable  = TO080(COMP_OSD_FONT);
    osd_temp_buf    = TO080(OSD0_TEMP_YA);
#endif
/*===========================================================================
// STACK
//===========================================================================*/
    /*
    ** STACK location , 1.7K ,terry,2004/7/26 02:51PM
    */    
    _stkptr         = STK_PTR;
    _stkptr_dbg     = STK_DBG_PTR;
    _stkbtm         = STK_BTM_PTR;
    _stkbtm_dbg     = STK_DBG_BTM_PTR;
}
MEMORY
{
    garbage   : org = 0x00000000, l = 1m
    bootrom   : org = 0xbfc00000, l = 512k    /* Un-cached ROM boot       */
    rom       : org = 0x88000000, l = 1024k   /* cached ROM image in ROM  */
	rom_title :	org = 0x88000000+987*1024, l = 37k
    /*
    * reference memmap0b.txt
    */
#ifdef USE_C_IOP
    sdram_drv_iop : org = 0x080400000, l = 64k                               /* 0000 */
    sdram_iop_rst : org = 0x180400000, l = 64k                               /* 0000 */
#else
    sdram_drv_iop : org = 0x080000000, l = 2k                               /* 0000 */
    sdram_iop_rst : org = 0x180000000, l = 2k                               /* 0000 */
#endif
    sdram_cs      : org = TO080(SDRAM_CS_ST),		l = K(SDRAM_CS_SZ)    /* 0007 */
//#ifdef SDRAM_16Mb_Mode
//  #ifdef MEMCFG_MOVE_OSDSUP
//     sdram_jpeg    : org = 0x080000000 + 87*1024,l =  8k	/* AUDYA=85, 36-34=2, 85+2=87 */
//  #else
//    sdram_jpeg    : org = 0x080000000 +  102*1024,l =  8k
//  #endif
//#else
    sdram_jpeg    : org = TO080(JPEG_CODE_YA),		l = K(JPEG_CODE_SIZE)      /* 3422 */
//#endif
    sdram_flash   : org = TO180(100),				l = 10k                    /* 0100 */
//#ifdef SDRAM_16Mb_Mode
    sdram_drv1    : org = TO080(DRV1N2_ST),			l = K(DRV1_2_CODESIZE) /* PCM_YA=51 */
    sdram_drv2    : org = TO180(DRV1N2_ST),			l = K(DRV1_2_CODESIZE) /* PCM_YA=51 */
//#else
//    sdram_drv1    : org = 0x080000000+1024*DRV1N2_ST, l = 1024*DRV1_2_CODESIZE   /* 2530 */
//    sdram_drv2    : org = 0x180000000+1024*DRV1N2_ST, l = 1024*DRV1_2_CODESIZE   /* 2530 */
//#endif
    sdram_ap2     : org = TO080(AP2N3_ST),			l = K(AP2_CODESIZE)      /* 2566 */
    sdram_ap3     : org = TO180(AP2N3_ST),			l = K(AP3_CODESIZE)      /* 2566 */
    sdram_ap1     : org = TO080(AP1_ST),			l = K(AP_CODESIZE)         /* 2598 */
    sdram_udfbuf  : org = TO080(A_UDF_WORK_BUF),	l = K(UDF_WORK_BUF_SIZE)       /* 2744 */
//#ifdef SDRAM_16Mb_Mode
    sdram_srvdp   : org = TO080(A_SERVO_YA),		l = K(SERVO_SIZE)      /* 2028 */
    sdram_cdrom   : org = TO080(CDROM_CODE_YA),		l = K(CDROM_CODE_SIZE)      /* 1968 */
    sdram_dvd     : org = TO080(DVD_NAV_CODE),		l =K(DVD_CODE_SIZE) /* 3770 */
//#else
//    sdram_srvdp   : org = TO080(A_SERVO_YA), l = K(SERVO_SIZE)                      /* 2744 */
//    sdram_cdrom   : org = TO080(CDROM_CODE_YA), l = K(CDROM_CODE_SIZE)      /* 3430 */
//    sdram_dvd     : org = TO080(DVD_NAV_CODE), l = K(DVD_CODE_SIZE)         /* 3770 */
//#endif
    sdram_mp4     : org = TO080(A_MP4_CODE_YA),		l = K(MP4_CODE_SIZE)
    sdram_wma     : org = TO080(A_WMA_CODE_YA),		l = K(WMA_CODE_SIZE)
#ifdef DVDRELEASE
    #ifdef SDRAM_16Mb_Mode
    sdram_free    : org = TO080(FREE_CODE_YA),		l = K(FREE_CODESIZE+1)       /* 4022 */
    #else
    sdram_free    : org = TO080(FREE_CODE_YA),		l = K(FREE_CODESIZE+2)       /* 4022 */
    #endif
#else
    sdram_free    : org = TO080(FREE_CODE_YA),		l = K(FREE_CODESIZE)       /* 4022 */
#endif
    sdram_other   : org = 0x180700000, l = 1024k                            /* 7168 */
}
ENTRY(__romstart)

						