开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 多媒体 > Audio > 查看源码
pixel-a.asm
资源名称：chapter15.rar　[点击查看]
上传用户：hjq518
上传日期：2021-12-09
资源大小：5084k
文件大小：21k
源码类别：

Audio

开发平台：

Visual C++

pixel-a.asm：源码内容
  1. ;*****************************************************************************
  2. ;* pixel.asm: h264 encoder library
  3. ;*****************************************************************************
  4. ;* Copyright (C) 2003 x264 project
  5. ;* $Id: pixel.asm,v 1.1 2004/06/03 19:27:07 fenrir Exp $
  6. ;*
  7. ;* Authors: Laurent Aimar <fenrir@via.ecp.fr>
  8. ;*
  9. ;* This program is free software; you can redistribute it and/or modify
  10. ;* it under the terms of the GNU General Public License as published by
  11. ;* the Free Software Foundation; either version 2 of the License, or
  12. ;* (at your option) any later version.
  13. ;*
  14. ;* This program is distributed in the hope that it will be useful,
  15. ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  16. ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17. ;* GNU General Public License for more details.
  18. ;*
  19. ;* You should have received a copy of the GNU General Public License
  20. ;* along with this program; if not, write to the Free Software
  21. ;* Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111, USA.
  22. ;*****************************************************************************
  24. BITS 64
  26. ;=============================================================================
  27. ; Macros and other preprocessor constants
  28. ;=============================================================================
  30. %include "amd64inc.asm"
  32. %macro SAD_INC_2x16P 0
  33.     movq    mm1,    [parm1q]
  34.     movq    mm2,    [parm1q+8]
  35.     movq    mm3,    [parm1q+parm2q]
  36.     movq    mm4,    [parm1q+parm2q+8]
  37.     psadbw  mm1,    [parm3q]
  38.     psadbw  mm2,    [parm3q+8]
  39.     psadbw  mm3,    [parm3q+parm4q]
  40.     psadbw  mm4,    [parm3q+parm4q+8]
  41.     lea     parm1q, [parm1q+2*parm2q]
  42.     paddw   mm1,    mm2
  43.     paddw   mm3,    mm4
  44.     lea     parm3q, [parm3q+2*parm4q]
  45.     paddw   mm0,    mm1
  46.     paddw   mm0,    mm3
  47. %endmacro
  49. %macro SAD_INC_2x8P 0
  50.     movq    mm1,    [parm1q]
  51.     movq    mm2,    [parm1q+parm2q]
  52.     psadbw  mm1,    [parm3q]
  53.     psadbw  mm2,    [parm3q+parm4q]
  54.     lea     parm1q,    [parm1q+2*parm2q]
  55.     paddw   mm0,    mm1
  56.     paddw   mm0,    mm2
  57.     lea     parm3q, [parm3q+2*parm4q]
  58. %endmacro
  60. %macro SAD_INC_2x4P 0
  61.     movd    mm1,    [parm1q]
  62.     movd    mm2,    [parm3q]
  63.     movd    mm3,    [parm1q+parm2q]
  64.     movd    mm4,    [parm3q+parm4q]
  66.     psadbw  mm1,    mm2
  67.     psadbw  mm3,    mm4
  68.     paddw   mm0,    mm1
  69.     paddw   mm0,    mm3
  71.     lea     parm1q, [parm1q+2*parm2q]
  72.     lea     parm3q, [parm3q+2*parm4q]
  73. %endmacro
  75. %macro SSD_INC_1x16P 0
  76.     movq    mm1,    [rax]
  77.     movq    mm2,    [rcx]
  78.     movq    mm3,    [rax+8]
  79.     movq    mm4,    [rcx+8]
  81.     movq    mm5,    mm2
  82.     movq    mm6,    mm4
  83.     psubusb mm2,    mm1
  84.     psubusb mm4,    mm3
  85.     psubusb mm1,    mm5
  86.     psubusb mm3,    mm6
  87.     por     mm1,    mm2
  88.     por     mm3,    mm4
  90.     movq    mm2,    mm1
  91.     movq    mm4,    mm3
  92.     punpcklbw mm1,  mm7
  93.     punpcklbw mm3,  mm7
  94.     punpckhbw mm2,  mm7
  95.     punpckhbw mm4,  mm7
  96.     pmaddwd mm1,    mm1
  97.     pmaddwd mm2,    mm2
  98.     pmaddwd mm3,    mm3
  99.     pmaddwd mm4,    mm4
  101.     add     rax,    rbx
  102.     add     rcx,    rdx
  103.     paddd   mm0,    mm1
  104.     paddd   mm0,    mm2
  105.     paddd   mm0,    mm3
  106.     paddd   mm0,    mm4
  107. %endmacro
  109. %macro SSD_INC_1x8P 0
  110.     movq    mm1,    [rax]
  111.     movq    mm2,    [rcx]
  113.     movq    mm5,    mm2
  114.     psubusb mm2,    mm1
  115.     psubusb mm1,    mm5
  116.     por     mm1,    mm2         ; mm1 = 8bit abs diff
  118.     movq    mm2,    mm1
  119.     punpcklbw mm1,  mm7
  120.     punpckhbw mm2,  mm7         ; (mm1,mm2) = 16bit abs diff
  121.     pmaddwd mm1,    mm1
  122.     pmaddwd mm2,    mm2
  124.     add     rax,    rbx
  125.     add     rcx,    rdx
  126.     paddd   mm0,    mm1
  127.     paddd   mm0,    mm2
  128. %endmacro
  130. %macro SSD_INC_1x4P 0
  131.     movd    mm1,    [rax]
  132.     movd    mm2,    [rcx]
  134.     movq    mm5,    mm2
  135.     psubusb mm2,    mm1
  136.     psubusb mm1,    mm5
  137.     por     mm1,    mm2
  138.     punpcklbw mm1,  mm7
  139.     pmaddwd mm1,    mm1
  141.     add     rax,    rbx
  142.     add     rcx,    rdx
  143.     paddd   mm0,    mm1
  144. %endmacro
  146. %macro SSD_INC_8x16P 0
  147.     SSD_INC_1x16P
  148.     SSD_INC_1x16P
  149.     SSD_INC_1x16P
  150.     SSD_INC_1x16P
  151.     SSD_INC_1x16P
  152.     SSD_INC_1x16P
  153.     SSD_INC_1x16P
  154.     SSD_INC_1x16P
  155. %endmacro
  157. %macro SSD_INC_4x8P 0
  158.     SSD_INC_1x8P
  159.     SSD_INC_1x8P
  160.     SSD_INC_1x8P
  161.     SSD_INC_1x8P
  162. %endmacro
  164. %macro SSD_INC_4x4P 0
  165.     SSD_INC_1x4P
  166.     SSD_INC_1x4P
  167.     SSD_INC_1x4P
  168.     SSD_INC_1x4P
  169. %endmacro
  171. %macro LOAD_DIFF_4P 4  ; MMP, MMT, [pix1], [pix2]
  172.     movd        %1, %3
  173.     movd        %2, %4
  174.     punpcklbw   %1, %2
  175.     punpcklbw   %2, %2
  176.     psubw       %1, %2
  177. %endmacro
  179. %macro LOAD_DIFF_INC_4x4 10 ; p1,p2,p3,p4, t, pix1, i_pix1, pix2, i_pix2, offset
  180.     LOAD_DIFF_4P %1, %5, [%6+%10],    [%8+%10]
  181.     LOAD_DIFF_4P %2, %5, [%6+%7+%10], [%8+%9+%10]
  182.     lea %6, [%6+2*%7]
  183.     lea %8, [%8+2*%9]
  184.     LOAD_DIFF_4P %3, %5, [%6+%10],    [%8+%10]
  185.     LOAD_DIFF_4P %4, %5, [%6+%7+%10], [%8+%9+%10]
  186.     lea %6, [%6+2*%7]
  187.     lea %8, [%8+2*%9]
  188. %endmacro
  190. %macro LOAD_DIFF_4x4 10 ; p1,p2,p3,p4, t, pix1, i_pix1, pix2, i_pix2, offset
  191.     LOAD_DIFF_4P %1, %5, [%6+%10],      [%8+%10]
  192.     LOAD_DIFF_4P %3, %5, [%6+2*%7+%10], [%8+2*%9+%10]
  193.     add     %6, %7
  194.     add     %8, %9
  195.     LOAD_DIFF_4P %2, %5, [%6+%10],      [%8+%10]
  196.     LOAD_DIFF_4P %4, %5, [%6+2*%7+%10], [%8+2*%9+%10]
  197. %endmacro
  199. %macro HADAMARD4_SUB_BADC 4
  200.     paddw %1,   %2
  201.     paddw %3,   %4
  202.     paddw %2,   %2
  203.     paddw %4,   %4
  204.     psubw %2,   %1
  205.     psubw %4,   %3
  206. %endmacro
  208. %macro HADAMARD4x4 4
  209.     HADAMARD4_SUB_BADC %1, %2, %3, %4
  210.     HADAMARD4_SUB_BADC %1, %3, %2, %4
  211. %endmacro
  213. %macro SBUTTERFLYwd 3
  214.     movq        %3, %1
  215.     punpcklwd   %1, %2
  216.     punpckhwd   %3, %2
  217. %endmacro
  219. %macro SBUTTERFLYdq 3
  220.     movq        %3, %1
  221.     punpckldq   %1, %2
  222.     punpckhdq   %3, %2
  223. %endmacro
  225. %macro TRANSPOSE4x4 5   ; abcd-t -> adtc
  226.     SBUTTERFLYwd %1, %2, %5
  227.     SBUTTERFLYwd %3, %4, %2
  228.     SBUTTERFLYdq %1, %3, %4
  229.     SBUTTERFLYdq %5, %2, %3
  230. %endmacro
  232. %macro MMX_ABS 2        ; mma, mmt
  233.     pxor    %2, %2
  234.     psubw   %2, %1
  235.     pmaxsw  %1, %2
  236. %endmacro
  238. %macro HADAMARD4x4_SUM 1    ; %1 = dest (row sum of one block)
  239.     HADAMARD4x4 mm4, mm5, mm6, mm7
  240.     TRANSPOSE4x4 mm4, mm5, mm6, mm7, %1
  241.     HADAMARD4x4 mm4, mm7, %1, mm6
  242.     MMX_ABS     mm4, mm5
  243.     MMX_ABS     mm7, mm5
  244.     MMX_ABS     %1,  mm5
  245.     MMX_ABS     mm6, mm5
  246.     paddw       %1,  mm4
  247.     paddw       mm6, mm7
  248.     pavgw       %1,  mm6
  249. %endmacro
  251. ;=============================================================================
  252. ; Code
  253. ;=============================================================================
  255. SECTION .text
  257. cglobal x264_pixel_sad_16x16_mmxext
  258. cglobal x264_pixel_sad_16x8_mmxext
  259. cglobal x264_pixel_sad_8x16_mmxext
  260. cglobal x264_pixel_sad_8x8_mmxext
  261. cglobal x264_pixel_sad_8x4_mmxext
  262. cglobal x264_pixel_sad_4x8_mmxext
  263. cglobal x264_pixel_sad_4x4_mmxext
  265. cglobal x264_pixel_sad_pde_16x16_mmxext
  266. cglobal x264_pixel_sad_pde_16x8_mmxext
  267. cglobal x264_pixel_sad_pde_8x16_mmxext
  269. cglobal x264_pixel_ssd_16x16_mmxext
  270. cglobal x264_pixel_ssd_16x8_mmxext
  271. cglobal x264_pixel_ssd_8x16_mmxext
  272. cglobal x264_pixel_ssd_8x8_mmxext
  273. cglobal x264_pixel_ssd_8x4_mmxext
  274. cglobal x264_pixel_ssd_4x8_mmxext
  275. cglobal x264_pixel_ssd_4x4_mmxext
  277. cglobal x264_pixel_satd_4x4_mmxext
  278. cglobal x264_pixel_satd_4x8_mmxext
  279. cglobal x264_pixel_satd_8x4_mmxext
  280. cglobal x264_pixel_satd_8x8_mmxext
  281. cglobal x264_pixel_satd_16x8_mmxext
  282. cglobal x264_pixel_satd_8x16_mmxext
  283. cglobal x264_pixel_satd_16x16_mmxext
  285. %macro SAD_START 0
  286.     pxor    mm0,    mm0
  287. %endmacro
  289. %macro SAD_END 0
  290.     movd    eax, mm0
  291.     ret
  292. %endmacro
  294. ALIGN 16
  295. ;-----------------------------------------------------------------------------
  296. ;   int x264_pixel_sad_16x16_mmxext (uint8_t *, int, uint8_t *, int )
  297. ;-----------------------------------------------------------------------------
  298. x264_pixel_sad_16x16_mmxext:
  299.     SAD_START
  300.     SAD_INC_2x16P
  301.     SAD_INC_2x16P
  302.     SAD_INC_2x16P
  303.     SAD_INC_2x16P
  304.     SAD_INC_2x16P
  305.     SAD_INC_2x16P
  306.     SAD_INC_2x16P
  307.     SAD_INC_2x16P
  308.     SAD_END
  310. ALIGN 16
  311. ;-----------------------------------------------------------------------------
  312. ;   int x264_pixel_sad_16x8_mmxext (uint8_t *, int, uint8_t *, int )
  313. ;-----------------------------------------------------------------------------
  314. x264_pixel_sad_16x8_mmxext:
  315.     SAD_START
  316.     SAD_INC_2x16P
  317.     SAD_INC_2x16P
  318.     SAD_INC_2x16P
  319.     SAD_INC_2x16P
  320.     SAD_END
  322. ALIGN 16
  323. ;-----------------------------------------------------------------------------
  324. ;   int x264_pixel_sad_8x16_mmxext (uint8_t *, int, uint8_t *, int )
  325. ;-----------------------------------------------------------------------------
  326. x264_pixel_sad_8x16_mmxext:
  327.     SAD_START
  328.     SAD_INC_2x8P
  329.     SAD_INC_2x8P
  330.     SAD_INC_2x8P
  331.     SAD_INC_2x8P
  332.     SAD_INC_2x8P
  333.     SAD_INC_2x8P
  334.     SAD_INC_2x8P
  335.     SAD_INC_2x8P
  336.     SAD_END
  338. ALIGN 16
  339. ;-----------------------------------------------------------------------------
  340. ;   int x264_pixel_sad_8x8_mmxext (uint8_t *, int, uint8_t *, int )
  341. ;-----------------------------------------------------------------------------
  342. x264_pixel_sad_8x8_mmxext:
  343.     SAD_START
  344.     SAD_INC_2x8P
  345.     SAD_INC_2x8P
  346.     SAD_INC_2x8P
  347.     SAD_INC_2x8P
  348.     SAD_END
  350. ALIGN 16
  351. ;-----------------------------------------------------------------------------
  352. ;   int x264_pixel_sad_8x4_mmxext (uint8_t *, int, uint8_t *, int )
  353. ;-----------------------------------------------------------------------------
  354. x264_pixel_sad_8x4_mmxext:
  355.     SAD_START
  356.     SAD_INC_2x8P
  357.     SAD_INC_2x8P
  358.     SAD_END
  360. ALIGN 16
  361. ;-----------------------------------------------------------------------------
  362. ;   int x264_pixel_sad_4x8_mmxext (uint8_t *, int, uint8_t *, int )
  363. ;-----------------------------------------------------------------------------
  364. x264_pixel_sad_4x8_mmxext:
  365.     SAD_START
  366.     SAD_INC_2x4P
  367.     SAD_INC_2x4P
  368.     SAD_INC_2x4P
  369.     SAD_INC_2x4P
  370.     SAD_END
  372. ALIGN 16
  373. ;-----------------------------------------------------------------------------
  374. ;   int x264_pixel_sad_4x4_mmxext (uint8_t *, int, uint8_t *, int )
  375. ;-----------------------------------------------------------------------------
  376. x264_pixel_sad_4x4_mmxext:
  377.     SAD_START
  378.     SAD_INC_2x4P
  379.     SAD_INC_2x4P
  380.     SAD_END
  384. %macro PDE_CHECK 0
  385.     movd eax, mm0
  386.     cmp  eax, parm5d ; prev_score
  387.     jl   .continue
  388.     ret
  389. ALIGN 4
  390. .continue:
  391. %endmacro
  393. ALIGN 16
  394. ;-----------------------------------------------------------------------------
  395. ;   int __cdecl x264_pixel_sad_pde_16x16_mmxext (uint8_t *, int, uint8_t *, int, int )
  396. ;-----------------------------------------------------------------------------
  397. x264_pixel_sad_pde_16x16_mmxext:
  398.     SAD_START
  399.     SAD_INC_2x16P
  400.     SAD_INC_2x16P
  401.     SAD_INC_2x16P
  402.     SAD_INC_2x16P
  403.     PDE_CHECK
  404.     SAD_INC_2x16P
  405.     SAD_INC_2x16P
  406.     SAD_INC_2x16P
  407.     SAD_INC_2x16P
  408.     SAD_END
  410. ALIGN 16
  411. ;-----------------------------------------------------------------------------
  412. ;   int __cdecl x264_pixel_sad_pde_16x8_mmxext (uint8_t *, int, uint8_t *, int, int )
  413. ;-----------------------------------------------------------------------------
  414. x264_pixel_sad_pde_16x8_mmxext:
  415.     SAD_START
  416.     SAD_INC_2x16P
  417.     SAD_INC_2x16P
  418.     PDE_CHECK
  419.     SAD_INC_2x16P
  420.     SAD_INC_2x16P
  421.     SAD_END
  423. ALIGN 16
  424. ;-----------------------------------------------------------------------------
  425. ;   int __cdecl x264_pixel_sad_pde_8x16_mmxext (uint8_t *, int, uint8_t *, int, int )
  426. ;-----------------------------------------------------------------------------
  427. x264_pixel_sad_pde_8x16_mmxext:
  428.     SAD_START
  429.     SAD_INC_2x8P
  430.     SAD_INC_2x8P
  431.     SAD_INC_2x8P
  432.     SAD_INC_2x8P
  433.     PDE_CHECK
  434.     SAD_INC_2x8P
  435.     SAD_INC_2x8P
  436.     SAD_INC_2x8P
  437.     SAD_INC_2x8P
  438.     SAD_END
  442. %macro SSD_START 0
  443.     firstpush rbx
  444.     pushreg   rbx
  445.     endprolog
  447.     mov     rax, parm1q         ; pix1 =parm1
  448.     movsxd  rbx, parm2d         ; stride1 =parm2
  449. %ifdef WIN64
  450.     mov     rcx, parm3q
  451.     movsxd  rdx, parm4d
  452. %else
  453.    xchg     rcx, rdx
  454. %endif
  456.     pxor    mm7,    mm7         ; zero
  457.     pxor    mm0,    mm0         ; mm0 holds the sum
  458. %endmacro
  460. %macro SSD_END 0
  461.     movq    mm1,    mm0
  462.     psrlq   mm1,    32
  463.     paddd   mm0,    mm1
  464.     movd    eax,    mm0
  466.     pop rbx
  467.     ret
  468.     endfunc
  469. %endmacro
  471. ALIGN 16
  472. ;-----------------------------------------------------------------------------
  473. ;   int x264_pixel_ssd_16x16_mmxext (uint8_t *, int, uint8_t *, int )
  474. ;-----------------------------------------------------------------------------
  475. x264_pixel_ssd_16x16_mmxext:
  476.     SSD_START
  477.     SSD_INC_8x16P
  478.     SSD_INC_8x16P
  479.     SSD_END
  481. ALIGN 16
  482. x264_pixel_ssd_16x8_mmxext:
  483.     SSD_START
  484.     SSD_INC_8x16P
  485.     SSD_END
  487. ALIGN 16
  488. x264_pixel_ssd_8x16_mmxext:
  489.     SSD_START
  490.     SSD_INC_4x8P
  491.     SSD_INC_4x8P
  492.     SSD_INC_4x8P
  493.     SSD_INC_4x8P
  494.     SSD_END
  496. ALIGN 16
  497. x264_pixel_ssd_8x8_mmxext:
  498.     SSD_START
  499.     SSD_INC_4x8P
  500.     SSD_INC_4x8P
  501.     SSD_END
  503. ALIGN 16
  504. x264_pixel_ssd_8x4_mmxext:
  505.     SSD_START
  506.     SSD_INC_4x8P
  507.     SSD_END
  509. ALIGN 16
  510. x264_pixel_ssd_4x8_mmxext:
  511.     SSD_START
  512.     SSD_INC_4x4P
  513.     SSD_INC_4x4P
  514.     SSD_END
  516. ALIGN 16
  517. x264_pixel_ssd_4x4_mmxext:
  518.     SSD_START
  519.     SSD_INC_4x4P
  520.     SSD_END
  523. %macro SATD_START 0
  524. ;   mov     rdi, rdi            ; pix1
  525. ;   movsxd  rsi, esi            ; stride1
  526. ;   mov     rdx, rdx            ; pix2
  527. ;   movsxd  rcx, ecx            ; stride2
  528. %endmacro
  530. %macro SATD_END 0
  531.     pshufw      mm1, mm0, 01001110b
  532.     paddw       mm0, mm1
  533.     pshufw      mm1, mm0, 10110001b
  534.     paddw       mm0, mm1
  535.     movd        eax, mm0
  536.     and         eax, 0xffff
  537.     ret
  538. %endmacro
  540. ALIGN 16
  541. ;-----------------------------------------------------------------------------
  542. ;   int x264_pixel_satd_4x4_mmxext (uint8_t *, int, uint8_t *, int )
  543. ;-----------------------------------------------------------------------------
  544. x264_pixel_satd_4x4_mmxext:
  545.     SATD_START
  546.     LOAD_DIFF_4x4       mm4, mm5, mm6, mm7, mm0, parm1q, parm2q, parm3q, parm4q, 0
  547.     HADAMARD4x4_SUM     mm0
  548.     SATD_END
  550. ALIGN 16
  551. ;-----------------------------------------------------------------------------
  552. ;   int x264_pixel_satd_4x8_mmxext (uint8_t *, int, uint8_t *, int )
  553. ;-----------------------------------------------------------------------------
  554. x264_pixel_satd_4x8_mmxext:
  555.     SATD_START
  556.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm0, parm1q, parm2q, parm3q, parm4q, 0
  557.     HADAMARD4x4_SUM     mm0
  558.     LOAD_DIFF_4x4       mm4, mm5, mm6, mm7, mm1, parm1q, parm2q, parm3q, parm4q, 0
  559.     HADAMARD4x4_SUM     mm1
  560.     paddw       mm0, mm1
  561.     SATD_END
  563. ALIGN 16
  564. ;-----------------------------------------------------------------------------
  565. ;   int x264_pixel_satd_8x4_mmxext (uint8_t *, int, uint8_t *, int )
  566. ;-----------------------------------------------------------------------------
  567. x264_pixel_satd_8x4_mmxext:
  568.     SATD_START
  569.     LOAD_DIFF_4x4       mm4, mm5, mm6, mm7, mm0, parm1q, parm2q, parm3q, parm4q, 0
  570.     HADAMARD4x4_SUM     mm0
  571.     sub         parm1q, parm2q
  572.     sub         parm3q, parm4q
  573.     LOAD_DIFF_4x4       mm4, mm5, mm6, mm7, mm1, parm1q, parm2q, parm3q, parm4q, 4
  574.     HADAMARD4x4_SUM     mm1
  575.     paddw       mm0, mm1
  576.     SATD_END
  578. ALIGN 16
  579. ;-----------------------------------------------------------------------------
  580. ;   int x264_pixel_satd_8x8_mmxext (uint8_t *, int, uint8_t *, int )
  581. ;-----------------------------------------------------------------------------
  582. x264_pixel_satd_8x8_mmxext:
  583.     SATD_START
  584.     mov         r10, parm1q        ; pix1
  585.     mov         r11, parm3q        ; pix2
  587.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm0, parm1q, parm2q, parm3q, parm4q, 0
  588.     HADAMARD4x4_SUM     mm0
  589.     LOAD_DIFF_4x4       mm4, mm5, mm6, mm7, mm1, parm1q, parm2q, parm3q, parm4q, 0
  590.     HADAMARD4x4_SUM     mm1
  592.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm2, r10, parm2q, r11, parm4q, 4
  593.     HADAMARD4x4_SUM     mm2
  594.     LOAD_DIFF_4x4       mm4, mm5, mm6, mm7, mm3, r10, parm2q, r11, parm4q, 4
  595.     HADAMARD4x4_SUM     mm3
  596.     paddw       mm0, mm1
  597.     paddw       mm2, mm3
  598.     paddw       mm0, mm2
  599.     SATD_END
  601. ALIGN 16
  602. ;-----------------------------------------------------------------------------
  603. ;   int x264_pixel_satd_16x8_mmxext (uint8_t *, int, uint8_t *, int )
  604. ;-----------------------------------------------------------------------------
  605. x264_pixel_satd_16x8_mmxext:
  606.     SATD_START
  607.     mov         r10, parm1q
  608.     mov         r11, parm3q
  610.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm0, parm1q, parm2q, parm3q, parm4q, 0
  611.     HADAMARD4x4_SUM     mm0
  612.     LOAD_DIFF_4x4       mm4, mm5, mm6, mm7, mm1, parm1q, parm2q, parm3q, parm4q, 0
  613.     HADAMARD4x4_SUM     mm1
  615.     mov         parm1q, r10
  616.     mov         parm3q, r11
  617.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm2, parm1q, parm2q, parm3q, parm4q, 4
  618.     HADAMARD4x4_SUM     mm2
  619.     LOAD_DIFF_4x4       mm4, mm5, mm6, mm7, mm3, parm1q, parm2q, parm3q, parm4q, 4
  620.     HADAMARD4x4_SUM     mm3
  621.     paddw       mm0, mm1
  622.     paddw       mm2, mm3
  623.     paddw       mm0, mm2
  625.     mov         parm1q, r10
  626.     mov         parm3q, r11
  627.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm1, parm1q, parm2q, parm3q, parm4q, 8
  628.     HADAMARD4x4_SUM     mm1
  629.     LOAD_DIFF_4x4       mm4, mm5, mm6, mm7, mm2, parm1q, parm2q, parm3q, parm4q, 8
  630.     HADAMARD4x4_SUM     mm2
  631.     paddw       mm1, mm2
  633.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm2, r10, parm2q, r11, parm4q, 12
  634.     HADAMARD4x4_SUM     mm2
  635.     LOAD_DIFF_4x4       mm4, mm5, mm6, mm7, mm3, r10, parm2q, r11, parm4q, 12
  636.     HADAMARD4x4_SUM     mm3
  637.     paddw       mm0, mm1
  638.     paddw       mm2, mm3
  639.     paddw       mm0, mm2
  640.     SATD_END
  642. ALIGN 16
  643. ;-----------------------------------------------------------------------------
  644. ;   int x264_pixel_satd_8x16_mmxext (uint8_t *, int, uint8_t *, int )
  645. ;-----------------------------------------------------------------------------
  646. x264_pixel_satd_8x16_mmxext:
  647.     SATD_START
  648.     mov         r10, parm1q
  649.     mov         r11, parm3q
  651.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm0, parm1q, parm2q, parm3q, parm4q, 0
  652.     HADAMARD4x4_SUM     mm0
  653.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm1, parm1q, parm2q, parm3q, parm4q, 0
  654.     HADAMARD4x4_SUM     mm1
  655.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm2, parm1q, parm2q, parm3q, parm4q, 0
  656.     HADAMARD4x4_SUM     mm2
  657.     LOAD_DIFF_4x4       mm4, mm5, mm6, mm7, mm3, parm1q, parm2q, parm3q, parm4q, 0
  658.     HADAMARD4x4_SUM     mm3
  659.     paddw       mm0, mm1
  660.     paddw       mm2, mm3
  661.     paddw       mm0, mm2
  663.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm1, r10, parm2q, r11, parm4q, 4
  664.     HADAMARD4x4_SUM     mm1
  665.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm2, r10, parm2q, r11, parm4q, 4
  666.     HADAMARD4x4_SUM     mm2
  667.     paddw       mm1, mm2
  669.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm2, r10, parm2q, r11, parm4q, 4
  670.     HADAMARD4x4_SUM     mm2
  671.     LOAD_DIFF_4x4       mm4, mm5, mm6, mm7, mm3, r10, parm2q, r11, parm4q, 4
  672.     HADAMARD4x4_SUM     mm3
  673.     paddw       mm0, mm1
  674.     paddw       mm2, mm3
  675.     paddw       mm0, mm2
  676.     SATD_END
  678. ALIGN 16
  679. ;-----------------------------------------------------------------------------
  680. ;   int x264_pixel_satd_16x16_mmxext (uint8_t *, int, uint8_t *, int )
  681. ;-----------------------------------------------------------------------------
  682. x264_pixel_satd_16x16_mmxext:
  683.     SATD_START
  684.     mov         r10, parm1q
  685.     mov         r11, parm3q
  687.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm0, parm1q, parm2q, parm3q, parm4q, 0
  688.     HADAMARD4x4_SUM     mm0
  689.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm1, parm1q, parm2q, parm3q, parm4q, 0
  690.     HADAMARD4x4_SUM     mm1
  691.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm2, parm1q, parm2q, parm3q, parm4q, 0
  692.     HADAMARD4x4_SUM     mm2
  693.     LOAD_DIFF_4x4       mm4, mm5, mm6, mm7, mm3, parm1q, parm2q, parm3q, parm4q, 0
  694.     HADAMARD4x4_SUM     mm3
  695.     paddw       mm0, mm1
  696.     paddw       mm2, mm3
  697.     paddw       mm0, mm2
  699.     mov         parm1q, r10
  700.     mov         parm3q, r11
  701.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm1, parm1q, parm2q, parm3q, parm4q, 4
  702.     HADAMARD4x4_SUM     mm1
  703.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm2, parm1q, parm2q, parm3q, parm4q, 4
  704.     HADAMARD4x4_SUM     mm2
  705.     paddw       mm1, mm2
  707.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm2, parm1q, parm2q, parm3q, parm4q, 4
  708.     HADAMARD4x4_SUM     mm2
  709.     LOAD_DIFF_4x4       mm4, mm5, mm6, mm7, mm3, parm1q, parm2q, parm3q, parm4q, 4
  710.     HADAMARD4x4_SUM     mm3
  711.     paddw       mm0, mm1
  712.     paddw       mm2, mm3
  713.     paddw       mm0, mm2
  715.     mov         parm1q, r10
  716.     mov         parm3q, r11
  717.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm1, parm1q, parm2q, parm3q, parm4q, 8
  718.     HADAMARD4x4_SUM     mm1
  719.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm2, parm1q, parm2q, parm3q, parm4q, 8
  720.     HADAMARD4x4_SUM     mm2
  721.     paddw       mm1, mm2
  723.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm2, parm1q, parm2q, parm3q, parm4q, 8
  724.     HADAMARD4x4_SUM     mm2
  725.     LOAD_DIFF_4x4       mm4, mm5, mm6, mm7, mm3, parm1q, parm2q, parm3q, parm4q, 8
  726.     HADAMARD4x4_SUM     mm3
  727.     paddw       mm0, mm1
  728.     paddw       mm2, mm3
  729.     paddw       mm0, mm2
  731.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm1, r10, parm2q, r11, parm4q, 12
  732.     HADAMARD4x4_SUM     mm1
  733.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm2, r10, parm2q, r11, parm4q, 12
  734.     HADAMARD4x4_SUM     mm2
  735.     paddw       mm1, mm2
  737.     LOAD_DIFF_INC_4x4   mm4, mm5, mm6, mm7, mm2, r10, parm2q, r11, parm4q, 12
  738.     HADAMARD4x4_SUM     mm2
  739.     LOAD_DIFF_4x4       mm4, mm5, mm6, mm7, mm3, r10, parm2q, r11, parm4q, 12
  740.     HADAMARD4x4_SUM     mm3
  741.     paddw       mm0, mm1
  742.     paddw       mm2, mm3
  743.     paddw       mm0, mm2
  745.     pxor        mm3, mm3
  746.     pshufw      mm1, mm0, 01001110b
  747.     paddw       mm0, mm1
  748.     punpcklwd   mm0, mm3
  749.     pshufw      mm1, mm0, 01001110b
  750.     paddd       mm0, mm1
  751.     movd        eax, mm0
  752.     ret