开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 多媒体 > Audio > 查看源码
deblock-a.asm
资源名称：chapter15.rar　[点击查看]
上传用户：hjq518
上传日期：2021-12-09
资源大小：5084k
文件大小：13k
源码类别：

Audio

开发平台：

Visual C++

deblock-a.asm：源码内容
  1. ;*****************************************************************************
  2. ;* deblock-a.asm: h264 encoder library
  3. ;*****************************************************************************
  4. ;* Copyright (C) 2005 x264 project
  5. ;*
  6. ;* Authors: Loren Merritt <lorenm@u.washington.edu>
  7. ;*
  8. ;* This program is free software; you can redistribute it and/or modify
  9. ;* it under the terms of the GNU General Public License as published by
  10. ;* the Free Software Foundation; either version 2 of the License, or
  11. ;* (at your option) any later version.
  12. ;*
  13. ;* This program is distributed in the hope that it will be useful,
  14. ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  15. ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16. ;* GNU General Public License for more details.
  17. ;*
  18. ;* You should have received a copy of the GNU General Public License
  19. ;* along with this program; if not, write to the Free Software
  20. ;* Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111, USA.
  21. ;*****************************************************************************
  23. BITS 64
  25. %include "amd64inc.asm"
  27. SECTION .rodata align=16
  28. pb_01: times 16 db 0x01
  29. pb_3f: times 16 db 0x3f
  30. pb_ff: times 16 db 0xff
  32. SECTION .text
  33. cglobal x264_deblock_v_luma_sse2
  34. cglobal x264_deblock_h_luma_sse2
  35. cglobal x264_deblock_v_chroma_mmxext
  36. cglobal x264_deblock_h_chroma_mmxext
  37. cglobal x264_deblock_v_chroma_intra_mmxext
  38. cglobal x264_deblock_h_chroma_intra_mmxext
  40. ; expands to [base],...,[base+7*stride]
  41. %define PASS8ROWS(base, base3, stride, stride3) 
  42.     [base], [base+stride], [base+stride*2], [base3], 
  43.     [base3+stride], [base3+stride*2], [base3+stride3], [base3+stride*4]
  45. ; in: 8 rows of 4 bytes in %1..%8
  46. ; out: 4 rows of 8 bytes in mm0..mm3
  47. %macro TRANSPOSE4x8_LOAD 8
  48.     movd       mm0, %1
  49.     movd       mm2, %2
  50.     movd       mm1, %3
  51.     movd       mm3, %4
  52.     punpcklbw  mm0, mm2
  53.     punpcklbw  mm1, mm3
  54.     movq       mm2, mm0
  55.     punpcklwd  mm0, mm1
  56.     punpckhwd  mm2, mm1
  58.     movd       mm4, %5
  59.     movd       mm6, %6
  60.     movd       mm5, %7
  61.     movd       mm7, %8
  62.     punpcklbw  mm4, mm6
  63.     punpcklbw  mm5, mm7
  64.     movq       mm6, mm4
  65.     punpcklwd  mm4, mm5
  66.     punpckhwd  mm6, mm5
  68.     movq       mm1, mm0
  69.     movq       mm3, mm2
  70.     punpckldq  mm0, mm4
  71.     punpckhdq  mm1, mm4
  72.     punpckldq  mm2, mm6
  73.     punpckhdq  mm3, mm6
  74. %endmacro
  76. ; in: 4 rows of 8 bytes in mm0..mm3
  77. ; out: 8 rows of 4 bytes in %1..%8
  78. %macro TRANSPOSE8x4_STORE 8
  79.     movq       mm4, mm0
  80.     movq       mm5, mm1
  81.     movq       mm6, mm2
  82.     punpckhdq  mm4, mm4
  83.     punpckhdq  mm5, mm5
  84.     punpckhdq  mm6, mm6
  86.     punpcklbw  mm0, mm1
  87.     punpcklbw  mm2, mm3
  88.     movq       mm1, mm0
  89.     punpcklwd  mm0, mm2
  90.     punpckhwd  mm1, mm2
  91.     movd       %1,  mm0
  92.     punpckhdq  mm0, mm0
  93.     movd       %2,  mm0
  94.     movd       %3,  mm1
  95.     punpckhdq  mm1, mm1
  96.     movd       %4,  mm1
  98.     punpckhdq  mm3, mm3
  99.     punpcklbw  mm4, mm5
  100.     punpcklbw  mm6, mm3
  101.     movq       mm5, mm4
  102.     punpcklwd  mm4, mm6
  103.     punpckhwd  mm5, mm6
  104.     movd       %5,  mm4
  105.     punpckhdq  mm4, mm4
  106.     movd       %6,  mm4
  107.     movd       %7,  mm5
  108.     punpckhdq  mm5, mm5
  109.     movd       %8,  mm5
  110. %endmacro
  112. %macro SBUTTERFLY 4
  113.     movq       %4, %2
  114.     punpckl%1  %2, %3
  115.     punpckh%1  %4, %3
  116. %endmacro
  118. ; in: 8 rows of 8 (only the middle 6 pels are used) in %1..%8
  119. ; out: 6 rows of 8 in [%9+0*16] .. [%9+5*16]
  120. %macro TRANSPOSE6x8_MEM 9
  121.     movq  mm0, %1
  122.     movq  mm1, %3
  123.     movq  mm2, %5
  124.     movq  mm3, %7
  125.     SBUTTERFLY bw, mm0, %2, mm4
  126.     SBUTTERFLY bw, mm1, %4, mm5
  127.     SBUTTERFLY bw, mm2, %6, mm6
  128.     movq  [%9+0x10], mm5
  129.     SBUTTERFLY bw, mm3, %8, mm7
  130.     SBUTTERFLY wd, mm0, mm1, mm5
  131.     SBUTTERFLY wd, mm2, mm3, mm1
  132.     punpckhdq mm0, mm2
  133.     movq  [%9+0x00], mm0
  134.     SBUTTERFLY wd, mm4, [%9+0x10], mm3
  135.     SBUTTERFLY wd, mm6, mm7, mm2
  136.     SBUTTERFLY dq, mm4, mm6, mm0
  137.     SBUTTERFLY dq, mm5, mm1, mm7
  138.     punpckldq mm3, mm2
  139.     movq  [%9+0x10], mm5
  140.     movq  [%9+0x20], mm7
  141.     movq  [%9+0x30], mm4
  142.     movq  [%9+0x40], mm0
  143.     movq  [%9+0x50], mm3
  144. %endmacro
  146. ; out: %4 = |%1-%2|>%3
  147. ; clobbers: %5
  148. %macro DIFF_GT 6
  149.     mov%1   %6, %3
  150.     mov%1   %5, %2
  151.     psubusb %6, %2
  152.     psubusb %5, %3
  153.     por     %5, %6
  154.     psubusb %5, %4
  155. %endmacro
  156. %macro DIFF_GT_MMX 5
  157.     DIFF_GT q, %1, %2, %3, %4, %5
  158. %endmacro
  159. %macro DIFF_GT_SSE2 5
  160.     DIFF_GT dqa, %1, %2, %3, %4, %5
  161. %endmacro
  163. ; in: mm0=p1 mm1=p0 mm2=q0 mm3=q1 %1=alpha-1 %2=beta-1
  164. ; out: mm5=beta-1, mm7=mask
  165. ; clobbers: mm4,mm6
  166. %macro LOAD_MASK_MMX 2
  167.     movd     mm4, %1
  168.     movd     mm5, %2
  169.     pshufw   mm4, mm4, 0
  170.     pshufw   mm5, mm5, 0
  171.     packuswb mm4, mm4  ; 8x alpha-1
  172.     packuswb mm5, mm5  ; 8x beta-1
  173.     DIFF_GT_MMX  mm1, mm2, mm4, mm7, mm6 ; |p0-q0| > alpha-1
  174.     DIFF_GT_MMX  mm0, mm1, mm5, mm4, mm6 ; |p1-p0| > beta-1
  175.     por      mm7, mm4
  176.     DIFF_GT_MMX  mm3, mm2, mm5, mm4, mm6 ; |q1-q0| > beta-1
  177.     por      mm7, mm4
  178.     pxor     mm6, mm6
  179.     pcmpeqb  mm7, mm6
  180. %endmacro
  181. %macro LOAD_MASK_SSE2 2
  182.     movd     xmm4, %1
  183.     movd     xmm5, %2
  184.     pshuflw  xmm4, xmm4, 0
  185.     pshuflw  xmm5, xmm5, 0
  186.     punpcklqdq xmm4, xmm4
  187.     punpcklqdq xmm5, xmm5
  188.     packuswb xmm4, xmm4  ; 16x alpha-1
  189.     packuswb xmm5, xmm5  ; 16x beta-1
  190.     DIFF_GT_SSE2  xmm1, xmm2, xmm4, xmm7, xmm6 ; |p0-q0| > alpha-1
  191.     DIFF_GT_SSE2  xmm0, xmm1, xmm5, xmm4, xmm6 ; |p1-p0| > beta-1
  192.     por      xmm7, xmm4
  193.     DIFF_GT_SSE2  xmm3, xmm2, xmm5, xmm4, xmm6 ; |q1-q0| > beta-1
  194.     por      xmm7, xmm4
  195.     pxor     xmm6, xmm6
  196.     pcmpeqb  xmm7, xmm6
  197. %endmacro
  199. ; in: mm0=p1 mm1=p0 mm2=q0 mm3=q1 mm7=(tc&mask)
  200. ; out: mm1=p0' mm2=q0'
  201. ; clobbers: mm0,3-6
  202. %macro DEBLOCK_P0_Q0 2
  203.     ; a = q0^p0^((p1-q1)>>2)
  204.     mov%1   %2m4, %2m0
  205.     psubb   %2m4, %2m3
  206.     psrlw   %2m4, 2
  207.     pxor    %2m4, %2m1
  208.     pxor    %2m4, %2m2
  209.     ; b = p0^(q1>>2)
  210.     psrlw   %2m3, 2
  211.     pand    %2m3, [pb_3f GLOBAL]
  212.     mov%1   %2m5, %2m1
  213.     pxor    %2m5, %2m3
  214.     ; c = q0^(p1>>2)
  215.     psrlw   %2m0, 2
  216.     pand    %2m0, [pb_3f GLOBAL]
  217.     mov%1   %2m6, %2m2
  218.     pxor    %2m6, %2m0
  219.     ; d = (c^b) & ~(b^a) & 1
  220.     pxor    %2m6, %2m5
  221.     pxor    %2m5, %2m4
  222.     pandn   %2m5, %2m6
  223.     pand    %2m5, [pb_01 GLOBAL]
  224.     ; delta = (((q0 - p0 ) << 2) + (p1 - q1) + 4) >> 3
  225.     ;       = (avg(q0, p1>>2) + (d&a))
  226.     ;       - (avg(p0, q1>>2) + (d^(d&a)))
  227.     pavgb   %2m0, %2m2
  228.     pand    %2m4, %2m5
  229.     paddusb %2m0, %2m4
  230.     pavgb   %2m3, %2m1
  231.     pxor    %2m4, %2m5
  232.     paddusb %2m3, %2m4
  233.     ; p0 += clip(delta, -tc0, tc0)
  234.     ; q0 -= clip(delta, -tc0, tc0)
  235.     mov%1   %2m4, %2m0
  236.     psubusb %2m0, %2m3
  237.     psubusb %2m3, %2m4
  238.     pminub  %2m0, %2m7
  239.     pminub  %2m3, %2m7
  240.     paddusb %2m1, %2m0
  241.     paddusb %2m2, %2m3
  242.     psubusb %2m1, %2m3
  243.     psubusb %2m2, %2m0
  244. %endmacro
  245. %macro DEBLOCK_P0_Q0_MMX 0
  246.     DEBLOCK_P0_Q0 q, m
  247. %endmacro
  248. %macro DEBLOCK_P0_Q0_SSE2 0
  249.     DEBLOCK_P0_Q0 dqa, xm
  250. %endmacro
  252. ; in: mm1=p0 mm2=q0
  253. ;     %1=p1 %2=q2 %3=[q2] %4=[q1] %5=tc0 %6=tmp
  254. ; out: [q1] = clip( (q2+((p0+q0+1)>>1))>>1, q1-tc0, q1+tc0 )
  255. ; clobbers: q2, tmp, tc0
  256. %macro LUMA_Q1_SSE2 6
  257.     movdqa  %6, xmm1
  258.     pavgb   %6, xmm2
  259.     pavgb   %2, %6             ; avg(p2,avg(p0,q0))
  260.     pxor    %6, %3
  261.     pand    %6, [pb_01 GLOBAL] ; (p2^avg(p0,q0))&1
  262.     psubusb %2, %6             ; (p2+((p0+q0+1)>>1))>>1
  263.     movdqa  %6, %1
  264.     psubusb %6, %5
  265.     paddusb %5, %1
  266.     pmaxub  %2, %6
  267.     pminub  %2, %5
  268.     movdqa  %4, %2
  269. %endmacro
  272. SECTION .text
  273. ALIGN 16
  274. ;-----------------------------------------------------------------------------
  275. ;   void x264_deblock_v_luma_sse2( uint8_t *pix, int stride, int alpha, int beta, int8_t *tc0 )
  276. ;-----------------------------------------------------------------------------
  277. x264_deblock_v_luma_sse2:
  278.     ; rdi = pix
  279.     movsxd rsi, esi ; stride
  280.     dec    edx      ; alpha-1
  281.     dec    ecx      ; beta-1
  282.     movd   xmm8, [r8] ; tc0
  283.     mov    r8,  rdi
  284.     sub    r8,  rsi
  285.     sub    r8,  rsi
  286.     sub    r8,  rsi ; pix-3*stride
  288.     movdqa  xmm0, [r8+rsi]    ; p1
  289.     movdqa  xmm1, [r8+2*rsi]  ; p0
  290.     movdqa  xmm2, [rdi]       ; q0
  291.     movdqa  xmm3, [rdi+rsi]   ; q1
  292.     LOAD_MASK_SSE2  edx, ecx
  294.     punpcklbw xmm8, xmm8
  295.     punpcklbw xmm8, xmm8 ; xmm8 = 4x tc0[3], 4x tc0[2], 4x tc0[1], 4x tc0[0]
  296.     movdqa  xmm9, [pb_ff GLOBAL]
  297.     pcmpeqb xmm9, xmm8
  298.     pandn   xmm9, xmm7
  299.     pand    xmm8, xmm9
  301.     movdqa  xmm3, [r8] ; p2
  302.     DIFF_GT_SSE2  xmm1, xmm3, xmm5, xmm6, xmm7 ; |p2-p0| > beta-1
  303.     pandn   xmm6, xmm9
  304.     pcmpeqb xmm6, xmm9
  305.     pand    xmm6, xmm9
  306.     movdqa  xmm7, [pb_01 GLOBAL]
  307.     pand    xmm7, xmm6
  308.     pand    xmm6, xmm8
  309.     paddb   xmm7, xmm8
  310.     LUMA_Q1_SSE2  xmm0, xmm3, [r8], [r8+rsi], xmm6, xmm4
  312.     movdqa  xmm4, [rdi+2*rsi] ; q2
  313.     DIFF_GT_SSE2  xmm2, xmm4, xmm5, xmm6, xmm3 ; |q2-q0| > beta-1
  314.     pandn   xmm6, xmm9
  315.     pcmpeqb xmm6, xmm9
  316.     pand    xmm6, xmm9
  317.     pand    xmm8, xmm6
  318.     pand    xmm6, [pb_01 GLOBAL]
  319.     paddb   xmm7, xmm6
  320.     movdqa  xmm3, [rdi+rsi]
  321.     LUMA_Q1_SSE2  xmm3, xmm4, [rdi+2*rsi], [rdi+rsi], xmm8, xmm6
  323.     DEBLOCK_P0_Q0_SSE2
  324.     movdqa  [r8+2*rsi], xmm1
  325.     movdqa  [rdi], xmm2
  327.     ret
  329. ALIGN 16
  330. ;-----------------------------------------------------------------------------
  331. ;   void x264_deblock_h_luma_sse2( uint8_t *pix, int stride, int alpha, int beta, int8_t *tc0 )
  332. ;-----------------------------------------------------------------------------
  333. x264_deblock_h_luma_sse2:
  334.     movsxd r10, esi
  335.     lea    r11, [r10+r10*2]
  336.     lea    rax, [rdi-4]
  337.     lea    r9,  [rdi-4+r11]
  338.     %define pix_tmp rsp-104 ; 16x6 for the buffer + 8 for x264_deblock_v_luma_sse2's return address
  340.     ; transpose 6x16 -> tmp space
  341.     TRANSPOSE6x8_MEM  PASS8ROWS(rax, r9, r10, r11), pix_tmp
  342.     lea    rax, [rax+r10*8]
  343.     lea    r9,  [r9 +r10*8]
  344.     TRANSPOSE6x8_MEM  PASS8ROWS(rax, r9, r10, r11), pix_tmp+8
  346.     ; vertical filter
  347.     ; alpha, beta, tc0 are still in edx, ecx, r8
  348.     ; don't backup rax, r9, r10, r11 because x264_deblock_v_luma_sse2 doesn't use them
  349.     lea    rdi, [pix_tmp+0x30]
  350.     mov    esi, 0x10
  351.     call   x264_deblock_v_luma_sse2
  353.     ; transpose 16x4 -> original space  (only the middle 4 rows were changed by the filter)
  354.     add    rax, 2
  355.     add    r9,  2
  356.     movq   mm0, [pix_tmp+0x18]
  357.     movq   mm1, [pix_tmp+0x28]
  358.     movq   mm2, [pix_tmp+0x38]
  359.     movq   mm3, [pix_tmp+0x48]
  360.     TRANSPOSE8x4_STORE  PASS8ROWS(rax, r9, r10, r11)
  362.     shl    r10, 3
  363.     sub    rax, r10
  364.     sub    r9,  r10
  365.     shr    r10, 3
  366.     movq   mm0, [pix_tmp+0x10]
  367.     movq   mm1, [pix_tmp+0x20]
  368.     movq   mm2, [pix_tmp+0x30]
  369.     movq   mm3, [pix_tmp+0x40]
  370.     TRANSPOSE8x4_STORE  PASS8ROWS(rax, r9, r10, r11)
  372.     ret
  375. %macro CHROMA_V_START 0
  376.     ; rdi = pix
  377.     movsxd rsi, esi ; stride
  378.     dec    edx      ; alpha-1
  379.     dec    ecx      ; beta-1
  380.     mov    rax, rdi
  381.     sub    rax, rsi
  382.     sub    rax, rsi
  383. %endmacro
  385. %macro CHROMA_H_START 0
  386.     movsxd rsi, esi
  387.     dec    edx
  388.     dec    ecx
  389.     sub    rdi, 2
  390.     lea    r9, [rsi+rsi*2]
  391.     mov    rax, rdi
  392.     add    rdi, r9
  393. %endmacro
  395. ALIGN 16
  396. ;-----------------------------------------------------------------------------
  397. ;   void x264_deblock_v_chroma_mmxext( uint8_t *pix, int stride, int alpha, int beta, int8_t *tc0 )
  398. ;-----------------------------------------------------------------------------
  399. x264_deblock_v_chroma_mmxext:
  400.     CHROMA_V_START
  402.     movq  mm0, [rax]
  403.     movq  mm1, [rax+rsi]
  404.     movq  mm2, [rdi]
  405.     movq  mm3, [rdi+rsi]
  407.     LOAD_MASK_MMX  edx, ecx
  408.     movd       mm6, [r8] ; tc0
  409.     punpcklbw  mm6, mm6
  410.     pand       mm7, mm6
  411.     DEBLOCK_P0_Q0_MMX
  413.     movq  [rax+rsi], mm1
  414.     movq  [rdi], mm2
  415.     ret
  418. ALIGN 16
  419. ;-----------------------------------------------------------------------------
  420. ;   void x264_deblock_h_chroma_mmxext( uint8_t *pix, int stride, int alpha, int beta, int8_t *tc0 )
  421. ;-----------------------------------------------------------------------------
  422. x264_deblock_h_chroma_mmxext:
  423.     CHROMA_H_START
  425.     TRANSPOSE4x8_LOAD  PASS8ROWS(rax, rdi, rsi, r9)
  426.     movq  [rsp-8], mm0
  427.     movq  [rsp-16], mm3
  429.     LOAD_MASK_MMX  edx, ecx
  430.     movd       mm6, [r8] ; tc0
  431.     punpcklbw  mm6, mm6
  432.     pand       mm7, mm6
  433.     DEBLOCK_P0_Q0_MMX
  435.     movq  mm0, [rsp-8]
  436.     movq  mm3, [rsp-16]
  437.     TRANSPOSE8x4_STORE PASS8ROWS(rax, rdi, rsi, r9)
  438.     ret
  441. ; in: %1=p0 %2=p1 %3=q1
  442. ; out: p0 = (p0 + q1 + 2*p1 + 2) >> 2
  443. %macro CHROMA_INTRA_P0 3
  444.     movq    mm4, %1
  445.     pxor    mm4, %3
  446.     pand    mm4, [pb_01 GLOBAL] ; mm4 = (p0^q1)&1
  447.     pavgb   %1,  %3
  448.     psubusb %1,  mm4
  449.     pavgb   %1,  %2             ; dst = avg(p1, avg(p0,q1) - ((p0^q1)&1))
  450. %endmacro
  452. %macro CHROMA_INTRA_BODY 0
  453.     LOAD_MASK_MMX edx, ecx
  454.     movq   mm5, mm1
  455.     movq   mm6, mm2
  456.     CHROMA_INTRA_P0  mm1, mm0, mm3
  457.     CHROMA_INTRA_P0  mm2, mm3, mm0
  458.     psubb  mm1, mm5
  459.     psubb  mm2, mm6
  460.     pand   mm1, mm7
  461.     pand   mm2, mm7
  462.     paddb  mm1, mm5
  463.     paddb  mm2, mm6
  464. %endmacro
  466. ALIGN 16
  467. ;-----------------------------------------------------------------------------
  468. ;   void x264_deblock_v_chroma_intra_mmxext( uint8_t *pix, int stride, int alpha, int beta )
  469. ;-----------------------------------------------------------------------------
  470. x264_deblock_v_chroma_intra_mmxext:
  471.     CHROMA_V_START
  473.     movq  mm0, [rax]
  474.     movq  mm1, [rax+rsi]
  475.     movq  mm2, [rdi]
  476.     movq  mm3, [rdi+rsi]
  478.     CHROMA_INTRA_BODY
  480.     movq  [rax+rsi], mm1
  481.     movq  [rdi], mm2
  482.     ret
  484. ALIGN 16
  485. ;-----------------------------------------------------------------------------
  486. ;   void x264_deblock_h_chroma_intra_mmxext( uint8_t *pix, int stride, int alpha, int beta )
  487. ;-----------------------------------------------------------------------------
  488. x264_deblock_h_chroma_intra_mmxext:
  489.     CHROMA_H_START
  490.     TRANSPOSE4x8_LOAD  PASS8ROWS(rax, rdi, rsi, r9)
  491.     CHROMA_INTRA_BODY
  492.     TRANSPOSE8x4_STORE PASS8ROWS(rax, rdi, rsi, r9)
  493.     ret