开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > Windows CE > 查看源码
mcomp_mmx.asm
资源名称：tcpmp.rar　[点击查看]
上传用户：wstnjxml
上传日期：2014-04-03
资源大小：7248k
文件大小：7k
源码类别：

Windows CE

开发平台：

C/C++

mcomp_mmx.asm：源码内容
  1. ;*****************************************************************************
  2. ;*
  3. ;* This program is free software ; you can redistribute it and/or modify
  4. ;* it under the terms of the GNU General Public License as published by
  5. ;* the Free Software Foundation; either version 2 of the License, or
  6. ;* (at your option) any later version.
  7. ;*
  8. ;* This program is distributed in the hope that it will be useful,
  9. ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  10. ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  11. ;* GNU General Public License for more details.
  12. ;*
  13. ;* You should have received a copy of the GNU General Public License
  14. ;* along with this program; if not, write to the Free Software
  15. ;* Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  16. ;*
  17. ;* $Id: mcomp_mmx.asm 327 2005-11-04 07:09:17Z picard $
  18. ;*
  19. ;* The Core Pocket Media Player
  20. ;* Copyright (c) 2004-2005 Gabor Kovacs
  21. ;*
  22. ;*****************************************************************************
  24. BITS 32
  25. SECTION .text
  27. %macro cglobal 2
  28. %define %1 _%1@%2
  29. global %1
  30. %endmacro
  32. cglobal EMMS,0
  33. cglobal AddBlock,12
  34. cglobal AddBlockHor,12
  35. cglobal AddBlockVer,12
  36. cglobal AddBlockHorVer,12
  37. cglobal CopyBlockM,16
  38. cglobal CopyBlock,16
  39. cglobal CopyBlockHor,16
  40. cglobal CopyBlockVer,16
  41. cglobal CopyBlockHorVer,16 
  42. cglobal CopyBlockHorRound,16
  43. cglobal CopyBlockVerRound,16 
  44. cglobal CopyBlockHorVerRound,16
  46. ALIGN 16
  47. EMMS:
  48. emms
  49. ret 0
  51. %macro loadparam 1
  52. mov esi,[esp+12] ;src
  53. mov edi,[esp+12+4] ;dst
  54. mov eax,[esp+12+8] ;src pitch
  55. %if %1>0
  56. mov edx,8 ;dst pitch (fixed for AddBlock)
  57. %else
  58. mov edx,[esp+12+12] ;dst pitch
  59. %endif
  60. %endmacro
  62. %macro loadmask1 0
  63. mov ecx,0x01010101
  64. movd mm6,ecx
  65. pcmpeqb mm7,mm7
  66. punpckldq mm6,mm6
  67. pxor mm7,mm6
  68. %endmacro
  70. %macro loadmask4 0
  71. mov ecx,0x03030303
  72. movd mm6,ecx
  73. pcmpeqb mm7,mm7
  74. punpckldq mm6,mm6
  75. pxor mm7,mm6
  76. %endmacro
  78. %macro load1 2
  79. movq mm0,[esi+%1]
  80. %if %2>0
  81. add esi,eax
  82. %endif
  83. movq mm1,mm0
  84. pand mm1,mm7
  85. psrlq mm1,1
  86. %endmacro
  88. %macro load2 2
  89. movq mm2,[esi+%1]
  90. %if %2>0
  91. add esi,eax
  92. %endif
  93. movq mm3,mm2
  94. pand mm3,mm7
  95. psrlq mm3,1
  96. %endmacro
  98. %macro load1hv 0
  99. movq mm0,[esi]
  100. movq mm4,[esi+1]
  101. add esi,eax
  102. movq mm1,mm0
  103. movq mm5,mm4
  104. pand mm0,mm6
  105. pand mm4,mm6
  106. pand mm1,mm7
  107. pand mm5,mm7
  108. psrlq mm1,2
  109. psrlq mm5,2
  110. paddb mm0,mm4
  111. paddb mm1,mm5
  112. %endmacro
  114. %macro load2hv 0
  115. movq mm2,[esi]
  116. movq mm4,[esi+1]
  117. add esi,eax
  118. movq mm3,mm2
  119. movq mm5,mm4
  120. pand mm2,mm6
  121. pand mm4,mm6
  122. pand mm3,mm7
  123. pand mm5,mm7
  124. psrlq mm3,2
  125. psrlq mm5,2
  126. paddb mm2,mm4
  127. paddb mm3,mm5
  128. %endmacro
  130. %macro avg1 0
  131. por mm0,mm2
  132. pand mm0,mm6
  133. paddb mm0,mm1
  134. paddb mm0,mm3
  135. %endmacro
  137. %macro avg2 0
  138. por mm2,mm0
  139. pand mm2,mm6
  140. paddb mm2,mm3
  141. paddb mm2,mm1
  142. %endmacro
  144. %macro avground1 0
  145. pand mm0,mm2
  146. pand mm0,mm6
  147. paddb mm0,mm1
  148. paddb mm0,mm3
  149. %endmacro
  151. %macro avground2 0
  152. pand mm2,mm0
  153. pand mm2,mm6
  154. paddb mm2,mm3
  155. paddb mm2,mm1
  156. %endmacro
  158. %macro save1 0
  159. movq [edi],mm0
  160. add edi,edx
  161. %endmacro
  163. %macro save2 0
  164. movq [edi],mm2
  165. add edi,edx
  166. %endmacro
  168. %macro saveadd1 0
  169. movq mm4,[edi]
  170. movq mm1,mm0
  171. pand mm0,mm7
  172. por mm1,mm4
  173. pand mm4,mm7
  174. pand mm1,mm6
  175. psrlq mm0,1
  176. psrlq mm4,1
  177. paddb mm1,mm0
  178. paddb mm1,mm4
  179. movq [edi],mm1
  180. add edi,edx
  181. %endmacro
  183. %macro saveadd2 0
  184. movq mm4,[edi]
  185. movq mm3,mm2
  186. pand mm2,mm7
  187. por mm3,mm4
  188. pand mm4,mm7
  189. pand mm3,mm6
  190. psrlq mm2,1
  191. psrlq mm4,1
  192. paddb mm3,mm2
  193. paddb mm3,mm4
  194. movq [edi],mm3
  195. add edi,edx
  196. %endmacro
  198. ALIGN 16
  199. CopyBlock:
  200. push esi
  201. push edi
  202. loadparam 0
  204. %rep 4
  205. movq mm0,[esi]
  206. movq mm1,[esi+eax]
  207. lea esi,[esi+eax*2]
  208. movq [edi],mm0
  209. movq [edi+edx],mm1
  210. lea edi,[edi+edx*2]
  211. %endrep
  213. pop edi
  214. pop esi 
  215. ret 16
  217. ALIGN 16
  218. CopyBlockM:
  219. push esi
  220. push edi
  221. loadparam 0
  223. %rep 8
  224. movq mm0,[esi]
  225. movq mm1,[esi+8]
  226. movq mm2,[esi+eax]
  227. movq mm3,[esi+eax+8]
  228. lea esi,[esi+eax*2]
  229. movq [edi],mm0
  230. movq [edi+8],mm1
  231. movq [edi+edx],mm2
  232. movq [edi+edx+8],mm3
  233. lea edi,[edi+edx*2]
  234. %endrep
  236. pop edi
  237. pop esi 
  238. ret 16
  240. ALIGN 16
  241. CopyBlockHor:
  242. push esi
  243. push edi
  245. loadparam 0
  246. loadmask1
  248. %rep 8
  249. load1 0,0
  250. load2 1,1
  251. avg1
  252. save1
  253. %endrep
  255. pop edi
  256. pop esi 
  257. ret 16
  259. ALIGN 16
  260. CopyBlockVer:
  261. push esi
  262. push edi
  264. loadparam 0
  265. loadmask1
  266. load1 0,1
  267. %rep 4 
  268. load2 0,1
  269. avg1
  270. save1
  271. load1 0,1
  272. avg2
  273. save2
  274. %endrep
  276. pop edi
  277. pop esi 
  278. ret 16
  280. ALIGN 16
  281. CopyBlockHorVer:
  282. push esi
  283. push edi
  285. loadparam 0
  286. loadmask4
  288. load1hv
  289. %rep 4
  290. load2hv
  292. pcmpeqb mm4,mm4 ;-1
  293. paddb mm0,mm2
  294. paddb mm4,mm4 ;-2
  295. paddb mm1,mm3
  296. psubb mm0,mm4 ;+2
  297. pand mm0,mm7
  298. psrlq mm0,2
  299. paddb mm0,mm1
  301. save1
  303. load1hv
  305. pcmpeqb mm4,mm4 ;-1
  306. paddb mm2,mm0
  307. paddb mm4,mm4 ;-2
  308. paddb mm3,mm1
  309. psubb mm2,mm4 ;+2
  310. pand mm2,mm7
  311. psrlq mm2,2
  312. paddb mm2,mm3
  314. save2
  315. %endrep
  317. pop edi
  318. pop esi 
  319. ret 16
  321. ALIGN 16
  322. CopyBlockHorRound:
  323. push esi
  324. push edi
  326. loadparam 0
  327. loadmask1
  329. %rep 8
  330. load1 0,0
  331. load2 1,1
  332. avground1
  333. save1
  334. %endrep
  336. pop edi
  337. pop esi 
  338. ret 16
  340. ALIGN 16
  341. CopyBlockVerRound:
  342. push esi
  343. push edi
  345. loadparam 0
  346. loadmask1
  347. load1 0,1
  348. %rep 4 
  349. load2 0,1
  350. avground1
  351. save1
  352. load1 0,1
  353. avground2
  354. save2
  355. %endrep
  357. pop edi
  358. pop esi 
  359. ret 16
  361. ALIGN 16
  362. CopyBlockHorVerRound:
  363. push esi
  364. push edi
  366. loadparam 0
  367. loadmask4
  369. load1hv
  370. %rep 4
  371. load2hv
  373. pcmpeqb mm4,mm4 ;-1
  374. paddb mm0,mm2
  375. paddb mm1,mm3
  376. psubb mm0,mm4 ;+1
  377. pand mm0,mm7
  378. psrlq mm0,2
  379. paddb mm0,mm1
  381. save1
  383. load1hv
  385. pcmpeqb mm4,mm4 ;-1
  386. paddb mm2,mm0
  387. paddb mm3,mm1
  388. psubb mm2,mm4 ;+1
  389. pand mm2,mm7
  390. psrlq mm2,2
  391. paddb mm2,mm3
  393. save2
  394. %endrep
  396. pop edi
  397. pop esi 
  398. ret 16
  400. ALIGN 16
  401. AddBlock:
  402. push esi
  403. push edi
  405. loadparam 1
  406. loadmask1
  408. %rep 8
  409. movq mm0,[esi]
  410. add esi,eax
  411. saveadd1
  412. %endrep
  414. pop edi
  415. pop esi 
  416. ret 12
  418. ALIGN 16
  419. AddBlockHor:
  420. push esi
  421. push edi
  423. loadparam 1
  424. loadmask1
  426. %rep 8
  427. load1 0,0
  428. load2 1,1
  429. avg1
  430. saveadd1
  431. %endrep
  433. pop edi
  434. pop esi 
  435. ret 12
  437. ALIGN 16
  438. AddBlockVer:
  439. push esi
  440. push edi
  442. loadparam 1
  443. loadmask1
  444. load1 0,1
  445. %rep 4 
  446. load2 0,1
  447. avg1
  448. saveadd1
  449. load1 0,1
  450. avg2
  451. saveadd2
  452. %endrep
  454. pop edi
  455. pop esi 
  456. ret 12
  458. ALIGN 16
  459. AddBlockHorVer:
  460. push esi
  461. push edi
  463. loadparam 1
  464. loadmask4
  466. load1hv
  467. %rep 4
  468. load2hv
  470. pcmpeqb mm5,mm5 ;-1
  471. paddb mm0,mm2
  472. paddb mm5,mm5 ;-2
  473. paddb mm1,mm3
  474. psubb mm0,mm5 ;+=2
  475. pand mm0,mm7
  476. psrlq mm0,2
  477. paddb mm0,mm1
  479. paddb mm6,mm5 ;0x03-2=0x01
  480. psubb mm7,mm5 ;0xFD+2=0xFF
  481. saveadd1
  482. psubb mm6,mm5 ;restore mask
  483. paddb mm7,mm5 ;restore mask
  485. load1hv
  487. pcmpeqb mm5,mm5 ;-1
  488. paddb mm2,mm0
  489. paddb mm5,mm5 ;-2
  490. paddb mm3,mm1
  491. psubb mm2,mm5 ;+=2
  492. pand mm2,mm7
  493. psrlq mm2,2
  494. paddb mm2,mm3
  496. paddb mm6,mm5 ;0x03-2=0x01
  497. psubb mm7,mm5 ;0xFD+2=0xFF
  498. saveadd2
  499. psubb mm6,mm5 ;restore mask
  500. paddb mm7,mm5 ;restore mask
  502. %endrep
  504. pop edi
  505. pop esi 
  506. ret 12