开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > Windows CE > 查看源码
blit_mmx.asm
资源名称：tcpmp.rar　[点击查看]
上传用户：wstnjxml
上传日期：2014-04-03
资源大小：7248k
文件大小：18k
源码类别：

Windows CE

开发平台：

C/C++

blit_mmx.asm：源码内容
  1. ;*****************************************************************************
  2. ;*
  3. ;* This program is free software ; you can redistribute it and/or modify
  4. ;* it under the terms of the GNU General Public License as published by
  5. ;* the Free Software Foundation; either version 2 of the License, or
  6. ;* (at your option) any later version.
  7. ;*
  8. ;* This program is distributed in the hope that it will be useful,
  9. ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  10. ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  11. ;* GNU General Public License for more details.
  12. ;*
  13. ;* You should have received a copy of the GNU General Public License
  14. ;* along with this program; if not, write to the Free Software
  15. ;* Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  16. ;*
  17. ;* $Id: blit_mmx.asm 323 2005-11-01 20:52:32Z picard $
  18. ;*
  19. ;* The Core Pocket Media Player
  20. ;* Copyright (c) 2004-2005 Gabor Kovacs
  21. ;*
  22. ;*****************************************************************************
  24. BITS 32
  25. SECTION .data
  27. OFFSET_COL equ 8
  29. align 8
  30. const_b254 dd 0xfefefefe,0xfefefefe
  32. SECTION .text
  34. %macro func 2
  35. %define %1 _%1@%2
  36. global %1
  37. align 16
  38. %1:
  39. %endmacro
  41. %macro _prefetch 2
  42. %if s%1=smmx2
  43. prefetchnta [%2+256]
  44. %elif s%1=s3dnow
  45. prefetch [%2+256]
  46. %endif
  47. %endmacro
  49. ; caps, in, src, in2, src2, tmp1, tmp2
  50. %macro avg 7
  51. %if s%1=smmx
  52. movq %6,%3
  53. movq %7,%5
  54. pxor %6,%2
  55. pxor %7,%4
  56. por %2,%6
  57. por %4,%7
  58. pand %6,[const_b254]
  59. pand %7,[const_b254]
  60. psrlq %6,1
  61. psrlq %7,1
  62. psubb %2,%6
  63. psubb %4,%7
  65. %elif s%1=smmx2
  66. pavgb %2,%3
  67. pavgb %4,%5
  68. %elif s%1=s3dnow
  69. pavgusb %2,%3
  70. pavgusb %4,%5
  71. %else
  72. %error not supported caps %1
  73. %endif
  74. %endmacro
  76. %macro save 3
  77. %if s%1=smmx2
  78.   movntq %2,%3
  79. %else
  80. movq %2,%3
  81. %endif
  82. %endmacro
  84. %define savg 2
  85. %define smmx2 3
  86. %define s3dnow 4
  87. %define snone 5
  88. %define smmx 6
  89. %define srgb32 7
  90. %define srgb24 8
  91. %define sbgr32 9
  92. %define sbgr24 10
  93. %define syuy2 11
  94. %define srgb 12
  95. %define srgb16 13
  96. %define sbgr16 14
  97. %define syuy2_color 15
  99. ;eax tmp/Col
  100. ;ebx SrcPitch/2
  101. ;ecx SrcPtr[1]
  102. ;edx StrPtr[2]
  103. ;esi SrcPtr[0]
  104. ;edi DstPtr
  105. ;ebp Width/2
  107. ;---------------------------------------------------------------------
  109. ; caps, type, mode
  110. %macro blit_pack_single_yuy2 3
  111. mov al,[esi]
  112. add esi,2
  113. mov [edi],al
  114. mov al,[ecx]
  115. %if %2=2
  116. add al,[ecx+ebx]
  117. rcr al,1
  118. %endif
  119. add ecx,1
  120. mov [edi+1],al
  121. mov al,[esi-1]
  122. add edi,4
  123. mov [edi-2],al
  124. mov al,[edx]
  125. %if %2=2
  126. add al,[edx+ebx]
  127. rcr al,1
  128. %endif
  129. add edx,1
  130. mov [edi-1],al
  131. %endmacro
  133. ; caps, type, mode, i
  134. %macro blit_pack_block_yuy2 4
  135. movq mm0,[esi-16]
  136. movq mm2,[ecx]
  137. movq mm3,[edx]
  138. movq mm1,[esi-8]
  140. %if %2=2
  141. avg %1,mm2,[ecx+ebx],mm3,[edx+ebx],mm4,mm5
  142. %endif
  144. _prefetch %1,esi
  146. movq mm5,mm0
  147. movq mm4,mm2
  148. punpcklbw mm2,mm3
  149. punpckhbw mm4,mm3
  150. movq mm3,mm1
  151.     punpcklbw mm0,mm2
  152.     punpcklbw mm1,mm4
  153.     punpckhbw mm5,mm2
  154.     punpckhbw mm3,mm4
  156. %if %2=2
  157. _prefetch %1,ecx+ebx
  158. %endif
  160. save %1,[edi],mm0
  161. add ecx,8
  162. save %1,[edi+8],mm5
  163. add edx,8
  164. save %1,[edi+16],mm1
  165. add esi,16
  166. save %1,[edi+24],mm3
  167. add edi,32
  169. %if %2=2
  170. _prefetch %1,edx+ebx
  171. %endif
  172. %endmacro
  174. ;---------------------------------------------------------------------
  176. ; caps, type, mode
  177. %macro blit_pack_single_yuy2_color 3
  179. movzx eax,word [esi]
  180. add esi,2
  181. movd mm0,eax
  182. mov al,[ecx]
  183. %if %2=2
  184. add al,[ecx+ebx]
  185. rcr al,1
  186. %endif
  187. add ecx,1
  188. movd mm2,eax
  189. mov al,[edx]
  190. %if %2=2
  191. add al,[edx+ebx]
  192. rcr al,1
  193. %endif
  194. add edx,1
  195. movd mm3,eax
  196. mov eax,[esp]
  198. pxor mm7,mm7
  199. punpcklbw mm0,mm7
  200. punpcklbw mm2,mm7
  201. punpcklbw mm3,mm7
  202. psllw  mm0,5
  203. psllw  mm2,5
  204. psllw  mm3,5
  205. pmulhw mm0,[eax+8*0]
  206. pmulhw mm2,[eax+8*2]
  207. pmulhw mm3,[eax+8*4]
  208. paddsw mm0,[eax+8*1]
  209. paddsw mm2,[eax+8*3]
  210. paddsw mm3,[eax+8*5]
  211. packuswb mm0,mm0
  212. packuswb mm2,mm2
  213. packuswb mm3,mm3
  215. punpcklbw mm2,mm3
  216.     punpcklbw mm0,mm2
  217. movd [edi],mm0
  218. add edi,4
  220. %endmacro
  222. ; caps, type, mode, i
  223. %macro blit_pack_block_yuy2_color 4
  224. movq mm0,[esi-16]
  225. movq mm2,[ecx]
  226. movq mm3,[edx]
  227. movq mm1,[esi-8]
  229. %if %2=2
  230. avg %1,mm2,[ecx+ebx],mm3,[edx+ebx],mm4,mm5
  231. %endif
  233. _prefetch %1,esi
  235. movq mm6,[eax+8*0]
  236. pxor mm7,mm7
  237. movq mm4,mm0
  238. movq mm5,mm1
  239. punpcklbw mm0,mm7
  240. punpcklbw mm1,mm7
  241. psllw  mm0,5
  242. psllw  mm1,5
  243. pmulhw mm0,mm6
  244. pmulhw mm1,mm6
  245. punpckhbw mm4,mm7
  246. punpckhbw mm5,mm7
  247. movq mm7,[eax+8*1]
  248. psllw  mm4,5
  249. psllw  mm5,5
  250. pmulhw mm4,mm6
  251. pmulhw mm5,mm6
  252. paddsw mm0,mm7
  253. paddsw mm1,mm7
  254. paddsw mm4,mm7
  255. paddsw mm5,mm7
  256. packuswb mm0,mm4
  257. packuswb mm1,mm5
  259. %if %2=2
  260. _prefetch %1,ecx+ebx
  261. %endif
  263. pxor mm7,mm7
  264. movq mm4,mm2
  265. movq mm5,mm3
  266. punpcklbw mm2,mm7
  267. punpcklbw mm3,mm7
  268. punpckhbw mm4,mm7
  269. punpckhbw mm5,mm7
  270. movq mm6,[eax+8*2]
  271. movq mm7,[eax+8*4]
  272. psllw  mm2,5
  273. psllw  mm3,5
  274. pmulhw mm2,mm6
  275. pmulhw mm3,mm7
  276. psllw  mm4,5
  277. psllw  mm5,5
  278. pmulhw mm4,mm6
  279. pmulhw mm5,mm7
  280. movq mm6,[eax+8*3]
  281. movq mm7,[eax+8*5]
  282. paddsw mm2,mm6
  283. paddsw mm3,mm7
  284. paddsw mm4,mm6
  285. paddsw mm5,mm7
  286. packuswb mm2,mm4
  287. packuswb mm3,mm5
  289. movq mm5,mm0
  290. movq mm4,mm2
  291. punpcklbw mm2,mm3
  292. punpckhbw mm4,mm3
  293. movq mm3,mm1
  294.     punpcklbw mm0,mm2
  295.     punpcklbw mm1,mm4
  296.     punpckhbw mm5,mm2
  297.     punpckhbw mm3,mm4
  299. %if %2=2
  300. _prefetch %1,edx+ebx
  301. %endif
  303. save %1,[edi],mm0
  304. add ecx,8
  305. save %1,[edi+8],mm5
  306. add edx,8
  307. save %1,[edi+16],mm1
  308. add esi,16
  309. save %1,[edi+24],mm3
  310. add edi,32
  312. %endmacro
  314. ;---------------------------------------------------------------------
  316. ;input
  317. ; mm0 y(8)
  318. ; mm1 u(4)
  319. ; mm2 v(4)
  320. ; mm7 0
  321. ;output
  322. ; mm0 g
  323. ; mm1 b
  324. ; mm2 r
  326. %macro yuv_rgb 0
  328. movq mm5,mm0
  329. movq mm3,[eax+8]
  330. punpcklbw mm0,mm7
  331. movq mm4,[eax+16+8]
  332. punpckhbw mm5,mm7
  333. movq mm6,[eax+32+8]
  334. punpcklbw mm1,mm7
  335. paddsw mm0,mm3
  336. punpcklbw mm2,mm7
  337. paddsw mm5,mm3
  338. movq mm7,[eax]
  339. psllw mm0,7
  340. paddsw mm1,mm4
  341. psllw mm5,7
  342. paddsw mm2,mm6
  343. psllw mm1,7
  344. psllw mm2,7
  345. pmulhw mm0,mm7
  346. movq mm6,[eax+16]
  347. pmulhw mm5,mm7
  348. movq mm7,[eax+32]
  349. movq mm3,mm1
  350. movq mm4,mm2
  351. punpckldq mm1,mm1
  352. punpckldq mm2,mm2
  353. pmulhw mm1,mm6
  354. pmulhw mm2,mm7
  355. punpckhdq mm3,mm3
  356. punpckhdq mm4,mm4
  357. pmulhw mm3,mm6
  358. pmulhw mm4,mm7
  359. movq mm6,mm1
  360. movq mm7,mm2
  361. punpcklwd mm1,mm1
  362. punpcklwd mm2,mm2
  363. punpckhwd mm6,mm6
  364. punpckhwd mm7,mm7
  365. paddsw mm1,mm0 ;y*y_mul+u*u_mul_lo
  366. paddsw mm2,mm0      ;y*y_mul           +v*v_mul_lo
  367. paddsw mm0,mm6
  368. paddsw mm0,mm7      ;y*y_mul+u*u_mul_hi+v*v_mul_hi
  369. psraw mm1,4
  370. psraw mm2,4
  371. psraw mm0,4
  372. movq mm6,mm3
  373. movq mm7,mm4
  374. punpcklwd mm3,mm3
  375. punpcklwd mm4,mm4
  376. punpckhwd mm6,mm6
  377. punpckhwd mm7,mm7
  378. paddsw mm3,mm5 ;y*y_mul+u*u_mul_lo
  379. paddsw mm4,mm5      ;y*y_mul           +v*v_mul_lo
  380. paddsw mm5,mm6
  381. paddsw mm5,mm7      ;y*y_mul+u*u_mul_hi+v*v_mul_hi
  382. psraw mm3,4
  383. psraw mm4,4
  384. psraw mm5,4
  385. packuswb mm1,mm3    ;b
  386. packuswb mm2,mm4 ;r
  387. packuswb mm0,mm5    ;g
  389. %endmacro
  391. ; caps, type, mode
  392. %macro blit_pack_single_rgb 3
  393. movzx eax,word [esi]
  394. add esi,2
  395. pxor mm7,mm7
  396. movd mm0,eax
  397. %if %2=2
  398. mov al,[ecx]
  399. add al,[ecx+ebx]
  400. rcr al,1
  401. %else
  402. movzx eax,byte [ecx]
  403. %endif
  404. add ecx,1
  405. movd mm1,eax
  406. %if %2=2
  407. mov al,[edx]
  408. add al,[edx+ebx]
  409. rcr al,1
  410. %else
  411. movzx eax,byte [edx]
  412. %endif
  413. add edx,1
  414. movd mm2,eax
  415. mov eax,[esp]
  416. yuv_rgb
  418. pxor mm7,mm7
  419. %if (s%3=srgb32) || (s%3=srgb24)
  420. punpcklbw mm2,mm7 ;0r0r0r0r (0)
  421. punpcklbw mm1,mm0 ;gbgbgbgb (0)
  422. punpcklwd mm1,mm2 ;0rgb0rgb (0)
  423. %else
  424. punpcklbw mm1,mm7 ;0b0b0b0b (0)
  425. punpcklbw mm2,mm0 ;grgrgrgr (0)
  426. punpcklwd mm2,mm1 ;0bgr0bgr (0)
  427. %endif
  429. %if s%3=srgb32
  430. save %1,[edi],mm1
  431. add edi,8
  432. %endif
  433. %if s%3=sbgr32
  434. save %1,[edi],mm2
  435. add edi,8
  436. %endif
  437. %if (s%3=srgb24) || (s%3=sbgr24)
  438. %if s%3=srgb24
  439. movq mm2,mm1
  440. %else
  441. movq mm1,mm2
  442. %endif
  443. punpckhdq mm2,mm7 ;00000bgr (1)
  444. punpckldq mm1,mm7 ;00000bgr (0)
  445. psllq mm2,24 ;00bgr000 (1)
  446. por mm2,mm1 ;00bgrbgr
  447. movd eax,mm2
  448. psrlq mm2,32
  449. mov [edi],eax
  450. movd eax,mm2
  451. mov [edi+4],ax
  452. add edi,6
  453. %endif
  455. %endmacro
  457. ; caps, type, mode, i
  458. %macro blit_pack_block_rgb 4
  459. movq mm0,[esi-16]
  460. movd mm1,[ecx]
  461. pxor mm7,mm7
  462. movd mm2,[edx]
  463. %if %2=2
  464. avg %1,mm1,[ecx+ebx],mm2,[edx+ebx],mm4,mm5
  465. %endif
  466. %if (%4=0)
  467. _prefetch %1,esi
  468. %endif
  469. yuv_rgb
  471. %if (%2=2) 
  472. %if (%4=0)
  473. _prefetch %1,edx+ebx
  474. %else
  475. _prefetch %1,ecx+ebx
  476. %endif
  477. %endif
  479. pxor mm7,mm7
  480. %if (s%3=srgb32) || (s%3=srgb24)
  481. movq mm3,mm2
  482. movq mm4,mm1
  483. punpcklbw mm2,mm7 ;0r0r0r0r (0)
  484. punpckhbw mm3,mm7 ;0r0r0r0r (1)
  485. punpcklbw mm1,mm0 ;gbgbgbgb (0)
  486. punpckhbw mm4,mm0 ;gbgbgbgb (1)
  487. movq mm7,mm1
  488. movq mm0,mm4
  489. punpcklwd mm1,mm2 ;0rgb0rgb (0)
  490. punpckhwd mm7,mm2 ;0rgb0rgb (1)
  491. punpcklwd mm4,mm3 ;0rgb0rgb (2)
  492. punpckhwd mm0,mm3 ;0rgb0rgb (3)
  493. %else
  494. movq mm3,mm1
  495. movq mm4,mm2
  496. punpcklbw mm1,mm7 ;0b0b0b0b (0)
  497. punpckhbw mm3,mm7 ;0b0b0b0b (1)
  498. punpcklbw mm2,mm0 ;grgrgrgr (0)
  499. punpckhbw mm4,mm0 ;grgrgrgr (1)
  500. movq mm7,mm2
  501. movq mm0,mm4
  502. punpcklwd mm2,mm1 ;0bgr0bgr (0)
  503. punpckhwd mm7,mm1 ;0bgr0bgr (1)
  504. punpcklwd mm4,mm3 ;0bgr0bgr (2)
  505. punpckhwd mm0,mm3 ;0bgr0bgr (3)
  506. movq mm1,mm2
  507. %endif
  509. %if (s%3=srgb32) || (s%3=sbgr32)
  510. save %1,[edi],mm1
  511. add ecx,4
  512. save %1,[edi+8],mm7
  513. add edx,4
  514. save %1,[edi+16],mm4
  515. add esi,8
  516. save %1,[edi+24],mm0
  517. add edi,32
  518. %else
  519. pxor mm6,mm6
  520. movq mm3,mm7 ;0ddd0ccc
  521. movq mm5,mm4 ;0fff0eee
  522. pslld mm0,8  ;hhh0ggg0
  523. psrld mm5,8 ;00ffxxxx
  524. punpckhdq mm6,mm1 ;0bbb0000
  525. punpckhdq mm5,mm0 ;hhh000ff
  526. psllq mm0,32 ;ggg00000
  527. pslld mm3,16 ;xxxxcc00
  528. psrlq mm6,8 ;00bbb000
  529. punpckldq mm1,mm3 ;cc000aaa
  530. punpckldq mm3,mm4 ;0eeexxxx
  531. pslld mm4,24 ;f000xxxx
  532. psrlq mm0,24 ;000ggg00
  533. por mm1,mm6 ;ccbbbaaa
  534. punpckldq mm6,mm7 ;0cccxxxx
  535. pslld mm7,8 ;ddd0xxxx
  536. por mm5,mm0 ;hhhgggff
  537. psrld mm6,16 ;000cxxxx
  538. punpckhdq mm7,mm3 ;0eeeddd0
  539. punpckhdq mm6,mm4 ;f000000c
  540. save %1,[edi],mm1
  541. por mm7,mm6 ;feeedddc
  542. add ecx,4
  543. add edx,4
  544. save %1,[edi+8],mm7
  545. add esi,8
  546. save %1,[edi+16],mm5
  547. add edi,24
  548. %endif
  550. %endmacro
  552. ;---------------------------------------------------------------------
  554. ;caps, mode, type, align, repeat, name
  555. %macro blit_pack_line 6
  557. %%small:
  558. add ebp,ebp
  559. %%smallstart:
  560. %if (s%6=srgb) || (s%6=syuy2_color)
  561. push eax
  562. %endif
  563. %%smallloop:
  564. blit_pack_single_%6 %1,%3,%2
  565. sub ebp,2
  566. jne %%smallloop
  567. %if (s%6=srgb) || (s%6=syuy2_color)
  568. pop eax
  569. %endif
  570. ret
  572. blit_i420_%2_%3_%1:
  573. cmp ebp,8+%4
  574. jl %%small
  576. %%large4:
  577. lea ebp,[esi+ebp*2]
  578. %if %4==4
  579. test edi,4
  580. je %%noalign4
  581. %if (s%6=srgb) || (s%6=syuy2_color)
  582. push eax
  583. %endif
  584. blit_pack_single_%6 %1,%3,%2
  585. %if (s%6=srgb) || (s%6=syuy2_color)
  586. pop eax
  587. %endif
  588. %%noalign4:
  589. %endif
  591. add esi,16
  592. %%move4:
  593. %assign i 0
  594. %rep %5
  595. blit_pack_block_%6 %1,%3,%2,i
  596. %assign i i+1 
  597. %endrep
  598. cmp esi,ebp
  599. jbe %%move4
  600. sub esi,16
  601. sub ebp,esi
  602. je  %%end
  603. jmp %%smallstart
  604. %%end:
  605. ret
  607. %endmacro
  609. %macro blit_pack_inner 3
  611. sub dword [esp+24+28],2
  612. jle %%noloop3
  614. %%loop3:
  615. call blit_i420_%2_1_%1
  616. mov ebp,[esp] ;-Width/2
  617. %if %3==6
  618. lea edi,[edi+ebp*4]
  619. lea edi,[edi+ebp*2]
  620. %else
  621. lea edi,[edi+ebp*%3]
  622. %endif
  623. lea esi,[esi+ebp*2]
  624. add ecx,ebp
  625. add edx,ebp
  626. mov ebp,[esp+4] ;Width/2
  628. add edi,[esp+12+28] ;DstPitch
  629. lea esi,[esi+ebx*2]
  631. call blit_i420_%2_2_%1
  632. mov ebp,[esp] ;-Width/2
  633. %if %3==6
  634. lea edi,[edi+ebp*4]
  635. lea edi,[edi+ebp*2]
  636. %else
  637. lea edi,[edi+ebp*%3]
  638. %endif
  639. lea esi,[esi+ebp*2]
  640. add ecx,ebp
  641. add edx,ebp
  642. mov ebp,[esp+4] ;Width/2
  644. add edi,[esp+12+28] ;DstPitch
  645. lea esi,[esi+ebx*2] ;
  646. add ecx,ebx
  647. add edx,ebx
  648. sub dword [esp+24+28],2
  649. jg %%loop3
  651. %%noloop3
  652. call blit_i420_%2_1_%1
  653. mov ebp,[esp] ;-Width/2
  654. %if %3==6
  655. lea edi,[edi+ebp*4]
  656. lea edi,[edi+ebp*2]
  657. %else
  658. lea edi,[edi+ebp*%3]
  659. %endif
  660. lea esi,[esi+ebp*2]
  661. add ecx,ebp
  662. add edx,ebp
  663. mov ebp,[esp+4] ;Width/2
  665. add edi,[esp+12+28] ;DstPitch
  666. lea esi,[esi+ebx*2]
  668. cmp dword [esp+24+28],0
  669. jne %%nolast3
  670. call blit_i420_%2_1_%1
  671. %%nolast3:
  673. add esp,8
  674. emms
  675. pop ebp
  676. pop ebx
  677. pop edi
  678. pop esi
  679. ret 32
  681. %endmacro
  683. ;caps, mode, align, block, name, color
  684. %macro blit_pack 6
  686. blit_pack_line %1,%2,1,%3,%4,%5
  687. blit_pack_line %1,%2,2,%3,%4,%5
  689. %if %6
  690. blit_pack_line %1,%2_color,1,%3,%4,%5_color
  691. blit_pack_line %1,%2_color,2,%3,%4,%5_color
  692. %endif
  694. func blit_i420_%2_%1,32
  695. push esi
  696. push edi
  697. push ebx
  698. push ebp
  700. mov ebx,[esp+16+20] ;SrcPitch
  701. mov edi,[esp+4+20]  ;DstPtr
  702. mov esi,[esp+8+20]  ;SrcPtr
  703. mov ebp,[esp+20+20] ;Width
  704. mov edi,[edi]
  705. sar ebx,1
  706. sar ebp,1
  707. xor eax,eax
  708. push ebp
  709. sub eax,ebp
  710. push eax
  711. mov eax,[esp+0+28] ;this
  712. mov ecx,[esi+4] ;u
  713. mov edx,[esi+8] ;v
  714. mov esi,[esi] ;y
  715. add eax,OFFSET_COL
  717. %if %6
  718. cmp dword [eax],2048+(2048<<16)
  719. jne %%color
  720. cmp dword [eax+8],0
  721. jne %%color
  722. cmp dword [eax+8*2],2048+(2048<<16)
  723. jne %%color
  724. cmp dword [eax+8*3],0
  725. jne %%color
  726. cmp dword [eax+8*4],2048+(2048<<16)
  727. jne %%color
  728. cmp dword [eax+8*5],0
  729. jne %%color
  730. jmp %%nocolor
  731. %%color:
  732. blit_pack_inner %1,%2_color,%3
  733. %%nocolor
  734. %endif
  736. blit_pack_inner %1,%2,%3
  738. %endmacro
  740. %macro blit_plane_rgb 3
  742. func blit_%2_%3_%1,32
  743. push esi
  744. push edi
  745. push ebx
  746. push ebp
  748. mov eax,[esp+12+20] ;DstPitch
  749. mov ebx,[esp+16+20] ;SrcPitch
  751. mov edi,[esp+4+20]  ;DstPtr
  752. mov esi,[esp+8+20]  ;SrcPtr
  753. mov ebp,[esp+20+20] ;Width
  754. mov edx,[esp+24+20] ;Height
  755. mov edi,[edi]
  756. mov esi,[esi]
  757. %if (s%2=srgb32) || (s%2=sbgr32)
  758. shl ebp,2
  759. %endif
  760. %if (s%2=srgb24) || (s%2=sbgr24)
  761. lea ebp,[ebp+ebp*2]
  762. %endif
  763. %if (s%2=srgb16) || (s%2=sbgr16)
  764. shl ebp,2
  765. %endif
  767. %%loopy6:
  768. _prefetch %1,esi
  769. mov ecx,ebp
  770. cmp ebp,32+4
  771. jl %%small6
  773. push ebp
  774. add ebp,esi
  775. %if (s%2=srgb16) || (s%2=sbgr16)
  776. test edi,2
  777. je %%noalignw6
  778. movsw
  779. %%noalignw6:
  780. %endif
  781. test edi,4
  782. je %%noalignd6
  783. movsd
  784. %%noalignd6:
  785. add esi,32
  786. %%move6:
  787. movq mm0,[esi-32]
  788. movq mm1,[esi-24]
  789. movq mm2,[esi-16]
  790. movq mm3,[esi-8]
  791. add esi,32
  792. _prefetch %1,esi
  793. save %1,[edi+0],mm0
  794. save %1,[edi+8],mm1
  795. save %1,[edi+16],mm2
  796. save %1,[edi+24],mm3
  797. add edi,32
  798. cmp esi,ebp
  799. jbe %%move6
  801. sub esi,32
  802. mov ecx,ebp
  803. pop ebp
  804. sub ecx,esi
  806. %%small6:
  807. rep movsb
  808. add edi,eax
  809. add esi,ebx
  810. sub edi,ebp
  811. sub esi,ebp
  812. dec edx
  813. jne %%loopy6
  815. emms
  816. pop ebp
  817. pop ebx
  818. pop edi
  819. pop esi
  820. ret 32
  822. %endmacro
  824. %macro blit 1
  826. ;This,DstPtr,SrcPtr,DstPitch,SrcPitch,Width,Height,Src2SrcLast
  828. ; edi dst
  829. ; esi src
  830. ; eax dstpitch
  831. ; ebx srcpitch
  832. ; ebp width
  833. ; edx height
  834. ; ecx mul,ofs
  836. blit_plane_yuv_%1:
  837. cmp word [ecx],2048
  838. jne %%jmpcolor
  839. cmp word [ecx+8],0
  840. je  %%loopy
  841. %%jmpcolor:
  842. jmp %%color
  844. %%loopy:
  845. _prefetch %1,esi
  846. mov ecx,ebp
  847. cmp ebp,32+4
  848. jl %%small
  850. push ebp
  851. add ebp,esi
  852. test edi,2
  853. je %%noalignw
  854. movsw
  855. %%noalignw:
  856. test edi,4
  857. je %%noalignd
  858. movsd
  859. %%noalignd:
  860. add esi,32
  861. %%move:
  862. movq mm0,[esi-32]
  863. movq mm1,[esi-24]
  864. movq mm2,[esi-16]
  865. movq mm3,[esi-8]
  866. add esi,32
  867. _prefetch %1,esi
  868. save %1,[edi+0],mm0
  869. save %1,[edi+8],mm1
  870. save %1,[edi+16],mm2
  871. save %1,[edi+24],mm3
  872. add edi,32
  873. cmp esi,ebp
  874. jbe %%move
  876. sub esi,32
  877. mov ecx,ebp
  878. pop ebp
  879. sub ecx,esi
  881. %%small:
  882. rep movsb
  883. add edi,eax
  884. add esi,ebx
  885. sub edi,ebp
  886. sub esi,ebp
  887. dec edx
  888. jne %%loopy
  889. ret
  891. %%color:
  892. movq mm5,[ecx]
  893. movq mm6,[ecx+8]
  894. pxor mm7,mm7
  896. %%loopy2:
  897. _prefetch %1,esi
  898. cmp ebp,16+4
  899. jge %%large2
  900. mov ecx,ebp
  901. jmp %%small2
  903. %%large2:
  904. push ebp
  905. add ebp,esi
  906. test edi,4
  907. je %%noalignd2
  909. movd mm0,[esi]
  910. add esi,4
  911. punpcklbw mm0,mm7
  912. psllw  mm0,5
  913. pmulhw mm0,mm5
  914. paddsw mm0,mm6
  915. packuswb mm0,mm0
  916. movd [edi],mm0
  917. add edi,4
  919. %%noalignd2:
  920. add esi,16
  921. %%move2:
  922. movq mm0,[esi-16]
  923. movq mm2,[esi-8]
  924. _prefetch %1,esi
  925. add esi,16
  926. movq mm1,mm0
  927. movq mm3,mm2
  928. punpcklbw mm0,mm7
  929. punpcklbw mm2,mm7
  930. psllw  mm0,5
  931. psllw  mm2,5
  932. pmulhw mm0,mm5
  933. pmulhw mm2,mm5
  934. punpckhbw mm1,mm7
  935. punpckhbw mm3,mm7
  936. psllw  mm1,5
  937. psllw  mm3,5
  938. pmulhw mm1,mm5
  939. pmulhw mm3,mm5
  940. paddsw mm0,mm6
  941. paddsw mm2,mm6
  942. paddsw mm1,mm6
  943. paddsw mm3,mm6
  944. packuswb mm0,mm1
  945. packuswb mm2,mm3
  946. save %1,[edi+0],mm0
  947. save %1,[edi+8],mm2
  948. add edi,16
  949. cmp esi,ebp
  950. jbe %%move2
  952. sub esi,16
  953. mov ecx,ebp
  954. pop ebp
  955. sub ecx,esi
  957. %%small2:
  958. or ecx,ecx
  959. jle %%nosmall2
  960. push eax
  961. %%smallloop2:
  962. movzx eax,byte [esi]
  963. add esi,1
  964. movd mm0,eax
  965. punpcklbw mm0,mm7
  966. psllw  mm0,5
  967. pmulhw mm0,mm5
  968. paddsw mm0,mm6
  969. packuswb mm0,mm0
  970. movd eax,mm0
  971. mov [edi],al
  972. add edi,1
  973. dec ecx
  974. jne %%smallloop2
  975. pop eax
  976. %%nosmall2:
  978. add edi,eax
  979. add esi,ebx
  980. sub edi,ebp
  981. sub esi,ebp
  982. dec edx
  983. jne %%loopy2
  984. ret
  986. func blit_i420_i420_%1,32
  987. push esi
  988. push edi
  989. push ebx
  990. push ebp
  992. mov eax,[esp+12+20] ;DstPitch
  993. mov ebx,[esp+16+20] ;SrcPitch
  995. mov ecx,[esp+0+20]  ;this
  996. mov edi,[esp+4+20]  ;DstPtr
  997. mov esi,[esp+8+20]  ;SrcPtr
  998. mov ebp,[esp+20+20] ;Width
  999. mov edx,[esp+24+20] ;Height
  1000. mov edi,[edi] ;y
  1001. mov esi,[esi] ;y
  1002. add ecx,OFFSET_COL
  1003. call blit_plane_yuv_%1
  1005. sar eax,1
  1006. sar ebx,1
  1008. mov ecx,[esp+0+20]  ;this
  1009. mov edi,[esp+4+20]  ;DstPtr
  1010. mov esi,[esp+8+20]  ;SrcPtr
  1011. mov ebp,[esp+20+20] ;Width
  1012. mov edx,[esp+24+20] ;Height
  1013. sar ebp,1
  1014. sar edx,1
  1015. mov edi,[edi+4] ;u
  1016. mov esi,[esi+4] ;u
  1017. add ecx,OFFSET_COL+8*2
  1018. call blit_plane_yuv_%1
  1020. mov ecx,[esp+0+20]  ;this
  1021. mov edi,[esp+4+20]  ;DstPtr
  1022. mov esi,[esp+8+20]  ;SrcPtr
  1023. mov ebp,[esp+20+20] ;Width
  1024. mov edx,[esp+24+20] ;Height
  1025. sar ebp,1
  1026. sar edx,1
  1027. mov edi,[edi+8] ;v
  1028. mov esi,[esi+8] ;v
  1029. add ecx,OFFSET_COL+8*4
  1030. call blit_plane_yuv_%1
  1032. emms
  1033. pop ebp
  1034. pop ebx
  1035. pop edi
  1036. pop esi
  1037. ret 32
  1039. blit_plane_rgb %1,rgb32,rgb32
  1040. blit_plane_rgb %1,rgb24,rgb24
  1041. blit_plane_rgb %1,rgb16,rgb16
  1042. ;blit_plane_rgb %1,rgb32,rgb24
  1043. ;blit_plane_rgb %1,rgb24,rgb32
  1044. ;blit_plane_rgb %1,rgb32,bgr32
  1045. ;blit_plane_rgb %1,rgb24,bgr24
  1046. ;blit_plane_rgb %1,rgb32,bgr24
  1047. ;blit_plane_rgb %1,rgb24,bgr32
  1049. blit_pack %1,yuy2,4,1,yuy2,1
  1050. blit_pack %1,rgb32,8,2,rgb,0
  1051. blit_pack %1,rgb24,6,2,rgb,0
  1052. blit_pack %1,bgr32,8,2,rgb,0
  1053. blit_pack %1,bgr24,6,2,rgb,0
  1055. %endmacro
  1057. blit mmx2
  1058. blit mmx
  1059. blit 3dnow