手机WAP编程

开发平台：
ASP/ASPX

Checker.asp：源码内容
							<!--#include file="../admin_sb.asp"-->
<%
'************** ASPSecurity  服务器信息探测插件 ****
' Copyright 2006
' Create:2006-7-25
' Update:2006-7-29
'***************************************************
%>
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" rev="stylesheet" href="../inc/control.css" type="text/css" media="all" />
</head>
<body class="ContentBody">
<div class="MainDiv">
<table width="100%" border="0" cellpadding="0" cellspacing="0" class="CContent">
  <tr>
    <th class="CTitle">雷客图ASP站长安全助手 服务器组件和信息探测
  </tr>
  <tr>
    <td class="CPanel">
        <div id="updateInfo" style="background:ffffe1;border:1px solid #89441f;padding:4px;display:none"></div>
	<table width="100%" border="0" cellpadding="0" cellspacing="0">
	 <tr>
		 <td valign="top" style="padding:5px;width:140px"><img src="../images/Icon/ControlPanel.png" width="128" height="128"/></td>
		 <td valign="top">		 <div align="left" style="padding:5px;line-height:170%;clear:both;font-size:12px">
		     <p></p>
		     <table width="80%"  border="0"  style="padding:5px;line-height:170%;clear:both;font-size:12px">
               <tr>
                 <td colspan="2"><div align="center"><strong>服务器信息</strong></div></td>
                 </tr>
               <tr>
                 <td width="25%"><div align="center">服务器名</div></td>
                 <td width="75%">&nbsp;<%=Request.ServerVariables("SERVER_NAME")%></td>
               </tr>
               <tr>
                 <td><div align="center">服务器IP</div></td>
                 <td>&nbsp;<%=Request.ServerVariables("LOCAL_ADDR")%></td>
               </tr>
               <tr>
                 <td><div align="center">服务器端口</div></td>
                 <td>&nbsp;<%=Request.ServerVariables("SERVER_PORT")%></td>
               </tr>
               <tr>
                 <td><div align="center">服务器时间</div></td>
                 <td>&nbsp;<%=Now()%></td>
               </tr>
               <tr>
                 <td><div align="center">IIS版本</div></td>
                 <td>&nbsp;<%=Request.ServerVariables("SERVER_SOFTWARE")%></td>
               </tr>
               <tr>
                 <td><div align="center">脚本超时时间</div></td>
                 <td>&nbsp;<%=Server.ScriptTimeout%> 秒</td>
               </tr>
               <tr>
                 <td><div align="center">Session过期时间</div></td>
                 <td>&nbsp;<%=session.Timeout%> 分钟</td>
               </tr>
               <tr>
                 <td><div align="center">脚本解释引擎</div></td>
                 <td>&nbsp;<%=ScriptEngine & "/"& ScriptEngineMajorVersion &"."&ScriptEngineMinorVersion&"."& ScriptEngineBuildVersion %></td>
               </tr>
               <tr>
                 <td><div align="center">站点根目录</div></td>
                 <td>&nbsp;<%=Server.MapPath("")%></td>
               </tr>
               <tr>
                 <td colspan="2"><div align="center"><strong>服务器组件探测</strong></div></td>
                </tr>
		<%
		Dim aObj(8)
		aObj(0) = "Scripting.FileSystemObject"
		aObj(1) = "Adodb.Stream"
		aObj(2) = "Shel" & anti & "l.App" & anti & "lication"
		aObj(3) = "WScr" & anti & "ipt.Shell"
		aObj(4) = "WScript.Network"
		aObj(5) = "ADOX.Catalog"
		aObj(6) = "JMail.SmtpMail"
		aObj(7) = "Microso" & anti & "ft.XMLHTTP"
		aObj(8) = "Msxml2.ServerXMLHTTP"
		On Error Resume Next
		For Each x In aObj
			Set objTmp = Server.CreateObject(x)
			If Err <> -2147221005 Then
				IsSupport = "√"
			Else
				IsSupport = "×"
			End If
			Err.Clear
			Response.Write "<tr><td><div align=""center"">"&x&"</div></td><td>&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;"&IsSupport&"</td></tr>"
		Next
		
	if getIP()<>request.ServerVariables("REMOTE_ADDR") then
			CIP=getIP()
			CP=request.ServerVariables("REMOTE_ADDR")
	else
			CIP=request.ServerVariables("REMOTE_ADDR")
			CP="匿名代理或者未使用代理"
	end if
		%>
               <tr>
                 <td colspan="2"><div align="center"><strong>客户端交互信息</strong></div></td>
                 </tr>
               <tr>
                 <td><div align="center">客户端IP</div></td>
                 <td>&nbsp;<%=CIP%></td>
               </tr>
               <tr>
                 <td><div align="center">代理IP</div></td>
                 <td>&nbsp;<%=CP%></td>
               </tr>
               <tr>
                 <td><div align="center">客户端浏览器标识</div></td>
                 <td>&nbsp;<%=request.ServerVariables("HTTP_USER_AGENT")%></td>
               </tr>
             </table>
		     <p><br/>  
                </p>
		 <a href="#" onClick="javascript:history.go(-1);">返回插件首页</a></div>    	  
	 </tr>
	</table>
</td></tr></table>
</div>
</body>
</html>
<%
	
Function getIP() 
    Dim strIPAddr
    If Request.ServerVariables("HTTP_X_FORWARDED_FOR") = "" OR InStr(Request.ServerVariables("HTTP_X_FORWARDED_FOR"), "unknown") > 0 Then
        strIPAddr = Request.ServerVariables("REMOTE_ADDR")
    ElseIf InStr(Request.ServerVariables("HTTP_X_FORWARDED_FOR"), ",") > 0 Then
        strIPAddr = Mid(Request.ServerVariables("HTTP_X_FORWARDED_FOR"), 1, InStr(Request.ServerVariables("HTTP_X_FORWARDED_FOR"), ",")-1)
    ElseIf InStr(Request.ServerVariables("HTTP_X_FORWARDED_FOR"), ";") > 0 Then
        strIPAddr = Mid(Request.ServerVariables("HTTP_X_FORWARDED_FOR"), 1, InStr(Request.ServerVariables("HTTP_X_FORWARDED_FOR"), ";")-1)
    Else
        strIPAddr = Request.ServerVariables("HTTP_X_FORWARDED_FOR")
    End If
    getIP = Trim(Mid(strIPAddr, 1, 30))
End Function
%>

						