开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 多媒体 > Audio > 查看源码
deblock-a.asm
资源名称：chapter15.rar　[点击查看]
上传用户：hjq518
上传日期：2021-12-09
资源大小：5084k
文件大小：14k
源码类别：

Audio

开发平台：

Visual C++

deblock-a.asm：源码内容
  1. ;*****************************************************************************
  2. ;* deblock-a.asm: h264 encoder library
  3. ;*****************************************************************************
  4. ;* Copyright (C) 2005 x264 project
  5. ;*
  6. ;* Authors: Loren Merritt <lorenm@u.washington.edu>
  7. ;*
  8. ;* This program is free software; you can redistribute it and/or modify
  9. ;* it under the terms of the GNU General Public License as published by
  10. ;* the Free Software Foundation; either version 2 of the License, or
  11. ;* (at your option) any later version.
  12. ;*
  13. ;* This program is distributed in the hope that it will be useful,
  14. ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  15. ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16. ;* GNU General Public License for more details.
  17. ;*
  18. ;* You should have received a copy of the GNU General Public License
  19. ;* along with this program; if not, write to the Free Software
  20. ;* Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111, USA.
  21. ;*****************************************************************************
  23. BITS 32
  25. %include "i386inc.asm"
  27. SECTION_RODATA
  28. pb_01: times 16 db 0x01
  29. pb_3f: times 16 db 0x3f
  30. pb_ff: times 16 db 0xff
  32. SECTION .text
  33. cglobal x264_deblock_v8_luma_mmxext
  34. cglobal x264_deblock_h_luma_mmxext
  35. cglobal x264_deblock_v_chroma_mmxext
  36. cglobal x264_deblock_h_chroma_mmxext
  37. cglobal x264_deblock_v_chroma_intra_mmxext
  38. cglobal x264_deblock_h_chroma_intra_mmxext
  40. ; expands to [base],...,[base+7*stride]
  41. %define PASS8ROWS(base, base3, stride, stride3) 
  42.     [base], [base+stride], [base+stride*2], [base3], 
  43.     [base3+stride], [base3+stride*2], [base3+stride3], [base3+stride*4]
  45. ; in: 8 rows of 4 bytes in %1..%8
  46. ; out: 4 rows of 8 bytes in mm0..mm3
  47. %macro TRANSPOSE4x8_LOAD 8
  48.     movd       mm0, %1
  49.     movd       mm2, %2
  50.     movd       mm1, %3
  51.     movd       mm3, %4
  52.     punpcklbw  mm0, mm2
  53.     punpcklbw  mm1, mm3
  54.     movq       mm2, mm0
  55.     punpcklwd  mm0, mm1
  56.     punpckhwd  mm2, mm1
  58.     movd       mm4, %5
  59.     movd       mm6, %6
  60.     movd       mm5, %7
  61.     movd       mm7, %8
  62.     punpcklbw  mm4, mm6
  63.     punpcklbw  mm5, mm7
  64.     movq       mm6, mm4
  65.     punpcklwd  mm4, mm5
  66.     punpckhwd  mm6, mm5
  68.     movq       mm1, mm0
  69.     movq       mm3, mm2
  70.     punpckldq  mm0, mm4
  71.     punpckhdq  mm1, mm4
  72.     punpckldq  mm2, mm6
  73.     punpckhdq  mm3, mm6
  74. %endmacro
  76. ; in: 4 rows of 8 bytes in mm0..mm3
  77. ; out: 8 rows of 4 bytes in %1..%8
  78. %macro TRANSPOSE8x4_STORE 8
  79.     movq       mm4, mm0
  80.     movq       mm5, mm1
  81.     movq       mm6, mm2
  82.     punpckhdq  mm4, mm4
  83.     punpckhdq  mm5, mm5
  84.     punpckhdq  mm6, mm6
  86.     punpcklbw  mm0, mm1
  87.     punpcklbw  mm2, mm3
  88.     movq       mm1, mm0
  89.     punpcklwd  mm0, mm2
  90.     punpckhwd  mm1, mm2
  91.     movd       %1,  mm0
  92.     punpckhdq  mm0, mm0
  93.     movd       %2,  mm0
  94.     movd       %3,  mm1
  95.     punpckhdq  mm1, mm1
  96.     movd       %4,  mm1
  98.     punpckhdq  mm3, mm3
  99.     punpcklbw  mm4, mm5
  100.     punpcklbw  mm6, mm3
  101.     movq       mm5, mm4
  102.     punpcklwd  mm4, mm6
  103.     punpckhwd  mm5, mm6
  104.     movd       %5,  mm4
  105.     punpckhdq  mm4, mm4
  106.     movd       %6,  mm4
  107.     movd       %7,  mm5
  108.     punpckhdq  mm5, mm5
  109.     movd       %8,  mm5
  110. %endmacro
  112. %macro SBUTTERFLY 4
  113.     movq       %4, %2
  114.     punpckl%1  %2, %3
  115.     punpckh%1  %4, %3
  116. %endmacro
  118. ; in: 8 rows of 8 (only the middle 6 pels are used) in %1..%8
  119. ; out: 6 rows of 8 in [%9+0*16] .. [%9+5*16]
  120. %macro TRANSPOSE6x8_MEM 9
  121.     movq  mm0, %1
  122.     movq  mm1, %3
  123.     movq  mm2, %5
  124.     movq  mm3, %7
  125.     SBUTTERFLY bw, mm0, %2, mm4
  126.     SBUTTERFLY bw, mm1, %4, mm5
  127.     SBUTTERFLY bw, mm2, %6, mm6
  128.     movq  [%9+0x10], mm5
  129.     SBUTTERFLY bw, mm3, %8, mm7
  130.     SBUTTERFLY wd, mm0, mm1, mm5
  131.     SBUTTERFLY wd, mm2, mm3, mm1
  132.     punpckhdq mm0, mm2
  133.     movq  [%9+0x00], mm0
  134.     SBUTTERFLY wd, mm4, [%9+0x10], mm3
  135.     SBUTTERFLY wd, mm6, mm7, mm2
  136.     SBUTTERFLY dq, mm4, mm6, mm0
  137.     SBUTTERFLY dq, mm5, mm1, mm7
  138.     punpckldq mm3, mm2
  139.     movq  [%9+0x10], mm5
  140.     movq  [%9+0x20], mm7
  141.     movq  [%9+0x30], mm4
  142.     movq  [%9+0x40], mm0
  143.     movq  [%9+0x50], mm3
  144. %endmacro
  146. ; out: %4 = |%1-%2|>%3
  147. ; clobbers: %5
  148. %macro DIFF_GT_MMX 5
  149.     movq    %5, %2
  150.     movq    %4, %1
  151.     psubusb %5, %1
  152.     psubusb %4, %2
  153.     por     %4, %5
  154.     psubusb %4, %3
  155. %endmacro
  157. ; in: mm0=p1 mm1=p0 mm2=q0 mm3=q1 %1=alpha-1 %2=beta-1
  158. ; out: mm5=beta-1, mm7=mask
  159. ; clobbers: mm4,mm6
  160. %macro LOAD_MASK_MMX 2
  161.     movd     mm4, %1
  162.     movd     mm5, %2
  163.     pshufw   mm4, mm4, 0
  164.     pshufw   mm5, mm5, 0
  165.     packuswb mm4, mm4  ; 8x alpha-1
  166.     packuswb mm5, mm5  ; 8x beta-1
  167.     DIFF_GT_MMX  mm1, mm2, mm4, mm7, mm6 ; |p0-q0| > alpha-1
  168.     DIFF_GT_MMX  mm0, mm1, mm5, mm4, mm6 ; |p1-p0| > beta-1
  169.     por      mm7, mm4
  170.     DIFF_GT_MMX  mm3, mm2, mm5, mm4, mm6 ; |q1-q0| > beta-1
  171.     por      mm7, mm4
  172.     pxor     mm6, mm6
  173.     pcmpeqb  mm7, mm6
  174. %endmacro
  176. ; in: mm0=p1 mm1=p0 mm2=q0 mm3=q1 mm7=(tc&mask)
  177. ; out: mm1=p0' mm2=q0'
  178. ; clobbers: mm0,3-6
  179. %macro DEBLOCK_P0_Q0_MMX 0
  180.     ; a = q0^p0^((p1-q1)>>2)
  181.     movq    mm4, mm0
  182.     psubb   mm4, mm3
  183.     psrlw   mm4, 2
  184.     pxor    mm4, mm1
  185.     pxor    mm4, mm2
  186.     ; b = p0^(q1>>2)
  187.     psrlw   mm3, 2
  188.     pand    mm3, [pb_3f GOT_ebx]
  189.     movq    mm5, mm1
  190.     pxor    mm5, mm3
  191.     ; c = q0^(p1>>2)
  192.     psrlw   mm0, 2
  193.     pand    mm0, [pb_3f GOT_ebx]
  194.     movq    mm6, mm2
  195.     pxor    mm6, mm0
  196.     ; d = (c^b) & ~(b^a) & 1
  197.     pxor    mm6, mm5
  198.     pxor    mm5, mm4
  199.     pandn   mm5, mm6
  200.     pand    mm5, [pb_01 GOT_ebx]
  201.     ; delta = (((q0 - p0 ) << 2) + (p1 - q1) + 4) >> 3
  202.     ;       = (avg(q0, p1>>2) + (d&a))
  203.     ;       - (avg(p0, q1>>2) + (d^(d&a)))
  204.     pavgb   mm0, mm2
  205.     pand    mm4, mm5
  206.     paddusb mm0, mm4
  207.     pavgb   mm3, mm1
  208.     pxor    mm4, mm5
  209.     paddusb mm3, mm4
  210.     ; p0 += clip(delta, -tc0, tc0)
  211.     ; q0 -= clip(delta, -tc0, tc0)
  212.     movq    mm4, mm0
  213.     psubusb mm0, mm3
  214.     psubusb mm3, mm4
  215.     pminub  mm0, mm7
  216.     pminub  mm3, mm7
  217.     paddusb mm1, mm0
  218.     paddusb mm2, mm3
  219.     psubusb mm1, mm3
  220.     psubusb mm2, mm0
  221. %endmacro
  223. ; in: mm1=p0 mm2=q0
  224. ;     %1=p1 %2=q2 %3=[q2] %4=[q1] %5=tc0 %6=tmp
  225. ; out: [q1] = clip( (q2+((p0+q0+1)>>1))>>1, q1-tc0, q1+tc0 )
  226. ; clobbers: q2, tmp, tc0
  227. %macro LUMA_Q1_MMX 6
  228.     movq    %6, mm1
  229.     pavgb   %6, mm2
  230.     pavgb   %2, %6              ; avg(p2,avg(p0,q0))
  231.     pxor    %6, %3
  232.     pand    %6, [pb_01 GOT_ebx] ; (p2^avg(p0,q0))&1
  233.     psubusb %2, %6              ; (p2+((p0+q0+1)>>1))>>1
  234.     movq    %6, %1
  235.     psubusb %6, %5
  236.     paddusb %5, %1
  237.     pmaxub  %2, %6
  238.     pminub  %2, %5
  239.     movq    %4, %2
  240. %endmacro
  243. SECTION .text
  245. ALIGN 16
  246. ;-----------------------------------------------------------------------------
  247. ;   void x264_deblock_v8_luma_mmxext( uint8_t *pix, int stride, int alpha, int beta, int8_t *tc0 )
  248. ;-----------------------------------------------------------------------------
  249. x264_deblock_v8_luma_mmxext:
  250.     picpush ebx
  251.     picgetgot ebx
  252.     push    edi
  253.     push    esi
  254.     mov     edi, [picesp+12] ; pix
  255.     mov     esi, [picesp+16] ; stride
  256.     mov     edx, [picesp+20] ; alpha
  257.     mov     ecx, [picesp+24] ; beta
  258.     dec     edx
  259.     dec     ecx
  260.     mov     eax, edi
  261.     sub     eax, esi
  262.     sub     eax, esi
  263.     sub     eax, esi ; pix-3*stride
  264.     sub     esp, 16
  266.     movq    mm0, [eax+esi]   ; p1
  267.     movq    mm1, [eax+2*esi] ; p0
  268.     movq    mm2, [edi]       ; q0
  269.     movq    mm3, [edi+esi]   ; q1
  270.     LOAD_MASK_MMX  edx, ecx
  272.     mov     ecx, [picesp+44] ; tc0, use only the low 16 bits
  273.     movd    mm4, [ecx]
  274.     punpcklbw mm4, mm4
  275.     punpcklbw mm4, mm4 ; tc = 4x tc0[1], 4x tc0[0]
  276.     movq   [esp+8], mm4 ; tc
  277.     pcmpgtb mm4, [pb_ff GOT_ebx]
  278.     pand    mm4, mm7
  279.     movq   [esp+0], mm4 ; mask
  281.     movq    mm3, [eax] ; p2
  282.     DIFF_GT_MMX  mm1, mm3, mm5, mm6, mm7 ; |p2-p0| > beta-1
  283.     pandn   mm6, mm4
  284.     pcmpeqb mm6, mm4
  285.     pand    mm6, mm4
  286.     pand    mm4, [esp+8] ; tc
  287.     movq    mm7, [pb_01 GOT_ebx]
  288.     pand    mm7, mm6
  289.     pand    mm6, mm4
  290.     paddb   mm7, mm4
  291.     LUMA_Q1_MMX  mm0, mm3, [eax], [eax+esi], mm6, mm4
  293.     movq    mm4, [edi+2*esi] ; q2
  294.     DIFF_GT_MMX  mm2, mm4, mm5, mm6, mm3 ; |q2-q0| > beta-1
  295.     movq    mm5, [esp+0] ; mask
  296.     pandn   mm6, mm5
  297.     pcmpeqb mm6, mm5
  298.     pand    mm6, mm5
  299.     movq    mm5, [esp+8] ; tc
  300.     pand    mm5, mm6
  301.     pand    mm6, [pb_01 GOT_ebx]
  302.     paddb   mm7, mm6
  303.     movq    mm3, [edi+esi]
  304.     LUMA_Q1_MMX  mm3, mm4, [edi+2*esi], [edi+esi], mm5, mm6
  306.     DEBLOCK_P0_Q0_MMX ; XXX: make sure ebx has the GOT in PIC mode
  307.     movq    [eax+2*esi], mm1
  308.     movq    [edi], mm2
  310.     add     esp, 16
  311.     pop     esi
  312.     pop     edi
  313.     picpop  ebx
  314.     ret
  317. ALIGN 16
  318. ;-----------------------------------------------------------------------------
  319. ;   void x264_deblock_h_luma_mmxext( uint8_t *pix, int stride, int alpha, int beta, int8_t *tc0 )
  320. ;-----------------------------------------------------------------------------
  321. x264_deblock_h_luma_mmxext:
  322.     push   ebx
  323.     push   ebp
  324.     mov    eax, [esp+12] ; pix
  325.     mov    ebx, [esp+16] ; stride
  326.     lea    ebp, [ebx+ebx*2]
  327.     sub    eax, 4
  328.     lea    ecx, [eax+ebp]
  329.     sub    esp, 96
  330. %define pix_tmp esp
  332.     ; transpose 6x16 -> tmp space
  333.     TRANSPOSE6x8_MEM  PASS8ROWS(eax, ecx, ebx, ebp), pix_tmp
  334.     lea    eax, [eax+ebx*8]
  335.     lea    ecx, [ecx+ebx*8]
  336.     TRANSPOSE6x8_MEM  PASS8ROWS(eax, ecx, ebx, ebp), pix_tmp+8
  338.     ; vertical filter
  339.     push   dword [esp+124] ; tc0
  340.     push   dword [esp+124] ; beta
  341.     push   dword [esp+124] ; alpha
  342.     push   dword 16
  343.     push   dword pix_tmp
  344.     add    dword [esp], 0x40 ; pix_tmp+0x30
  345.     call   x264_deblock_v8_luma_mmxext
  347.     add    dword [esp   ], 8 ; pix_tmp+0x38
  348.     add    dword [esp+16], 2 ; tc0+2
  349.     call   x264_deblock_v8_luma_mmxext
  350.     add    esp, 20
  351.     
  352.     ; transpose 16x4 -> original space  (only the middle 4 rows were changed by the filter)
  353.     mov    eax, [esp+108] ; pix
  354.     sub    eax, 2
  355.     lea    ecx, [eax+ebp]
  357.     movq   mm0, [pix_tmp+0x10]
  358.     movq   mm1, [pix_tmp+0x20]
  359.     movq   mm2, [pix_tmp+0x30]
  360.     movq   mm3, [pix_tmp+0x40]
  361.     TRANSPOSE8x4_STORE  PASS8ROWS(eax, ecx, ebx, ebp)
  363.     lea    eax, [eax+ebx*8]
  364.     lea    ecx, [ecx+ebx*8]
  365.     movq   mm0, [pix_tmp+0x18]
  366.     movq   mm1, [pix_tmp+0x28]
  367.     movq   mm2, [pix_tmp+0x38]
  368.     movq   mm3, [pix_tmp+0x48]
  369.     TRANSPOSE8x4_STORE  PASS8ROWS(eax, ecx, ebx, ebp)
  371.     add    esp, 96
  372.     pop    ebp
  373.     pop    ebx
  374.     ret
  377. %macro CHROMA_V_START 0
  378.     push  edi
  379.     push  esi
  380.     mov   edi, [esp+12] ; pix
  381.     mov   esi, [esp+16] ; stride
  382.     mov   edx, [esp+20] ; alpha
  383.     mov   ecx, [esp+24] ; beta
  384.     dec   edx
  385.     dec   ecx
  386.     mov   eax, edi
  387.     sub   eax, esi
  388.     sub   eax, esi
  389. %endmacro
  391. %macro CHROMA_H_START 0
  392.     push  edi
  393.     push  esi
  394.     push  ebp
  395.     mov   edi, [esp+16]
  396.     mov   esi, [esp+20]
  397.     mov   edx, [esp+24]
  398.     mov   ecx, [esp+28]
  399.     dec   edx
  400.     dec   ecx
  401.     sub   edi, 2
  402.     mov   ebp, esi
  403.     add   ebp, esi
  404.     add   ebp, esi
  405.     mov   eax, edi
  406.     add   edi, ebp
  407. %endmacro
  409. %macro CHROMA_END 0
  410.     pop  esi
  411.     pop  edi
  412.     ret
  413. %endmacro
  415. ALIGN 16
  416. ;-----------------------------------------------------------------------------
  417. ;   void x264_deblock_v_chroma_mmxext( uint8_t *pix, int stride, int alpha, int beta, int8_t *tc0 )
  418. ;-----------------------------------------------------------------------------
  419. x264_deblock_v_chroma_mmxext:
  420.     CHROMA_V_START
  421.     push  ebx
  422.     mov   ebx, [esp+32] ; tc0
  424.     movq  mm0, [eax]
  425.     movq  mm1, [eax+esi]
  426.     movq  mm2, [edi]
  427.     movq  mm3, [edi+esi]
  429.     LOAD_MASK_MMX  edx, ecx
  430.     movd       mm6, [ebx]
  431.     punpcklbw  mm6, mm6
  432.     pand       mm7, mm6
  433.     picgetgot  ebx ; no need to push ebx, it's already been done
  434.     DEBLOCK_P0_Q0_MMX ; XXX: make sure ebx has the GOT in PIC mode
  436.     movq  [eax+esi], mm1
  437.     movq  [edi], mm2
  439.     pop  ebx
  440.     CHROMA_END
  443. ALIGN 16
  444. ;-----------------------------------------------------------------------------
  445. ;   void x264_deblock_h_chroma_mmxext( uint8_t *pix, int stride, int alpha, int beta, int8_t *tc0 )
  446. ;-----------------------------------------------------------------------------
  447. x264_deblock_h_chroma_mmxext:
  448.     CHROMA_H_START
  449.     push  ebx
  450.     mov   ebx, [esp+36] ; tc0
  451.     sub   esp, 16
  453.     TRANSPOSE4x8_LOAD  PASS8ROWS(eax, edi, esi, ebp)
  454.     movq  [esp+8], mm0
  455.     movq  [esp+0], mm3
  457.     LOAD_MASK_MMX  edx, ecx
  458.     movd       mm6, [ebx]
  459.     punpcklbw  mm6, mm6
  460.     pand       mm7, mm6
  461.     picgetgot  ebx ; no need to push ebx, it's already been done
  462.     DEBLOCK_P0_Q0_MMX ; XXX: make sure ebx has the GOT in PIC mode
  464.     movq  mm0, [esp+8]
  465.     movq  mm3, [esp+0]
  466.     TRANSPOSE8x4_STORE PASS8ROWS(eax, edi, esi, ebp)
  468.     add  esp, 16
  469.     pop  ebx
  470.     pop  ebp
  471.     CHROMA_END
  474. ; in: %1=p0 %2=p1 %3=q1
  475. ; out: p0 = (p0 + q1 + 2*p1 + 2) >> 2
  476. %macro CHROMA_INTRA_P0 3
  477.     movq    mm4, %1
  478.     pxor    mm4, %3
  479.     pand    mm4, [pb_01 GOT_ebx]  ; mm4 = (p0^q1)&1
  480.     pavgb   %1,  %3
  481.     psubusb %1,  mm4
  482.     pavgb   %1,  %2       ; dst = avg(p1, avg(p0,q1) - ((p0^q1)&1))
  483. %endmacro
  485. %macro CHROMA_INTRA_BODY 0
  486.     LOAD_MASK_MMX edx, ecx
  487.     movq   mm5, mm1
  488.     movq   mm6, mm2
  489.     CHROMA_INTRA_P0  mm1, mm0, mm3
  490.     CHROMA_INTRA_P0  mm2, mm3, mm0
  491.     psubb  mm1, mm5
  492.     psubb  mm2, mm6
  493.     pand   mm1, mm7
  494.     pand   mm2, mm7
  495.     paddb  mm1, mm5
  496.     paddb  mm2, mm6
  497. %endmacro
  499. ALIGN 16
  500. ;-----------------------------------------------------------------------------
  501. ;   void x264_deblock_v_chroma_intra_mmxext( uint8_t *pix, int stride, int alpha, int beta )
  502. ;-----------------------------------------------------------------------------
  503. x264_deblock_v_chroma_intra_mmxext:
  504.     CHROMA_V_START
  505.     picpush ebx
  506.     picgetgot ebx
  507.     movq  mm0, [eax]
  508.     movq  mm1, [eax+esi]
  509.     movq  mm2, [edi]
  510.     movq  mm3, [edi+esi]
  511.     CHROMA_INTRA_BODY ; XXX: make sure ebx has the GOT in PIC mode
  512.     movq  [eax+esi], mm1
  513.     movq  [edi], mm2
  514.     picpop ebx
  515.     CHROMA_END
  517. ALIGN 16
  518. ;-----------------------------------------------------------------------------
  519. ;   void x264_deblock_h_chroma_intra_mmxext( uint8_t *pix, int stride, int alpha, int beta )
  520. ;-----------------------------------------------------------------------------
  521. x264_deblock_h_chroma_intra_mmxext:
  522.     CHROMA_H_START
  523.     picpush ebx
  524.     picgetgot ebx
  525.     TRANSPOSE4x8_LOAD  PASS8ROWS(eax, edi, esi, ebp)
  526.     CHROMA_INTRA_BODY ; XXX: make sure ebx has the GOT in PIC mode
  527.     TRANSPOSE8x4_STORE PASS8ROWS(eax, edi, esi, ebp)
  528.     picpop ebx
  529.     pop  ebp ; needed because of CHROMA_H_START
  530.     CHROMA_END