开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > Windows CE > 查看源码
rmt.asx
资源名称：tcpmp.rar　[点击查看]
上传用户：wstnjxml
上传日期：2014-04-03
资源大小：7248k
文件大小：22k
源码类别：

Windows CE

开发平台：

C/C++

rmt.asx：源码内容
  1. ;*
  2. ;* Raster Music Tracker, RMT Atari routine version 1.20051226
  3. ;* (c) Radek Sterba, Raster/C.P.U., 2002 - 2005
  4. ;* http://raster.atari.org
  5. ;*
  6. ;* Warnings:
  7. ;*
  8. ;* 1. RMT player routine needs 19 itself reserved bytes in zero page (no accessed
  9. ;*    from any other routines) as well as cca 1KB of memory before the "PLAYER"
  10. ;*    address for frequency tables and functionary variables. It's:
  11. ;*   a) from PLAYER-$400 to PLAYER for stereo RMTplayer
  12. ;*    b) from PLAYER-$380 to PLAYER for mono RMTplayer
  13. ;*
  14. ;* 2. RMT player routine MUST (!!!) be compiled from the begin of the memory page.
  15. ;*    i.e. "PLAYER" address can be $..00 only!
  16. ;*
  17. ;* 3. Because of RMTplayer provides a lot of effects, it spent a lot of CPU time.
  18. ;*
  19. ;* STEREOMODE equ 0 ;0 => compile RMTplayer for 4 tracks mono
  20. ;* ;1 => compile RMTplayer for 8 tracks stereo
  21. ;* ;2 => compile RMTplayer for 4 tracks stereo L1 R2 R3 L4
  22. ;* ;3 => compile RMTplayer for 4 tracks stereo L1 L2 R3 R4
  23. ;*
  24. PLAYER equ $0600
  25. ;*
  26. IFT STEREOMODE==1
  27. TRACKS equ 8
  28. ELS
  29. TRACKS equ 4
  30. EIF
  31. ;*
  32. ;* RMT FEATures definitions
  33. ;* For optimizations of RMT player routine to concrete RMT modul only!
  34. ;* --------BEGIN--------
  35. FEAT_INSTRSPEED equ 0 ;* cca 21 or 5 bytes
  36. FEAT_CONSTANTSPEED equ 0 ;* cca 28 bytes
  37. ;* VARIOUS COMMANDS
  38. FEAT_COMMAND1 equ 1 ;* cca 8 bytes
  39. FEAT_COMMAND2 equ 1 ;* cca 20 bytes (+save 1 address in zero page) and quicker whole RMT routine
  40. FEAT_COMMAND3 equ 1 ;* cca 12 bytes
  41. FEAT_COMMAND4 equ 1 ;* cca 15 bytes
  42. FEAT_COMMAND5 equ 1 ;* cca 67 bytes
  43. FEAT_COMMAND6 equ 1 ;* cca 15 bytes
  44. ;* COMMAND7 SETNOTE (i.e. command 7 with parameter != $80)
  45. FEAT_COMMAND7SETNOTE equ 1 ;* cca 12 bytes
  46. ;* COMMAND7 VOLUMEONLY (i.e. command 7 with parameter == $80)
  47. FEAT_COMMAND7VOLUMEONLY equ 1 ;* cca 74 bytes
  48. ;* PORTAMENTO
  49. FEAT_PORTAMENTO equ 1 ;* cca 138 bytes and quicker whole RMT routine
  50. ;* FILTER
  51. FEAT_FILTER equ 1 ;* cca 179 bytes and quicker whole RMT routine
  52. FEAT_FILTERG0L equ 1 ;* (cca 38 bytes for each)
  53. FEAT_FILTERG1L equ 1
  54. FEAT_FILTERG0R equ 1
  55. FEAT_FILTERG1R equ 1
  56. ;* BASS16B (i.e. distortion value 6)
  57. FEAT_BASS16 equ 1 ;* cca 194 bytes +128bytes freq table and quicker whole RMT routine
  58. FEAT_BASS16G1L equ 1 ;* (cca 47 bytes for each)
  59. FEAT_BASS16G3L equ 1
  60. FEAT_BASS16G1R equ 1
  61. FEAT_BASS16G3R equ 1
  62. ;* VOLUME ONLY for particular generators
  63. FEAT_VOLUMEONLYG0L equ 1 ;* (cca 7 bytes for each)
  64. FEAT_VOLUMEONLYG2L equ 1
  65. FEAT_VOLUMEONLYG3L equ 1
  66. FEAT_VOLUMEONLYG0R equ 1
  67. FEAT_VOLUMEONLYG2R equ 1
  68. FEAT_VOLUMEONLYG3R equ 1
  69. ;* TABLE TYPE (i.e. TABLETYPE=1)
  70. FEAT_TABLETYPE equ 1 ;* cca 53 bytes and quicker whole RMT routine
  71. ;* TABLE MODE (i.e. TABLEMODE=1)
  72. FEAT_TABLEMODE equ 1 ;* cca 16 bytes and quicker whole RMT routine
  73. ;* TABLE GO (i.e. TGO is nonzero value)
  74. FEAT_TABLEGO equ 1 ;* cca 6 bytes and quicker whole RMT routine
  75. ;* AUDCTLMANUALSET (i.e. any MANUAL AUDCTL setting is nonzero value)
  76. FEAT_AUDCTLMANUALSET equ 1 ;* cca 27 bytes and quicker whole RMT routine
  77. ;* VOLUME MINIMUM (i.e. VMIN is nonzero value)
  78. FEAT_VOLUMEMIN equ 1 ;* cca 12 bytes and quicker whole RMT routine
  79. ;* --------END--------
  81. ;*
  82. ;* RMT ZeroPage addresses
  83. org 203
  84. p_tis
  85. p_instrstable org *+2
  86. p_trackslbstable org *+2
  87. p_trackshbstable org *+2
  88. p_song org *+2
  89. ns org *+2
  90. nr org *+2
  91. nt org *+2
  92. reg1 org *+1
  93. reg2 org *+1
  94. reg3 org *+1
  95. tmp org *+1
  96. IFT FEAT_COMMAND2
  97. frqaddcmd2 org *+1
  98. EIF
  99. IFT TRACKS>4
  100. org PLAYER-$400
  101. ELS
  102. org PLAYER-$380
  103. EIF
  104. track_variables
  105. trackn_db org *+TRACKS
  106. trackn_hb org *+TRACKS
  107. trackn_idx org *+TRACKS
  108. trackn_pause org *+TRACKS
  109. trackn_note org *+TRACKS
  110. trackn_volume org *+TRACKS
  111. trackn_distor  org *+TRACKS
  112. trackn_shiftfrq org *+TRACKS
  113. IFT FEAT_PORTAMENTO
  114. trackn_portafrqc org *+TRACKS
  115. trackn_portafrqa org *+TRACKS
  116. trackn_portaspeed org *+TRACKS
  117. trackn_portaspeeda org *+TRACKS
  118. trackn_portadepth org *+TRACKS
  119. EIF
  120. trackn_instrx2 org *+TRACKS
  121. trackn_instrdb org *+TRACKS
  122. trackn_instrhb org *+TRACKS
  123. trackn_instridx org *+TRACKS
  124. trackn_instrlen org *+TRACKS
  125. trackn_instrlop org *+TRACKS
  126. trackn_instrreachend org *+TRACKS
  127. trackn_volumeslidedepth org *+TRACKS
  128. trackn_volumeslidevalue org *+TRACKS
  129. IFT FEAT_VOLUMEMIN
  130. trackn_volumemin org *+TRACKS
  131. EIF
  132. trackn_effdelay org *+TRACKS
  133. trackn_effvibratoa org *+TRACKS
  134. trackn_effvibratobeg org *+TRACKS
  135. trackn_effvibratoend org *+TRACKS
  136. trackn_effshift org *+TRACKS
  137. trackn_tabletypespeed org *+TRACKS
  138. IFT FEAT_TABLEMODE
  139. trackn_tablemode org *+TRACKS
  140. EIF
  141. trackn_tablenote org *+TRACKS
  142. trackn_tablea org *+TRACKS
  143. trackn_tableend org *+TRACKS
  144. IFT FEAT_TABLEGO
  145. trackn_tablelop org *+TRACKS
  146. EIF
  147. trackn_tablespeeda org *+TRACKS
  148. trackn_command org *+TRACKS
  149. IFT FEAT_BASS16
  150. trackn_outnote org *+TRACKS
  151. EIF
  152. IFT FEAT_FILTER
  153. trackn_filter org *+TRACKS
  154. EIF
  155. trackn_audf org *+TRACKS
  156. trackn_audc org *+TRACKS
  157. IFT FEAT_AUDCTLMANUALSET
  158. trackn_audctl org *+TRACKS
  159. EIF
  160. IFT FEAT_CONSTANTSPEED==0
  161. v_speed org *+1
  162. EIF
  163. v_aspeed org *+1
  164. IFT FEAT_INSTRSPEED==0||FEAT_INSTRSPEED>1
  165. v_ainstrspeed org *+1
  166. EIF
  167. v_abeat org *+1
  168. track_endvariables
  169. org PLAYER-$100-$140-$30
  170. INSTRPAR equ 12
  171. tabbeganddistor
  172.  dta frqtabpure-frqtab,$00
  173.  dta frqtabpure-frqtab,$20
  174.  dta frqtabpure-frqtab,$40
  175.  dta frqtabbass1-frqtab,$c0
  176.  dta frqtabpure-frqtab,$80
  177.  dta frqtabpure-frqtab,$a0
  178.  dta frqtabbass1-frqtab,$c0
  179.  dta frqtabbass2-frqtab,$c0
  180. vibtabbeg dta 0,vib1-vib0,vib2-vib0,vib3-vib0,vibx-vib0
  181. vib0 dta 0
  182. vib1 dta 1,-1,-1,1
  183. vib2 dta 1,0,-1,-1,0,1
  184. vib3 dta 1,1,0,-1,-1,-1,-1,0,1,1
  185. vibx
  186. :PLAYER-$100-$140-* dta 0
  187. ; org PLAYER-$100-$140
  188. IFT FEAT_BASS16
  189. frqtabbasslo
  190. dta $F2,$33,$96,$E2,$38,$8C,$00,$6A,$E8,$6A,$EF,$80,$08,$AE,$46,$E6
  191. dta $95,$41,$F6,$B0,$6E,$30,$F6,$BB,$84,$52,$22,$F4,$C8,$A0,$7A,$55
  192. dta $34,$14,$F5,$D8,$BD,$A4,$8D,$77,$60,$4E,$38,$27,$15,$06,$F7,$E8
  193. dta $DB,$CF,$C3,$B8,$AC,$A2,$9A,$90,$88,$7F,$78,$70,$6A,$64,$5E,$00
  194. EIF
  195. org PLAYER-$100-$100
  196. frqtab
  197. ERT [<frqtab]!=0 ;* frqtab must begin at the memory page bound! (i.e. $..00 address)
  198. frqtabbass1
  199. dta $BF,$B6,$AA,$A1,$98,$8F,$89,$80,$F2,$E6,$DA,$CE,$BF,$B6,$AA,$A1
  200. dta $98,$8F,$89,$80,$7A,$71,$6B,$65,$5F,$5C,$56,$50,$4D,$47,$44,$3E
  201. dta $3C,$38,$35,$32,$2F,$2D,$2A,$28,$25,$23,$21,$1F,$1D,$1C,$1A,$18
  202. dta $17,$16,$14,$13,$12,$11,$10,$0F,$0E,$0D,$0C,$0B,$0A,$09,$08,$07
  203. frqtabbass2
  204. dta $FF,$F1,$E4,$D8,$CA,$C0,$B5,$AB,$A2,$99,$8E,$87,$7F,$79,$73,$70
  205. dta $66,$61,$5A,$55,$52,$4B,$48,$43,$3F,$3C,$39,$37,$33,$30,$2D,$2A
  206. dta $28,$25,$24,$21,$1F,$1E,$1C,$1B,$19,$17,$16,$15,$13,$12,$11,$10
  207. dta $0F,$0E,$0D,$0C,$0B,$0A,$09,$08,$07,$06,$05,$04,$03,$02,$01,$00
  208. frqtabpure
  209. dta $F3,$E6,$D9,$CC,$C1,$B5,$AD,$A2,$99,$90,$88,$80,$79,$72,$6C,$66
  210. dta $60,$5B,$55,$51,$4C,$48,$44,$40,$3C,$39,$35,$32,$2F,$2D,$2A,$28
  211. dta $25,$23,$21,$1F,$1D,$1C,$1A,$18,$17,$16,$14,$13,$12,$11,$10,$0F
  212. dta $0E,$0D,$0C,$0B,$0A,$09,$08,$07,$06,$05,$04,$03,$02,$01,$00,$00
  213. IFT FEAT_BASS16
  214. frqtabbasshi
  215. dta $0D,$0D,$0C,$0B,$0B,$0A,$0A,$09,$08,$08,$07,$07,$07,$06,$06,$05
  216. dta $05,$05,$04,$04,$04,$04,$03,$03,$03,$03,$03,$02,$02,$02,$02,$02
  217. dta $02,$02,$01,$01,$01,$01,$01,$01,$01,$01,$01,$01,$01,$01,$00,$00
  218. dta $00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00
  219. EIF
  220. org PLAYER-$0100
  221. volumetab
  222. dta $00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00
  223. dta $00,$00,$00,$00,$00,$00,$00,$00,$01,$01,$01,$01,$01,$01,$01,$01
  224. dta $00,$00,$00,$00,$01,$01,$01,$01,$01,$01,$01,$01,$02,$02,$02,$02
  225. dta $00,$00,$00,$01,$01,$01,$01,$01,$02,$02,$02,$02,$02,$03,$03,$03
  226. dta $00,$00,$01,$01,$01,$01,$02,$02,$02,$02,$03,$03,$03,$03,$04,$04
  227. dta $00,$00,$01,$01,$01,$02,$02,$02,$03,$03,$03,$04,$04,$04,$05,$05
  228. dta $00,$00,$01,$01,$02,$02,$02,$03,$03,$04,$04,$04,$05,$05,$06,$06
  229. dta $00,$00,$01,$01,$02,$02,$03,$03,$04,$04,$05,$05,$06,$06,$07,$07
  230. dta $00,$01,$01,$02,$02,$03,$03,$04,$04,$05,$05,$06,$06,$07,$07,$08
  231. dta $00,$01,$01,$02,$02,$03,$04,$04,$05,$05,$06,$07,$07,$08,$08,$09
  232. dta $00,$01,$01,$02,$03,$03,$04,$05,$05,$06,$07,$07,$08,$09,$09,$0A
  233. dta $00,$01,$01,$02,$03,$04,$04,$05,$06,$07,$07,$08,$09,$0A,$0A,$0B
  234. dta $00,$01,$02,$02,$03,$04,$05,$06,$06,$07,$08,$09,$0A,$0A,$0B,$0C
  235. dta $00,$01,$02,$03,$03,$04,$05,$06,$07,$08,$09,$0A,$0A,$0B,$0C,$0D
  236. dta $00,$01,$02,$03,$04,$05,$06,$07,$07,$08,$09,$0A,$0B,$0C,$0D,$0E
  237. dta $00,$01,$02,$03,$04,$05,$06,$07,$08,$09,$0A,$0B,$0C,$0D,$0E,$0F
  238. org PLAYER
  239. ;*
  240. ;* Set of RMT main vectors:
  241. ;*
  242. RASTERMUSICTRACKER
  243. jmp rmt_init
  244. jmp rmt_play
  245. jmp rmt_p3
  246. jmp rmt_silence
  247. jmp SetPokey
  248. rmt_init
  249. stx ns
  250. sty ns+1
  251. pha
  252. IFT track_endvariables-track_variables>255
  253. ldy #0
  254. tya
  255. ri0 sta track_variables,y
  256. sta track_endvariables-$100,y
  257. iny
  258. bne ri0
  259. ELS
  260. ldy #track_endvariables-track_variables
  261. lda #0
  262. ri0 sta track_variables-1,y
  263. dey
  264. bne ri0
  265. EIF
  266. ldy #4
  267. lda (ns),y
  268. sta v_maxtracklen
  269. iny
  270. IFT FEAT_CONSTANTSPEED==0
  271. lda (ns),y
  272. sta v_speed
  273. EIF
  274. IFT FEAT_INSTRSPEED==0
  275. iny
  276. lda (ns),y
  277. sta v_instrspeed
  278. sta v_ainstrspeed
  279. ELI FEAT_INSTRSPEED>1
  280. lda #FEAT_INSTRSPEED
  281. sta v_ainstrspeed
  282. EIF
  283. ldy #8
  284. ri1 lda (ns),y
  285. sta p_tis-8,y
  286. iny
  287. cpy #8+8
  288. bne ri1
  289. pla
  290. pha
  291. IFT TRACKS>4
  292. asl @
  293. asl @
  294. asl @
  295. clc
  296. adc p_song
  297. sta p_song
  298. pla
  299. php
  300. and #$e0
  301. asl @
  302. rol @
  303. rol @
  304. rol @
  305. ELS
  306. asl @
  307. asl @
  308. clc
  309. adc p_song
  310. sta p_song
  311. pla
  312. php
  313. and #$c0
  314. asl @
  315. rol @
  316. rol @
  317. EIF
  318. plp
  319. adc p_song+1
  320. sta p_song+1
  321. jsr GetSongLineTrackLineInitOfNewSetInstrumentsOnlyRmtp3
  322. rmt_silence
  323. IFT STEREOMODE>0
  324. lda #0
  325. sta $d208
  326. sta $d218
  327. ldy #3
  328. sty $d20f
  329. sty $d21f
  330. ldy #8
  331. si1 sta $d200,y
  332. sta $d210,y
  333. dey
  334. bpl si1
  335. ELS
  336. lda #0
  337. sta $d208
  338. ldy #3
  339. sty $d20f
  340. ldy #8
  341. si1 sta $d200,y
  342. dey
  343. bpl si1
  344. EIF
  345. IFT FEAT_INSTRSPEED==0
  346. lda v_instrspeed
  347. ELS
  348. lda #FEAT_INSTRSPEED
  349. EIF
  350. rts
  351. GetSongLineTrackLineInitOfNewSetInstrumentsOnlyRmtp3
  352. GetSongLine
  353. ldx #0
  354. stx v_abeat
  355. nn0
  356. nn1 txa
  357. tay
  358. lda (p_song),y
  359. cmp #$fe
  360. bcs nn2
  361. tay
  362. lda (p_trackslbstable),y
  363. sta trackn_db,x
  364. lda (p_trackshbstable),y
  365. nn1a sta trackn_hb,x
  366. lda #0
  367. sta trackn_idx,x
  368. lda #1
  369. nn1a2 sta trackn_pause,x
  370. lda #$80
  371. sta trackn_instrx2,x
  372. inx
  373. xtracks01 cpx #TRACKS
  374. bne nn1
  375. lda p_song
  376. clc
  377. xtracks02 adc #TRACKS
  378. sta p_song
  379. bcc GetTrackLine
  380. inc p_song+1
  381. nn1b
  382. jmp GetTrackLine
  383. nn2
  384. beq nn3
  385. nn2a
  386. lda #0
  387. beq nn1a2
  388. nn3
  389. ldy #2
  390. lda (p_song),y
  391. tax
  392. iny
  393. lda (p_song),y
  394. sta p_song+1
  395. stx p_song
  396. ldx #0
  397. beq nn0
  398. GetTrackLine
  399. oo0
  400. oo0a
  401. IFT FEAT_CONSTANTSPEED==0
  402. lda v_speed
  403. sta v_bspeed
  404. EIF
  405. ldx #-1
  406. oo1
  407. inx
  408. dec trackn_pause,x
  409. bne oo1x
  410. oo1b
  411. lda trackn_db,x
  412. sta ns
  413. lda trackn_hb,x
  414. sta ns+1
  415. oo1i
  416. ldy trackn_idx,x
  417. inc trackn_idx,x
  418. lda (ns),y
  419. sta reg1
  420. and #$3f
  421. cmp #61
  422. beq oo1a
  423. bcs oo2
  424. sta trackn_note,x
  425. IFT FEAT_BASS16
  426. sta trackn_outnote,x
  427. EIF
  428. iny
  429. lda (ns),y
  430. lsr @
  431. and #$3f*2
  432. sta trackn_instrx2,x
  433. oo1a
  434. lda #1
  435. sta trackn_pause,x
  436. ldy trackn_idx,x
  437. inc trackn_idx,x
  438. lda (ns),y
  439. lsr @
  440. ror reg1
  441. lsr @
  442. ror reg1
  443. lda reg1
  444. and #$f0
  445. sta trackn_volume,x
  446. oo1x
  447. xtracks03sub1 cpx #TRACKS-1
  448. bne oo1
  449. IFT FEAT_CONSTANTSPEED==0
  450. lda #$ff
  451. v_bspeed equ *-1
  452. sta v_speed
  453. ELS
  454. lda #FEAT_CONSTANTSPEED
  455. EIF
  456. sta v_aspeed
  457. jmp InitOfNewSetInstrumentsOnly
  458. oo2
  459. cmp #63
  460. beq oo63
  461. lda reg1
  462. and #$c0
  463. beq oo62_b
  464. asl @
  465. rol @
  466. rol @
  467. sta trackn_pause,x
  468. jmp oo1x
  469. oo62_b
  470. iny
  471. lda (ns),y
  472. sta trackn_pause,x
  473. inc trackn_idx,x
  474. jmp oo1x
  475. oo63
  476. lda reg1
  477. IFT FEAT_CONSTANTSPEED==0
  478. bmi oo63_1X
  479. iny
  480. lda (ns),y
  481. sta v_bspeed
  482. inc trackn_idx,x
  483. jmp oo1i
  484. oo63_1X
  485. EIF
  486. cmp #255
  487. beq oo63_11
  488. iny
  489. lda (ns),y
  490. sta trackn_idx,x
  491. jmp oo1i
  492. oo63_11
  493. jmp GetSongLine
  494. p2xrmtp3 jmp rmt_p3
  495. p2x0 dex
  496.  bmi p2xrmtp3
  497. InitOfNewSetInstrumentsOnly
  498. p2x1 ldy trackn_instrx2,x
  499. bmi p2x0
  500. SetUpInstrumentY2
  501. lda (p_instrstable),y
  502. sta trackn_instrdb,x
  503. sta nt
  504. iny
  505. lda (p_instrstable),y
  506. sta trackn_instrhb,x
  507. sta nt+1
  508. IFT FEAT_FILTER
  509. lda #1
  510. sta trackn_filter,x
  511. EIF
  512. IFT FEAT_TABLEGO
  513. IFT FEAT_FILTER
  514. tay
  515. ELS
  516. ldy #1
  517. EIF
  518. lda (nt),y
  519. sta trackn_tablelop,x
  520. iny
  521. ELS
  522. ldy #2
  523. EIF
  524. lda (nt),y
  525. sta trackn_instrlen,x
  526. iny
  527. lda (nt),y
  528. sta trackn_instrlop,x
  529. iny
  530. lda (nt),y
  531. sta trackn_tabletypespeed,x
  532. IFT FEAT_TABLETYPE||FEAT_TABLEMODE
  533. and #$3f
  534. EIF
  535. sta trackn_tablespeeda,x
  536. IFT FEAT_TABLEMODE
  537. lda (nt),y
  538. and #$40
  539. sta trackn_tablemode,x
  540. EIF
  541. IFT FEAT_AUDCTLMANUALSET
  542. iny
  543. lda (nt),y
  544. sta trackn_audctl,x
  545. iny
  546. ELS
  547. ldy #6
  548. EIF
  549. lda (nt),y
  550. sta trackn_volumeslidedepth,x
  551. IFT FEAT_VOLUMEMIN
  552. iny
  553. lda (nt),y
  554. sta trackn_volumemin,x
  555. iny
  556. ELS
  557. ldy #8
  558. EIF
  559. lda (nt),y
  560. sta trackn_effdelay,x
  561. iny
  562. lda (nt),y
  563. tay
  564. lda vibtabbeg,y
  565. sta trackn_effvibratoa,x
  566. sta trackn_effvibratobeg,x
  567. lda vibtabbeg+1,y
  568. sta trackn_effvibratoend,x
  569. ldy #10
  570. lda (nt),y
  571. sta trackn_effshift,x
  572. lda #128
  573. sta trackn_volumeslidevalue,x
  574. sta trackn_instrx2,x
  575. asl @
  576. sta trackn_instrreachend,x
  577. sta trackn_shiftfrq,x
  578. tay
  579. lda (nt),y
  580. sta trackn_tableend,x
  581. adc #0
  582. sta trackn_instridx,x
  583. lda #INSTRPAR
  584. sta trackn_tablea,x
  585. tay
  586. lda (nt),y
  587. sta trackn_tablenote,x
  588. xata_rtshere
  589. jmp p2x0
  590. rmt_play
  591. rmt_p0
  592. jsr SetPokey
  593. rmt_p1
  594. IFT FEAT_INSTRSPEED==0||FEAT_INSTRSPEED>1
  595. dec v_ainstrspeed
  596. bne rmt_p3
  597. EIF
  598. IFT FEAT_INSTRSPEED==0
  599. lda #$ff
  600. v_instrspeed equ *-1
  601. sta v_ainstrspeed
  602. ELI FEAT_INSTRSPEED>1
  603. lda #FEAT_INSTRSPEED
  604. sta v_ainstrspeed
  605. EIF
  606. rmt_p2
  607. dec v_aspeed
  608. bne rmt_p3
  609. inc v_abeat
  610. lda v_abeat
  611. cmp #$ff
  612. v_maxtracklen equ *-1
  613. beq p2o3
  614. jmp GetTrackLine
  615. p2o3
  616. jmp GetSongLineTrackLineInitOfNewSetInstrumentsOnlyRmtp3
  617. go_ppnext jmp ppnext
  618. rmt_p3
  619. lda #>frqtab
  620. sta nr+1
  621. xtracks05sub1 ldx #TRACKS-1
  622. pp1
  623. lda trackn_instrhb,x
  624. beq go_ppnext
  625. sta ns+1
  626. lda trackn_instrdb,x
  627. sta ns
  628. ldy trackn_instridx,x
  629. lda (ns),y
  630. sta reg1
  631. iny
  632. lda (ns),y
  633. sta reg2
  634. iny
  635. lda (ns),y
  636. sta reg3
  637. iny
  638. tya
  639. cmp trackn_instrlen,x
  640. bcc pp2
  641. beq pp2
  642. lda #$80
  643. sta trackn_instrreachend,x
  644. pp1b
  645. lda trackn_instrlop,x
  646. pp2 sta trackn_instridx,x
  647. lda reg1
  648. IFT TRACKS>4
  649. cpx #4
  650. bcc pp2s
  651. lsr @
  652. lsr @
  653. lsr @
  654. lsr @
  655. pp2s
  656. EIF
  657. and #$0f
  658. ora trackn_volume,x
  659. tay
  660. lda volumetab,y
  661. sta tmp
  662. lda reg2
  663. and #$0e
  664. tay
  665. lda tabbeganddistor,y
  666. sta nr
  667. lda tmp
  668. ora tabbeganddistor+1,y
  669. sta trackn_audc,x
  670. InstrumentsEffects
  671. lda trackn_effdelay,x
  672. beq ei2
  673. cmp #1
  674. bne ei1
  675. lda trackn_shiftfrq,x
  676. clc
  677. adc trackn_effshift,x
  678. clc
  679. ldy trackn_effvibratoa,x
  680. adc vib0,y
  681. sta trackn_shiftfrq,x
  682. iny
  683. tya
  684. cmp trackn_effvibratoend,x
  685. bne ei1a
  686. lda trackn_effvibratobeg,x
  687. ei1a
  688. sta trackn_effvibratoa,x
  689. jmp ei2
  690. ei1
  691. dec trackn_effdelay,x
  692. ei2
  693. ldy trackn_tableend,x
  694. cpy #INSTRPAR+1
  695. bcc ei3
  696. lda trackn_tablespeeda,x
  697. bpl ei2f
  698. ei2c
  699. tya
  700. cmp trackn_tablea,x
  701. bne ei2c2
  702. IFT FEAT_TABLEGO
  703. lda trackn_tablelop,x
  704. ELS
  705. lda #INSTRPAR
  706. EIF
  707. sta trackn_tablea,x
  708. bne ei2a
  709. ei2c2
  710. inc trackn_tablea,x
  711. ei2a
  712. lda trackn_instrdb,x
  713. sta nt
  714. lda trackn_instrhb,x
  715. sta nt+1
  716. ldy trackn_tablea,x
  717. lda (nt),y
  718. IFT FEAT_TABLEMODE
  719. ldy trackn_tablemode,x
  720. beq ei2e
  721. clc
  722. adc trackn_tablenote,x
  723. ei2e
  724. EIF
  725. sta trackn_tablenote,x
  726. lda trackn_tabletypespeed,x
  727. IFT FEAT_TABLETYPE||FEAT_TABLEMODE
  728. and #$3f
  729. EIF
  730. ei2f
  731. sec
  732. sbc #1
  733. sta trackn_tablespeeda,x
  734. ei3
  735. lda trackn_instrreachend,x
  736. bpl ei4
  737. lda trackn_volume,x
  738. beq ei4
  739. IFT FEAT_VOLUMEMIN
  740. cmp trackn_volumemin,x
  741. beq ei4
  742. bcc ei4
  743. EIF
  744. tay
  745. lda trackn_volumeslidevalue,x
  746. clc
  747. adc trackn_volumeslidedepth,x
  748. sta trackn_volumeslidevalue,x
  749. bcc ei4
  750. tya
  751. sbc #16
  752. sta trackn_volume,x
  753. ei4
  754. IFT FEAT_COMMAND2
  755. lda #0
  756. sta frqaddcmd2
  757. EIF
  758. lda reg2
  759. sta trackn_command,x
  760. and #$70
  761. lsr @
  762. lsr @
  763. sta jmx+1
  764. jmx bcc *
  765. jmp cmd0
  766. nop
  767. jmp cmd1
  768. nop
  769. jmp cmd2
  770. nop
  771. jmp cmd3
  772. nop
  773. jmp cmd4
  774. nop
  775. jmp cmd5
  776. nop
  777. jmp cmd6
  778. nop
  779. jmp cmd7
  780. cmd1
  781. IFT FEAT_COMMAND1
  782. lda reg3
  783. jmp cmd0c
  784. EIF
  785. cmd2
  786. IFT FEAT_COMMAND2
  787. lda reg3
  788. sta frqaddcmd2
  789. lda trackn_note,x
  790. jmp cmd0a
  791. EIF
  792. cmd3
  793. IFT FEAT_COMMAND3
  794. lda trackn_note,x
  795. clc
  796. adc reg3
  797. sta trackn_note,x
  798. jmp cmd0a
  799. EIF
  800. cmd4
  801. IFT FEAT_COMMAND4
  802. lda trackn_shiftfrq,x
  803. clc
  804. adc reg3
  805. sta trackn_shiftfrq,x
  806. lda trackn_note,x
  807. jmp cmd0a
  808. EIF
  809. cmd5
  810. IFT FEAT_COMMAND5&&FEAT_PORTAMENTO
  811. IFT FEAT_TABLETYPE
  812. lda trackn_tabletypespeed,x
  813. bpl cmd5a1
  814. ldy trackn_note,x
  815. lda (nr),y
  816. clc
  817. adc trackn_tablenote,x
  818. jmp cmd5ax
  819. EIF
  820. cmd5a1
  821. lda trackn_note,x
  822. clc
  823. adc trackn_tablenote,x
  824. cmp #61
  825. bcc cmd5a2
  826. lda #63
  827. cmd5a2
  828. tay
  829. lda (nr),y
  830. cmd5ax
  831. sta trackn_portafrqc,x
  832. ldy reg3
  833. bne cmd5a
  834. sta trackn_portafrqa,x
  835. cmd5a
  836. tya
  837. lsr @
  838. lsr @
  839. lsr @
  840. lsr @
  841. sta trackn_portaspeed,x
  842. sta trackn_portaspeeda,x
  843. lda reg3
  844. and #$0f
  845. sta trackn_portadepth,x
  846. lda trackn_note,x
  847. jmp cmd0a
  848. ELI FEAT_COMMAND5
  849. jmp pp9
  850. EIF
  851. cmd6
  852. IFT FEAT_COMMAND6&&FEAT_FILTER
  853. lda reg3
  854. clc
  855. adc trackn_filter,x
  856. sta trackn_filter,x
  857. lda trackn_note,x
  858. jmp cmd0a
  859. ELI FEAT_COMMAND6
  860. jmp pp9
  861. EIF
  862. cmd7
  863. IFT FEAT_COMMAND7SETNOTE||FEAT_COMMAND7VOLUMEONLY
  864. IFT FEAT_COMMAND7SETNOTE
  865. lda reg3
  866. IFT FEAT_COMMAND7VOLUMEONLY
  867. cmp #$80
  868. beq cmd7a
  869. EIF
  870. sta trackn_note,x
  871. jmp cmd0a
  872. EIF
  873. IFT FEAT_COMMAND7VOLUMEONLY
  874. cmd7a
  875. lda trackn_audc,x
  876. ora #$f0
  877. sta trackn_audc,x
  878. lda trackn_note,x
  879. jmp cmd0a
  880. EIF
  881. EIF
  882. cmd0
  883. lda trackn_note,x
  884. clc
  885. adc reg3
  886. cmd0a
  887. IFT FEAT_TABLETYPE
  888. ldy trackn_tabletypespeed,x
  889. bmi cmd0b
  890. EIF
  891. clc
  892. adc trackn_tablenote,x
  893. cmp #61
  894. bcc cmd0a1
  895. lda #0
  896. sta trackn_audc,x
  897. lda #63
  898. cmd0a1
  899. IFT FEAT_BASS16
  900. sta trackn_outnote,x
  901. EIF
  902. tay
  903. lda (nr),y
  904. clc
  905. adc trackn_shiftfrq,x
  906. IFT FEAT_COMMAND2
  907. clc
  908. adc frqaddcmd2
  909. EIF
  910. IFT FEAT_TABLETYPE
  911. jmp cmd0c
  912. cmd0b
  913. cmp #61
  914. bcc cmd0b1
  915. lda #0
  916. sta trackn_audc,x
  917. lda #63
  918. cmd0b1
  919. tay
  920. lda trackn_shiftfrq,x
  921. clc
  922. adc trackn_tablenote,x
  923. clc
  924. adc (nr),y
  925. IFT FEAT_COMMAND2
  926. clc
  927. adc frqaddcmd2
  928. EIF
  929. EIF
  930. cmd0c
  931. sta trackn_audf,x
  932. pp9
  933. IFT FEAT_PORTAMENTO
  934. lda trackn_portaspeeda,x
  935. beq pp10
  936. dec trackn_portaspeeda,x
  937. bne pp10
  938. lda trackn_portaspeed,x
  939. sta trackn_portaspeeda,x
  940. lda trackn_portafrqa,x
  941. cmp trackn_portafrqc,x
  942. beq pp10
  943. bcs pps1
  944. adc trackn_portadepth,x
  945. bcs pps8
  946. cmp trackn_portafrqc,x
  947. bcs pps8
  948. jmp pps9
  949. pps1
  950. sbc trackn_portadepth,x
  951. bcc pps8
  952. cmp trackn_portafrqc,x
  953. bcs pps9
  954. pps8
  955. lda trackn_portafrqc,x
  956. pps9
  957. sta trackn_portafrqa,x
  958. pp10
  959. lda reg2
  960. and #$01
  961. beq pp11
  962. lda trackn_portafrqa,x
  963. clc
  964. adc trackn_shiftfrq,x
  965. sta trackn_audf,x
  966. pp11
  967. EIF
  968. ppnext
  969. dex
  970. bmi rmt_p4
  971. jmp pp1
  972. rmt_p4
  973. IFT FEAT_AUDCTLMANUALSET
  974. lda trackn_audctl+0
  975. ora trackn_audctl+1
  976. ora trackn_audctl+2
  977. ora trackn_audctl+3
  978. tax
  979. ELS
  980. ldx #0
  981. EIF
  982. qq1
  983. stx v_audctl
  984. IFT FEAT_FILTER
  985. IFT FEAT_FILTERG0L
  986. lda trackn_command+0
  987. bpl qq2
  988. lda trackn_audc+0
  989. and #$0f
  990. beq qq2
  991. lda trackn_audf+0
  992. clc
  993. adc trackn_filter+0
  994. sta trackn_audf+2
  995. IFT FEAT_COMMAND7VOLUMEONLY&&FEAT_VOLUMEONLYG2L
  996. lda trackn_audc+2
  997. and #$10
  998. bne qq1a
  999. EIF
  1000. lda #0
  1001. sta trackn_audc+2
  1002. qq1a
  1003. txa
  1004. ora #4
  1005. tax
  1006. EIF
  1007. qq2
  1008. IFT FEAT_FILTERG1L
  1009. lda trackn_command+1
  1010. bpl qq3
  1011. lda trackn_audc+1
  1012. and #$0f
  1013. beq qq3
  1014. lda trackn_audf+1
  1015. clc
  1016. adc trackn_filter+1
  1017. sta trackn_audf+3
  1018. IFT FEAT_COMMAND7VOLUMEONLY&&FEAT_VOLUMEONLYG3L
  1019. lda trackn_audc+3
  1020. and #$10
  1021. bne qq2a
  1022. EIF
  1023. lda #0
  1024. sta trackn_audc+3
  1025. qq2a
  1026. txa
  1027. ora #2
  1028. tax
  1029. EIF
  1030. qq3
  1031. IFT FEAT_FILTERG0L||FEAT_FILTERG1L
  1032. cpx v_audctl
  1033. bne qq5
  1034. EIF
  1035. EIF
  1036. IFT FEAT_BASS16
  1037. IFT FEAT_BASS16G1L
  1038. lda trackn_command+1
  1039. and #$0e
  1040. cmp #6
  1041. bne qq4
  1042. lda trackn_audc+1
  1043. and #$0f
  1044. beq qq4
  1045. ldy trackn_outnote+1
  1046. lda frqtabbasslo,y
  1047. sta trackn_audf+0
  1048. lda frqtabbasshi,y
  1049. sta trackn_audf+1
  1050. IFT FEAT_COMMAND7VOLUMEONLY&&FEAT_VOLUMEONLYG0L
  1051. lda trackn_audc+0
  1052. and #$10
  1053. bne qq3a
  1054. EIF
  1055. lda #0
  1056. sta trackn_audc+0
  1057. qq3a
  1058. txa
  1059. ora #$50
  1060. tax
  1061. EIF
  1062. qq4
  1063. IFT FEAT_BASS16G3L
  1064. lda trackn_command+3
  1065. and #$0e
  1066. cmp #6
  1067. bne qq5
  1068. lda trackn_audc+3
  1069. and #$0f
  1070. beq qq5
  1071. ldy trackn_outnote+3
  1072. lda frqtabbasslo,y
  1073. sta trackn_audf+2
  1074. lda frqtabbasshi,y
  1075. sta trackn_audf+3
  1076. IFT FEAT_COMMAND7VOLUMEONLY&&FEAT_VOLUMEONLYG2L
  1077. lda trackn_audc+2
  1078. and #$10
  1079. bne qq4a
  1080. EIF
  1081. lda #0
  1082. sta trackn_audc+2
  1083. qq4a
  1084. txa
  1085. ora #$28
  1086. tax
  1087. EIF
  1088. EIF
  1089. qq5
  1090. stx v_audctl
  1091. IFT TRACKS>4
  1092. IFT FEAT_AUDCTLMANUALSET
  1093. lda trackn_audctl+4
  1094. ora trackn_audctl+5
  1095. ora trackn_audctl+6
  1096. ora trackn_audctl+7
  1097. tax
  1098. ELS
  1099. ldx #0
  1100. EIF
  1101. stx v_audctl2
  1102. IFT FEAT_FILTER
  1103. IFT FEAT_FILTERG0R
  1104. lda trackn_command+0+4
  1105. bpl qs2
  1106. lda trackn_audc+0+4
  1107. and #$0f
  1108. beq qs2
  1109. lda trackn_audf+0+4
  1110. clc
  1111. adc trackn_filter+0+4
  1112. sta trackn_audf+2+4
  1113. IFT FEAT_COMMAND7VOLUMEONLY&&FEAT_VOLUMEONLYG2R
  1114. lda trackn_audc+2+4
  1115. and #$10
  1116. bne qs1a
  1117. EIF
  1118. lda #0
  1119. sta trackn_audc+2+4
  1120. qs1a
  1121. txa
  1122. ora #4
  1123. tax
  1124. EIF
  1125. qs2
  1126. IFT FEAT_FILTERG1R
  1127. lda trackn_command+1+4
  1128. bpl qs3
  1129. lda trackn_audc+1+4
  1130. and #$0f
  1131. beq qs3
  1132. lda trackn_audf+1+4
  1133. clc
  1134. adc trackn_filter+1+4
  1135. sta trackn_audf+3+4
  1136. IFT FEAT_COMMAND7VOLUMEONLY&&FEAT_VOLUMEONLYG3R
  1137. lda trackn_audc+3+4
  1138. and #$10
  1139. bne qs2a
  1140. EIF
  1141. lda #0
  1142. sta trackn_audc+3+4
  1143. qs2a
  1144. txa
  1145. ora #2
  1146. tax
  1147. EIF
  1148. qs3
  1149. IFT FEAT_FILTERG0R||FEAT_FILTERG1R
  1150. cpx v_audctl2
  1151. bne qs5
  1152. EIF
  1153. EIF
  1154. IFT FEAT_BASS16
  1155. IFT FEAT_BASS16G1R
  1156. lda trackn_command+1+4
  1157. and #$0e
  1158. cmp #6
  1159. bne qs4
  1160. lda trackn_audc+1+4
  1161. and #$0f
  1162. beq qs4
  1163. ldy trackn_outnote+1+4
  1164. lda frqtabbasslo,y
  1165. sta trackn_audf+0+4
  1166. lda frqtabbasshi,y
  1167. sta trackn_audf+1+4
  1168. IFT FEAT_COMMAND7VOLUMEONLY&&FEAT_VOLUMEONLYG0R
  1169. lda trackn_audc+0+4
  1170. and #$10
  1171. bne qs3a
  1172. EIF
  1173. lda #0
  1174. sta trackn_audc+0+4
  1175. qs3a
  1176. txa
  1177. ora #$50
  1178. tax
  1179. EIF
  1180. qs4
  1181. IFT FEAT_BASS16G3R
  1182. lda trackn_command+3+4
  1183. and #$0e
  1184. cmp #6
  1185. bne qs5
  1186. lda trackn_audc+3+4
  1187. and #$0f
  1188. beq qs5
  1189. ldy trackn_outnote+3+4
  1190. lda frqtabbasslo,y
  1191. sta trackn_audf+2+4
  1192. lda frqtabbasshi,y
  1193. sta trackn_audf+3+4
  1194. IFT FEAT_COMMAND7VOLUMEONLY&&FEAT_VOLUMEONLYG2R
  1195. lda trackn_audc+2+4
  1196. and #$10
  1197. bne qs4a
  1198. EIF
  1199. lda #0
  1200. sta trackn_audc+2+4
  1201. qs4a
  1202. txa
  1203. ora #$28
  1204. tax
  1205. EIF
  1206. EIF
  1207. qs5
  1208. stx v_audctl2
  1209. EIF
  1210. rmt_p5
  1211. IFT FEAT_INSTRSPEED==0||FEAT_INSTRSPEED>1
  1212. lda v_ainstrspeed
  1213. ELS
  1214. lda #1
  1215. EIF
  1216. rts
  1217. SetPokey
  1218. IFT STEREOMODE==1 ;* L1 L2 L3 L4 R1 R2 R3 R4
  1219. ldy #$ff
  1220. v_audctl2 equ *-1
  1221. lda trackn_audf+0+4
  1222. ldx trackn_audf+0
  1223. xstastx01 sta $d210
  1224. stx $d200
  1225. lda trackn_audc+0+4
  1226. ldx trackn_audc+0
  1227. xstastx02 sta $d211
  1228. stx $d201
  1229. lda trackn_audf+1+4
  1230. ldx trackn_audf+1
  1231. xstastx03 sta $d212
  1232. stx $d202
  1233. lda trackn_audc+1+4
  1234. ldx trackn_audc+1
  1235. xstastx04 sta $d213
  1236. stx $d203
  1237. lda trackn_audf+2+4
  1238. ldx trackn_audf+2
  1239. xstastx05 sta $d214
  1240. stx $d204
  1241. lda trackn_audc+2+4
  1242. ldx trackn_audc+2
  1243. xstastx06 sta $d215
  1244. stx $d205
  1245. lda trackn_audf+3+4
  1246. ldx trackn_audf+3
  1247. xstastx07 sta $d216
  1248. stx $d206
  1249. lda trackn_audc+3+4
  1250. ldx trackn_audc+3
  1251. xstastx08 sta $d217
  1252. stx $d207
  1253. lda #$ff
  1254. v_audctl equ *-1
  1255. xstysta01 sty $d218
  1256. sta $d208
  1257. ELI STEREOMODE==0 ;* L1 L2 L3 L4
  1258. ldy #$ff
  1259. v_audctl equ *-1
  1260. lda trackn_audf+0
  1261. ldx trackn_audc+0
  1262. sta $d200
  1263. stx $d201
  1264. lda trackn_audf+1
  1265. ldx trackn_audc+1
  1266. sta $d200+2
  1267. stx $d201+2
  1268. lda trackn_audf+2
  1269. ldx trackn_audc+2
  1270. sta $d200+4
  1271. stx $d201+4
  1272. lda trackn_audf+3
  1273. ldx trackn_audc+3
  1274. sta $d200+6
  1275. stx $d201+6
  1276. sty $d208
  1277. ELI STEREOMODE==2 ;* L1 R2 R3 L4
  1278. ldy #$ff
  1279. v_audctl equ *-1
  1280. lda trackn_audf+0
  1281. ldx trackn_audc+0
  1282. sta $d200
  1283. stx $d201
  1284. sta $d210
  1285. lda trackn_audf+1
  1286. ldx trackn_audc+1
  1287. sta $d210+2
  1288. stx $d211+2
  1289. lda trackn_audf+2
  1290. ldx trackn_audc+2
  1291. sta $d210+4
  1292. stx $d211+4
  1293. sta $d200+4
  1294. lda trackn_audf+3
  1295. ldx trackn_audc+3
  1296. sta $d200+6
  1297. stx $d201+6
  1298. sta $d210+6
  1299. sty $d218
  1300. sty $d208
  1301. ELI STEREOMODE==3 ;* L1 L2 R3 R4
  1302. ldy #$ff
  1303. v_audctl equ *-1
  1304. lda trackn_audf+0
  1305. ldx trackn_audc+0
  1306. sta $d200
  1307. stx $d201
  1308. lda trackn_audf+1
  1309. ldx trackn_audc+1
  1310. sta $d200+2
  1311. stx $d201+2
  1312. lda trackn_audf+2
  1313. ldx trackn_audc+2
  1314. sta $d210+4
  1315. stx $d211+4
  1316. sta $d200+4
  1317. lda trackn_audf+3
  1318. ldx trackn_audc+3
  1319. sta $d210+6
  1320. stx $d211+6
  1321. sta $d200+6
  1322. sty $d218
  1323. sty $d208
  1324. EIF
  1325. rts
  1326. RMTEND