开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > Delphi控件源码 > 查看源码
MMEQ.pas
资源名称：qqdelphiprog.rar　[点击查看]
上传用户：hylc_2004
上传日期：2014-01-23
资源大小：46800k
文件大小：33k
源码类别：

Delphi控件源码

开发平台：

Delphi

MMEQ.pas：源码内容
  1. {========================================================================}
  2. {=                (c) 1995-98 SwiftSoft Ronald Dittrich                 =}
  3. {========================================================================}
  4. {=                          All Rights Reserved                         =}
  5. {========================================================================}
  6. {=  D 01099 Dresden             = Fax.: +49 (0)351-8037944              =}
  7. {=  Loewenstr.7a                = info@swiftsoft.de                     =}
  8. {========================================================================}
  9. {=  Actual versions on http://www.swiftsoft.de/mmtools.html             =}
  10. {========================================================================}
  11. {=  This code is for reference purposes only and may not be copied or   =}
  12. {=  distributed in any format electronic or otherwise except one copy   =}
  13. {=  for backup purposes.                                                =}
  14. {=                                                                      =}
  15. {=  No Delphi Component Kit or Component individually or in a collection=}
  16. {=  subclassed or otherwise from the code in this unit, or associated   =}
  17. {=  .pas, .dfm, .dcu, .asm or .obj files may be sold or distributed     =}
  18. {=  without express permission from SwiftSoft.                          =}
  19. {=                                                                      =}
  20. {=  For more licence informations please refer to the associated        =}
  21. {=  HelpFile.                                                           =}
  22. {========================================================================}
  23. {=  $Date: 09.09.98 - 12:05:18 $                                        =}
  24. {========================================================================}
  25. unit MMEQ;
  27. {$I COMPILER.INC}
  29. interface
  31. uses
  32. {$IFDEF WIN32}
  33.     Windows,
  34. {$ELSE}
  35.     WinTypes,
  36.     WinProcs,
  37. {$ENDIF}
  38.     SysUtils,
  39.     Messages,
  40.     Classes,
  41.     Controls,
  42.     Forms,
  43.     MMSystem,
  44.     MMRegs,
  45.     MMUtils,
  46.     MMPcmSup,
  47.     MMObj,
  48.     MMDSPObj,
  49.     MMObjLst,
  50.     MMFFT,
  51.     MMFFTFlt,
  52.     MMSpectr,
  53.     IniFiles,
  54.     Registry;
  56. const
  57.     {$IFDEF CBUILDER3} {$EXTERNALSYM defEnabled} {$ENDIF}
  58.     defEnabled = True;
  59.     {$IFDEF CBUILDER3} {$EXTERNALSYM defChannel} {$ENDIF}
  60.     defChannel = chBoth;
  61.     {$IFDEF CBUILDER3} {$EXTERNALSYM defFFTLen} {$ENDIF}
  62.     defFFTLen  = 256;
  63.     {$IFDEF CBUILDER3} {$EXTERNALSYM defRate} {$ENDIF}
  64.     defRate    = 4000;
  65.     {$IFDEF CBUILDER3} {$EXTERNALSYM defWindow} {$ENDIF}
  66.     defWindow  = fwHamming;
  68. type
  69.    EMMEqualizerError = class(Exception);
  71.    TMMEqualizer = class;
  73.    {-- TMMEQFilter ------------------------------------------------------------}
  74.    TMMEQFilter = class(TObject)
  75.    private
  76.       Ff1      : Float;
  77.       Ff2      : Float;
  78.       FGain    : Float;
  79.       FData    : Pointer;
  80.       FEnabled : Boolean;
  81.       FOnChange: TNotifyEvent;
  83.       procedure SetValue(index: integer; aValue: Float);
  84.       procedure SetEnabled(aValue: Boolean);
  86.       procedure Store(S: TStream); virtual;
  87.       procedure Load(S: TStream); virtual;
  89.    protected
  90.       procedure Changed; virtual;
  92.    public
  93.       constructor Create;
  94.       constructor CreateEx(af1,af2,aGain: Float);
  95.       constructor CreateObject(af1,af2,aGain: Float; Data: Pointer);
  97.       procedure Assign(Source: TObject);
  99.       procedure SetParams(af1, af2, aGain: Float);
  101.       property OnChange: TNotifyEvent read FOnChange write FOnChange;
  103.       property f1: Float index 0 read Ff1 write SetValue;
  104.       property f2: Float index 1 read Ff2 write SetValue;
  105.       property Gain: Float index 2 read FGain write SetValue;
  106.       property Data: Pointer read FData write FData;
  107.       property Enabled: Boolean read FEnabled write SetEnabled;
  108.    end;
  110.    {-- TMMEQFilterList --------------------------------------------------------}
  111.    TMMEQFilterList = class(TObjectList)
  112.    private
  113.       FEqualizer: TMMEqualizer;
  115.       procedure SetFilter(Index: integer; Filter: TMMEQFilter);
  116.       function  GetFilter(Index: integer): TMMEQFilter;
  118.    protected
  119.       procedure DefineProperties(Filer: TFiler); override;
  120.       procedure ReadData(S: TStream); override;
  121.       procedure WriteData(S: TStream); override;
  123.    public
  124.       function  AddObject(Item: TObject): TOLSize; override;
  126.       procedure Assign(Source: TPersistent); override;
  127.       property Items[Index: integer]: TMMEQFilter read GetFilter write SetFilter; default;
  128.    end;
  130.    {-- TMMEqualizer -----------------------------------------------------------}
  131.    TMMEqualizer = class(TMMDSPComponent)
  132.    private
  133.       FEnabled       : Boolean;
  134.       FOpen          : Boolean;
  135.       FPFilter       : PFFTFilter;
  136.       FPTempFilter   : PFFTFilter;
  137.       FDescription   : String;
  138.       FFTLen         : integer;
  139.       FFilters       : TMMEQFilterList;
  140.       FWindow        : TMMFFTWindow;
  141.       Ffs            : Longint;
  142.       FChannel       : TMMChannel;
  143.       FUpdating      : Boolean;
  144.       FRealBufSize   : Longint;
  145.       FSpectrum      : TMMSpectrum;
  147.       FOnChange      : TNotifyEvent;
  148.       FOnPcmOverflow : TNotifyEvent;
  150.       procedure SetFFTLen(aValue: integer);
  151.       procedure SetSampleRate(aValue: Longint);
  152.       procedure SetWindow(aValue: TMMFFTWindow);
  153.       procedure SetEnabled(aValue: Boolean);
  154.       procedure SetDescription(aValue: String);
  155.       procedure SetFilters(aValue: TMMEQFilterList);
  156.       procedure SetChannel(aValue: TMMChannel);
  157.       procedure SetSpectrum(aValue: TMMSpectrum);
  158.       procedure NotifySpectrum;
  159.       procedure SpectrumNeedData(Sender: TObject);
  160.       procedure FiltersChanged(Sender: TObject);
  161.       procedure FilterChanged(Sender: TObject);
  162.       procedure UpdateTempFilter(Init: Boolean);
  164.    protected
  165.       procedure SetPWaveFormat(aValue: PWaveFormatEx); override;
  166.       procedure Assign(Source: TPersistent); override;
  167.       procedure Notification(AComponent: TComponent; Operation: TOperation); override;
  169.       procedure Loaded; override;
  170.       procedure Update; virtual;
  171.       procedure ResetEQ; virtual;
  172.       procedure Change; virtual;
  174.       procedure Opened; override;
  175.       procedure Closed; override;
  176.       procedure Started; override;
  177.       procedure Reseting; override;
  179.       procedure PcmOverflow; dynamic;
  180.       procedure BufferReady(lpwh: PWaveHdr); override;
  181.       procedure BufferLoad(lpwh: PWaveHdr; var MoreBuffers: Boolean); override;
  182.    public
  183.       constructor Create(aOwner: TComponent); override;
  184.       destructor  Destroy; override;
  186.       property IsOpen: Boolean read FOpen;
  188.       procedure Open;
  189.       procedure Reset;
  190.       procedure Close;
  191.       procedure Process(Buffer: PChar; Length: integer);
  193.       procedure SaveToRegIniFile(Ini: TRegIniFile; Section: string);
  194.       procedure ReadFromRegIniFile(Ini: TRegIniFile; Section: string);
  196.       procedure SaveToIniFileEx(Ini: TIniFile; Section: string);
  197.       procedure ReadFromIniFileEx(Ini: TIniFile; Section: string);
  199.       procedure SaveToIniFile(IniFile: TFileName; Section: string);
  200.       procedure ReadFromIniFile(IniFile: TFileName; Section: string);
  202.    published
  203.       property OnChange: TNotifyEvent read FOnChange write FOnChange;
  204.       property OnPcmOverflow: TNotifyEvent read FOnPcmOverflow write FOnPcmOverflow;
  206.       property Input;
  207.       property Output;
  208.       property Enabled: Boolean read FEnabled write SetEnabled default defEnabled;
  209.       property SampleRate: Longint read Ffs write SetSampleRate default defRate;
  210.       property FFTLength: integer read FFTLen write SetFFTLen default defFFTLen;
  211.       property Description: String read FDescription write SetDescription stored False;
  212.       property Filters: TMMEQFilterList read FFilters write SetFilters;
  213.       property Spectrum: TMMSpectrum read FSpectrum write SetSpectrum;
  214.       property Channel: TMMChannel read FChannel write SetChannel default defChannel;
  215.       property Window: TMMFFTWindow read FWindow write SetWindow default defWindow;
  216.    end;
  219. implementation
  221. const
  222.    STREAMKENNUNG : Longint = $00555145; { 'EQU ' }
  224. {== TMMEQFilter ===============================================================}
  225. constructor TMMEQFilter.Create;
  226. begin
  227.    inherited Create;
  229.    Ff1      := 0;
  230.    Ff2      := 0;
  231.    FGain    := 0;
  232.    FData    := nil;
  233.    FEnabled := True;
  234.    FOnChange:= nil;
  235. end;
  237. {-- TMMEQFilter ---------------------------------------------------------------}
  238. constructor TMMEQFilter.CreateEx(af1,af2,aGain: Float);
  239. begin
  240.    inherited Create;
  242.    Ff1      := af1;
  243.    Ff2      := af2;
  244.    FGain    := aGain;
  245.    FEnabled := True;
  246.    FOnChange:= nil;
  247. end;
  249. {-- TMMEQFilter ---------------------------------------------------------------}
  250. constructor TMMEQFilter.CreateObject(af1,af2,aGain: Float; Data: Pointer);
  251. begin
  252.    CreateEx(af1,af2,aGain);
  253.    FData := Data;
  254. end;
  256. {-- TMMEQFilter ---------------------------------------------------------------}
  257. procedure TMMEQFilter.Changed;
  258. begin
  259.    if assigned(FOnChange) then FOnChange(Self);
  260. end;
  262. {-- TMMEQFilter ---------------------------------------------------------------}
  263. procedure TMMEQFilter.SetParams(af1, af2, aGain: Float);
  264. begin
  265.    if (af1 <> Ff1) or (af2 <> Ff2) or (aGain <> FGain) then
  266.    begin
  267.       Ff1 := af1;
  268.       Ff2 := af2;
  269.       FGain := aGain;
  270.       Changed;
  271.    end;
  272. end;
  274. {-- TMMEQFilter ---------------------------------------------------------------}
  275. procedure TMMEQFilter.SetEnabled(aValue: Boolean);
  276. begin
  277.    if (aValue <> FEnabled) then
  278.    begin
  279.       FEnabled := aValue;
  280.       Changed;
  281.    end;
  282. end;
  284. {-- TMMEQFilter ---------------------------------------------------------------}
  285. procedure TMMEQFilter.SetValue(index: integer; aValue: Float);
  286. var
  287.    af1,af2,aGain: Float;
  289. begin
  290.    af1 := Ff1;
  291.    af2 := Ff2;
  292.    aGain := FGain;
  293.    case index of
  294.        0: af1 := aValue;
  295.        1: af2 := aValue;
  296.        2: aGain := aValue;
  297.    end;
  298.    SetParams(af1, af2, aGain);
  299. end;
  301. {-- TMMEQFilter ---------------------------------------------------------------}
  302. procedure TMMEQFilter.Store(S: TStream);
  303. begin
  304.    S.WriteBuffer(FEnabled,SizeOf(FEnabled));
  305.    S.WriteBuffer(Ff1,SizeOf(Ff1));
  306.    S.WriteBuffer(Ff2,SizeOf(Ff2));
  307.    S.WriteBuffer(FGain,SizeOf(FGain));
  308. end;
  310. {-- TMMEQFilter ---------------------------------------------------------------}
  311. procedure TMMEQFilter.Load(S: TStream);
  312. var
  313.    af1,af2,aGain: Float;
  315. begin
  316.    S.ReadBuffer(FEnabled,SizeOf(FEnabled));
  317.    S.ReadBuffer(af1,SizeOf(af1));
  318.    S.ReadBuffer(af2,SizeOf(af2));
  319.    S.ReadBuffer(aGain,SizeOf(aGain));
  320.    SetParams(af1,af2,aGain);
  321. end;
  323. {-- TMMEQFilter ---------------------------------------------------------------}
  324. procedure TMMEQFilter.Assign(Source: TObject);
  325. begin
  326.    if Source is TMMEQFilter then
  327.    begin
  328.       SetParams(TMMEQFilter(Source).f1,
  329.                 TMMEQFilter(Source).f2,
  330.                 TMMEQFilter(Source).Gain);
  331.       Data := TMMEQFilter(Source).Data;
  332.       Enabled := TMMEQFilter(Source).Enabled;
  333.    end;
  334. end;
  336. {== TMMEQFilterList ===========================================================}
  337. procedure TMMEQFilterList.SetFilter(Index: integer; Filter: TMMEQFilter);
  338. begin
  339.    Put(Index, Filter);
  340. end;
  342. {-- TMMEQFilterList -----------------------------------------------------------}
  343. function TMMEQFilterList.GetFilter(Index: integer): TMMEQFilter;
  344. begin
  345.    Result := TMMEQFilter(Get(Index));
  346. end;
  348. {-- TMMEQFilterList -----------------------------------------------------------}
  349. function TMMEQFilterList.AddObject(Item: TObject): TOLSize;
  350. begin
  351.    Result := inherited AddObject(Item);
  352.    (Item as TMMEQFilter).OnChange := FEqualizer.FilterChanged;
  353. end;
  355. {-- TMMEQFilterList -----------------------------------------------------------}
  356. procedure TMMEQFilterList.Assign(Source: TPersistent);
  357. var
  358.    i: integer;
  359.    Filter: TMMEQFilter;
  361. begin
  362.    if (Source is TMMEQFilterList) or (Source = nil) then
  363.    begin
  364.       BeginUpdate;
  365.       try
  366.          if (FEqualizer <> nil) then
  367.              FEqualizer.FUpdating := True;
  369.          FreeAll;
  370.          if (Source <> nil) then
  371.          for i := 0 to TMMEQFilterList(Source).Count-1 do
  372.          begin
  373.             Filter := TMMEQFilter.Create;
  374.             Filter.Assign(TMMEQFilterList(Source)[i]);
  375.             AddObject(Filter);
  376.          end;
  378.       finally
  379.          if (FEqualizer <> nil) then
  380.              FEqualizer.FUpdating := False;
  382.          EndUpdate;
  383.       end;
  384.    end
  385.    else inherited assign(Source);
  386. end;
  388. {-- TMMEQFilterList -----------------------------------------------------------}
  389. procedure TMMEQFilterList.DefineProperties(Filer: TFiler);
  390. begin
  391.    Filer.DefineBinaryProperty('ObjectContainer', ReadData, WriteData, True);
  392. end;
  394. {-- TMMEQFilterList -----------------------------------------------------------}
  395. procedure TMMEQFilterList.ReadData(S: TStream);
  396. Var
  397.    pBuf: PChar;
  398.    Kennung: Longint;
  399.    ObjCount,
  400.    Index: TOLSize;
  401.    Destroy: Boolean;
  402.    Value: Longint;
  404. begin
  405.    BeginUpdate;
  406.    try
  407.       FEqualizer.FUpdating := True;
  408.       S.ReadBuffer(Kennung,sizeOf(STREAMKENNUNG));
  409.       if (Kennung <> STREAMKENNUNG) then
  410.          raise EStreamError.Create('Invalid Object stream');
  411.       FreeAll;
  412.       { load stream items }
  413.       S.ReadBuffer(Destroy,SizeOf(Destroy));
  414.       DestroyObjects := Destroy;
  416.       { read string length }
  417.       S.ReadBuffer(Value,SizeOf(Value));
  418.       if Value > 0 then
  419.       begin
  420.          pBuf := StrAlloc(Value+1);
  421.          try
  422.             FillChar(pBuf^, Value+1, 0);
  423.             S.ReadBuffer(pBuf^, Value);
  424.             FEqualizer.Description := StrPas(pBuf);
  425.          finally
  426.             StrDispose(pBuf);
  427.          end;
  428.       end;
  430.       S.ReadBuffer(Value,SizeOf(Value));
  431.       FEqualizer.FFTLength := Value;
  433.       S.ReadBuffer(ObjCount,SizeOf(Objcount));  { Read in Object count }
  434.       if Capacity-Count < ObjCount then Capacity := Count+ObjCount;
  436.       { Read in Object Count }
  437.       for Index := 0 to ObjCount-1 do
  438.           AddObject(ReadObjectFromStream(S));
  440.    finally
  441.       FEqualizer.FUpdating := False;
  442.       EndUpdate;
  443.    end;
  444. end;
  446. {-- TMMEQFilterList -----------------------------------------------------------}
  447. procedure TMMEQFilterList.WriteData(S: TStream);
  448. var
  449.    Index,ObjCount: TOlSize;
  450.    Destroy: Boolean;
  451.    Value: Longint;
  453. begin
  454.    { Write list to Stream }
  455.    S.WriteBuffer(STREAMKENNUNG,SizeOf(STREAMKENNUNG));
  456.    Destroy := DestroyObjects;
  457.    S.WriteBuffer(Destroy,SizeOf(Destroy));
  459.    { write string length }
  460.    Value := Length(FEqualizer.FDescription);
  461.    S.WriteBuffer(Value, SizeOf(Value));
  462. {$IFDEF WIN32}
  463.    S.WriteBuffer(PChar(FEqualizer.FDescription)^, Length(FEqualizer.FDescription));
  464. {$ELSE}
  465.    S.WriteBuffer(FEqualizer.FDescription[1], Length(FEqaulizer.FDescription));
  466. {$ENDIF}
  468.    Value := FEqualizer.FFTLen;
  469.    S.WriteBuffer(Value, SizeOf(Value));
  471.    ObjCount := Count;
  472.    S.WriteBuffer(ObjCount,SizeOf(ObjCount));
  473.    for Index := 0 to Count-1 do
  474.        WriteObjectToStream(Items[Index],S);
  475. end;
  477. {== TMMEqualizer ==============================================================}
  478. constructor TMMEqualizer.Create(aOwner: TComponent);
  479. begin
  480.    inherited Create(aOwner);
  482.    FFilters := TMMEQFilterList.Create;
  483.    FFilters.OnChange := FiltersChanged;
  484.    FFilters.FEqualizer := Self;
  486.    FPFilter    := nil;
  487.    FPTempFilter:= nil;
  488.    FDescription:= 'Untitled';
  489.    Ffs         := defRate;
  490.    FWindow     := defWindow;
  491.    FChannel    := defChannel;
  492.    FEnabled    := defEnabled;
  493.    FOpen       := False;
  494.    FUpdating   := False;
  495.    FSpectrum   := nil;
  496.    FFTLen      := 8;
  497.    FFTLength   := defFFTLen;
  499.    ErrorCode := ComponentRegistered(InitCode, Self, ClassName);
  500.    if (ErrorCode <> 0) then RegisterFailed(InitCode, Self , ClassName);
  501. end;
  503. {-- TMMEqualizer --------------------------------------------------------------}
  504. destructor TMMEqualizer.Destroy;
  505. begin
  506.    Close;
  508.    SetSpectrum(nil);
  510.    FFilters.Free;
  512.    inherited Destroy;
  513. end;
  515. {-- TMMEqualizer --------------------------------------------------------------}
  516. procedure TMMEqualizer.Notification(aComponent: TComponent; Operation: TOperation);
  517. begin
  518.    inherited Notification(aComponent, Operation);
  520.    if (Operation = opRemove) then
  521.    begin
  522.       if (aComponent = FSpectrum) then
  523.           FSpectrum := nil;
  524.    end;
  525. end;
  527. {-- TMMEqualizer --------------------------------------------------------------}
  528. procedure TMMEqualizer.PcmOverflow;
  529. begin
  530.    if assigned(FOnPcmOverflow) then FOnPcmOverflow(Self);
  531. end;
  533. {-- TMMEqualizer --------------------------------------------------------------}
  534. procedure TMMEqualizer.SetPWaveFormat(aValue: PWaveFormatEx);
  535. begin
  536.    if (aValue <> nil) then
  537.    begin
  538.       if not (csDesigning in ComponentState) then
  539.          if not pcmIsValidFormat(aValue) or (aValue^.wBitsPerSample = 8) then
  540.             raise EMMEqualizerError.Create(LoadResStr(IDS_INVALIDFORMAT));
  542.       SampleRate := aValue^.nSamplesPerSec;
  543.    end;
  545.    inherited SetPWaveFormat(aValue);
  546. end;
  548. {-- TMMEqualizer --------------------------------------------------------------}
  549. procedure TMMEqualizer.SaveToRegIniFile(Ini: TRegIniFile; Section: string);
  550. var
  551.    i: integer;
  552. begin
  553.    if (Ini <> nil) then
  554.    begin
  555.       with Ini do
  556.       begin
  557.          WriteInteger(Section, 'FFTLen', FFTLength);
  558.          WriteInteger(Section, 'Samplerate', Samplerate);
  559.          WriteInteger(Section, 'Window', Ord(Window));
  561.          WriteInteger(Section, 'Bands', Filters.Count);
  562.          for i := 0 to Filters.Count-1 do
  563.          with Filters[i] do
  564.          begin
  565.             WriteString(Section, 'Band'+IntToStr(i)+' f1', FloatToStr(f1));
  566.             WriteString(Section, 'Band'+IntToStr(i)+' f2', FloatToStr(f2));
  567.             WriteString(Section, 'Band'+IntToStr(i)+' Gain', FloatToStr(Gain));
  568.             WriteBool(Section, 'Band'+IntToStr(i)+' Enabled', Enabled);
  569.          end;
  570.       end;
  571.    end;
  572. end;
  574. {-- TMMEqualizer --------------------------------------------------------------}
  575. procedure TMMEqualizer.SaveToIniFileEx(Ini: TIniFile; Section: string);
  576. var
  577.    i: integer;
  578. begin
  579.    if (Ini <> nil) then
  580.    begin
  581.       with Ini do
  582.       begin
  583.          WriteInteger(Section, 'FFTLen', FFTLength);
  584.          WriteInteger(Section, 'Samplerate', Samplerate);
  585.          WriteInteger(Section, 'Window', Ord(Window));
  587.          WriteInteger(Section, 'Bands', Filters.Count);
  588.          for i := 0 to Filters.Count-1 do
  589.          with Filters[i] do
  590.          begin
  591.             WriteString(Section, 'Band'+IntToStr(i)+' f1', FloatToStr(f1));
  592.             WriteString(Section, 'Band'+IntToStr(i)+' f2', FloatToStr(f2));
  593.             WriteString(Section, 'Band'+IntToStr(i)+' Gain', FloatToStr(Gain));
  594.             WriteBool(Section, 'Band'+IntToStr(i)+' Enabled', Enabled);
  595.          end;
  596.       end;
  597.    end;
  598. end;
  600. {-- TMMEqualizer --------------------------------------------------------------}
  601. procedure TMMEqualizer.ReadFromRegIniFile(Ini: TRegIniFile; Section: string);
  602. var
  603.    Cnt, i: integer;
  604.    f1,f2,Gain: Float;
  605.    Enabl: Boolean;
  607. begin
  608.    if (Ini <> nil) then
  609.    begin
  610.       with Ini do
  611.       begin
  612.          i := ReadInteger(Section, 'FFTLen', -1);
  613.          if (i > 0) then
  614.          begin
  615.             Filters.BeginUpdate;
  616.             try
  617.                FUpdating := True;
  619.                Filters.FreeAll;
  621.                FFTLength   := ReadInteger(Section, 'FFTLen', defFFTLen);
  622.                Samplerate  := ReadInteger(Section, 'Samplerate', defRate);
  623.                Window      := TMMFFTWindow(ReadInteger(Section, 'Window', Ord(defWindow)));
  624.                Description := Section;
  626.                Cnt := ReadInteger(Section, 'Bands', 0);
  628.                for i := 0 to Cnt-1 do
  629.                begin
  630.                   f1   := StrToFloat(CheckFloat(ReadString(Section, 'Band'+IntToStr(i)+' f1', '0')));
  631.                   f2   := StrToFloat(CheckFloat(ReadString(Section, 'Band'+IntToStr(i)+' f2', '0')));
  632.                   Gain := StrToFloat(CheckFloat(ReadString(Section, 'Band'+IntToStr(i)+' Gain', '0')));
  633.                   Enabl:= ReadBool(Section, 'Band'+IntToStr(i)+' Enabled', True);
  635.                   Filters.AddObject(TMMEQFilter.CreateEx(f1,f2,Gain));
  636.                   Filters[i].Enabled := Enabl;
  637.                end;
  639.             finally
  640.                FUpdating := False;
  641.                Filters.EndUpdate;
  642.             end;
  643.          end;
  644.       end;
  645.    end;
  646. end;
  648. {-- TMMEqualizer --------------------------------------------------------------}
  649. procedure TMMEqualizer.ReadFromIniFileEx(Ini: TIniFile; Section: string);
  650. var
  651.    Cnt, i: integer;
  652.    f1,f2,Gain: Float;
  653.    Enabl: Boolean;
  655. begin
  656.    if (Ini <> nil) then
  657.    begin
  658.       with Ini do
  659.       begin
  660.          i := ReadInteger(Section, 'FFTLen', -1);
  661.          if (i > 0) then
  662.          begin
  663.             Filters.BeginUpdate;
  664.             try
  665.                FUpdating := True;
  667.                Filters.FreeAll;
  669.                FFTLength   := ReadInteger(Section, 'FFTLen', defFFTLen);
  670.                Samplerate  := ReadInteger(Section, 'Samplerate', defRate);
  671.                Window      := TMMFFTWindow(ReadInteger(Section, 'Window', Ord(defWindow)));
  672.                Description := Section;
  674.                Cnt := ReadInteger(Section, 'Bands', 0);
  676.                for i := 0 to Cnt-1 do
  677.                begin
  678.                   f1   := StrToFloat(CheckFloat(ReadString(Section, 'Band'+IntToStr(i)+' f1', '0')));
  679.                   f2   := StrToFloat(CheckFloat(ReadString(Section, 'Band'+IntToStr(i)+' f2', '0')));
  680.                   Gain := StrToFloat(CheckFloat(ReadString(Section, 'Band'+IntToStr(i)+' Gain', '0')));
  681.                   Enabl:= ReadBool(Section, 'Band'+IntToStr(i)+' Enabled', True);
  683.                   Filters.AddObject(TMMEQFilter.CreateEx(f1,f2,Gain));
  684.                   Filters[i].Enabled := Enabl;
  685.                end;
  687.             finally
  688.                FUpdating := False;
  689.                Filters.EndUpdate;
  690.             end;
  691.          end;
  692.       end;
  693.    end;
  694. end;
  696. {-- TMMEqualizer --------------------------------------------------------------}
  697. procedure TMMEqualizer.SaveToIniFile(IniFile: TFileName; Section: string);
  698. var
  699.    Ini: TIniFile;
  700. begin
  701.    if (IniFile <> '') then
  702.    begin
  703.       Ini := TIniFile.Create(IniFile);
  704.       try
  705.          Section := 'EQ.'+Section;
  706.          SaveToIniFileEx(Ini, Section);
  707.       finally
  708.          Ini.Free;
  709.       end;
  710.    end;
  711. end;
  713. {-- TMMEqualizer --------------------------------------------------------------}
  714. procedure TMMEqualizer.ReadFromIniFile(IniFile: TFileName; Section: string);
  715. var
  716.    Ini: TInifile;
  717. begin
  718.    if (IniFile <> '') then
  719.    begin
  720.       Ini := TIniFile.Create(IniFile);
  721.       try
  722.          Section := 'EQ.'+Section;
  723.          ReadFromIniFileEx(Ini,Section);
  724.       finally
  725.          Ini.Free;
  726.       end;
  727.    end;
  728. end;
  730. {-- TMMEqualizer --------------------------------------------------------------}
  731. procedure TMMEqualizer.SetFilters(aValue: TMMEQFilterList);
  732. begin
  733.    if (aValue <> FFilters) then FFilters.Assign(aValue);
  734. end;
  736. {-- TMMEqualizer --------------------------------------------------------------}
  737. procedure TMMEqualizer.FilterChanged(Sender: TObject);
  738. begin
  739.    { setup one equalizer band with the params }
  740.    if not FUpdating then
  741.    begin
  742.       if FOpen then
  743.       with (Sender as TMMEQFilter) do
  744.       begin
  745.          { now update the filter channels }
  746.          if Enabled then
  747.             SetFFTFilterBand(FPFilter,f1,f2,gain)
  748.          else
  749.             SetFFTFilterBand(FPFilter,f1,f2,0);
  750.       end;
  751.       Change;
  752.    end;
  753. end;
  755. {-- TMMEqualizer --------------------------------------------------------------}
  756. procedure TMMEqualizer.FiltersChanged(Sender: TObject);
  757. begin
  758.    if not FUpdating and (Filters.UpdateCount = 0) then
  759.    begin
  760.       Update;
  761.       Change;
  762.    end;
  763. end;
  765. {-- TMMEqualizer --------------------------------------------------------------}
  766. procedure TMMEqualizer.Loaded;
  767. begin
  768.    inherited Loaded;
  770.    NotifySpectrum;
  771. end;
  773. {-- TMMEqualizer --------------------------------------------------------------}
  774. procedure TMMEqualizer.Change;
  775. begin
  776.    NotifySpectrum;
  778.    if assigned(FOnChange) then FOnChange(Self);
  779. end;
  781. {-- TMMEqualizer --------------------------------------------------------------}
  782. procedure TMMEqualizer.Update;
  783. var
  784.    i: integer;
  786. begin
  787.    { setup the equalizer with the params }
  788.    if FOpen then
  789.    begin
  790.       ResetEQ;
  791.       for i := 0 to Filters.Count-1 do
  792.       with Filters[i] do
  793.       begin
  794.         { now update the filter channels }
  795.         if Enabled then SetFFTFilterBand(FPFilter,f1,f2,Gain);
  796.       end;
  797.    end;
  798. end;
  800. {-- TMMEqualizer --------------------------------------------------------------}
  801. procedure TMMEqualizer.ResetEQ;
  802. begin
  803.    if FOpen and (FPFilter <> nil) then
  804.    begin
  805.       { reset the equalizer }
  806.       SetFFTFilterBand(FPFilter,0,Ffs/2,0);
  807.    end;
  808. end;
  810. {-- TMMEqualizer --------------------------------------------------------------}
  811. procedure TMMEqualizer.UpdateTempFilter(Init: Boolean);
  812. var
  813.    wfx: TWaveFormatEx;
  814. begin
  815.    DoneFFTFilter(FPTempFilter);
  817.    if Init and (FSpectrum <> nil) then
  818.    begin
  819.       pcmBuildWaveHeader(@wfx, 16, 1, Ffs);
  820.       FPTempFilter := InitFFTFilter(@wfx,FFTLen,8192);
  821.       FSpectrum.PCMWaveFormat := PPCMWaveFormat(@wfx)^;
  822.       SetFFTFilterWindow(FPTempFilter,Ord(FWindow));
  823.       NotifySpectrum;
  824.    end;
  825. end;
  827. {-- TMMEqualizer --------------------------------------------------------------}
  828. procedure TMMEqualizer.SetSpectrum(aValue: TMMSpectrum);
  829. begin
  830.    if Longint(Self) = Longint(aValue) then exit;
  832.    if (aValue <> FSpectrum) then
  833.    begin
  834.       if (aValue = nil) then
  835.       begin
  836.          FSpectrum.OnNeedData := nil;
  837.          NotifySpectrum;
  838.          UpdateTempFilter(False);
  839.       end;
  841.       FSpectrum := aValue;
  843.       if (FSpectrum <> nil) then
  844.       begin
  845.          UpdateTempFilter(True);
  846.          FSpectrum.Window := fwRectangular;
  847.          FSpectrum.OnNeedData := SpectrumNeedData;
  848.          NotifySpectrum;
  849.       end;
  850.    end;
  851. end;
  853. {-- TMMEqualizer --------------------------------------------------------------}
  854. procedure TMMEqualizer.NotifySpectrum;
  855. begin
  856.    if (FSpectrum = nil) or
  857.       (csLoading in ComponentState) or
  858.       (csReading in ComponentState) then exit;
  860.    FSpectrum.ResetData;
  861. end;
  863. {-- TMMEqualizer --------------------------------------------------------------}
  864. procedure TMMEqualizer.SpectrumNeedData(Sender: TObject);
  865. var
  866.    i: integer;
  867.    Buf: array[0..8192] of Smallint;
  869. begin
  870.    if (Sender <> nil) and (FPTempFilter <> nil) then
  871.    with TMMSpectrum(Sender) do
  872.    begin
  873.       { reset the filter }
  874.       SetFFTFilterBand(FPTempFilter,0,Ffs/2, 0);
  876.       for i := 0 to Filters.Count-1 do
  877.       with Filters[i] do
  878.       begin
  879.          { now update the filter bands }
  880.          if Enabled then SetFFTFilterBand(FPTempFilter,f1,f2,Gain);
  881.       end;
  883.       GlobalFillMem(Buf,sizeOf(Buf),0);
  884.       Buf[0] := 21500;
  886.       DoFFTFilter(FPTempFilter, chLeft, @Buf, Max(BytesPerSpectrum,2*FFTLen));
  888.       RefreshPCMData(@Buf);
  889.    end;
  890. end;
  892. {-- TMMEqualizer --------------------------------------------------------------}
  893. procedure TMMEqualizer.Assign(Source: TPersistent);
  894. begin
  895.    if (Source is TMMEqualizer) then
  896.    begin
  897.       if (Source <> nil) then
  898.       begin
  899.          Channel    := TMMEqualizer(Source).Channel;
  900.          Enabled    := TMMEqualizer(Source).Enabled;
  901.          Description:= TMMEqualizer(Source).Description;
  902.          FFTLength  := TMMEqualizer(Source).FFTLength;
  903.          Window     := TMMEqualizer(Source).Window;
  904.          Filters    := TMMEqualizer(Source).Filters;
  905.          SampleRate := TMMEqualizer(Source).SampleRate;
  906.       end;
  907.    end;
  908. end;
  910. {-- TMMEqualizer --------------------------------------------------------------}
  911. procedure TMMEqualizer.SetChannel(aValue: TMMChannel);
  912. begin
  913.    if (aValue <> FChannel) then
  914.    begin
  915.       FChannel := aValue;
  916.    end;
  917. end;
  919. {-- TMMEqualizer --------------------------------------------------------------}
  920. procedure TMMEqualizer.SetSampleRate(aValue: Longint);
  921. begin
  922.    if (aValue <> Ffs) then
  923.    begin
  924.       Ffs := MinMax(aValue,4000,100000);
  925.       UpdateTempFilter(True);
  926.    end;
  927. end;
  929. {-- TMMEqualizer --------------------------------------------------------------}
  930. procedure TMMEqualizer.SetWindow(aValue: TMMFFTWindow);
  931. begin
  932.    if (aValue <> FWindow) then
  933.    begin
  934.       FWindow := aValue;
  935.       if FOpen then SetFFTFilterWindow(FPFilter,Ord(FWindow));
  936.       UpdateTempFilter(True);
  937.    end;
  938. end;
  940. {-- TMMEqualizer --------------------------------------------------------------}
  941. procedure TMMEqualizer.SetFFTLen(aValue: integer);
  942. var
  943.    Order: integer;
  945. begin
  946. { band wide = (44100/2)/(FFTLen/2) = 172 Hz. for fft(256)         }
  947. {             (44100/2)/(FFTLen/2) = 86 Hz wide of band. fft(512) }
  949.    aValue := MinMax(aValue,8,MAX_FFTLEN);
  950.    { Convert FFTLen to a power of 2 }
  951.    Order := 0;
  952.    while aValue > 1 do
  953.    begin
  954.       aValue := aValue shr 1;
  955.       inc(Order);
  956.    end;
  957.    if (Order > 0) then aValue := aValue shl Order;
  959.    if (aValue <> FFTLen) then
  960.    begin
  961.       { re-init the FFTObject with the new FFT-length }
  962.       FFTLen := aValue;
  963.       UpdateTempFilter(True);
  965.       if FOpen then
  966.       begin
  967.          DoneFFTFilter(FPFilter);
  968.          FPFilter := InitFFTFilter(PWaveFormat, FFTLength, FRealBufSize);
  969.          if (FPFilter = nil) then OutOfMemoryError;
  970.          SetFFTFilterWindow(FPFilter,Ord(FWindow));
  971.          Update;
  972.       end;
  973.    end;
  974. end;
  976. {-- TMMEqualizer --------------------------------------------------------------}
  977. procedure TMMEqualizer.SetDescription(aValue: String);
  978. begin
  979.    if (aValue <> FDescription) then
  980.    begin
  981.       FDescription := aValue;
  982.    end;
  983. end;
  985. {-- TMMEqualizer --------------------------------------------------------------}
  986. procedure TMMEqualizer.SetEnabled(aValue: Boolean);
  987. begin
  988.    if (aValue <> FEnabled) then
  989.    begin
  990.       FEnabled := aValue;
  991.       Reset;
  992.    end;
  993. end;
  995. {-- TMMEqualizer --------------------------------------------------------------}
  996. procedure TMMEqualizer.Open;
  997. begin
  998.    if not FOpen then
  999.    begin
  1000.       if pcmIsValidFormat(PWaveFormat) then
  1001.       begin
  1002.          FRealBufSize := Max(Max(QUEUE_READ_SIZE,QUEUE_WRITE_SIZE),BufferSize);
  1004.          FPFilter := InitFFTFilter(PWaveFormat, FFTLength, FRealBufSize);
  1005.          if (FPFilter = nil) then OutOfMemoryError;
  1006.          SetFFTFilterWindow(FPFilter,Ord(FWindow));
  1007.          FOpen := True;
  1008.          Update;
  1009.       end;
  1010.    end;
  1011. end;
  1013. {-- TMMEqualizer --------------------------------------------------------------}
  1014. procedure TMMEqualizer.Reset;
  1015. begin
  1016.    if FOpen and (FPFilter <> nil) then
  1017.    begin
  1018.       ResetFFTFilter(FPFilter);
  1019.    end;
  1020. end;
  1022. {-- TMMEqualizer --------------------------------------------------------------}
  1023. procedure TMMEqualizer.Close;
  1024. begin
  1025.    if FOpen then
  1026.    begin
  1027.       FOpen := False;
  1028.       DoneFFTFilter(FPFilter);
  1029.    end;
  1030. end;
  1032. {-- TMMEqualizer --------------------------------------------------------------}
  1033. procedure TMMEqualizer.Process(Buffer: PChar; Length: integer);
  1034. begin
  1035.    { process the buffer trough the filter engine }
  1036.    if FOpen and (FPFilter <> nil) and FEnabled then
  1037.    begin
  1038.       if DoFFTFilter(FPFilter, FChannel, Buffer, Length) then
  1039.       begin
  1040.          if assigned(FOnPcmOverflow) then
  1041.             GlobalSynchronize(PcmOverflow);
  1042.       end;
  1043.    end;
  1044. end;
  1046. {-- TMMEqualizer --------------------------------------------------------------}
  1047. procedure TMMEqualizer.Opened;
  1048. begin
  1049.    Open;
  1051.    inherited Opened;
  1052. end;
  1054. {-- TMMEqualizer --------------------------------------------------------------}
  1055. procedure TMMEqualizer.Closed;
  1056. begin
  1057.    Close;
  1059.    inherited Closed;
  1060. end;
  1062. {-- TMMEqualizer --------------------------------------------------------------}
  1063. procedure TMMEqualizer.Started;
  1064. begin
  1065.    Update;
  1066.    Reset;
  1068.    inherited Started;
  1069. end;
  1071. {-- TMMEqualizer --------------------------------------------------------------}
  1072. procedure TMMEqualizer.Reseting;
  1073. begin
  1074.    Reset;
  1076.    inherited Reseting;
  1077. end;
  1079. {-- TMMEqualizer --------------------------------------------------------------}
  1080. procedure TMMEqualizer.BufferReady(lpwh: PWaveHdr);
  1081. begin
  1082.    if FOpen then
  1083.    begin
  1084.       Process(lpwh^.lpData, lpwh^.dwBytesRecorded);
  1085.    end;
  1087.    inherited BufferReady(lpwh);
  1088. end;
  1090. {-- TMMEqualizer --------------------------------------------------------------}
  1091. procedure TMMEqualizer.BufferLoad(lpwh: PWaveHdr; var MoreBuffers: Boolean);
  1092. begin
  1093.    inherited BufferLoad(lpwh, MoreBuffers);
  1095.    if FOpen then
  1096.    begin
  1097.       Process(lpwh^.lpData, lpwh^.dwBytesRecorded);
  1098.    end;
  1099. end;
  1101. initialization
  1102.    { register filter class for streaming ! }
  1103.    DoRegisterClass(@TMMEQFilter.Load,
  1104.                    @TMMEQFilter.Store,
  1105.                     TMMEQFilter);
  1107. end.