开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 多媒体 > Audio > 查看源码
pixel-32.asm
资源名称：chapter15.rar　[点击查看]
上传用户：hjq518
上传日期：2021-12-09
资源大小：5084k
文件大小：11k
源码类别：

Audio

开发平台：

Visual C++

pixel-32.asm：源码内容
  1. ;*****************************************************************************
  2. ;* pixel-32.asm: h264 encoder library
  3. ;*****************************************************************************
  4. ;* Copyright (C) 2003-2008 x264 project
  5. ;*
  6. ;* Authors: Laurent Aimar <fenrir@via.ecp.fr>
  7. ;*          Loren Merritt <lorenm@u.washington.edu>
  8. ;*
  9. ;* This program is free software; you can redistribute it and/or modify
  10. ;* it under the terms of the GNU General Public License as published by
  11. ;* the Free Software Foundation; either version 2 of the License, or
  12. ;* (at your option) any later version.
  13. ;*
  14. ;* This program is distributed in the hope that it will be useful,
  15. ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  16. ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17. ;* GNU General Public License for more details.
  18. ;*
  19. ;* You should have received a copy of the GNU General Public License
  20. ;* along with this program; if not, write to the Free Software
  21. ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02111, USA.
  22. ;*****************************************************************************
  24. %include "x86inc.asm"
  25. %include "x86util.asm"
  27. SECTION .text
  28. INIT_MMX
  30. %macro LOAD_DIFF_4P 4  ; mp, mt, dx, dy
  31.     movd        %1, [eax+ebx*%4+%3]
  32.     movd        %2, [ecx+edx*%4+%3]
  33.     punpcklbw   %1, %2
  34.     punpcklbw   %2, %2
  35.     psubw       %1, %2
  36. %endmacro
  38. %macro LOAD_DIFF_4x8P 1 ; dx
  39.     LOAD_DIFF_4P  m0, m7, %1, 0
  40.     LOAD_DIFF_4P  m1, m7, %1, 1
  41.     lea  eax, [eax+2*ebx]
  42.     lea  ecx, [ecx+2*edx]
  43.     LOAD_DIFF_4P  m2, m7, %1, 0
  44.     LOAD_DIFF_4P  m3, m7, %1, 1
  45.     lea  eax, [eax+2*ebx]
  46.     lea  ecx, [ecx+2*edx]
  47.     LOAD_DIFF_4P  m4, m7, %1, 0
  48.     LOAD_DIFF_4P  m5, m7, %1, 1
  49.     lea  eax, [eax+2*ebx]
  50.     lea  ecx, [ecx+2*edx]
  51.     LOAD_DIFF_4P  m6, m7, %1, 0
  52.     movq [spill], m6
  53.     LOAD_DIFF_4P  m7, m6, %1, 1
  54.     movq m6, [spill]
  55. %endmacro
  57. %macro SUM4x8_MM 0
  58.     movq [spill],   m6
  59.     movq [spill+8], m7
  60.     ABS2     m0, m1, m6, m7
  61.     ABS2     m2, m3, m6, m7
  62.     paddw    m0, m2
  63.     paddw    m1, m3
  64.     movq     m6, [spill]
  65.     movq     m7, [spill+8]
  66.     ABS2     m4, m5, m2, m3
  67.     ABS2     m6, m7, m2, m3
  68.     paddw    m4, m6
  69.     paddw    m5, m7
  70.     paddw    m0, m4
  71.     paddw    m1, m5
  72.     paddw    m0, m1
  73. %endmacro
  75. ;-----------------------------------------------------------------------------
  76. ; int x264_pixel_sa8d_8x8_mmxext( uint8_t *, int, uint8_t *, int )
  77. ;-----------------------------------------------------------------------------
  78. cglobal x264_pixel_sa8d_8x8_mmxext
  79.     push   ebx
  80.     mov    eax, [esp+ 8]  ; pix1
  81.     mov    ebx, [esp+12]  ; stride1
  82.     mov    ecx, [esp+16]  ; pix2
  83.     mov    edx, [esp+20]  ; stride2
  84.     sub    esp, 0x70
  85. %define args  esp+0x74
  86. %define spill esp+0x60 ; +16
  87. %define trans esp+0    ; +96
  88.     LOAD_DIFF_4x8P 0
  89.     HADAMARD8_1D m0, m1, m2, m3, m4, m5, m6, m7
  91.     movq   [spill], m0
  92.     TRANSPOSE4x4W 4, 5, 6, 7, 0
  93.     movq   [trans+0x00], m4
  94.     movq   [trans+0x08], m5
  95.     movq   [trans+0x10], m6
  96.     movq   [trans+0x18], m7
  97.     movq   m0, [spill]
  98.     TRANSPOSE4x4W 0, 1, 2, 3, 4
  99.     movq   [trans+0x20], m0
  100.     movq   [trans+0x28], m1
  101.     movq   [trans+0x30], m2
  102.     movq   [trans+0x38], m3
  104.     mov    eax, [args+4]
  105.     mov    ecx, [args+12]
  106.     LOAD_DIFF_4x8P 4
  107.     HADAMARD8_1D m0, m1, m2, m3, m4, m5, m6, m7
  109.     movq   [spill], m7
  110.     TRANSPOSE4x4W 0, 1, 2, 3, 7
  111.     movq   [trans+0x40], m0
  112.     movq   [trans+0x48], m1
  113.     movq   [trans+0x50], m2
  114.     movq   [trans+0x58], m3
  115.     movq   m7, [spill]
  116.     TRANSPOSE4x4W 4, 5, 6, 7, 0
  117.     movq   m0, [trans+0x00]
  118.     movq   m1, [trans+0x08]
  119.     movq   m2, [trans+0x10]
  120.     movq   m3, [trans+0x18]
  122.     HADAMARD8_1D m0, m1, m2, m3, m4, m5, m6, m7
  123.     SUM4x8_MM
  124.     movq   [trans], m0
  126.     movq   m0, [trans+0x20]
  127.     movq   m1, [trans+0x28]
  128.     movq   m2, [trans+0x30]
  129.     movq   m3, [trans+0x38]
  130.     movq   m4, [trans+0x40]
  131.     movq   m5, [trans+0x48]
  132.     movq   m6, [trans+0x50]
  133.     movq   m7, [trans+0x58]
  135.     HADAMARD8_1D m0, m1, m2, m3, m4, m5, m6, m7
  136.     SUM4x8_MM
  138.     pavgw  m0, [trans]
  139.     pshufw m1, m0, 01001110b
  140.     paddw  m0, m1
  141.     pshufw m1, m0, 10110001b
  142.     paddw  m0, m1
  143.     movd  eax, m0
  144.     and   eax, 0xffff
  145.     mov   ecx, eax ; preserve rounding for 16x16
  146.     add   eax, 1
  147.     shr   eax, 1
  148.     add   esp, 0x70
  149.     pop   ebx
  150.     ret
  151. %undef args
  152. %undef spill
  153. %undef trans
  155. %macro SUM_MM_X3 8 ; 3x sum, 4x tmp, op
  156.     pxor        %7, %7
  157.     pshufw      %4, %1, 01001110b
  158.     pshufw      %5, %2, 01001110b
  159.     pshufw      %6, %3, 01001110b
  160.     paddusw     %1, %4
  161.     paddusw     %2, %5
  162.     paddusw     %3, %6
  163.     punpcklwd   %1, %7
  164.     punpcklwd   %2, %7
  165.     punpcklwd   %3, %7
  166.     pshufw      %4, %1, 01001110b
  167.     pshufw      %5, %2, 01001110b
  168.     pshufw      %6, %3, 01001110b
  169.     %8          %1, %4
  170.     %8          %2, %5
  171.     %8          %3, %6
  172. %endmacro
  174. %macro LOAD_4x8P 1 ; dx
  175.     pxor        m7, m7
  176.     movd        m6, [eax+%1+7*FENC_STRIDE]
  177.     movd        m0, [eax+%1+0*FENC_STRIDE]
  178.     movd        m1, [eax+%1+1*FENC_STRIDE]
  179.     movd        m2, [eax+%1+2*FENC_STRIDE]
  180.     movd        m3, [eax+%1+3*FENC_STRIDE]
  181.     movd        m4, [eax+%1+4*FENC_STRIDE]
  182.     movd        m5, [eax+%1+5*FENC_STRIDE]
  183.     punpcklbw   m6, m7
  184.     punpcklbw   m0, m7
  185.     punpcklbw   m1, m7
  186.     movq   [spill], m6
  187.     punpcklbw   m2, m7
  188.     punpcklbw   m3, m7
  189.     movd        m6, [eax+%1+6*FENC_STRIDE]
  190.     punpcklbw   m4, m7
  191.     punpcklbw   m5, m7
  192.     punpcklbw   m6, m7
  193.     movq        m7, [spill]
  194. %endmacro
  196. ;-----------------------------------------------------------------------------
  197. ; void x264_intra_sa8d_x3_8x8_core_mmxext( uint8_t *fenc, int16_t edges[2][8], int *res )
  198. ;-----------------------------------------------------------------------------
  199. cglobal x264_intra_sa8d_x3_8x8_core_mmxext
  200.     mov    eax, [esp+4]
  201.     mov    ecx, [esp+8]
  202.     sub    esp, 0x70
  203. %define args  esp+0x74
  204. %define spill esp+0x60 ; +16
  205. %define trans esp+0    ; +96
  206. %define sum   esp+0    ; +32
  207.     LOAD_4x8P 0
  208.     HADAMARD8_1D m0, m1, m2, m3, m4, m5, m6, m7
  210.     movq   [spill], m0
  211.     TRANSPOSE4x4W 4, 5, 6, 7, 0
  212.     movq   [trans+0x00], m4
  213.     movq   [trans+0x08], m5
  214.     movq   [trans+0x10], m6
  215.     movq   [trans+0x18], m7
  216.     movq   m0, [spill]
  217.     TRANSPOSE4x4W 0, 1, 2, 3, 4
  218.     movq   [trans+0x20], m0
  219.     movq   [trans+0x28], m1
  220.     movq   [trans+0x30], m2
  221.     movq   [trans+0x38], m3
  223.     LOAD_4x8P 4
  224.     HADAMARD8_1D m0, m1, m2, m3, m4, m5, m6, m7
  226.     movq   [spill], m7
  227.     TRANSPOSE4x4W 0, 1, 2, 3, 7
  228.     movq   [trans+0x40], m0
  229.     movq   [trans+0x48], m1
  230.     movq   [trans+0x50], m2
  231.     movq   [trans+0x58], m3
  232.     movq   m7, [spill]
  233.     TRANSPOSE4x4W 4, 5, 6, 7, 0
  234.     movq   m0, [trans+0x00]
  235.     movq   m1, [trans+0x08]
  236.     movq   m2, [trans+0x10]
  237.     movq   m3, [trans+0x18]
  239.     HADAMARD8_1D m0, m1, m2, m3, m4, m5, m6, m7
  241.     movq [spill+0], m0
  242.     movq [spill+8], m1
  243.     ABS2     m2, m3, m0, m1
  244.     ABS2     m4, m5, m0, m1
  245.     paddw    m2, m4
  246.     paddw    m3, m5
  247.     ABS2     m6, m7, m4, m5
  248.     movq     m0, [spill+0]
  249.     movq     m1, [spill+8]
  250.     paddw    m2, m6
  251.     paddw    m3, m7
  252.     paddw    m2, m3
  253.     ABS1     m1, m4
  254.     paddw    m2, m1 ; 7x4 sum
  255.     movq     m7, m0
  256.     movq     m1, [ecx+8] ; left bottom
  257.     psllw    m1, 3
  258.     psubw    m7, m1
  259.     ABS2     m0, m7, m5, m3
  260.     paddw    m0, m2
  261.     paddw    m7, m2
  262.     movq [sum+0], m0 ; dc
  263.     movq [sum+8], m7 ; left
  265.     movq   m0, [trans+0x20]
  266.     movq   m1, [trans+0x28]
  267.     movq   m2, [trans+0x30]
  268.     movq   m3, [trans+0x38]
  269.     movq   m4, [trans+0x40]
  270.     movq   m5, [trans+0x48]
  271.     movq   m6, [trans+0x50]
  272.     movq   m7, [trans+0x58]
  274.     HADAMARD8_1D m0, m1, m2, m3, m4, m5, m6, m7
  276.     movd   [sum+0x10], m0
  277.     movd   [sum+0x12], m1
  278.     movd   [sum+0x14], m2
  279.     movd   [sum+0x16], m3
  280.     movd   [sum+0x18], m4
  281.     movd   [sum+0x1a], m5
  282.     movd   [sum+0x1c], m6
  283.     movd   [sum+0x1e], m7
  285.     movq [spill],   m0
  286.     movq [spill+8], m1
  287.     ABS2     m2, m3, m0, m1
  288.     ABS2     m4, m5, m0, m1
  289.     paddw    m2, m4
  290.     paddw    m3, m5
  291.     paddw    m2, m3
  292.     movq     m0, [spill]
  293.     movq     m1, [spill+8]
  294.     ABS2     m6, m7, m4, m5
  295.     ABS1     m1, m3
  296.     paddw    m2, m7
  297.     paddw    m1, m6
  298.     paddw    m2, m1 ; 7x4 sum
  299.     movq     m1, m0
  301.     movq     m7, [ecx+0]
  302.     psllw    m7, 3   ; left top
  304.     movzx   edx, word [ecx+0]
  305.     add      dx,  [ecx+16]
  306.     lea     edx, [4*edx+32]
  307.     and     edx, -64
  308.     movd     m6, edx ; dc
  310.     psubw    m1, m7
  311.     psubw    m0, m6
  312.     ABS2     m0, m1, m5, m6
  313.     movq     m3, [sum+0] ; dc
  314.     paddw    m0, m2
  315.     paddw    m1, m2
  316.     movq     m2, m0
  317.     paddw    m0, m3
  318.     paddw    m1, [sum+8] ; h
  319.     psrlq    m2, 16
  320.     paddw    m2, m3
  322.     movq     m3, [ecx+16] ; top left
  323.     movq     m4, [ecx+24] ; top right
  324.     psllw    m3, 3
  325.     psllw    m4, 3
  326.     psubw    m3, [sum+16]
  327.     psubw    m4, [sum+24]
  328.     ABS2     m3, m4, m5, m6
  329.     paddw    m2, m3
  330.     paddw    m2, m4 ; v
  332.     SUM_MM_X3 m0, m1, m2, m3, m4, m5, m6, paddd
  333.     mov     eax, [args+8]
  334.     movd    ecx, m2
  335.     movd    edx, m1
  336.     add     ecx, 2
  337.     add     edx, 2
  338.     shr     ecx, 2
  339.     shr     edx, 2
  340.     mov [eax+0], ecx ; i8x8_v satd
  341.     mov [eax+4], edx ; i8x8_h satd
  342.     movd    ecx, m0
  343.     add     ecx, 2
  344.     shr     ecx, 2
  345.     mov [eax+8], ecx ; i8x8_dc satd
  347.     add     esp, 0x70
  348.     ret
  349. %undef args
  350. %undef spill
  351. %undef trans
  352. %undef sum
  356. ;-----------------------------------------------------------------------------
  357. ; void x264_pixel_ssim_4x4x2_core_mmxext( const uint8_t *pix1, int stride1,
  358. ;                                         const uint8_t *pix2, int stride2, int sums[2][4] )
  359. ;-----------------------------------------------------------------------------
  360. cglobal x264_pixel_ssim_4x4x2_core_mmxext
  361.     push     ebx
  362.     push     edi
  363.     mov      ebx, [esp+16]
  364.     mov      edx, [esp+24]
  365.     mov      edi, 4
  366.     pxor      m0, m0
  367. .loop:
  368.     mov      eax, [esp+12]
  369.     mov      ecx, [esp+20]
  370.     add      eax, edi
  371.     add      ecx, edi
  372.     pxor      m1, m1
  373.     pxor      m2, m2
  374.     pxor      m3, m3
  375.     pxor      m4, m4
  376. %rep 4
  377.     movd      m5, [eax]
  378.     movd      m6, [ecx]
  379.     punpcklbw m5, m0
  380.     punpcklbw m6, m0
  381.     paddw     m1, m5
  382.     paddw     m2, m6
  383.     movq      m7, m5
  384.     pmaddwd   m5, m5
  385.     pmaddwd   m7, m6
  386.     pmaddwd   m6, m6
  387.     paddd     m3, m5
  388.     paddd     m4, m7
  389.     paddd     m3, m6
  390.     add      eax, ebx
  391.     add      ecx, edx
  392. %endrep
  393.     mov      eax, [esp+28]
  394.     lea      eax, [eax+edi*4]
  395.     pshufw    m5, m1, 0xE
  396.     pshufw    m6, m2, 0xE
  397.     paddusw   m1, m5
  398.     paddusw   m2, m6
  399.     punpcklwd m1, m2
  400.     pshufw    m2, m1, 0xE
  401.     pshufw    m5, m3, 0xE
  402.     pshufw    m6, m4, 0xE
  403.     paddusw   m1, m2
  404.     paddd     m3, m5
  405.     paddd     m4, m6
  406.     punpcklwd m1, m0
  407.     punpckldq m3, m4
  408.     movq [eax+0], m1
  409.     movq [eax+8], m3
  410.     sub      edi, 4
  411.     jge .loop
  412.     pop       edi
  413.     pop       ebx
  414.     emms
  415.     ret