开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > Windows CE > 查看源码
mcomp_arm.asm
资源名称：tcpmp.rar　[点击查看]
上传用户：wstnjxml
上传日期：2014-04-03
资源大小：7248k
文件大小：20k
源码类别：

Windows CE

开发平台：

C/C++

mcomp_arm.asm：源码内容
  1. ;*****************************************************************************
  2. ;*
  3. ;* This program is free software ; you can redistribute it and/or modify
  4. ;* it under the terms of the GNU General Public License as published by
  5. ;* the Free Software Foundation; either version 2 of the License, or
  6. ;* (at your option) any later version.
  7. ;*
  8. ;* This program is distributed in the hope that it will be useful,
  9. ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  10. ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  11. ;* GNU General Public License for more details.
  12. ;*
  13. ;* You should have received a copy of the GNU General Public License
  14. ;* along with this program; if not, write to the Free Software
  15. ;* Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  16. ;*
  17. ;* $Id: mcomp_arm.asm 327 2005-11-04 07:09:17Z picard $
  18. ;*
  19. ;* The Core Pocket Media Player
  20. ;* Copyright (c) 2004-2005 Gabor Kovacs
  21. ;*
  22. ;*****************************************************************************
  24. ;R0 src
  25. ;R1 dst
  26. ;R2 srcpitch
  27. ;R3 dstpitch
  29. AREA |.text|, CODE
  31.   macro 
  32.   PreLoad $ARM5,$Pos
  33.     if $ARM5>0
  34.   if $Pos >= 0
  35.        if $Pos > 0
  36.       pld [r0,r2,lsl #1]
  37.       add r0,r0,#8
  38.       pld [r0,r2,lsl #1]
  39.       sub r0,r0,#8
  40.     else
  41.       pld [r0,r2,lsl #1]
  42.       add r0,r0,#4
  43.       pld [r0,r2,lsl #1]
  44.       sub r0,r0,#4
  45.     endif
  46.   else
  47.     pld [r0,r2,lsl #1]
  48.     add r0,r0,#7
  49.     pld [r0,r2,lsl #1]
  50.     sub r0,r0,#7
  51.   endif
  52. endif
  53.   mend
  55.   macro 
  56.   PreLoad2Init $ARM5,$Pos
  57.     if $ARM5>0
  58.   if $Pos >= 0
  59.        if $Pos > 0
  60.       add r10,r2,r2
  61.       add r10,r10,#8
  62.     else
  63.       add r10,r2,r2
  64.       add r10,r10,#4
  65.     endif
  66.   else
  67.       add r10,r2,r2
  68.       add r10,r10,#7
  69.   endif
  70. endif
  71.   mend
  73.   macro 
  74.   PreLoad2 $ARM5,$Pos
  75. if $ARM5>0
  76.       pld [r0,r2,lsl #1]
  77.       pld [r0,r10]
  78. endif
  79.   mend
  81.   macro 
  82.   CopyBuild $Name,$Sub,$Round,$Add,$Fast,$ARM5
  84. align 16
  85. export $Name
  86. $Name proc
  87. if $ARM5>0
  88. add ip,r2,#7
  89. pld [r0,r2]
  90. pld [r0,#7]
  91. endif
  92. stmdb sp!, {r4 - r11, lr}
  93. if $ARM5>0
  94. pld [r0,ip]
  95. pld [r0]
  96. endif
  97. if $Fast>0
  98. movs r4,r0,lsl #30
  99. beq $Name.L00
  100. cmps r4,#0x80000000
  101. beq $Name.L10
  102. bhi $Name.L11
  103. $Name.L01
  104. bic r0,r0,#3
  105. $Sub $Name.8,8,$Round,$Add,$ARM5
  106. $Name.L10
  107. bic r0,r0,#3
  108. $Sub $Name.16,16,$Round,$Add,$ARM5
  109. $Name.L11
  110. bic r0,r0,#3
  111. $Sub $Name.24,24,$Round,$Add,$ARM5
  112. $Name.L00
  113. $Sub $Name.0,0,$Round,$Add,$ARM5
  114. else
  115. $Sub $Name.s,-1,$Round,$Add,$ARM5
  116. endif
  117. endp
  118.   mend
  120. ;------------------------------------------
  121. ;COPYBLOCK
  122. ;------------------------------------------
  124.   macro
  125.   CopyBlockRow $Pos
  126. if $Pos > 0
  127.   ldr r5,[r0,#8]
  128.   ldr r6,[r0,#4]
  129.   ldr r4,[r0],r2
  131.   mov r5,r5,lsl #32-$Pos
  132.   orr r5,r5,r6,lsr #$Pos
  133.   mov r4,r4,lsr #$Pos
  134.   orr r4,r4,r6,lsl #32-$Pos
  135. else
  136.   ldr r5,[r0,#4]
  137.   ldr r4,[r0],r2
  138. endif
  140. str r5,[r1,#4]
  141. str r4,[r1],r3
  142.   mend
  144.   macro
  145.   CopyBlock $Id, $Pos, $Round, $Add, $ARM5
  147. PreLoad2Init $ARM5,$Pos
  148.     PreLoad2 $ARM5,$Pos
  149. CopyBlockRow $Pos 
  150.     PreLoad2 $ARM5,$Pos
  151. CopyBlockRow $Pos 
  152.     PreLoad2 $ARM5,$Pos
  153. CopyBlockRow $Pos 
  154.     PreLoad2 $ARM5,$Pos
  155. CopyBlockRow $Pos 
  156.     PreLoad2 $ARM5,$Pos
  157. CopyBlockRow $Pos 
  158.     PreLoad2 $ARM5,$Pos
  159. CopyBlockRow $Pos 
  160.     PreLoad2 $ARM5,$Pos
  161. CopyBlockRow $Pos 
  162.     PreLoad2 $ARM5,$Pos
  163. CopyBlockRow $Pos 
  165. ldmia sp!, {r4 - r11, pc}
  166.   mend
  168. ;------------------------------------------
  169. ;COPYBLOCKM
  170. ;------------------------------------------
  172.   macro
  173.   CopyBlockMRow $Pos
  174. if $Pos > 0
  175.   ldr r14,[r0,#16]
  176.   ldr r6,[r0,#12]
  177.   ldr r12,[r0,#8]
  179.   mov r14,r14,lsl #32-$Pos
  180.   orr r14,r14,r6,lsr #$Pos
  181.   mov r12,r12,lsr #$Pos
  182.   orr r12,r12,r6,lsl #32-$Pos
  184.   ldr r5,[r0,#8]
  185.   ldr r6,[r0,#4]
  186.   ldr r4,[r0],r2
  188.   mov r5,r5,lsl #32-$Pos
  189.   orr r5,r5,r6,lsr #$Pos
  190.   mov r4,r4,lsr #$Pos
  191.   orr r4,r4,r6,lsl #32-$Pos
  192. else
  193.   ldr r5,[r0,#4]
  194.   ldr r12,[r0,#8]
  195.   ldr r14,[r0,#12]
  196.   ldr r4,[r0],r2
  197. endif
  199. str r5,[r1,#4]
  200. str r12,[r1,#8]
  201. str r14,[r1,#12]
  202. str r4,[r1],r3
  203.   mend
  205.   macro
  206.   CopyBlockM $Id, $Pos, $Round, $Add, $ARM5
  208. PreLoad2Init $ARM5,$Pos
  209. mov r11,#16
  210. $Id.Loop
  211.     PreLoad2 $ARM5,$Pos
  212. CopyBlockMRow $Pos
  213. subs r11,r11,#1
  214. bne  $Id.Loop
  216. ldmia sp!, {r4 - r11, pc}
  217.   mend
  219. ;------------------------------------------
  220. ;COPYBLOCK16x16: no aligment!, only used in Copy()
  221. ;------------------------------------------
  223.   macro
  224.   CopyBlock16x16Row
  225. ldr r7,[r0,#12]
  226. ldr r6,[r0,#8]
  227. ldr r5,[r0,#4]
  228. ldr r4,[r0],r2
  229. str r7,[r1,#12]
  230. str r6,[r1,#8]
  231. str r5,[r1,#4]
  232. str r4,[r1],r3
  233.   mend
  235.   macro
  236.   CopyBlock16x16 $Id, $Pos, $Round, $Add, $ARM5
  238. mov r11,#15
  240. $Id.Loop
  241.     pld [r0,r2,lsl #1]
  242. CopyBlock16x16Row
  243. subs r11,r11,#1 
  244. bne  $Id.Loop
  246. ;unroll last (no preload needed)
  247. CopyBlock16x16Row
  248. ldmia sp!, {r4 - r11, pc}
  249.   mend
  251. ;------------------------------------------
  252. ;COPYBLOCK8x8: no aligment!, only used in Copy()
  253. ;------------------------------------------
  255.   macro
  256.   CopyBlock8x8 $Id, $Pos, $Round, $Add, $ARM5
  258. mov r11,#3
  260. $Id.Loop
  261.     pld [r0,r2,lsl #1]
  262. ldr r7,[r0,#4]
  263. ldr r6,[r0],r2
  264.     pld [r0,r2,lsl #1]
  265. ldr r5,[r0,#4]
  266. ldr r4,[r0],r2
  267. str r7,[r1,#4]
  268. str r6,[r1],r3
  269. str r5,[r1,#4]
  270. str r4,[r1],r3
  271. subs r11,r11,#1 
  272. bne $Id.Loop
  274. ;unroll last (no preload needed)
  275. ldr r7,[r0,#4]
  276. ldr r6,[r0],r2
  277. ldr r5,[r0,#4]
  278. ldr r4,[r0],r2
  279. str r7,[r1,#4]
  280. str r6,[r1],r3
  281. str r5,[r1,#4]
  282. str r4,[r1],r3
  283. ldmia sp!, {r4 - r11, pc}
  284.   mend
  286. ;------------------------------------------
  287. ;ADDBLOCK
  288. ;------------------------------------------
  290.   macro
  291.   AddBlockRow $Pos
  293. if $Pos < 0
  295. ldrb r4,[r0]
  296. ldrb r6,[r0,#1]
  297. ldrb r5,[r0,#4]
  298. ldrb r7,[r0,#5]
  299. orr r4,r4,r6,lsl #8
  300. ldrb r6,[r0,#2]
  301. orr r5,r5,r7,lsl #8
  302. ldrb r7,[r0,#6]
  303. orr r4,r4,r6,lsl #16
  304. ldrb r6,[r0,#3]
  305. orr r5,r5,r7,lsl #16
  306. ldrb r7,[r0,#7]
  307. orr r4,r4,r6,lsl #24
  308. add r0,r0,r2
  309. orr r5,r5,r7,lsl #24
  311. else
  312. if $Pos > 0
  313.   ldr r5,[r0,#8]
  314.   ldr r6,[r0,#4]
  315.   ldr r4,[r0],r2
  317.   mov r5,r5,lsl #32-$Pos
  318.   orr r5,r5,r6,lsr #$Pos
  319.   mov r4,r4,lsr #$Pos
  320.   orr r4,r4,r6,lsl #32-$Pos
  321. else
  322.   ldr r5,[r0,#4]
  323.   ldr r4,[r0],r2
  324. endif
  325. endif
  327. ldr r7,[r1,#4]
  328. ldr r6,[r1]
  329. and r9,r12,r5,lsr #1
  330. and r8,r12,r4,lsr #1
  331. orr r5,r7,r5
  332. orr r4,r6,r4
  333. and r7,r12,r7,lsr #1
  334. and r6,r12,r6,lsr #1
  335. add r7,r7,r9
  336. add r6,r6,r8
  337. and r5,r5,r14
  338. and r4,r4,r14
  339. add r7,r7,r5
  340. add r6,r6,r4
  341. str r7,[r1,#4]
  342. str r6,[r1],#8
  343.   mend
  345.   macro
  346.   AddBlock $Id, $Pos, $Round, $Add, $ARM5
  348. PreLoad2Init $ARM5,$Pos
  349. ldr r14,$Id.Mask
  350. mov r11,#8
  351. mvn r12,r14,lsl #7
  353. $Id.Loop
  354.     PreLoad2 $ARM5,$Pos
  355. AddBlockRow $Pos
  356. subs r11,r11,#1 
  357. bne  $Id.Loop
  359. ldmia sp!, {r4 - r11, pc}
  360. $Id.Mask dcd 0x01010101
  361.   mend
  363. ;------------------------------------------
  364. ; COPYBLOCKHOR
  365. ;------------------------------------------
  367.   macro
  368.   LoadHorRow $Id, $Pos
  370.     ; result is r4,r5 and r8,r9 (one pixel to the right)
  371.     ; r6,r7 can be used
  373. if $Pos < 0
  375. ldrb r4,[r0]
  376. ldrb r6,[r0,#1]
  377. ldrb r5,[r0,#4]
  378. ldrb r7,[r0,#5]
  379. orr r4,r4,r6,lsl #8
  380. ldrb r6,[r0,#2]
  381. orr r5,r5,r7,lsl #8
  382. ldrb r7,[r0,#6]
  383. orr r4,r4,r6,lsl #16
  384. ldrb r6,[r0,#3]
  385. orr r5,r5,r7,lsl #16
  386. ldrb r7,[r0,#7]
  387. orr r4,r4,r6,lsl #24
  388. ldrb r6,[r0,#8]
  389. orr r5,r5,r7,lsl #24
  391. mov r8,r4,lsr #8
  392. mov r9,r5,lsr #8
  393. orr r8,r8,r5,lsl #24
  394. orr r9,r9,r6,lsl #24
  396. add r0,r0,r2
  398. else
  400.     ldr r5,[r0,#4]
  401.     ldr r6,[r0,#8]
  402.     ldr r4,[r0],r2
  404.     if $Pos+8 < 32
  405.   mov r9,r5,lsr #$Pos+8
  406.   orr r9,r9,r6,lsl #32-$Pos-8
  407.   mov r8,r4,lsr #$Pos+8
  408.   orr r8,r8,r5,lsl #32-$Pos-8
  409.     else
  410.   mov r8,r5
  411.   mov r9,r6
  412.     endif
  414. if $Pos > 0
  415.   mov r4,r4,lsr #$Pos
  416.   mov r6,r6,lsl #32-$Pos
  417.   orr r4,r4,r5,lsl #32-$Pos
  418.   orr r5,r6,r5,lsr #$Pos
  419. endif
  420. endif
  421.   mend
  423.   macro
  424.   CopyHorRow $Id, $Pos, $Round, $Add
  426. ;r14 01010101
  427. ;r12 7f7f7f7f
  429. LoadHorRow $Id,$Pos
  431. and r6,r12,r4,lsr #1
  432. and r7,r12,r5,lsr #1
  434. if $Round
  435.   and r4,r4,r8
  436.   and r5,r5,r9
  437. else
  438.   orr r4,r4,r8
  439.   orr r5,r5,r9
  440. endif
  442. and r8,r12,r8,lsr #1
  443. and r9,r12,r9,lsr #1
  445. and r4,r4,r14
  446. and r5,r5,r14
  448. add r4,r4,r6
  449. add r5,r5,r7
  450. add r4,r4,r8
  451. add r5,r5,r9
  453. if $Add
  454.   ldr r7,[r1,#4]
  455.   ldr r6,[r1]
  456.   and r9,r12,r5,lsr #1
  457.   and r8,r12,r4,lsr #1
  458.   orr r5,r7,r5
  459.   orr r4,r6,r4
  460.   and r7,r12,r7,lsr #1
  461.   and r6,r12,r6,lsr #1
  462.   add r7,r7,r9
  463.   add r6,r6,r8
  464.   and r5,r5,r14
  465.   and r4,r4,r14
  466.   add r7,r7,r5
  467.   add r6,r6,r4
  468.   str r7,[r1,#4]
  469.   str r6,[r1],#8
  470. else
  471.   str r5,[r1,#4]
  472.   str r4,[r1],r3
  473. endif
  474.   mend
  476.   macro
  477.   CopyBlockHor $Id, $Pos, $Round, $Add, $ARM5
  479. PreLoad2Init $ARM5,$Pos
  480. ldr r14,$Id.Mask
  481. mov r11,#8
  482. mvn r12,r14,lsl #7
  484. $Id.Loop
  485.     PreLoad2 $ARM5,$Pos
  486. CopyHorRow $Id,$Pos,$Round,$Add
  487. subs r11,r11,#1
  488. bne  $Id.Loop
  490. ldmia sp!, {r4 - r11, pc}
  491. $Id.Mask dcd 0x01010101
  492.   mend
  494. ;------------------------------------------
  495. ; COPYBLOCKVER
  496. ;------------------------------------------
  498.   macro
  499.   LoadVerRow $Id, $Pos, $Parity
  500.   if $Parity
  501.     ; result is r8,r9 (r10=r8>>1,r11=r9>>1) 
  502.     ; r10,r11 can be used
  504. if $Pos < 0
  505.     ldrb r8,[r0]
  506.   ldrb r10,[r0,#1]
  507.   ldrb r9,[r0,#4]
  508.   ldrb r11,[r0,#5]
  509.   orr r8,r8,r10,lsl #8 
  510.   ldrb r10,[r0,#2]
  511.   orr r9,r9,r11,lsl #8
  512.   ldrb r11,[r0,#6]
  513.   orr r8,r8,r10,lsl #16
  514.   ldrb r10,[r0,#3]
  515.   orr r9,r9,r11,lsl #16
  516.   ldrb r11,[r0,#7]
  517.   orr r8,r8,r10,lsl #24
  518.   add r0,r0,r2
  519.   orr r9,r9,r11,lsl #24
  520. else
  521.     if $Pos > 0
  522.   ldr r9,[r0,#8]
  523.   ldr r10,[r0,#4]
  524.   ldr r8,[r0],r2
  526.   mov r9,r9,lsl #32-$Pos
  527.   orr r9,r9,r10,lsr #$Pos
  528.   mov r8,r8,lsr #$Pos
  529.   orr r8,r8,r10,lsl #32-$Pos
  530.     else
  531.   ldr r9,[r0,#4]
  532.   ldr r8,[r0],r2
  533.     endif
  534. endif
  535. and r11,r12,r9,lsr #1
  536. and r10,r12,r8,lsr #1
  537.   else
  538.     ; result is r4,r5 (r6=r4>>1,r7=r5>>1) 
  539.     ; r6,r7 can be used
  541. if $Pos < 0
  542.     ldrb r4,[r0]
  543.   ldrb r6,[r0,#1]
  544.   ldrb r5,[r0,#4]
  545.   ldrb r7,[r0,#5]
  546.   orr r4,r4,r6,lsl #8
  547.   ldrb r6,[r0,#2]
  548.   orr r5,r5,r7,lsl #8
  549.   ldrb r7,[r0,#6]
  550.   orr r4,r4,r6,lsl #16
  551.   ldrb r6,[r0,#3]
  552.   orr r5,r5,r7,lsl #16
  553.   ldrb r7,[r0,#7]
  554.   orr r4,r4,r6,lsl #24
  555.   add r0,r0,r2
  556.   orr r5,r5,r7,lsl #24
  557. else
  558.     if $Pos > 0
  559.   ldr r5,[r0,#8]
  560.   ldr r6,[r0,#4]
  561.   ldr r4,[r0],r2
  563.   mov r5,r5,lsl #32-$Pos
  564.   orr r5,r5,r6,lsr #$Pos
  565.   mov r4,r4,lsr #$Pos
  566.   orr r4,r4,r6,lsl #32-$Pos
  567.     else
  568.   ldr r5,[r0,#4]
  569.   ldr r4,[r0],r2
  570.     endif
  571. endif
  572. and r7,r12,r5,lsr #1
  573. and r6,r12,r4,lsr #1
  574.   endif
  575.   mend
  577.   macro
  578.   CopyVerRow $Id, $Pos, $Parity, $Round, $Add
  580. ;r14 01010101
  581. ;r12 7f7f7f7f
  583. LoadVerRow $Id,$Pos,$Parity
  585.     if $Parity
  586.   if $Round
  587.     and r4,r4,r8
  588.     and r5,r5,r9
  589.   else
  590.     orr r4,r4,r8
  591.     orr r5,r5,r9
  592.   endif
  593.   and r4,r4,r14
  594.   and r5,r5,r14
  596.   add r4,r4,r6
  597.   add r5,r5,r7
  599.      add r4,r4,r10
  600.   add r5,r5,r11
  602.   if $Add
  603.     ldr r7,[r1,#4]
  604.     ldr r6,[r1]
  605.     and r3,r12,r5,lsr #1
  606. orr r5,r7,r5
  607.     and r7,r12,r7,lsr #1
  608. add r7,r7,r3
  609.     and r3,r12,r4,lsr #1
  610. orr r4,r6,r4
  611.     and r6,r12,r6,lsr #1
  612. add r6,r6,r3
  613. and r5,r5,r14
  614. and r4,r4,r14
  615. add r5,r5,r7
  616. add r4,r4,r6
  617. ldr r7,[sp] ;end src for loop compare
  618.     str r5,[r1,#4]
  619.     str r4,[r1],#8
  620.   else
  621. ldr r7,[sp] ;end src for loop compare
  622.     str r5,[r1,#4]
  623.     str r4,[r1],r3
  624.   endif
  625. else
  626.   if $Round
  627.     and r8,r8,r4
  628.     and r9,r9,r5
  629.   else
  630.     orr r8,r8,r4
  631.     orr r9,r9,r5
  632.   endif
  633.   and r8,r8,r14
  634.   and r9,r9,r14
  636.   add r8,r8,r10
  637.   add r9,r9,r11
  638.      add r8,r8,r6
  639.   add r9,r9,r7
  641.   if $Add
  642.     ldr r11,[r1,#4]
  643.     ldr r10,[r1]
  644.     and r3,r12,r9,lsr #1
  645. orr r9,r11,r9
  646.     and r11,r12,r11,lsr #1
  647. add r11,r11,r3
  648.     and r3,r12,r8,lsr #1
  649. orr r8,r10,r8
  650.     and r10,r12,r10,lsr #1
  651. add r10,r10,r3
  652. and r9,r9,r14
  653. and r8,r8,r14
  654. add r11,r11,r9
  655. add r10,r10,r8
  656.     str r11,[r1,#4]
  657.     str r10,[r1],#8
  658.   else
  659.     str r9,[r1,#4]
  660.     str r8,[r1],r3
  661.   endif
  662. endif
  663.   mend
  666.   macro
  667.   CopyBlockVer $Id, $Pos, $Round, $Add, $ARM5
  669. sub sp,sp,#4
  670. add r4,r0,r2,lsl #3
  671. add r4,r4,r2
  672. str r4,[sp] ;end src
  674. ldr r14,$Id.Mask
  675. mvn r12,r14,lsl #7
  677.     PreLoad $ARM5,$Pos
  678. LoadVerRow $Id,$Pos,1
  679. $Id.Loop
  680.     PreLoad $ARM5,$Pos
  681. CopyVerRow $Id,$Pos,0,$Round,$Add
  682.     PreLoad $ARM5,$Pos
  683. CopyVerRow $Id,$Pos,1,$Round,$Add
  685. cmp r0,r7
  686. bne $Id.Loop
  687. add sp,sp,#4
  688. ldmia sp!, {r4 - r11, pc}
  689. $Id.Mask dcd 0x01010101
  690.   mend
  692. ;------------------------------------------
  693. ; COPYBLOCKHORVER
  694. ;------------------------------------------
  696. ; load needs r2,r3 for temporary (r2 is restored from stack)
  698.   macro
  699.   LoadHorVerRow $Id, $Pos, $Parity
  700.   if $Parity
  702. ;read result r4,r5 and r2,r3 (one pixel to right)
  703. ;r6,r7 can be used
  705.     if $Pos<0
  707. ldrb r4,[r0]
  708. ldrb r6,[r0,#1]
  709. ldrb r5,[r0,#4]
  710. ldrb r7,[r0,#5]
  711. orr r4,r4,r6,lsl #8
  712. ldrb r6,[r0,#2]
  713. orr r5,r5,r7,lsl #8
  714. ldrb r7,[r0,#6]
  715. orr r4,r4,r6,lsl #16
  716. ldrb r6,[r0,#3]
  717. orr r5,r5,r7,lsl #16
  718. ldrb r7,[r0,#7]
  719. orr r4,r4,r6,lsl #24
  720. ldrb r6,[r0,#8]
  721. orr r5,r5,r7,lsl #24
  722. add r0,r0,r2
  724. mov r2,r4,lsr #8
  725. mov r3,r5,lsr #8
  726. orr r2,r2,r5,lsl #24
  727. orr r3,r3,r6,lsl #24
  729. else
  730.     ldr r5,[r0,#4]
  731.     ldr r6,[r0,#8]
  732.     ldr r4,[r0],r2
  734.     if $Pos+8 < 32
  735.   mov r3,r5,lsr #$Pos+8
  736.   orr r3,r3,r6,lsl #32-$Pos-8
  737.   mov r2,r4,lsr #$Pos+8
  738.   orr r2,r2,r5,lsl #32-$Pos-8
  739.     else
  740.   mov r2,r5
  741.   mov r3,r6
  742.     endif
  744. if $Pos > 0
  745.   mov r4,r4,lsr #$Pos
  746.   mov r6,r6,lsl #32-$Pos
  747.   orr r4,r4,r5,lsl #32-$Pos
  748.   orr r5,r6,r5,lsr #$Pos
  749. endif
  750. endif
  752. and r6,r2,r14
  753. and r2,r12,r2,lsr #2
  754. and r7,r4,r14
  755. and r4,r12,r4,lsr #2
  756. add r4,r4,r2
  757. add r6,r6,r7
  759. and r2,r3,r14
  760. and r3,r12,r3,lsr #2
  761. and r7,r5,r14
  762. and r5,r12,r5,lsr #2
  763. add r5,r5,r3
  764. add r7,r2,r7
  765.   else
  766. ;read result r8,r9 and r2,r3 (one pixel to right)
  767. ;r10,r11 can be used
  769.     if $Pos<0
  771. ldrb r8,[r0]
  772. ldrb r10,[r0,#1]
  773. ldrb r9,[r0,#4]
  774. ldrb r11,[r0,#5]
  775. orr r8,r8,r10,lsl #8
  776. ldrb r10,[r0,#2]
  777. orr r9,r9,r11,lsl #8
  778. ldrb r11,[r0,#6]
  779. orr r8,r8,r10,lsl #16
  780. ldrb r10,[r0,#3]
  781. orr r9,r9,r11,lsl #16
  782. ldrb r11,[r0,#7]
  783. orr r8,r8,r10,lsl #24
  784. ldrb r10,[r0,#8]
  785. orr r9,r9,r11,lsl #24
  786. add r0,r0,r2
  788. mov r2,r8,lsr #8
  789. mov r3,r9,lsr #8
  790. orr r2,r2,r9,lsl #24
  791. orr r3,r3,r10,lsl #24
  793. else
  794.     ldr r9,[r0,#4]
  795.     ldr r10,[r0,#8]
  796.     ldr r8,[r0],r2
  798.     if $Pos+8 < 32
  799.   mov r3,r9,lsr #$Pos+8
  800.   orr r3,r3,r10,lsl #32-$Pos-8
  801.   mov r2,r8,lsr #$Pos+8
  802.   orr r2,r2,r9,lsl #32-$Pos-8
  803.     else
  804.   mov r2,r9
  805.   mov r3,r10
  806.     endif
  808. if $Pos > 0
  809.   mov r8,r8,lsr #$Pos
  810.   mov r10,r10,lsl #32-$Pos
  811.   orr r8,r8,r9,lsl #32-$Pos
  812.   orr r9,r10,r9,lsr #$Pos
  813. endif
  814. endif
  816. and r10,r2,r14
  817. and r2,r12,r2,lsr #2
  818. and r11,r8,r14
  819. and r8,r12,r8,lsr #2
  820. add r8,r8,r2
  821. add r10,r10,r11
  823. and r2,r3,r14
  824. and r3,r12,r3,lsr #2
  825. and r11,r9,r14
  826. and r9,r12,r9,lsr #2
  827. add r9,r9,r3
  828. add r11,r2,r11
  829.   endif
  830. ldr r2,[sp]
  831.   mend
  833.   macro
  834.   CopyHorVerRow $Id, $Pos, $Parity, $Round, $Add
  836. ;r14 03030303
  837. ;r12 3f3f3f3f
  839. LoadHorVerRow $Id,$Pos,$Parity
  841. if $Round
  842.   and r3,r14,r14,lsr #1 ;0x01010101
  843. else
  844.   and r3,r14,r14,lsl #1 ;0x02020202
  845. endif
  846.     if $Parity
  847.   add r8,r8,r4
  848.   add r9,r9,r5
  849.   add r10,r10,r6
  850.   add r11,r11,r7
  852.   add r10,r10,r3
  853.   add r11,r11,r3
  854.   and r10,r14,r10,lsr #2
  855.   and r11,r14,r11,lsr #2
  857.   if $Add
  858.     add r8,r8,r10 
  859.     add r9,r9,r11
  860. orr r12,r12,r12,lsl #1  ;0x7F7F7F7F
  861.     ldr r11,[r1,#4]
  862.     ldr r10,[r1]
  863.     and r3,r12,r9,lsr #1
  864. orr r9,r11,r9
  865.     and r11,r12,r11,lsr #1
  866. add r11,r11,r3
  867.     and r3,r12,r8,lsr #1
  868. orr r8,r10,r8
  869.     and r10,r12,r10,lsr #1
  870. add r10,r10,r3
  871. and r3,r14,r14,lsr #1 ;0x01010101
  872. mvn r12,r14,lsl #6    ;restore r12
  873. and r9,r9,r3
  874. and r8,r8,r3
  875. add r11,r11,r9
  876. add r10,r10,r8
  877.     ldr r3,[sp,#4] ;end src for loop compare
  878.     str r11,[r1,#4]
  879.     str r10,[r1],#8
  880.   else
  881.     add r8,r8,r10
  882.     ldr r10,[sp,#8]  ;dstpitch
  883.     add r9,r9,r11
  884.     ldr r3,[sp,#4] ;end src for loop compare
  885.     str r9,[r1,#4]
  886.     str r8,[r1],r10
  887.   endif
  888. else
  889.   add r4,r4,r8
  890.   add r5,r5,r9
  891.   add r6,r6,r10
  892.   add r7,r7,r11
  894.   add r6,r6,r3
  895.   add r7,r7,r3
  896.   and r6,r14,r6,lsr #2
  897.   and r7,r14,r7,lsr #2
  899.   if $Add
  900.     add r4,r4,r6
  901.     add r5,r5,r7
  902. orr r12,r12,r12,lsl #1  ;0x7F7F7F7F
  903.     ldr r7,[r1,#4]
  904.     ldr r6,[r1]
  905.     and r3,r12,r5,lsr #1
  906. orr r5,r7,r5
  907.     and r7,r12,r7,lsr #1
  908. add r7,r7,r3
  909.     and r3,r12,r4,lsr #1
  910. orr r4,r6,r4
  911.     and r6,r12,r6,lsr #1
  912. add r6,r6,r3
  913. and r3,r14,r14,lsr #1 ;0x01010101
  914. mvn r12,r14,lsl #6    ;restore r12
  915. and r5,r5,r3
  916. and r4,r4,r3
  917. add r7,r7,r5
  918. add r6,r6,r4
  919.     str r7,[r1,#4]
  920.     str r6,[r1],#8
  921.   else
  922.     ldr r3,[sp,#8]  ;dstpitch
  923.     add r4,r4,r6
  924.     add r5,r5,r7
  925.     str r5,[r1,#4]
  926.     str r4,[r1],r3
  927.   endif
  928. endif
  929.   mend
  931.   macro
  932.   CopyBlockHorVer $Id, $Pos, $Round, $Add, $ARM5
  933. sub sp,sp,#12
  934. add r4,r0,r2,lsl #3
  935. add r4,r4,r2
  936. str r2,[sp] ;srcpitch
  937. str r4,[sp,#4] ;end src
  938. str r3,[sp,#8] ;dstpitch
  940. ldr r14,$Id.Mask
  941. mvn r12,r14,lsl #6
  942.     PreLoad $ARM5,$Pos
  943. LoadHorVerRow $Id,$Pos,1
  944. $Id.Loop
  945.     PreLoad $ARM5,$Pos
  946. CopyHorVerRow $Id,$Pos,0,$Round,$Add
  947.     PreLoad $ARM5,$Pos
  948. CopyHorVerRow $Id,$Pos,1,$Round,$Add
  949. cmp r0,r3
  950. bne $Id.Loop
  952. add sp,sp,#12
  953. ldmia sp!, {r4 - r11, pc}
  954. $Id.Mask dcd 0x03030303
  955.   mend
  957. ;---------------------------------------------------
  958. ; general unaligned copy (use preload)
  960. CopyBuild CopyBlock8x8,CopyBlock8x8,0,0,0,1
  961. CopyBuild CopyBlock16x16,CopyBlock16x16,0,0,0,1
  963. ;---------------------------------------------------
  964. ; smaller versions without preload
  965. ;
  966. ; CopyBuild CopyBlock,CopyBlock,0,0,1,0
  967. ; CopyBuild CopyBlockVer,CopyBlockVer,0,0,0,0
  968. ; CopyBuild CopyBlockHor,CopyBlockHor,0,0,0,0
  969. ; CopyBuild CopyBlockHorVer,CopyBlockHorVer,0,0,0,0
  970. ; CopyBuild CopyBlockVerRound,CopyBlockVer,1,0,0,0
  971. ; CopyBuild CopyBlockHorRound,CopyBlockHor,1,0,0,0
  972. ; CopyBuild CopyBlockHorVerRound,CopyBlockHorVer,1,0,0,0
  973. ;
  974. ; CopyBuild AddBlock,AddBlock,0,1,0,0
  975. ; CopyBuild AddBlockVer,CopyBlockVer,0,1,0,0
  976. ; CopyBuild AddBlockHor,CopyBlockHor,0,1,0,0
  977. ; CopyBuild AddBlockHorVer,CopyBlockHorVer,0,1,0,0
  978. ;
  979. ;---------------------------------------------------
  980. ; smaller versions with preload
  981. ;
  982. ; CopyBuild PreLoadCopyBlock,CopyBlock,0,0,1,1
  983. ; CopyBuild PreLoadCopyBlockVer,CopyBlockVer,0,0,0,1
  984. ; CopyBuild PreLoadCopyBlockHor,CopyBlockHor,0,0,0,1
  985. ; CopyBuild PreLoadCopyBlockHorVer,CopyBlockHorVer,0,0,0,1
  986. ; CopyBuild PreLoadCopyBlockVerRound,CopyBlockVer,1,0,0,1
  987. ; CopyBuild PreLoadCopyBlockHorRound,CopyBlockHor,1,0,0,1
  988. ; CopyBuild PreLoadCopyBlockHorVerRound,CopyBlockHorVer,1,0,0,1
  989. ;
  990. ; CopyBuild PreLoadAddBlock,AddBlock,0,1,0,1
  991. ; CopyBuild PreLoadAddBlockVer,CopyBlockVer,0,1,0,1
  992. ; CopyBuild PreLoadAddBlockHor,CopyBlockHor,0,1,0,1
  993. ; CopyBuild PreLoadAddBlockHorVer,CopyBlockHorVer,0,1,0,1
  994. ;
  995. ;---------------------------------------------------
  996. ; larger versions with preload
  997. ; (faster if there is enough intstruction cache available)
  999. CopyBuild CopyBlock,CopyBlock,0,0,1,1
  1000. CopyBuild CopyBlockVer,CopyBlockVer,0,0,1,1
  1001. CopyBuild CopyBlockHor,CopyBlockHor,0,0,1,1
  1002. CopyBuild CopyBlockHorVer,CopyBlockHorVer,0,0,1,1
  1003. CopyBuild CopyBlockVerRound,CopyBlockVer,1,0,1,1
  1004. CopyBuild CopyBlockHorRound,CopyBlockHor,1,0,1,1
  1005. CopyBuild CopyBlockHorVerRound,CopyBlockHorVer,1,0,1,1
  1007. CopyBuild AddBlock,AddBlock,0,1,1,1
  1008. CopyBuild AddBlockVer,CopyBlockVer,0,1,1,1
  1009. CopyBuild AddBlockHor,CopyBlockHor,0,1,1,1
  1010. CopyBuild AddBlockHorVer,CopyBlockHorVer,0,1,1,1
  1012. CopyBuild CopyBlockM,CopyBlockM,0,0,1,1
  1014. END