开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 多媒体 > Audio > 查看源码
dct-a.asm
资源名称：chapter15.rar　[点击查看]
上传用户：hjq518
上传日期：2021-12-09
资源大小：5084k
文件大小：16k
源码类别：

Audio

开发平台：

Visual C++

dct-a.asm：源码内容
  1. ;*****************************************************************************
  2. ;* dct-a.asm: h264 encoder library
  3. ;*****************************************************************************
  4. ;* Copyright (C) 2003-2008 x264 project
  5. ;*
  6. ;* Authors: Laurent Aimar <fenrir@via.ecp.fr>
  7. ;*          Loren Merritt <lorenm@u.washington.edu>
  8. ;*          Min Chen <chenm001.163.com>
  9. ;*
  10. ;* This program is free software; you can redistribute it and/or modify
  11. ;* it under the terms of the GNU General Public License as published by
  12. ;* the Free Software Foundation; either version 2 of the License, or
  13. ;* (at your option) any later version.
  14. ;*
  15. ;* This program is distributed in the hope that it will be useful,
  16. ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  17. ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18. ;* GNU General Public License for more details.
  19. ;*
  20. ;* You should have received a copy of the GNU General Public License
  21. ;* along with this program; if not, write to the Free Software
  22. ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02111, USA.
  23. ;*****************************************************************************
  25. %include "x86inc.asm"
  26. %include "x86util.asm"
  28. SECTION_RODATA
  29. pw_1:  times 8 dw 1
  30. pw_32: times 8 dw 32
  31. pb_sub4frame:   db 0,1,4,8,5,2,3,6,9,12,13,10,7,11,14,15
  32. pb_scan4framea: db 12,13,6,7,14,15,0,1,8,9,2,3,4,5,10,11
  33. pb_scan4frameb: db 0,1,8,9,2,3,4,5,10,11,12,13,6,7,14,15
  35. SECTION .text
  37. %macro HADAMARD4_1D 4
  38.     SUMSUB_BADC m%2, m%1, m%4, m%3
  39.     SUMSUB_BADC m%4, m%2, m%3, m%1
  40.     SWAP %1, %4, %3
  41. %endmacro
  43. ;-----------------------------------------------------------------------------
  44. ; void x264_dct4x4dc_mmx( int16_t d[4][4] )
  45. ;-----------------------------------------------------------------------------
  46. cglobal x264_dct4x4dc_mmx, 1,1
  47.     movq   m0, [r0+ 0]
  48.     movq   m1, [r0+ 8]
  49.     movq   m2, [r0+16]
  50.     movq   m3, [r0+24]
  51.     HADAMARD4_1D  0,1,2,3
  52.     TRANSPOSE4x4W 0,1,2,3,4
  53.     HADAMARD4_1D  0,1,2,3
  54.     movq   m6, [pw_1 GLOBAL]
  55.     paddw  m0, m6
  56.     paddw  m1, m6
  57.     paddw  m2, m6
  58.     paddw  m3, m6
  59.     psraw  m0, 1
  60.     psraw  m1, 1
  61.     psraw  m2, 1
  62.     psraw  m3, 1
  63.     movq  [r0+0], m0
  64.     movq  [r0+8], m1
  65.     movq [r0+16], m2
  66.     movq [r0+24], m3
  67.     RET
  69. ;-----------------------------------------------------------------------------
  70. ; void x264_idct4x4dc_mmx( int16_t d[4][4] )
  71. ;-----------------------------------------------------------------------------
  72. cglobal x264_idct4x4dc_mmx, 1,1
  73.     movq  m0, [r0+ 0]
  74.     movq  m1, [r0+ 8]
  75.     movq  m2, [r0+16]
  76.     movq  m3, [r0+24]
  77.     HADAMARD4_1D  0,1,2,3
  78.     TRANSPOSE4x4W 0,1,2,3,4
  79.     HADAMARD4_1D  0,1,2,3
  80.     movq  [r0+ 0], m0
  81.     movq  [r0+ 8], m1
  82.     movq  [r0+16], m2
  83.     movq  [r0+24], m3
  84.     RET
  86. %macro DCT4_1D 5
  87.     SUMSUB_BADC m%4, m%1, m%3, m%2
  88.     SUMSUB_BA   m%3, m%4
  89.     SUMSUB2_AB  m%1, m%2, m%5
  90.     SWAP %1, %3, %4, %5, %2
  91. %endmacro
  93. %macro IDCT4_1D 6
  94.     SUMSUB_BA   m%3, m%1
  95.     SUMSUBD2_AB m%2, m%4, m%6, m%5
  96.     SUMSUB_BADC m%2, m%3, m%5, m%1
  97.     SWAP %1, %2, %5, %4, %3
  98. %endmacro
  100. ;-----------------------------------------------------------------------------
  101. ; void x264_sub4x4_dct_mmx( int16_t dct[4][4], uint8_t *pix1, uint8_t *pix2 )
  102. ;-----------------------------------------------------------------------------
  103. cglobal x264_sub4x4_dct_mmx, 3,3
  104. .skip_prologue:
  105. %macro SUB_DCT4 1
  106.     LOAD_DIFF  m0, m6, m7, [r1+0*FENC_STRIDE], [r2+0*FDEC_STRIDE]
  107.     LOAD_DIFF  m1, m6, m7, [r1+1*FENC_STRIDE], [r2+1*FDEC_STRIDE]
  108.     LOAD_DIFF  m2, m6, m7, [r1+2*FENC_STRIDE], [r2+2*FDEC_STRIDE]
  109.     LOAD_DIFF  m3, m6, m7, [r1+3*FENC_STRIDE], [r2+3*FDEC_STRIDE]
  110.     DCT4_1D 0,1,2,3,4
  111.     TRANSPOSE%1 0,1,2,3,4
  112.     DCT4_1D 0,1,2,3,4
  113.     movq  [r0+ 0], m0
  114.     movq  [r0+ 8], m1
  115.     movq  [r0+16], m2
  116.     movq  [r0+24], m3
  117. %endmacro
  118.     SUB_DCT4 4x4W
  119.     RET
  121. ;-----------------------------------------------------------------------------
  122. ; void x264_add4x4_idct_mmx( uint8_t *p_dst, int16_t dct[4][4] )
  123. ;-----------------------------------------------------------------------------
  124. cglobal x264_add4x4_idct_mmx, 2,2
  125. .skip_prologue:
  126.     movq  m0, [r1+ 0]
  127.     movq  m1, [r1+ 8]
  128.     movq  m2, [r1+16]
  129.     movq  m3, [r1+24]
  130. %macro ADD_IDCT4 1
  131.     IDCT4_1D 0,1,2,3,4,5
  132.     TRANSPOSE%1 0,1,2,3,4
  133.     paddw m0, [pw_32 GLOBAL]
  134.     IDCT4_1D 0,1,2,3,4,5
  135.     pxor  m7, m7
  136.     STORE_DIFF  m0, m4, m7, [r0+0*FDEC_STRIDE]
  137.     STORE_DIFF  m1, m4, m7, [r0+1*FDEC_STRIDE]
  138.     STORE_DIFF  m2, m4, m7, [r0+2*FDEC_STRIDE]
  139.     STORE_DIFF  m3, m4, m7, [r0+3*FDEC_STRIDE]
  140. %endmacro
  141.     ADD_IDCT4 4x4W
  142.     RET
  144. INIT_XMM
  146. cglobal x264_sub8x8_dct_sse2, 3,3
  147. .skip_prologue:
  148.     call .8x4
  149.     add  r0, 64
  150.     add  r1, 4*FENC_STRIDE
  151.     add  r2, 4*FDEC_STRIDE
  152. .8x4:
  153.     SUB_DCT4 2x4x4W
  154.     movhps [r0+32], m0
  155.     movhps [r0+40], m1
  156.     movhps [r0+48], m2
  157.     movhps [r0+56], m3
  158.     ret
  160. cglobal x264_add8x8_idct_sse2, 2,2
  161. .skip_prologue:
  162.     call .8x4
  163.     add  r1, 64
  164.     add  r0, 4*FDEC_STRIDE
  165. .8x4:
  166.     movq   m0, [r1+ 0]
  167.     movq   m1, [r1+ 8]
  168.     movq   m2, [r1+16]
  169.     movq   m3, [r1+24]
  170.     movhps m0, [r1+32]
  171.     movhps m1, [r1+40]
  172.     movhps m2, [r1+48]
  173.     movhps m3, [r1+56]
  174.     ADD_IDCT4 2x4x4W
  175.     ret
  177. ;-----------------------------------------------------------------------------
  178. ; void x264_sub8x8_dct_mmx( int16_t dct[4][4][4], uint8_t *pix1, uint8_t *pix2 )
  179. ;-----------------------------------------------------------------------------
  180. %macro SUB_NxN_DCT 6
  181. cglobal %1, 3,3
  182. .skip_prologue:
  183.     call %2
  184.     add  r0, %3
  185.     add  r1, %4-%5-%6*FENC_STRIDE
  186.     add  r2, %4-%5-%6*FDEC_STRIDE
  187.     call %2
  188.     add  r0, %3
  189.     add  r1, (%4-%6)*FENC_STRIDE-%5-%4
  190.     add  r2, (%4-%6)*FDEC_STRIDE-%5-%4
  191.     call %2
  192.     add  r0, %3
  193.     add  r1, %4-%5-%6*FENC_STRIDE
  194.     add  r2, %4-%5-%6*FDEC_STRIDE
  195.     jmp  %2
  196. %endmacro
  198. ;-----------------------------------------------------------------------------
  199. ; void x264_add8x8_idct_mmx( uint8_t *pix, int16_t dct[4][4][4] )
  200. ;-----------------------------------------------------------------------------
  201. %macro ADD_NxN_IDCT 6
  202. cglobal %1, 2,2
  203. .skip_prologue:
  204.     call %2
  205.     add  r0, %4-%5-%6*FDEC_STRIDE
  206.     add  r1, %3
  207.     call %2
  208.     add  r0, (%4-%6)*FDEC_STRIDE-%5-%4
  209.     add  r1, %3
  210.     call %2
  211.     add  r0, %4-%5-%6*FDEC_STRIDE
  212.     add  r1, %3
  213.     jmp  %2
  214. %endmacro
  216. %ifndef ARCH_X86_64
  217. SUB_NxN_DCT  x264_sub8x8_dct_mmx,    x264_sub4x4_dct_mmx  %+ .skip_prologue, 32, 4, 0, 0
  218. ADD_NxN_IDCT x264_add8x8_idct_mmx,   x264_add4x4_idct_mmx %+ .skip_prologue, 32, 4, 0, 0
  219. SUB_NxN_DCT  x264_sub16x16_dct_mmx,  x264_sub8x8_dct_mmx  %+ .skip_prologue, 32, 8, 4, 4
  220. ADD_NxN_IDCT x264_add16x16_idct_mmx, x264_add8x8_idct_mmx %+ .skip_prologue, 32, 8, 4, 4
  222. cextern x264_sub8x8_dct8_mmx.skip_prologue
  223. cextern x264_add8x8_idct8_mmx.skip_prologue
  224. SUB_NxN_DCT  x264_sub16x16_dct8_mmx,  x264_sub8x8_dct8_mmx  %+ .skip_prologue, 128, 8, 0, 0
  225. ADD_NxN_IDCT x264_add16x16_idct8_mmx, x264_add8x8_idct8_mmx %+ .skip_prologue, 128, 8, 0, 0
  226. %define x264_sub8x8_dct8_sse2 x264_sub8x8_dct8_sse2.skip_prologue
  227. %define x264_add8x8_idct8_sse2 x264_add8x8_idct8_sse2.skip_prologue
  228. %endif
  230. SUB_NxN_DCT  x264_sub16x16_dct_sse2,  x264_sub8x8_dct_sse2  %+ .skip_prologue, 64, 8, 0, 4
  231. ADD_NxN_IDCT x264_add16x16_idct_sse2, x264_add8x8_idct_sse2 %+ .skip_prologue, 64, 8, 0, 4
  233. cextern x264_sub8x8_dct8_sse2
  234. cextern x264_add8x8_idct8_sse2
  235. SUB_NxN_DCT  x264_sub16x16_dct8_sse2,  x264_sub8x8_dct8_sse2,  128, 8, 0, 0
  236. ADD_NxN_IDCT x264_add16x16_idct8_sse2, x264_add8x8_idct8_sse2, 128, 8, 0, 0
  238. ;-----------------------------------------------------------------------------
  239. ; void x264_zigzag_scan_8x8_frame_ssse3( int16_t level[64], int16_t dct[8][8] )
  240. ;-----------------------------------------------------------------------------
  241. %macro SCAN_8x8 1
  242. cglobal x264_zigzag_scan_8x8_frame_%1, 2,2
  243.     movdqa    xmm0, [r1]
  244.     movdqa    xmm1, [r1+16]
  245.     movdq2q    mm0, xmm0
  246.     PALIGNR   xmm1, xmm1, 14, xmm2
  247.     movdq2q    mm1, xmm1
  249.     movdqa    xmm2, [r1+32]
  250.     movdqa    xmm3, [r1+48]
  251.     PALIGNR   xmm2, xmm2, 12, xmm4
  252.     movdq2q    mm2, xmm2
  253.     PALIGNR   xmm3, xmm3, 10, xmm4
  254.     movdq2q    mm3, xmm3
  256.     punpckhwd xmm0, xmm1
  257.     punpckhwd xmm2, xmm3
  259.     movq       mm4, mm1
  260.     movq       mm5, mm1
  261.     movq       mm6, mm2
  262.     movq       mm7, mm3
  263.     punpckhwd  mm1, mm0
  264.     psllq      mm0, 16
  265.     psrlq      mm3, 16
  266.     punpckhdq  mm1, mm1
  267.     punpckhdq  mm2, mm0
  268.     punpcklwd  mm0, mm4
  269.     punpckhwd  mm4, mm3
  270.     punpcklwd  mm4, mm2
  271.     punpckhdq  mm0, mm2
  272.     punpcklwd  mm6, mm3
  273.     punpcklwd  mm5, mm7
  274.     punpcklwd  mm5, mm6
  276.     movdqa    xmm4, [r1+64]
  277.     movdqa    xmm5, [r1+80]
  278.     movdqa    xmm6, [r1+96]
  279.     movdqa    xmm7, [r1+112]
  281.     movq [r0+2*00], mm0
  282.     movq [r0+2*04], mm4
  283.     movd [r0+2*08], mm1
  284.     movq [r0+2*36], mm5
  285.     movq [r0+2*46], mm6
  287.     PALIGNR   xmm4, xmm4, 14, xmm3
  288.     movdq2q    mm4, xmm4
  289.     PALIGNR   xmm5, xmm5, 12, xmm3
  290.     movdq2q    mm5, xmm5
  291.     PALIGNR   xmm6, xmm6, 10, xmm3
  292.     movdq2q    mm6, xmm6
  293. %ifidn %1, ssse3
  294.     PALIGNR   xmm7, xmm7, 8, xmm3
  295.     movdq2q    mm7, xmm7
  296. %else
  297.     movhlps   xmm3, xmm7
  298.     movlhps   xmm7, xmm7
  299.     movdq2q    mm7, xmm3
  300. %endif
  302.     punpckhwd xmm4, xmm5
  303.     punpckhwd xmm6, xmm7
  305.     movq       mm0, mm4
  306.     movq       mm1, mm5
  307.     movq       mm3, mm7
  308.     punpcklwd  mm7, mm6
  309.     psrlq      mm6, 16
  310.     punpcklwd  mm4, mm6
  311.     punpcklwd  mm5, mm4
  312.     punpckhdq  mm4, mm3
  313.     punpcklwd  mm3, mm6
  314.     punpckhwd  mm3, mm4
  315.     punpckhwd  mm0, mm1
  316.     punpckldq  mm4, mm0
  317.     punpckhdq  mm0, mm6
  318.     pshufw     mm4, mm4, 0x6c
  320.     movq [r0+2*14], mm4
  321.     movq [r0+2*25], mm0
  322.     movd [r0+2*54], mm7
  323.     movq [r0+2*56], mm5
  324.     movq [r0+2*60], mm3
  326.     movdqa    xmm3, xmm0
  327.     movdqa    xmm7, xmm4
  328.     punpckldq xmm0, xmm2
  329.     punpckldq xmm4, xmm6
  330.     punpckhdq xmm3, xmm2
  331.     punpckhdq xmm7, xmm6
  332.     pshufhw   xmm0, xmm0, 0x1b
  333.     pshuflw   xmm4, xmm4, 0x1b
  334.     pshufhw   xmm3, xmm3, 0x1b
  335.     pshuflw   xmm7, xmm7, 0x1b
  337.     movlps [r0+2*10], xmm0
  338.     movhps [r0+2*17], xmm0
  339.     movlps [r0+2*21], xmm3
  340.     movlps [r0+2*28], xmm4
  341.     movhps [r0+2*32], xmm3
  342.     movhps [r0+2*39], xmm4
  343.     movlps [r0+2*43], xmm7
  344.     movhps [r0+2*50], xmm7
  346.     RET
  347. %endmacro
  349. INIT_XMM
  350. %define PALIGNR PALIGNR_MMX
  351. SCAN_8x8 sse2
  352. %define PALIGNR PALIGNR_SSSE3
  353. SCAN_8x8 ssse3
  355. ;-----------------------------------------------------------------------------
  356. ; void x264_zigzag_scan_8x8_frame_mmxext( int16_t level[64], int16_t dct[8][8] )
  357. ;-----------------------------------------------------------------------------
  358. cglobal x264_zigzag_scan_8x8_frame_mmxext, 2,2
  359.     movq       mm0, [r1]
  360.     movq       mm1, [r1+2*8]
  361.     movq       mm2, [r1+2*14]
  362.     movq       mm3, [r1+2*21]
  363.     movq       mm4, [r1+2*28]
  364.     movq       mm5, mm0
  365.     movq       mm6, mm1
  366.     psrlq      mm0, 16
  367.     punpckldq  mm1, mm1
  368.     punpcklwd  mm5, mm6
  369.     punpckhwd  mm1, mm3
  370.     punpckhwd  mm6, mm0
  371.     punpckldq  mm5, mm0
  372.     movq       mm7, [r1+2*52]
  373.     movq       mm0, [r1+2*60]
  374.     punpckhwd  mm1, mm2
  375.     punpcklwd  mm2, mm4
  376.     punpckhwd  mm4, mm3
  377.     punpckldq  mm3, mm3
  378.     punpckhwd  mm3, mm2
  379.     movq      [r0], mm5
  380.     movq  [r0+2*4], mm1
  381.     movq  [r0+2*8], mm6
  382.     punpcklwd  mm6, mm0
  383.     punpcklwd  mm6, mm7
  384.     movq       mm1, [r1+2*32]
  385.     movq       mm5, [r1+2*39]
  386.     movq       mm2, [r1+2*46]
  387.     movq [r0+2*35], mm3
  388.     movq [r0+2*47], mm4
  389.     punpckhwd  mm7, mm0
  390.     psllq      mm0, 16
  391.     movq       mm3, mm5
  392.     punpcklwd  mm5, mm1
  393.     punpckhwd  mm1, mm2
  394.     punpckhdq  mm3, mm3
  395.     movq [r0+2*52], mm6
  396.     movq [r0+2*13], mm5
  397.     movq       mm4, [r1+2*11]
  398.     movq       mm6, [r1+2*25]
  399.     punpcklwd  mm5, mm7
  400.     punpcklwd  mm1, mm3
  401.     punpckhdq  mm0, mm7
  402.     movq       mm3, [r1+2*4]
  403.     movq       mm7, [r1+2*18]
  404.     punpcklwd  mm2, mm5
  405.     movq [r0+2*25], mm1
  406.     movq       mm1, mm4
  407.     movq       mm5, mm6
  408.     punpcklwd  mm4, mm3
  409.     punpcklwd  mm6, mm7
  410.     punpckhwd  mm1, mm3
  411.     punpckhwd  mm5, mm7
  412.     movq       mm3, mm6
  413.     movq       mm7, mm5
  414.     punpckldq  mm6, mm4
  415.     punpckldq  mm5, mm1
  416.     punpckhdq  mm3, mm4
  417.     punpckhdq  mm7, mm1
  418.     movq       mm4, [r1+2*35]
  419.     movq       mm1, [r1+2*49]
  420.     pshufw     mm6, mm6, 0x1b
  421.     pshufw     mm5, mm5, 0x1b
  422.     movq [r0+2*60], mm0
  423.     movq [r0+2*56], mm2
  424.     movq       mm0, [r1+2*42]
  425.     movq       mm2, [r1+2*56]
  426.     movq [r0+2*17], mm3
  427.     movq [r0+2*32], mm7
  428.     movq [r0+2*10], mm6
  429.     movq [r0+2*21], mm5
  430.     movq       mm3, mm0
  431.     movq       mm7, mm2
  432.     punpcklwd  mm0, mm4
  433.     punpcklwd  mm2, mm1
  434.     punpckhwd  mm3, mm4
  435.     punpckhwd  mm7, mm1
  436.     movq       mm4, mm2
  437.     movq       mm1, mm7
  438.     punpckhdq  mm2, mm0
  439.     punpckhdq  mm7, mm3
  440.     punpckldq  mm4, mm0
  441.     punpckldq  mm1, mm3
  442.     pshufw     mm2, mm2, 0x1b
  443.     pshufw     mm7, mm7, 0x1b
  444.     movq [r0+2*28], mm4
  445.     movq [r0+2*43], mm1
  446.     movq [r0+2*39], mm2
  447.     movq [r0+2*50], mm7
  448.     RET
  450. ;-----------------------------------------------------------------------------
  451. ; void x264_zigzag_scan_4x4_frame_mmx( int16_t level[16], int16_t dct[4][4] )
  452. ;-----------------------------------------------------------------------------
  453. cglobal x264_zigzag_scan_4x4_frame_mmx, 2,2
  454.     movq       mm0, [r1]
  455.     movq       mm1, [r1+8]
  456.     movq       mm2, [r1+16]
  457.     movq       mm3, [r1+24]
  458.     movq       mm4, mm0
  459.     movq       mm5, mm1
  460.     movq       mm6, mm2
  461.     movq       mm7, mm3
  462.     psllq      mm3, 16
  463.     psrlq      mm0, 16
  464.     punpckldq  mm2, mm2
  465.     punpckhdq  mm1, mm1
  466.     punpcklwd  mm4, mm5
  467.     punpcklwd  mm5, mm3
  468.     punpckldq  mm4, mm0
  469.     punpckhwd  mm5, mm2
  470.     punpckhwd  mm0, mm6
  471.     punpckhwd  mm6, mm7
  472.     punpcklwd  mm1, mm0
  473.     punpckhdq  mm3, mm6
  474.     movq      [r0], mm4
  475.     movq    [r0+8], mm5
  476.     movq   [r0+16], mm1
  477.     movq   [r0+24], mm3
  478.     RET
  480. ;-----------------------------------------------------------------------------
  481. ; void x264_zigzag_scan_4x4_frame_ssse3( int16_t level[16], int16_t dct[4][4] )
  482. ;-----------------------------------------------------------------------------
  483. cglobal x264_zigzag_scan_4x4_frame_ssse3, 2,2
  484.     movdqa    xmm1, [r1+16]
  485.     movdqa    xmm0, [r1]
  486.     pshufb    xmm1, [pb_scan4frameb GLOBAL]
  487.     pshufb    xmm0, [pb_scan4framea GLOBAL]
  488.     movdqa    xmm2, xmm1
  489.     psrldq    xmm1, 6
  490.     palignr   xmm2, xmm0, 6
  491.     pslldq    xmm0, 10
  492.     palignr   xmm1, xmm0, 10
  493.     movdqa    [r0], xmm2
  494.     movdqa [r0+16], xmm1
  495.     RET
  497. ;-----------------------------------------------------------------------------
  498. ; void x264_zigzag_scan_4x4_field_mmxext( int16_t level[16], int16_t dct[4][4] )
  499. ;-----------------------------------------------------------------------------
  500. ; sse2 is only 1 cycle faster, and ssse3/pshufb is slower on core2
  501. cglobal x264_zigzag_scan_4x4_field_mmxext, 2,3
  502.     pshufw     mm0, [r1+4], 0xd2
  503.     movq       mm1, [r1+16]
  504.     movq       mm2, [r1+24]
  505.     movq    [r0+4], mm0
  506.     movq   [r0+16], mm1
  507.     movq   [r0+24], mm2
  508.     mov        r2d, [r1]
  509.     mov       [r0], r2d
  510.     mov        r2d, [r1+12]
  511.     mov    [r0+12], r2d
  512.     RET
  514. ;-----------------------------------------------------------------------------
  515. ; void x264_zigzag_sub_4x4_frame_ssse3( int16_t level[16], const uint8_t *src, uint8_t *dst )
  516. ;-----------------------------------------------------------------------------
  517. cglobal x264_zigzag_sub_4x4_frame_ssse3, 3,3
  518.     movd      xmm0, [r1+0*FENC_STRIDE]
  519.     movd      xmm1, [r1+1*FENC_STRIDE]
  520.     movd      xmm2, [r1+2*FENC_STRIDE]
  521.     movd      xmm3, [r1+3*FENC_STRIDE]
  522.     movd      xmm4, [r2+0*FDEC_STRIDE]
  523.     movd      xmm5, [r2+1*FDEC_STRIDE]
  524.     movd      xmm6, [r2+2*FDEC_STRIDE]
  525.     movd      xmm7, [r2+3*FDEC_STRIDE]
  526.     movd      [r2+0*FDEC_STRIDE], xmm0
  527.     movd      [r2+1*FDEC_STRIDE], xmm1
  528.     movd      [r2+2*FDEC_STRIDE], xmm2
  529.     movd      [r2+3*FDEC_STRIDE], xmm3
  530.     punpckldq xmm0, xmm1
  531.     punpckldq xmm2, xmm3
  532.     punpckldq xmm4, xmm5
  533.     punpckldq xmm6, xmm7
  534.     movlhps   xmm0, xmm2
  535.     movlhps   xmm4, xmm6
  536.     movdqa    xmm7, [pb_sub4frame GLOBAL]
  537.     pshufb    xmm0, xmm7
  538.     pshufb    xmm4, xmm7
  539.     pxor      xmm6, xmm6
  540.     movdqa    xmm1, xmm0
  541.     movdqa    xmm5, xmm4
  542.     punpcklbw xmm0, xmm6
  543.     punpckhbw xmm1, xmm6
  544.     punpcklbw xmm4, xmm6
  545.     punpckhbw xmm5, xmm6
  546.     psubw     xmm0, xmm4
  547.     psubw     xmm1, xmm5
  548.     movdqa    [r0], xmm0
  549.     movdqa [r0+16], xmm1
  550.     RET