开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > Windows编程 > 多媒体编程 > 查看源码
idctmmx.asm
资源名称：fullMPCcode.rar　[点击查看]
上传用户：xjjlds
上传日期：2015-12-05
资源大小：22823k
文件大小：23k
源码类别：

多媒体编程

开发平台：

Visual C++

idctmmx.asm：源码内容
  1. ;
  2. ; idct8x8_xmm.asm
  3. ;
  4. ; Originally provided by Intel at AP-922
  5. ; http://developer.intel.com/vtune/cbts/strmsimd/922down.htm
  6. ; (See more app notes at http://developer.intel.com/vtune/cbts/strmsimd/appnotes.htm)
  7. ; but in a limited edition.
  8. ; New macro implements a column part for precise iDCT
  9. ; The routine precision now satisfies IEEE standard 1180-1990. 
  10. ;
  11. ; Copyright (c) 2000-2001 Peter Gubanov <peter@elecard.net.ru>
  12. ; Rounding trick Copyright (c) 2000 Michel Lespinasse <walken@zoy.org>
  13. ;
  14. ; http://www.elecard.com/peter/idct.html
  15. ; http://www.linuxvideo.org/mpeg2dec/
  16. ;
  17. ;=============================================================================
  18. ;
  19. ; These examples contain code fragments for first stage iDCT 8x8
  20. ; (for rows) and first stage DCT 8x8 (for columns)
  21. ;
  22. ;=============================================================================
  23. mword  typedef qword
  24. mptr  equ mword ptr
  26. BITS_INV_ACC = 5  ; 4 or 5 for IEEE
  27. SHIFT_INV_ROW = 16 - BITS_INV_ACC
  28. SHIFT_INV_COL = 1 + BITS_INV_ACC
  29. RND_INV_ROW = 1024 * (6 - BITS_INV_ACC) ; 1 << (SHIFT_INV_ROW-1)
  30. RND_INV_COL = 16 * (BITS_INV_ACC - 3)  ; 1 << (SHIFT_INV_COL-1)
  31. RND_INV_CORR = RND_INV_COL - 1  ; correction -1.0 and round
  33. BITS_FRW_ACC = 3  ; 2 or 3 for accuracy
  34. SHIFT_FRW_COL = BITS_FRW_ACC
  35. SHIFT_FRW_ROW = BITS_FRW_ACC + 17
  36. RND_FRW_ROW = 262144 * (BITS_FRW_ACC - 1) ; 1 << (SHIFT_FRW_ROW-1)
  38. _MMX = 1
  40. .nolist
  42. .586
  44. if @version GE 612
  45. .mmx
  46. ;mmword TEXTEQU <QWORD>
  47. else
  48. include IAMMX.INC
  49. endif
  51. if @version GE 614
  52. .xmm
  53. ;mm2word TEXTEQU <QWORD> ; needed for Streaming SIMD Extensions macros
  54. else
  55. include iaxmm.inc ; Streaming SIMD Extensions Emulator Macros
  56. endif
  58. .list
  59. .model flat
  61. _DATA SEGMENT PARA PUBLIC USE32 'DATA'
  63. one_corr  sword            1,            1,            1,            1
  64. round_inv_row dword  RND_INV_ROW,  RND_INV_ROW
  65. round_inv_col sword  RND_INV_COL,  RND_INV_COL,  RND_INV_COL, RND_INV_COL
  66. round_inv_corr sword RND_INV_CORR, RND_INV_CORR, RND_INV_CORR, RND_INV_CORR
  67. round_frw_row dword  RND_FRW_ROW,  RND_FRW_ROW
  68.   tg_1_16 sword  13036,  13036,  13036,  13036 ; tg * (2<<16) + 0.5
  69.   tg_2_16 sword  27146,  27146,  27146,  27146  ; tg * (2<<16) + 0.5
  70.   tg_3_16 sword -21746, -21746, -21746, -21746  ; tg * (2<<16) + 0.5
  71.  cos_4_16 sword -19195, -19195, -19195, -19195  ; cos * (2<<16) + 0.5
  72. ocos_4_16 sword  23170,  23170,  23170,  23170  ; cos * (2<<15) + 0.5
  74.  otg_3_16 sword  21895, 21895, 21895, 21895  ; tg * (2<<16) + 0.5
  76. ; assume SHIFT_INV_ROW == 12
  77. ;rounder_0 dword  65536, 65536
  78. ;rounder_4       dword      0,     0
  79. ;rounder_1       dword   7195,  7195
  80. ;rounder_7 dword   1024,  1024
  81. ;rounder_2 dword   4520,  4520
  82. ;rounder_6 dword   1024,  1024
  83. ;rounder_3 dword   2407,  2407
  84. ;rounder_5 dword    240,   240
  86. ; assume SHIFT_INV_ROW == 11
  87. rounder_0 dword  65536, 65536
  88. rounder_4       dword      0,     0
  89. rounder_1       dword   3597,  3597
  90. rounder_7 dword    512,   512
  91. rounder_2 dword   2260,  2260
  92. rounder_6 dword    512,   512
  93. rounder_3 dword   1203,  1203
  94. rounder_5 dword    120,   120
  96. ;=============================================================================
  97. ;
  98. ; The first stage iDCT 8x8 - inverse DCTs of rows
  99. ;
  100. ;-----------------------------------------------------------------------------
  101. ; The 8-point inverse DCT direct algorithm
  102. ;-----------------------------------------------------------------------------
  103. ;
  104. ; static const short w[32] = {
  105. ; FIX(cos_4_16),  FIX(cos_2_16),  FIX(cos_4_16),  FIX(cos_6_16),
  106. ; FIX(cos_4_16),  FIX(cos_6_16), -FIX(cos_4_16), -FIX(cos_2_16),
  107. ; FIX(cos_4_16), -FIX(cos_6_16), -FIX(cos_4_16),  FIX(cos_2_16),
  108. ; FIX(cos_4_16), -FIX(cos_2_16),  FIX(cos_4_16), -FIX(cos_6_16),
  109. ; FIX(cos_1_16),  FIX(cos_3_16),  FIX(cos_5_16),  FIX(cos_7_16),
  110. ; FIX(cos_3_16), -FIX(cos_7_16), -FIX(cos_1_16), -FIX(cos_5_16),
  111. ; FIX(cos_5_16), -FIX(cos_1_16),  FIX(cos_7_16),  FIX(cos_3_16),
  112. ; FIX(cos_7_16), -FIX(cos_5_16),  FIX(cos_3_16), -FIX(cos_1_16) };
  113. ;
  114. ; #define DCT_8_INV_ROW(x, y)
  115. ; {
  116. ;  int a0, a1, a2, a3, b0, b1, b2, b3;
  117. ;
  118. ;  a0 =x[0]*w[0]+x[2]*w[1]+x[4]*w[2]+x[6]*w[3];
  119. ;  a1 =x[0]*w[4]+x[2]*w[5]+x[4]*w[6]+x[6]*w[7];
  120. ;  a2 = x[0] * w[ 8] + x[2] * w[ 9] + x[4] * w[10] + x[6] * w[11];
  121. ;  a3 = x[0] * w[12] + x[2] * w[13] + x[4] * w[14] + x[6] * w[15];
  122. ;  b0 = x[1] * w[16] + x[3] * w[17] + x[5] * w[18] + x[7] * w[19];
  123. ;  b1 = x[1] * w[20] + x[3] * w[21] + x[5] * w[22] + x[7] * w[23];
  124. ;  b2 = x[1] * w[24] + x[3] * w[25] + x[5] * w[26] + x[7] * w[27];
  125. ;  b3 = x[1] * w[28] + x[3] * w[29] + x[5] * w[30] + x[7] * w[31];
  126. ;
  127. ;  y[0] = SHIFT_ROUND ( a0 + b0 );
  128. ;  y[1] = SHIFT_ROUND ( a1 + b1 );
  129. ;  y[2] = SHIFT_ROUND ( a2 + b2 );
  130. ;  y[3] = SHIFT_ROUND ( a3 + b3 );
  131. ;  y[4] = SHIFT_ROUND ( a3 - b3 );
  132. ;  y[5] = SHIFT_ROUND ( a2 - b2 );
  133. ;  y[6] = SHIFT_ROUND ( a1 - b1 );
  134. ;  y[7] = SHIFT_ROUND ( a0 - b0 );
  135. ; }
  136. ;
  137. ;-----------------------------------------------------------------------------
  138. ;
  139. ; In this implementation the outputs of the iDCT-1D are multiplied
  140. ;  for rows 0,4 - by cos_4_16,
  141. ;  for rows 1,7 - by cos_1_16,
  142. ;  for rows 2,6 - by cos_2_16,
  143. ;  for rows 3,5 - by cos_3_16
  144. ; and are shifted to the left for better accuracy
  145. ;
  146. ; For the constants used,
  147. ;  FIX(float_const) = (short) (float_const * (1<<15) + 0.5)
  148. ;
  149. ;=============================================================================
  151. ;=============================================================================
  152. ; MMX code
  153. ;=============================================================================
  155. ; Table for rows 0,4 - constants are multiplied by cos_4_16
  157. tab_i_04  sword  16384,  16384,  16384, -16384 ; movq-> w06 w04 w02 w00
  158. sword  21407,   8867,   8867, -21407 ; w07 w05 w03 w01
  159. sword  16384, -16384,  16384,  16384 ; w14 w12 w10 w08
  160. sword  -8867,  21407, -21407,  -8867 ; w15 w13 w11 w09
  161. sword  22725,  12873,  19266, -22725 ; w22 w20 w18 w16
  162. sword  19266,   4520,  -4520, -12873 ; w23 w21 w19 w17
  163. sword  12873,   4520,   4520,  19266 ; w30 w28 w26 w24
  164. sword -22725,  19266, -12873, -22725 ; w31 w29 w27 w25
  166. ; Table for rows 1,7 - constants are multiplied by cos_1_16
  168. tab_i_17 sword  22725,  22725,  22725, -22725 ; movq-> w06 w04 w02 w00
  169. sword  29692,  12299,  12299, -29692 ; w07 w05 w03 w01
  170. sword  22725, -22725,  22725,  22725 ; w14 w12 w10 w08
  171. sword -12299,  29692, -29692, -12299 ; w15 w13 w11 w09
  172. sword  31521,  17855,  26722, -31521 ; w22 w20 w18 w16
  173. sword  26722,   6270,  -6270, -17855 ; w23 w21 w19 w17
  174. sword  17855,   6270,   6270,  26722 ; w30 w28 w26 w24
  175. sword -31521,  26722, -17855, -31521 ; w31 w29 w27 w25
  177. ; Table for rows 2,6 - constants are multiplied by cos_2_16
  179. tab_i_26 sword  21407,  21407,  21407, -21407 ; movq-> w06 w04 w02 w00
  180. sword  27969,  11585,  11585, -27969 ; w07 w05 w03 w01
  181. sword  21407, -21407,  21407,  21407 ; w14 w12 w10 w08
  182. sword -11585,  27969, -27969, -11585 ; w15 w13 w11 w09
  183. sword  29692,  16819,  25172, -29692 ; w22 w20 w18 w16
  184. sword  25172,   5906,  -5906, -16819 ; w23 w21 w19 w17
  185. sword  16819,   5906,   5906,  25172 ; w30 w28 w26 w24
  186. sword -29692,  25172, -16819, -29692 ; w31 w29 w27 w25
  188. ; Table for rows 3,5 - constants are multiplied by cos_3_16
  190. tab_i_35 sword  19266,  19266,  19266, -19266 ; movq-> w06 w04 w02 w00
  191. sword  25172,  10426,  10426, -25172 ; w07 w05 w03 w01
  192. sword  19266, -19266,  19266,  19266 ; w14 w12 w10 w08
  193. sword -10426,  25172, -25172, -10426 ; w15 w13 w11 w09
  194. sword  26722,  15137,  22654, -26722 ; w22 w20 w18 w16
  195. sword  22654,   5315,  -5315, -15137 ; w23 w21 w19 w17
  196. sword  15137,   5315,   5315,  22654 ; w30 w28 w26 w24
  197. sword -26722,  22654, -15137, -26722 ; w31 w29 w27 w25
  199. ;-----------------------------------------------------------------------------
  201. DCT_8_INV_ROW_1 MACRO INP:REQ, OUT:REQ, TABLE:REQ, ROUNDER:REQ
  203. movq mm0, mptr [INP]  ; 0 ; x3 x2 x1 x0
  205. movq mm1, mptr [INP+8] ; 1 ; x7 x6 x5 x4
  206. movq mm2, mm0  ; 2 ; x3 x2 x1 x0
  208. movq mm3, mptr [TABLE] ; 3 ; w06 w04 w02 w00
  209. punpcklwd mm0, mm1  ; x5 x1 x4 x0
  211. movq mm5, mm0  ; 5 ; x5 x1 x4 x0
  212. punpckldq mm0, mm0  ; x4 x0 x4 x0
  214. movq mm4, mptr [TABLE+8]  ; 4 ; w07 w05 w03 w01
  215. punpckhwd mm2, mm1 ; 1 ; x7 x3 x6 x2
  217. pmaddwd mm3, mm0  ; x4*w06+x0*w04 x4*w02+x0*w00
  218. movq mm6, mm2  ; 6  ; x7 x3 x6 x2
  220. movq mm1, mptr [TABLE+32]  ; 1  ; w22 w20 w18 w16
  221. punpckldq mm2, mm2  ; x6 x2 x6 x2
  223. pmaddwd mm4, mm2  ; x6*w07+x2*w05 x6*w03+x2*w01
  224. punpckhdq mm5, mm5  ; x5 x1 x5 x1
  226. pmaddwd mm0, mptr [TABLE+16]  ; x4*w14+x0*w12 x4*w10+x0*w08
  227. punpckhdq mm6, mm6  ; x7 x3 x7 x3
  229. movq mm7, mptr [TABLE+40]  ; 7  ; w23 w21 w19 w17
  230. pmaddwd mm1, mm5  ; x5*w22+x1*w20 x5*w18+x1*w16
  232. paddd mm3, mptr [ROUNDER]  ; +rounder
  233. pmaddwd mm7, mm6  ; x7*w23+x3*w21 x7*w19+x3*w17
  235. pmaddwd mm2, mptr [TABLE+24]  ; x6*w15+x2*w13 x6*w11+x2*w09
  236. paddd mm3, mm4  ; 4  ; a1=sum(even1) a0=sum(even0)
  238. pmaddwd mm5, mptr [TABLE+48]  ; x5*w30+x1*w28 x5*w26+x1*w24
  239. movq mm4, mm3  ; 4  ; a1 a0
  241. pmaddwd mm6, mptr [TABLE+56]  ; x7*w31+x3*w29 x7*w27+x3*w25
  242. paddd mm1, mm7  ; 7  ; b1=sum(odd1) b0=sum(odd0)
  244. paddd mm0, mptr [ROUNDER] ; +rounder
  245. psubd mm3, mm1  ; a1-b1 a0-b0
  247. psrad mm3, SHIFT_INV_ROW  ; y6=a1-b1 y7=a0-b0
  248. paddd mm1, mm4  ; 4  ; a1+b1 a0+b0
  250. paddd mm0, mm2  ; 2  ; a3=sum(even3) a2=sum(even2)
  251. psrad mm1, SHIFT_INV_ROW  ; y1=a1+b1 y0=a0+b0
  253. paddd mm5, mm6  ; 6  ; b3=sum(odd3) b2=sum(odd2)
  254. movq mm4, mm0  ; 4  ; a3 a2
  256. paddd mm0, mm5  ; a3+b3 a2+b2
  257. psubd mm4, mm5  ; 5  ; a3-b3 a2-b2
  259. psrad mm0, SHIFT_INV_ROW  ; y3=a3+b3 y2=a2+b2
  260. psrad mm4, SHIFT_INV_ROW  ; y4=a3-b3 y5=a2-b2
  262. packssdw mm1, mm0  ; 0  ; y3 y2 y1 y0
  263. packssdw mm4, mm3  ; 3  ; y6 y7 y4 y5
  265. movq mm7, mm4  ; 7  ; y6 y7 y4 y5
  266. psrld mm4, 16  ; 0 y6 0 y4
  268. pslld mm7, 16  ; y7 0 y5 0
  269. movq mptr [OUT], mm1  ; 1  ; save y3 y2 y1 y0
  270.                              
  271. por mm7, mm4  ; 4  ; y7 y6 y5 y4
  272. movq mptr [OUT+8], mm7  ; 7  ; save y7 y6 y5 y4
  273. ENDM
  275. ;=============================================================================
  276. ; code for Pentium III
  277. ;=============================================================================
  279. ; Table for rows 0,4 - constants are multiplied by cos_4_16
  281. tab_i_04_s  sword 16384, 21407, 16384, 8867 ; movq-> w05 w04 w01 w00
  282. sword 16384, 8867, -16384, -21407 ; w07 w06 w03 w02
  283. sword 16384, -8867, 16384, -21407 ; w13 w12 w09 w08
  284. sword -16384, 21407, 16384, -8867 ; w15 w14 w11 w10
  285. sword 22725, 19266, 19266, -4520 ; w21 w20 w17 w16
  286. sword 12873, 4520, -22725, -12873 ; w23 w22 w19 w18
  287. sword 12873, -22725, 4520, -12873 ; w29 w28 w25 w24
  288. sword 4520, 19266, 19266, -22725 ; w31 w30 w27 w26
  290. ; Table for rows 1,7 - constants are multiplied by cos_1_16
  292. tab_i_17_s sword 22725, 29692, 22725, 12299 ; movq-> w05 w04 w01 w00
  293. sword 22725, 12299, -22725, -29692 ; w07 w06 w03 w02
  294. sword 22725, -12299, 22725, -29692 ; w13 w12 w09 w08
  295. sword -22725, 29692, 22725, -12299 ; w15 w14 w11 w10
  296. sword 31521, 26722, 26722, -6270 ; w21 w20 w17 w16
  297. sword 17855, 6270, -31521, -17855 ; w23 w22 w19 w18
  298. sword 17855, -31521, 6270, -17855 ; w29 w28 w25 w24
  299. sword 6270, 26722, 26722, -31521 ; w31 w30 w27 w26
  301. ; Table for rows 2,6 - constants are multiplied by cos_2_16
  303. tab_i_26_s sword 21407, 27969, 21407, 11585 ; movq-> w05 w04 w01 w00
  304. sword 21407, 11585, -21407, -27969 ; w07 w06 w03 w02
  305. sword 21407, -11585, 21407, -27969 ; w13 w12 w09 w08
  306. sword -21407, 27969, 21407, -11585 ; w15 w14 w11 w10
  307. sword 29692, 25172, 25172, -5906 ; w21 w20 w17 w16
  308. sword 16819, 5906, -29692, -16819 ; w23 w22 w19 w18
  309. sword 16819, -29692, 5906, -16819 ; w29 w28 w25 w24
  310. sword 5906, 25172, 25172, -29692 ; w31 w30 w27 w26
  312. ; Table for rows 3,5 - constants are multiplied by cos_3_16
  314. tab_i_35_s sword 19266, 25172, 19266, 10426 ; movq-> w05 w04 w01 w00
  315. sword 19266, 10426, -19266, -25172 ; w07 w06 w03 w02
  316. sword 19266, -10426, 19266, -25172 ; w13 w12 w09 w08
  317. sword -19266, 25172, 19266, -10426 ; w15 w14 w11 w10
  318. sword 26722, 22654, 22654, -5315 ; w21 w20 w17 w16
  319. sword 15137, 5315, -26722, -15137 ; w23 w22 w19 w18
  320. sword 15137, -26722, 5315, -15137 ; w29 w28 w25 w24
  321. sword 5315, 22654, 22654, -26722 ; w31 w30 w27 w26
  323. ;-----------------------------------------------------------------------------
  325. DCT_8_INV_ROW_1_s MACRO INP:REQ, OUT:REQ, TABLE:REQ, ROUNDER:REQ
  327. movq  mm0, mptr [INP]  ; 0  ; x3 x2 x1 x0
  329. movq  mm1, mptr [INP+8] ; 1  ; x7 x6 x5 x4
  330. movq  mm2, mm0  ; 2  ; x3 x2 x1 x0
  332. movq  mm3, mptr [TABLE]  ; 3  ; w05 w04 w01 w00
  333. pshufw mm0, mm0, 10001000b  ; x2 x0 x2 x0
  335. movq  mm4, mptr [TABLE+8]  ; 4  ; w07 w06 w03 w02
  336. movq  mm5, mm1 ; 5  ; x7 x6 x5 x4
  337. pmaddwd mm3, mm0  ; x2*w05+x0*w04 x2*w01+x0*w00
  339. movq  mm6, mptr [TABLE+32]  ; 6  ; w21 w20 w17 w16
  340. pshufw  mm1, mm1, 10001000b  ; x6 x4 x6 x4
  341. pmaddwd mm4, mm1  ; x6*w07+x4*w06 x6*w03+x4*w02
  343. movq  mm7, mptr [TABLE+40]  ; 7  ; w23 w22 w19 w18
  344. pshufw  mm2, mm2, 11011101b  ; x3 x1 x3 x1
  345. pmaddwd mm6, mm2  ; x3*w21+x1*w20 x3*w17+x1*w16
  347. pshufw  mm5, mm5, 11011101b  ; x7 x5 x7 x5
  348. pmaddwd mm7, mm5  ; x7*w23+x5*w22 x7*w19+x5*w18
  350. paddd  mm3, mptr [ROUNDER]  ; +rounder
  352. pmaddwd mm0, mptr [TABLE+16]  ; x2*w13+x0*w12 x2*w09+x0*w08
  353. paddd  mm3, mm4  ; 4  ; a1=sum(even1) a0=sum(even0)
  355. pmaddwd mm1, mptr [TABLE+24]  ; x6*w15+x4*w14 x6*w11+x4*w10
  356. movq  mm4, mm3  ; 4  ; a1 a0
  358. pmaddwd mm2, mptr [TABLE+48]  ; x3*w29+x1*w28 x3*w25+x1*w24
  359. paddd  mm6, mm7  ; 7  ; b1=sum(odd1) b0=sum(odd0)
  361. pmaddwd mm5, mptr [TABLE+56]  ; x7*w31+x5*w30 x7*w27+x5*w26
  362. paddd mm3, mm6  ; a1+b1 a0+b0
  364. paddd mm0, mptr [ROUNDER]  ; +rounder
  365. psrad mm3, SHIFT_INV_ROW  ; y1=a1+b1 y0=a0+b0
  367. paddd mm0, mm1  ; 1  ; a3=sum(even3) a2=sum(even2)
  368. psubd mm4, mm6  ; 6  ; a1-b1 a0-b0
  370. movq mm7, mm0  ; 7  ; a3 a2
  371. paddd mm2, mm5  ; 5  ; b3=sum(odd3) b2=sum(odd2)
  373. paddd mm0, mm2  ; a3+b3 a2+b2
  374. psrad mm4, SHIFT_INV_ROW  ; y6=a1-b1 y7=a0-b0
  376. psubd mm7, mm2  ; 2  ; a3-b3 a2-b2
  377. psrad mm0, SHIFT_INV_ROW  ; y3=a3+b3 y2=a2+b2
  379. psrad mm7, SHIFT_INV_ROW  ; y4=a3-b3 y5=a2-b2
  381. packssdw mm3, mm0  ; 0  ; y3 y2 y1 y0
  383. packssdw mm7, mm4  ; 4  ; y6 y7 y4 y5
  385. movq mptr [OUT], mm3  ; 3  ; save y3 y2 y1 y0
  386. pshufw mm7, mm7, 10110001b  ; y7 y6 y5 y4
  388. movq mptr [OUT+8], mm7  ; 7  ; save y7 y6 y5 y4
  389. ENDM
  391. ;=============================================================================
  392. ;
  393. ;=============================================================================
  395. ;=============================================================================
  396. ;
  397. ; The first stage DCT 8x8 - forward DCTs of columns
  398. ;
  399. ; The outputs are multiplied
  400. ; for rows 0,4 - on cos_4_16,
  401. ; for rows 1,7 - on cos_1_16,
  402. ; for rows 2,6 - on cos_2_16,
  403. ; for rows 3,5 - on cos_3_16
  404. ; and are shifted to the left for rise of accuracy
  405. ;
  406. ;-----------------------------------------------------------------------------
  407. ;
  408. ; The 8-point scaled forward DCT algorithm (26a8m)
  409. ;
  410. ;-----------------------------------------------------------------------------
  411. ;
  412. ; #define DCT_8_FRW_COL(x, y)
  413. ;{
  414. ; short t0, t1, t2, t3, t4, t5, t6, t7;
  415. ; short tp03, tm03, tp12, tm12, tp65, tm65;
  416. ; short tp465, tm465, tp765, tm765;
  417. ;
  418. ; t0 = LEFT_SHIFT ( x[0] + x[7] );
  419. ; t1 = LEFT_SHIFT ( x[1] + x[6] );
  420. ; t2 = LEFT_SHIFT ( x[2] + x[5] );
  421. ; t3 = LEFT_SHIFT ( x[3] + x[4] );
  422. ; t4 = LEFT_SHIFT ( x[3] - x[4] );
  423. ; t5 = LEFT_SHIFT ( x[2] - x[5] );
  424. ; t6 = LEFT_SHIFT ( x[1] - x[6] );
  425. ; t7 = LEFT_SHIFT ( x[0] - x[7] );
  426. ;
  427. ; tp03 = t0 + t3;
  428. ; tm03 = t0 - t3;
  429. ; tp12 = t1 + t2;
  430. ; tm12 = t1 - t2;
  431. ;
  432. ; y[0] = tp03 + tp12;
  433. ; y[4] = tp03 - tp12;
  434. ;
  435. ; y[2] = tm03 + tm12 * tg_2_16;
  436. ; y[6] = tm03 * tg_2_16 - tm12;
  437. ;
  438. ; tp65 =(t6 +t5 )*cos_4_16;
  439. ; tm65 =(t6 -t5 )*cos_4_16;
  440. ;
  441. ; tp765 = t7 + tp65;
  442. ; tm765 = t7 - tp65;
  443. ; tp465 = t4 + tm65;
  444. ; tm465 = t4 - tm65;
  445. ;
  446. ; y[1] = tp765 + tp465 * tg_1_16;
  447. ; y[7] = tp765 * tg_1_16 - tp465;
  448. ; y[5] = tm765 * tg_3_16 + tm465;
  449. ; y[3] = tm765 - tm465 * tg_3_16;
  450. ;}
  451. ;
  452. ;=============================================================================
  453. DCT_8_FRW_COL_4 MACRO INP:REQ, OUT:REQ
  454. LOCAL x0, x1, x2, x3, x4, x5, x6, x7
  455. LOCAL y0, y1, y2, y3, y4, y5, y6, y7
  456. x0 equ [INP + 0*16]
  457. x1 equ [INP + 1*16]
  458. x2 equ [INP + 2*16]
  459. x3 equ [INP + 3*16]
  460. x4 equ [INP + 4*16]
  461. x5 equ [INP + 5*16]
  462. x6 equ [INP + 6*16]
  463. x7 equ [INP + 7*16]
  464. y0 equ [OUT + 0*16]
  465. y1 equ [OUT + 1*16]
  466. y2 equ [OUT + 2*16]
  467. y3 equ [OUT + 3*16]
  468. y4 equ [OUT + 4*16]
  469. y5 equ [OUT + 5*16]
  470. y6 equ [OUT + 6*16]
  471. y7 equ [OUT + 7*16]
  472. movq mm0, x1 ; 0 ; x1
  473. movq mm1, x6 ; 1 ; x6
  474. movq mm2, mm0 ; 2 ; x1
  475. movq mm3, x2 ; 3 ; x2
  476. paddsw mm0, mm1 ; t1 = x[1] + x[6]
  477. movq mm4, x5 ; 4 ; x5
  478. psllw mm0, SHIFT_FRW_COL ; t1
  479. movq mm5, x0 ; 5 ; x0
  480. paddsw mm4, mm3 ; t2 = x[2] + x[5]
  481. paddsw mm5, x7 ; t0 = x[0] + x[7]
  482. psllw mm4, SHIFT_FRW_COL ; t2
  483. movq mm6, mm0 ; 6 ; t1
  484. psubsw mm2, mm1 ; 1 ; t6 = x[1] - x[6]
  485. movq mm1, mptr tg_2_16 ; 1 ; tg_2_16
  486. psubsw mm0, mm4 ; tm12 = t1 - t2
  487. movq mm7, x3 ; 7 ; x3
  488. pmulhw mm1, mm0 ; tm12*tg_2_16
  489. paddsw mm7, x4 ; t3 = x[3] + x[4]
  490. psllw mm5, SHIFT_FRW_COL ; t0
  491. paddsw mm6, mm4 ; 4 ; tp12 = t1 + t2
  492. psllw mm7, SHIFT_FRW_COL ; t3
  493. movq mm4, mm5 ; 4 ; t0
  494. psubsw mm5, mm7 ; tm03 = t0 - t3
  495. paddsw mm1, mm5 ; y2 = tm03 + tm12*tg_2_16
  496. paddsw mm4, mm7 ; 7 ; tp03 = t0 + t3
  497. por mm1, mptr one_corr ; correction y2 +0.5
  498. psllw mm2, SHIFT_FRW_COL+1 ; t6
  499. pmulhw mm5, mptr tg_2_16 ; tm03*tg_2_16
  500. movq mm7, mm4 ; 7 ; tp03
  501. psubsw mm3, x5 ; t5 = x[2] - x[5]
  502. psubsw mm4, mm6 ; y4 = tp03 - tp12
  503. movq y2, mm1 ; 1 ; save y2
  504. paddsw mm7, mm6 ; 6 ; y0 = tp03 + tp12
  505. movq mm1, x3 ; 1 ; x3
  506. psllw mm3, SHIFT_FRW_COL+1 ; t5
  507. psubsw mm1, x4 ; t4 = x[3] - x[4]
  508. movq mm6, mm2 ; 6 ; t6
  509. movq y4, mm4 ; 4 ; save y4
  510. paddsw mm2, mm3 ; t6 + t5
  511. pmulhw mm2, mptr ocos_4_16 ; tp65 = (t6 + t5)*cos_4_16
  512. psubsw mm6, mm3 ; 3 ; t6 - t5
  513. pmulhw mm6, mptr ocos_4_16 ; tm65 = (t6 - t5)*cos_4_16
  514. psubsw mm5, mm0 ; 0 ; y6 = tm03*tg_2_16 - tm12
  515. por mm5, mptr one_corr ; correction y6 +0.5
  516. psllw mm1, SHIFT_FRW_COL ; t4
  517. por mm2, mptr one_corr ; correction tp65 +0.5
  518. movq mm4, mm1 ; 4 ; t4
  519. movq mm3, x0 ; 3 ; x0
  520. paddsw mm1, mm6 ; tp465 = t4 + tm65
  521. psubsw mm3, x7 ; t7 = x[0] - x[7]
  522. psubsw mm4, mm6 ; 6 ; tm465 = t4 - tm65
  523. movq mm0, mptr tg_1_16 ; 0 ; tg_1_16
  524. psllw mm3, SHIFT_FRW_COL ; t7
  525. movq mm6, mptr tg_3_16 ; 6 ; tg_3_16
  526. pmulhw mm0, mm1 ; tp465*tg_1_16
  527. movq y0, mm7 ; 7 ; save y0
  528. pmulhw mm6, mm4 ; tm465*tg_3_16
  529. movq y6, mm5 ; 5 ; save y6
  530. movq mm7, mm3 ; 7 ; t7
  531. movq mm5, mptr tg_3_16 ; 5 ; tg_3_16
  532. psubsw mm7, mm2 ; tm765 = t7 - tp65
  533. paddsw mm3, mm2 ; 2 ; tp765 = t7 + tp65
  534. pmulhw mm5, mm7 ; tm765*tg_3_16
  535. paddsw mm0, mm3 ; y1 = tp765 + tp465*tg_1_16
  536. paddsw mm6, mm4 ; tm465*tg_3_16
  537. pmulhw mm3, mptr tg_1_16 ; tp765*tg_1_16
  538. por mm0, mptr one_corr ; correction y1 +0.5
  539. paddsw mm5, mm7 ; tm765*tg_3_16
  540. psubsw mm7, mm6 ; 6 ; y3 = tm765 - tm465*tg_3_16
  541. movq y1, mm0 ; 0 ; save y1
  542. paddsw mm5, mm4 ; 4 ; y5 = tm765*tg_3_16 + tm465
  543. movq y3, mm7 ; 7 ; save y3
  544. psubsw mm3, mm1 ; 1 ; y7 = tp765*tg_1_16 - tp465
  545. movq y5, mm5 ; 5 ; save y5
  546. movq y7, mm3 ; 3 ; save y7
  547. ENDM
  549. DCT_8_INV_COL_4 MACRO INP:REQ, OUT:REQ
  550. movq mm0, qword ptr tg_3_16
  552. movq mm3, qword ptr [INP+16*3]
  553. movq mm1, mm0 ; tg_3_16
  555. movq mm5, qword ptr [INP+16*5]
  556. pmulhw mm0, mm3 ; x3*(tg_3_16-1)
  558. movq mm4, qword ptr tg_1_16
  559. pmulhw mm1, mm5 ; x5*(tg_3_16-1)
  561. movq mm7, qword ptr [INP+16*7]
  562. movq mm2, mm4 ; tg_1_16
  564. movq mm6, qword ptr [INP+16*1]
  565. pmulhw mm4, mm7 ; x7*tg_1_16
  567. paddsw mm0, mm3 ; x3*tg_3_16
  568. pmulhw mm2, mm6 ; x1*tg_1_16
  570. paddsw mm1, mm3 ; x3+x5*(tg_3_16-1)
  571. psubsw mm0, mm5 ; x3*tg_3_16-x5 = tm35
  573. movq mm3, qword ptr ocos_4_16
  574. paddsw mm1, mm5 ; x3+x5*tg_3_16 = tp35
  576. paddsw mm4, mm6 ; x1+tg_1_16*x7 = tp17
  577. psubsw mm2, mm7 ; x1*tg_1_16-x7 = tm17
  579. movq mm5, mm4 ; tp17
  580. movq mm6, mm2 ; tm17
  582. paddsw mm5, mm1 ; tp17+tp35 = b0
  583. psubsw mm6, mm0 ; tm17-tm35 = b3
  585. psubsw mm4, mm1 ; tp17-tp35 = t1
  586. paddsw mm2, mm0 ; tm17+tm35 = t2
  588. movq mm7, qword ptr tg_2_16
  589. movq mm1, mm4 ; t1
  591. ; movq qword ptr [SCRATCH+0], mm5 ; save b0
  592. movq qword ptr [OUT+3*16], mm5 ; save b0
  593. paddsw mm1, mm2 ; t1+t2
  595. ; movq qword ptr [SCRATCH+8], mm6 ; save b3
  596. movq qword ptr [OUT+5*16], mm6 ; save b3
  597. psubsw mm4, mm2 ; t1-t2
  599. movq mm5, qword ptr [INP+2*16]
  600. movq mm0, mm7 ; tg_2_16
  602. movq mm6, qword ptr [INP+6*16]
  603. pmulhw mm0, mm5 ; x2*tg_2_16
  605. pmulhw mm7, mm6 ; x6*tg_2_16
  606. ; slot
  607. pmulhw mm1, mm3 ; ocos_4_16*(t1+t2) = b1/2
  608. ; slot
  609. movq mm2, qword ptr [INP+0*16]
  610. pmulhw mm4, mm3 ; ocos_4_16*(t1-t2) = b2/2
  612. psubsw mm0, mm6 ; t2*tg_2_16-x6 = tm26
  613. movq mm3, mm2 ; x0
  615. movq mm6, qword ptr [INP+4*16]
  616. paddsw mm7, mm5 ; x2+x6*tg_2_16 = tp26
  618. paddsw mm2, mm6 ; x0+x4 = tp04
  619. psubsw mm3, mm6 ; x0-x4 = tm04
  621. movq mm5, mm2 ; tp04
  622. movq mm6, mm3 ; tm04
  624. psubsw mm2, mm7 ; tp04-tp26 = a3
  625. paddsw mm3, mm0 ; tm04+tm26 = a1
  627. paddsw mm1, mm1 ; b1
  628. paddsw mm4, mm4 ; b2
  630. paddsw mm5, mm7 ; tp04+tp26 = a0
  631. psubsw mm6, mm0 ; tm04-tm26 = a2
  633. movq mm7, mm3 ; a1
  634. movq mm0, mm6 ; a2
  636. paddsw mm3, mm1 ; a1+b1
  637. paddsw mm6, mm4 ; a2+b2
  639. psraw mm3, SHIFT_INV_COL ; dst1
  640. psubsw mm7, mm1 ; a1-b1
  642. psraw mm6, SHIFT_INV_COL ; dst2
  643. psubsw mm0, mm4 ; a2-b2
  645. ; movq mm1, qword ptr [SCRATCH+0] ; load b0
  646. movq mm1, qword ptr [OUT+3*16] ; load b0
  647. psraw mm7, SHIFT_INV_COL ; dst6
  649. movq mm4, mm5 ; a0
  650. psraw mm0, SHIFT_INV_COL ; dst5
  652. movq qword ptr [OUT+1*16], mm3
  653. paddsw mm5, mm1 ; a0+b0
  655. movq qword ptr [OUT+2*16], mm6
  656. psubsw mm4, mm1 ; a0-b0
  658. ; movq mm3, qword ptr [SCRATCH+8] ; load b3
  659. movq mm3, qword ptr [OUT+5*16] ; load b3
  660. psraw mm5, SHIFT_INV_COL ; dst0
  662. movq mm6, mm2 ; a3
  663. psraw mm4, SHIFT_INV_COL ; dst7
  665. movq qword ptr [OUT+5*16], mm0
  666. paddsw mm2, mm3 ; a3+b3
  668. movq qword ptr [OUT+6*16], mm7
  669. psubsw mm6, mm3 ; a3-b3
  671. movq qword ptr [OUT+0*16], mm5
  672. psraw mm2, SHIFT_INV_COL ; dst3
  674. movq qword ptr [OUT+7*16], mm4
  675. psraw mm6, SHIFT_INV_COL ; dst4
  677. movq qword ptr [OUT+3*16], mm2
  679. movq qword ptr [OUT+4*16], mm6
  680. ENDM
  682. _TEXT SEGMENT PARA PUBLIC USE32 'CODE'
  684. ;
  685. ; extern "C" __fastcall void idct8x8_mmx (short *src_result);
  686. ;
  687. public  @MMX_IDCT@4
  689. @MMX_IDCT@4 proc near
  690. mov     eax, ecx          ; source
  692. DCT_8_INV_ROW_1 [eax+0], [eax+0], tab_i_04, rounder_0
  693. DCT_8_INV_ROW_1 [eax+16], [eax+16], tab_i_17, rounder_1
  694. DCT_8_INV_ROW_1 [eax+32], [eax+32], tab_i_26, rounder_2
  695. DCT_8_INV_ROW_1 [eax+48], [eax+48], tab_i_35, rounder_3
  696. DCT_8_INV_ROW_1 [eax+64], [eax+64], tab_i_04, rounder_4
  697. DCT_8_INV_ROW_1 [eax+80], [eax+80], tab_i_35, rounder_5
  698. DCT_8_INV_ROW_1 [eax+96], [eax+96], tab_i_26, rounder_6
  699. DCT_8_INV_ROW_1 [eax+112], [eax+112], tab_i_17, rounder_7
  701. DCT_8_INV_COL_4 [eax+0],[eax+0]
  702. DCT_8_INV_COL_4 [eax+8],[eax+8]
  704. ret    
  706. @MMX_IDCT@4 ENDP
  708. _TEXT ENDS
  710. _TEXT SEGMENT PARA PUBLIC USE32 'CODE'
  712. ;
  713. ; extern "C" __fastcall void idct8x8_sse (short *src_result);
  714. ;
  715. public  @SSEMMX_IDCT@4
  717. @SSEMMX_IDCT@4 proc near
  718. mov     eax, ecx          ; source
  720. DCT_8_INV_ROW_1_s [eax+0], [eax+0], tab_i_04_s, rounder_0
  721. DCT_8_INV_ROW_1_s [eax+16], [eax+16], tab_i_17_s, rounder_1
  722. DCT_8_INV_ROW_1_s [eax+32], [eax+32], tab_i_26_s, rounder_2
  723. DCT_8_INV_ROW_1_s [eax+48], [eax+48], tab_i_35_s, rounder_3
  724. DCT_8_INV_ROW_1_s [eax+64], [eax+64], tab_i_04_s, rounder_4
  725. DCT_8_INV_ROW_1_s [eax+80], [eax+80], tab_i_35_s, rounder_5
  726. DCT_8_INV_ROW_1_s [eax+96], [eax+96], tab_i_26_s, rounder_6
  727. DCT_8_INV_ROW_1_s [eax+112], [eax+112], tab_i_17_s, rounder_7
  729. DCT_8_INV_COL_4 [eax+0],[eax+0]
  730. DCT_8_INV_COL_4 [eax+8],[eax+8]
  732. ret
  734. @SSEMMX_IDCT@4 ENDP
  736. _TEXT ENDS
  738. END