弱点检测代码

开发平台：

ASP/ASPX

Cls_DB.asp：源码内容

							<%
'==========================================
'文 件 名：Cls_DB.asp
'文件用途：数据库函数类
'版权所有：方卡在线
'==========================================
Class Cls_DB
	Private ConnStr
	Private DBpath,DBLink,DBi
	'==============================
	'函 数 名：DB_Conn
	'作    用：数据库连接函数
	'参    数：
	'==============================
	Private Sub DB_Conn()
		On Error Resume Next
		Set Conn = Server.CreateObject("Adodb.Connection")
		ConnStr="Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(SiteData)
		Conn.Open ConnStr
		If Err Then
			Call AspErr()
		End If
	End Sub
	
	'==============================
	'函 数 名：PaperDB_Open
	'作    用：考试项目数据库连接函数
	'参    数：考试项目PaperId
	'==============================
	Public Sub PaperDB_Open(PaperId)
		On Error Resume Next
		Set PaperConn = Server.CreateObject("Adodb.Connection")
		ConnStr="Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(SiteDir&SiteDBDir&"/Paper"&PaperId&".mdb")
		PaperConn.Open ConnStr
		If Err Then
			Call AspErr()
		End If
	End Sub
	'==============================
	'函 数 名：DB_Open
	'作    用：创建读取对象
	'参    数：
	'==============================
	Public Sub DB_Open()
		Call DB_Conn()
		Set Rs=Server.Createobject("Adodb.RecordSet")
	End Sub
	
	'==============================
	'函 数 名：DB_Close
	'作    用：关闭读取对象
	'参    数：
	'==============================	
	Public Sub DB_Close()
		Set Rs=Nothing
		If IsObject(Conn) Then Conn.Close
		Set Conn = Nothing
	End Sub
	
	'==============================
	'函 数 名：PaperDB_Close
	'作    用：关闭读取考试项目对象
	'参    数：
	'==============================	
	Public Sub PaperDB_Close()
		If IsObject(PaperConn) Then PaperConn.Close
		Set PaperConn = Nothing
	End Sub
	
	'==============================
	'函 数 名：AspErr
	'作    用：连接报错
	'参    数：
	'==============================	
	Private Sub AspErr()
		DBLink = Request.ServerVariables("url")
		DBLink = Split(DBLink,"/")
		For DBi = 0 To Ubound(DBLink)-1
			DBpath = DBpath&DBLink(DBi)&"/"
		Next
		Response.Write "<body style='font-size:12px'>"
		Response.Write "错 误 号：" & Err.Number & "<br />"
		Response.Write "错误描述：" & Err.Description & "<br />"
		Response.Write "错误来源：" & Err.Source & "<br />"
		Response.Write "如果打开任意页面为这个提示可能原因为Inc/Conn.asp系统目录SiteDir或SiteDBDir的值设置错误！<br />"
		Response.Write "如果您正在安装系统或者移动了系统目录，<a href='Install.asp'>请点此进行安装</a>！<br />"
		Response.Write "如果您处理后仍然错误，请联系方卡在线，QQ861118936<br />"
		Response.Write "</body>"
		Err.Clear
		Response.End
	End Sub
End Class
%>

						