开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 多媒体 > IP电话/视频会议 > 查看源码
Admin_Style.asp
资源名称：NetPhone.rar　[点击查看]
上传用户：xxtaishan
上传日期：2022-01-02
资源大小：4063k
文件大小：38k
源码类别：

IP电话/视频会议

开发平台：

ASP/ASPX

Admin_Style.asp：源码内容
  1. <!--#include file = "Include/Startup.asp"-->
  2. <!--#include file = "admin_private.asp"-->
  3. <%
  5. Dim sStyleID, sStyleName, sStyleDir, sStyleCSS, sStyleUploadDir, sStyleWidth, sStyleHeight, sStyleMemo, nStyleIsSys, sStyleStateFlag, sStyleDetectFromWord, sStyleInitMode, sStyleBaseUrl, sStyleUploadObject, sStyleAutoDir, sStyleBaseHref, sStyleContentPath, sStyleAutoRemote, sStyleShowBorder
  6. Dim sStyleFileExt, sStyleFlashExt, sStyleImageExt, sStyleMediaExt, sStyleRemoteExt, sStyleFileSize, sStyleFlashSize, sStyleImageSize, sStyleMediaSize, sStyleRemoteSize
  7. Dim sToolBarID, sToolBarName, sToolBarOrder, sToolBarButton
  9. sPosition = sPosition & "样式管理"
  11. If sAction = "STYLEPREVIEW" Then
  12. ' 样式预览
  13. Call InitStyle()
  14. Call ShowStylePreview()
  15. Response.End
  16. End If
  19. Call Header()
  20. Call Content()
  21. Call Footer()
  24. Sub Content()
  25. Select Case sAction
  26. Case "COPY"
  27. ' 拷贝一标准样式
  28. Call InitStyle()
  29. Call DoCopy()
  30. Call ShowStyleList()
  31. Case "STYLEADD"
  32. ' 新增样式表单
  33. Call ShowStyleForm("ADD")
  34. Case "STYLESET"
  35. ' 样式设置，修改或查看
  36. Call InitStyle()
  37. Call ShowStyleForm("SET")
  38. Case "STYLEADDSAVE"
  39. ' 样式新增保存
  40. Call CheckStyleForm()
  41. Call DoStyleAddSave()
  42. Case "STYLESETSAVE"
  43. ' 样式设置修改保存
  44. Call CheckStyleForm()
  45. Call DoStyleSetSave()
  46. Call RemoveApplication()
  47. Case "STYLEDEL"
  48. ' 样式删除
  49. Call InitStyle()
  50. Call DoStyleDel()
  51. Call ShowStyleList()
  52. Call RemoveApplication()
  53. Case "CODE"
  54. ' 显示引用代码
  55. Call InitStyle()
  56. Call ShowStyleCode()
  57. Case "TOOLBAR"
  58. ' 显示工具栏表单
  59. Call InitStyle()
  60. Call ShowToolBarList()
  61. Case "TOOLBARADD"
  62. ' 新增工具栏
  63. Call InitStyle()
  64. Call DoToolBarAdd()
  65. Call ShowToolBarList()
  66. Call RemoveApplication()
  67. Case "TOOLBARMODI"
  68. ' 修改工具栏
  69. Call InitStyle()
  70. Call DoToolBarModi()
  71. Call ShowToolBarList()
  72. Call RemoveApplication()
  73. Case "TOOLBARDEL"
  74. ' 删除工具栏
  75. Call InitStyle()
  76. Call DoToolBarDel()
  77. Call ShowToolBarList()
  78. Call RemoveApplication()
  79. Case "BUTTONSET"
  80. ' 按钮设置
  81. Call InitStyle()
  82. Call InitToolBar()
  83. Call ShowButtonList()
  84. Case "BUTTONSAVE"
  85. ' 按钮设置保存
  86. Call InitStyle()
  87. Call InitToolBar()
  88. Call DoButtonSave()
  89. Call RemoveApplication()
  90. Case Else
  91. ' 当前所有样式列表
  92. Call ShowStyleList()
  93. End Select
  94. End Sub
  97. ' 当前所有样式列表
  98. Sub ShowStyleList()
  99. Response.Write "<table border=0 cellpadding=0 cellspacing=0 width='100%' height=40><tr>" & _
  100. "<td class=highlight2><b>以下为当前所有样式列表：</b></td>" & _
  101. "<td align=right><a href='?action=styleadd'>新增样式</a></td></tr></table>"
  103. Response.Write "<table border=0 cellpadding=0 cellspacing=0 class=list1>" & _
  104. "<form action='?action=del' method=post name=myform>" & _
  105. "<tr align=center>" & _
  106. "<th width=80>样式名</th>" & _
  107. "<th width=60>最佳宽度</th>" & _
  108. "<th width=60>最佳高度</th>" & _
  109. "<th width=200>说明</th>" & _
  110. "<th width=180>管理</th>" & _
  111. "</tr>"
  113. Dim sManage
  114. sSql = "select * from ewebeditor_style"
  115. oRs.Open sSql, oConn, 0, 1
  116. Do While Not oRs.Eof
  117. sManage = "<a href='?action=stylepreview&id=" & oRs("S_ID") & "' target='_blank'>预览</a>|<a href='?action=code&id=" & oRs("S_ID") & "'>代码</a>|<a href='?action=styleset&id=" & oRs("S_ID") & "'>设置</a>|<a href='?action=toolbar&id=" & oRs("S_ID") & "'>工具栏</a>"
  118. If oRs("S_IsSys") = 1 Then
  119. sManage = sManage & "|<a href='?action=copy&id=" & oRs("S_ID") & "'>拷贝</a>"
  120. Else
  121. sManage = sManage & "|<a href='?action=styledel&id=" & oRs("S_ID") & "'>删除</a>"
  122. End If
  123. Response.Write "<tr align=center>" & _
  124. "<td>" & outHTML(oRs("S_Name")) & "</td>" & _
  125. "<td>" & oRs("S_Width") & "</td>" & _
  126. "<td>" & oRs("S_Height") & "</td>" & _
  127. "<td align=left>" & outHTML(oRs("S_Memo")) & "</td>" & _
  128. "<td>" & sManage & "</td>" & _
  129. "</tr>"
  130. oRs.MoveNext
  131. Loop
  132. oRs.Close
  134. Response.Write "</table>"
  136. Response.Write "<p class=highlight1><b>说明：</b>系统自带样式不允许对设置进行修改删除，但允许查看设置！你可以先“拷贝一标准样式”然后对其设置进行修改以达到快速新建样式的目的。</p><br><br>"
  138. End Sub
  140. ' 拷贝一标准样式
  141. Sub DoCopy()
  142. ' 只有系统样式才有拷贝功能
  143. If nStyleIsSys <> 1 Then
  144. Exit Sub
  145. End If
  146. ' 自动取有效的样式名，从1......到...
  147. Dim i, b, sNewID, sNewName
  148. b = False
  149. i = 0
  150. Do While b = False
  151. i = i + 1
  152. sNewName = sStyleName & i
  153. sSql = "select s_id from ewebeditor_style where s_name='" & sNewName & "'"
  154. oRs.Open sSql, oConn, 0, 1
  155. If oRs.Eof And oRs.Bof Then
  156. b = True
  157. End If
  158. oRs.Close
  159. Loop
  160. ' 插入一与标准样式相同的记录，名不同
  161. sSql = "insert into ewebeditor_style(s_name,s_dir,s_css,s_uploaddir,s_width,s_height,s_memo,s_issys,s_fileext,s_flashext,s_imageext,s_mediaext, s_remoteext,s_filesize,s_flashsize,s_imagesize,s_mediasize,s_remotesize,s_stateflag,s_detectfromword,s_initmode,s_baseurl,s_uploadobject,s_basehref,s_contentpath) select '" & sNewName & "',s_dir,s_css,s_uploaddir,s_width,s_height,s_memo,0,s_fileext,s_flashext,s_imageext,s_mediaext,s_remoteext,s_filesize,s_flashsize,s_imagesize,s_mediasize,s_remotesize,s_stateflag,s_detectfromword,s_initmode,s_baseurl,s_uploadobject,s_basehref,s_contentpath from ewebeditor_style where s_id=" & sStyleID
  162. oConn.Execute sSql
  163. ' 取新样式的ID
  164. sSql = "select s_id from ewebeditor_style where s_name='" & sNewName & "'"
  165. oRs.Open sSql, oConn, 0, 1
  166. sNewID = oRs(0)
  167. oRs.Close
  168. ' 拷贝工具栏
  169. sSql = "insert into ewebeditor_toolbar(s_id,t_name,t_order,t_button) select " & sNewID & ",t_name,t_order,t_button from ewebeditor_toolbar where s_id=" & sStyleID
  170. oConn.Execute sSql
  171. End Sub
  173. ' 样式表单
  174. Sub ShowStyleForm(sFlag)
  175. Dim s_Title, s_Button, s_Action
  176. Dim s_FormStateFlag, s_FormDetectFromWord, s_FormInitMode, s_FormBaseUrl, s_FormUploadObject, s_FormAutoDir, s_FormAutoRemote, s_FormShowBorder
  178. If sFlag = "ADD" Then
  179. sStyleID = ""
  180. sStyleName = ""
  181. sStyleDir = "standard"
  182. sStyleCSS = "office"
  183. sStyleUploadDir = "UploadFile/"
  184. sStyleBaseHref = "http://Localhost/eWebEditor/"
  185. sStyleContentPath = "UploadFile/"
  186. sStyleWidth = "600"
  187. sStyleHeight = "400"
  188. sStyleMemo = ""
  189. nStyleIsSys = 0
  190. s_Title = "新增样式"
  191. s_Action = "StyleAddSave"
  192. sStyleFileExt = "rar|zip|exe|doc|xls|chm|hlp"
  193. sStyleFlashExt = "swf"
  194. sStyleImageExt = "gif|jpg|jpeg|bmp"
  195. sStyleMediaExt = "rm|mp3|wav|mid|midi|ra|avi|mpg|mpeg|asf|asx|wma|mov"
  196. sStyleRemoteExt = "gif|jpg|bmp"
  197. sStyleFileSize = "500"
  198. sStyleFlashSize = "100"
  199. sStyleImageSize = "100"
  200. sStyleMediaSize = "100"
  201. sStyleRemoteSize = "100"
  202. sStyleStateFlag = "1"
  203. sStyleAutoRemote = "1"
  204. sStyleShowBorder = "0"
  205. sStyleUploadObject = "0"
  206. sStyleAutoDir = "0"
  207. sStyleDetectFromWord = "true"
  208. sStyleInitMode = "EDIT"
  209. sStyleBaseUrl = "0"
  210. Else
  211. sStyleName = inHTML(sStyleName)
  212. sStyleDir = inHTML(sStyleDir)
  213. sStyleCSS = inHTML(sStyleCSS)
  214. sStyleUploadDir = inHTML(sStyleUploadDir)
  215. sStyleBaseHref = inHTML(sStyleBaseHref)
  216. sStyleContentPath = inHTML(sStyleContentPath)
  217. sStyleMemo = inHTML(sStyleMemo)
  218. s_Title = "设置样式"
  219. s_Action = "StyleSetSave"
  220. End If
  222. s_FormStateFlag = InitSelect("d_stateflag", Split("显示|不显示", "|"), Split("1|0", "|"), sStyleStateFlag, "", "")
  223. s_FormAutoRemote = InitSelect("d_autoremote", Split("自动上传|不自动上传", "|"), Split("1|0", "|"), sStyleAutoRemote, "", "")
  224. s_FormShowBorder = InitSelect("d_showborder", Split("默认显示|默认不显示", "|"), Split("1|0", "|"), sStyleShowBorder, "", "")
  225. s_FormUploadObject = InitSelect("d_uploadobject", Split("无惧无组件上传类|ASPUpload上传组件|SA-FileUp上传组件|LyfUpload上传组件", "|"), Split("0|1|2|3", "|"), sStyleUploadObject, "", "")
  226. s_FormAutoDir = InitSelect("d_autodir", Split("不使用|年目录|年月目录|年月日目录", "|"), Split("0|1|2|3", "|"), sStyleAutoDir, "", "")
  227. s_FormDetectFromWord = InitSelect("d_detectfromword", Split("自动检测有提示|不自动检测", "|"), Split("true|false", "|"), sStyleDetectFromWord, "", "")
  228. s_FormInitMode = InitSelect("d_initmode", Split("代码模式|编辑模式|文本模式|预览模式", "|"), Split("CODE|EDIT|TEXT|VIEW", "|"), sStyleInitMode, "", "")
  229. s_FormBaseUrl = InitSelect("d_baseurl", Split("相对路径|绝对根路径|绝对全路径", "|"), Split("0|1|2", "|"), sStyleBaseUrl, "", "")
  231. If nStyleIsSys = 0 Then
  232. s_Button = "<tr><td align=center colspan=4><input type=image border=0 src='admin/submit.gif' align=absmiddle>&nbsp;<a href='javascript:document.myform.reset()'><img border=0 src='admin/reset.gif' align=absmiddle></a></td></tr>"
  233. Else
  234. s_Button = ""
  235. End If
  237. Response.Write "<table border=0 cellpadding=5 cellspacing=0 height=20 width='100%'><tr><td align=right><a href='javascript:history.back()'>返回</a></td></tr></table>"
  239. Response.Write "<table border=0 cellpadding=0 cellspacing=0 align=center class=form1>" & _
  240. "<form action='?action=" & s_Action & "&id=" & sStyleID & "' method=post name=myform>" & _
  241. "<tr><th colspan=4>&nbsp;&nbsp;" & s_Title & "（鼠标移到输入框可看说明，带*号为必填项）</th></tr>" & _
  242. "<tr><td width='15%' align=right>样式名称：</td><td width='35%'><input type=text class=input size=20 name=d_name title='引用此样式的名字，不要加特殊符号，最大50个字符长度' value=""" & sStyleName & """> <span class=highlight2>*</span></td><td width='15%' align=right>初始模式：</td><td width='35%'>" & s_FormInitMode & " <span class=highlight2>*</span></td></tr>" & _
  243. "<tr><td width='15%' align=right>上传组件：</td><td width='35%'>" & s_FormUploadObject & " <span class=highlight2>*</span></td><td width='15%' align=right>自动目录：</td><td width='35%'>" & s_FormAutoDir & " <span class=highlight2>*</span></td></tr>" & _
  244. "<tr><td width='15%' align=right>图片目录：</td><td width='35%'><input type=text class=input size=20 name=d_dir title='存放此样式图片文件的目录名，必须在ButtonImage下，最大50个字符长度' value=""" & sStyleDir & """> <span class=highlight2>*</span></td><td width='15%' align=right>样式目录：</td><td width='35%'><input type=text class=input size=20 name=d_css title='存放此样式css文件的目录名，必须在CSS下，最大50个字符长度' value=""" & sStyleCSS & """> <span class=highlight2>*</span></td></tr>" & _
  245. "<tr><td width='15%' align=right>最佳宽度：</td><td width='35%'><input type=text class=input name=d_width size=20 title='最佳引用效果的宽度，数字型' value='" & sStyleWidth & "'> <span class=highlight2>*</span></td><td width='15%' align=right>最佳高度：</td><td width='35%'><input type=text class=input name=d_height size=20 title='最佳引用效果的高度，数字型' value='" & sStyleHeight & "'> <span class=highlight2>*</span></td></tr>" & _
  246. "<tr><td width='15%' align=right>状 态 栏：</td><td width='35%'>" & s_FormStateFlag & " <span class=highlight2>*</span></td><td width='15%' align=right>Word粘贴：</td><td width='35%'>" & s_FormDetectFromWord & " <span class=highlight2>*</span></td></tr>" & _
  247. "<tr><td width='15%' align=right>远程文件：</td><td width='35%'>" & s_FormAutoRemote & " <span class=highlight2>*</span></td><td width='15%' align=right>指导方针：</td><td width='35%'>" & s_FormShowBorder & " <span class=highlight2>*</span></td></tr>" & _
  248. "<tr><td colspan=4><span class=highlight2>&nbsp;&nbsp;&nbsp;上传文件及系统文件路径相关设置（只有在使用相对路径模式时，才要设置显示路径和内容路径）：</span></td></tr>" & _
  249. "<tr><td width='15%' align=right>路径模式：</td><td width='35%'>" & s_FormBaseUrl & " <span class=highlight2>*</span> <a href='#baseurl'>说明</a></td><td width='15%' align=right>上传路径：</td><td width='35%'><input type=text class=input size=20 name=d_uploaddir title='上传文件所存放路径，相对eWebEditor根目录文件的路径，最大50个字符长度' value=""" & sStyleUploadDir & """> <span class=highlight2>*</span></td></tr>" & _
  250. "<tr><td width='15%' align=right>显示路径：</td><td width='35%'><input type=text class=input size=20 name=d_basehref title='显示内容页所存放路径，必须以&quot;/&quot;开头，最大50个字符长度' value=""" & sStyleBaseHref & """></td><td width='15%' align=right>内容路径：</td><td width='35%'><input type=text class=input size=20 name=d_contentpath title='实际保存在内容中的路径，相对显示路径的路径，不能以&quot;/&quot;开头，最大50个字符长度' value=""" & sStyleContentPath & """></td></tr>" & _
  251. "<tr><td colspan=4><span class=highlight2>&nbsp;&nbsp;&nbsp;允许上传文件类型及文件大小设置（文件大小单位为KB，0表示没有限制）：</span></td></tr>" & _
  252. "<tr><td width='15%' align=right>图片类型：</td><td width='35%'><input type=text class=input name=d_imageext size=20 title='用于图片相关的上传，最大250个字符长度' value='" & sStyleImageExt & "'></td><td width='15%' align=right>图片限制：</td><td width='35%'><input type=text class=input name=d_imagesize size=20 title='数字型，单位KB' value='" & sStyleImageSize & "'></td></tr>" & _
  253. "<tr><td width='15%' align=right>Flash类型：</td><td width='35%'><input type=text class=input name=d_flashext size=20 title='用于插入Flash动画，最大250个字符长度' value='" & sStyleFlashExt & "'></td><td width='15%' align=right>Flash限制：</td><td width='35%'><input type=text class=input name=d_flashsize size=20 title='数字型，单位KB' value='" & sStyleFlashSize & "'></td></tr>" & _
  254. "<tr><td width='15%' align=right>媒体类型：</td><td width='35%'><input type=text class=input name=d_mediaext size=20 title='用于插入媒体文件，最大250个字符长度' value='" & sStyleMediaExt & "'></td><td width='15%' align=right>媒体限制：</td><td width='35%'><input type=text class=input name=d_mediasize size=20 title='数字型，单位KB' value='" & sStyleMediaSize & "'></td></tr>" & _
  255. "<tr><td width='15%' align=right>其它类型：</td><td width='35%'><input type=text class=input name=d_fileext size=20 title='用于插入其它文件，最大250个字符长度' value='" & sStyleFileExt & "'></td><td width='15%' align=right>其它限制：</td><td width='35%'><input type=text class=input name=d_filesize size=20 title='数字型，单位KB' value='" & sStyleFileSize & "'></td></tr>" & _
  256. "<tr><td width='15%' align=right>远程类型：</td><td width='35%'><input type=text class=input name=d_remoteext size=20 title='用于自动上传远程文件，最大250个字符长度' value='" & sStyleRemoteExt & "'></td><td width='15%' align=right>远程限制：</td><td width='35%'><input type=text class=input name=d_remotesize size=20 title='数字型，单位KB' value='" & sStyleRemoteSize & "'></td></tr>" & _
  257. "<tr><td align=right>备注说明：</td><td colspan=3><textarea class=textarea rows=7 cols=65 name=d_memo title='此样式的说明，更有利于调用'>" & sStyleMemo & "</textarea></td></tr>" & s_Button & _
  258. "</form>" & _
  259. "</table>"
  261. Response.Write "<a name=baseurl></a><p><span class=highlight2><b>路径模式设置说明：</b></span><br>" & _
  262. "<b>相对路径：</b>指所有的相关上传或自动插入文件路径，编辑后都以""UploadFile/...""或""../UploadFile/...""形式呈现，当使用此模式时，显示路径和内容路径必填，显示路径必须以""/""开头和结尾，内容路径设置中不能以""/""开头。<br>" & _
  263. "<b>绝对根路径：</b>指所有的相关上传或自动插入文件路径，编辑后都以""/eWebEditor/UploadFile/...""这种形式呈现，当使用此模式时，显示路径和内容路径不必填。<br>" & _
  264. "<b>绝对全路径：</b>指所有的相关上传或自动插入文件路径，编辑后都以""http://xxx.xxx.xxx/eWebEditor/UploadFile/...""这种形式呈现，当使用此模式时，显示路径和内容路径不必填。</p><br><br>"
  266. End Sub
  268. ' 初始化样式表数据
  269. Sub InitStyle()
  270. Dim b
  271. b = False
  272. sStyleID = Trim(Request("id"))
  273. If IsNumeric(sStyleID) = True Then
  274. sSql = "select * from ewebeditor_style where s_id=" & sStyleID
  275. oRs.Open sSql, oConn, 0, 1
  276. If Not oRs.Eof Then
  277. sStyleName = oRs("S_Name")
  278. sStyleDir = oRs("S_Dir")
  279. sStyleCSS = oRs("S_CSS")
  280. sStyleUploadDir = oRs("S_UploadDir")
  281. sStyleBaseHref = oRs("S_BaseHref")
  282. sStyleContentPath = oRs("S_ContentPath")
  283. sStyleWidth = CStr(oRs("S_Width"))
  284. sStyleHeight = CStr(oRs("S_Height"))
  285. sStyleMemo = oRs("S_Memo")
  286. nStyleIsSys = oRs("S_IsSys")
  287. sStyleFileExt = oRs("S_FileExt")
  288. sStyleFlashExt = oRs("S_FlashExt")
  289. sStyleImageExt = oRs("S_ImageExt")
  290. sStyleMediaExt = oRs("S_MediaExt")
  291. sStyleRemoteExt = oRs("S_RemoteExt")
  292. sStyleFileSize = oRs("S_FileSize")
  293. sStyleFlashSize = oRs("S_FlashSize")
  294. sStyleImageSize = oRs("S_ImageSize")
  295. sStyleMediaSize = oRs("S_MediaSize")
  296. sStyleRemoteSize = oRs("S_RemoteSize")
  297. sStyleStateFlag = CStr(oRs("S_StateFlag"))
  298. sStyleAutoRemote = CStr(oRs("S_AutoRemote"))
  299. sStyleShowBorder = CStr(oRs("S_ShowBorder"))
  300. sStyleUploadObject = CStr(oRs("S_UploadObject"))
  301. sStyleAutoDir = CStr(oRs("S_AutoDir"))
  302. sStyleDetectFromWord = oRs("S_DetectFromWord")
  303. sStyleInitMode = oRs("S_InitMode")
  304. sStyleBaseUrl = oRs("S_BaseUrl")
  305. b = True
  306. End If
  307. oRs.Close
  308. End If
  309. If b = False Then
  310. Go_Error "无效的样式ID号，请通过页面上的链接进行操作！"
  311. End If
  312. End Sub
  314. ' 检测样式表单提交的有效性
  315. Sub CheckStyleForm()
  316. sStyleName = Trim(Request("d_name"))
  317. sStyleDir = Trim(Request("d_dir"))
  318. sStyleCSS = Trim(Request("d_css"))
  319. sStyleUploadDir = Trim(Request("d_uploaddir"))
  320. sStyleBaseHref = Trim(Request("d_basehref"))
  321. sStyleContentPath = Trim(Request("d_contentpath"))
  322. sStyleWidth = Trim(Request("d_width"))
  323. sStyleHeight = Trim(Request("d_height"))
  324. sStyleMemo = Request("d_memo")
  325. sStyleImageExt = Request("d_imageext")
  326. sStyleFlashExt = Request("d_flashext")
  327. sStyleMediaExt = Request("d_mediaext")
  328. sStyleRemoteExt = Request("d_remoteext")
  329. sStyleFileExt = Request("d_fileext")
  330. sStyleImageSize = Request("d_imagesize")
  331. sStyleFlashSize = Request("d_flashsize")
  332. sStyleMediaSize = Request("d_mediasize")
  333. sStyleRemoteSize = Request("d_remotesize")
  334. sStyleFileSize = Request("d_filesize")
  335. sStyleStateFlag = Request("d_stateflag")
  336. sStyleAutoRemote = Request("d_autoremote")
  337. sStyleShowBorder = Request("d_showborder")
  338. sStyleUploadObject = Request("d_uploadobject")
  339. sStyleAutoDir = Request("d_autodir")
  340. sStyleDetectFromWord = Request("d_detectfromword")
  341. sStyleInitMode = Request("d_initmode")
  342. sStyleBaseUrl = Request("d_baseurl")
  344. sStyleUploadDir = Replace(sStyleUploadDir, "", "/")
  345. sStyleBaseHref = Replace(sStyleBaseHref, "", "/")
  346. sStyleContentPath = Replace(sStyleContentPath, "", "/")
  347. If Right(sStyleUploadDir, 1) <> "/" Then sStyleUploadDir = sStyleUploadDir & "/"
  348. If Right(sStyleBaseHref, 1) <> "/" Then sStyleBaseHref = sStyleBaseHref & "/"
  349. If Right(sStyleContentPath, 1) <> "/" Then sStyleContentPath = sStyleContentPath & "/"
  351. If sStyleName = "" Or Get_TrueLen(sStyleName) > 50 Then
  352. Go_Error "样式名不能为空，且不大于50个字符长度！"
  353. End If
  354. If IsSafeStr(sStyleName) = False Then
  355. Go_Error "样式名请勿包含特殊字符！"
  356. End If
  357. If sStyleDir = "" Or Get_TrueLen(sStyleDir) > 50 Then
  358. Go_Error "按钮图片目录名不能为空，且不大于50个字符长度！"
  359. End If
  360. If IsSafeStr(sStyleDir) = False Then
  361. Go_Error "按钮图片目录名请勿包含特殊字符！"
  362. End If
  363. If sStyleCSS = "" Or Get_TrueLen(sStyleCSS) > 50 Then
  364. Go_Error "样式CSS目录名不能为空，且不大于50个字符长度！"
  365. End If
  366. If IsSafeStr(sStyleCSS) = False Then
  367. Go_Error "样式CSS目录名请勿包含特殊字符！"
  368. End If
  370. If sStyleUploadDir = "" Or Get_TrueLen(sStyleUploadDir) > 50 Then
  371. Go_Error "上传路径不能为空，且不大于50个字符长度！"
  372. End If
  373. If IsSafeStr(sStyleUploadDir) = False Then
  374. Go_Error "上传路径请勿包含特殊字符！"
  375. End If
  376. Select Case sStyleBaseUrl
  377. Case "0"
  378. If sStyleBaseHref = "" Or Get_TrueLen(sStyleBaseHref) > 50 Then
  379. Go_Error "当使用相对路径模式时，显示路径不能为空，且不大于50个字符长度！"
  380. End If
  381. If IsSafeStr(sStyleBaseHref) = False Then
  382. Go_Error "当使用相对路径模式时，显示路径请勿包含特殊字符！"
  383. End If
  384. If Left(sStyleBaseHref, 1) <> "/" Then
  385. Go_Error "当使用相对路径模式时，显示路径必须以&quot;/&quot;开头！"
  386. End If
  388. If sStyleContentPath = "" Or Get_TrueLen(sStyleContentPath) > 50 Then
  389. Go_Error "当使用相对路径模式时，内容路径不能为空，且不大于50个字符长度！"
  390. End If
  391. If IsSafeStr(sStyleContentPath) = False Then
  392. Go_Error "当使用相对路径模式时，内容路径请勿包含特殊字符！"
  393. End If
  394. If Left(sStyleContentPath, 1) = "/" Then
  395. Go_Error "当使用相对路径模式时，内容路径不能以&quot;/&quot;开头！"
  396. End If
  397. Case "1", "2"
  398. sStyleBaseHref = ""
  399. sStyleContentPath = ""
  400. End Select
  402. If IsNumeric(sStyleWidth) = False Then
  403. Go_Error "请填写有效的最佳引用宽度！"
  404. End If
  405. If IsNumeric(sStyleHeight) = False Then
  406. Go_Error "请填写有效的最佳引用高度！"
  407. End If
  409. If Get_TrueLen(sStyleImageExt) > 250 Then
  410. Go_Error "图片文件类型不能大于250个字符长度！"
  411. End If
  412. If Get_TrueLen(sStyleFlashExt) > 250 Then
  413. Go_Error "Flash文件类型不能大于250个字符长度！"
  414. End If
  415. If Get_TrueLen(sStyleMediaExt) > 250 Then
  416. Go_Error "媒体文件类型不能大于250个字符长度！"
  417. End If
  418. If Get_TrueLen(sStyleFileExt) > 250 Then
  419. Go_Error "其它文件类型不能大于250个字符长度！"
  420. End If
  421. If Get_TrueLen(sStyleRemoteExt) > 250 Then
  422. Go_Error "远程文件类型不能大于250个字符长度！"
  423. End If
  425. If IsNumeric(sStyleImageSize) = False Then
  426. Go_Error "请填写有效的图片限制大小！"
  427. End If
  428. If IsNumeric(sStyleFlashSize) = False Then
  429. Go_Error "请填写有效的Flash限制大小！"
  430. End If
  431. If IsNumeric(sStyleMediaSize) = False Then
  432. Go_Error "请填写有效的媒体文件限制大小！"
  433. End If
  434. If IsNumeric(sStyleFileSize) = False Then
  435. Go_Error "请填写有效的其它文件限制大小！"
  436. End If
  437. If IsNumeric(sStyleRemoteSize) = False Then
  438. Go_Error "请填写有效的远程文件限制大小！"
  439. End If
  441. End Sub
  443. ' 样式新增保存
  444. Sub DoStyleAddSave()
  445. sSql = "select * from ewebeditor_style where s_name='" & sStyleName & "'"
  446. oRs.Open sSql, oConn, 0, 1
  447. If Not oRs.Eof Then
  448. Go_Error "此样式名已经存在，请用另一个样式名！"
  449. End If
  450. oRs.Close
  452. sSql = "select * from ewebeditor_style where s_id=0"
  453. oRs.Open sSql, oConn, 1, 3
  454. oRs.AddNew
  455. oRs("S_Name") = sStyleName
  456. oRs("S_Dir") = sStyleDir
  457. oRs("S_CSS") = sStyleCSS
  458. oRs("S_UploadDir") = sStyleUploadDir
  459. oRs("S_BaseHref") = sStyleBaseHref
  460. oRs("S_ContentPath") = sStyleContentPath
  461. oRs("S_Width") = sStyleWidth
  462. oRs("S_Height") = sStyleHeight
  463. oRs("S_Memo") = sStyleMemo
  464. oRs("S_ImageExt") = sStyleImageExt
  465. oRs("S_FlashExt") = sStyleFlashExt
  466. oRs("S_MediaExt") = sStyleMediaExt
  467. oRs("S_FileExt") = sStyleFileExt
  468. oRs("S_RemoteExt") = sStyleRemoteExt
  469. oRs("S_ImageSize") = sStyleImageSize
  470. oRs("S_FlashSize") = sStyleFlashSize
  471. oRs("S_MediaSize") = sStyleMediaSize
  472. oRs("S_FileSize") = sStyleFileSize
  473. oRs("S_RemoteSize") = sStyleRemoteSize
  474. oRs("S_StateFlag") = sStyleStateFlag
  475. oRs("S_AutoRemote") = sStyleAutoRemote
  476. oRs("S_ShowBorder") = sStyleShowBorder
  477. oRs("S_UploadObject") = sStyleUploadObject
  478. oRs("S_AutoDir") = sStyleAutoDir
  479. oRs("S_DetectFromWord") = sStyleDetectFromWord
  480. oRs("S_InitMode") = sStyleInitMode
  481. oRs("S_BaseUrl") = sStyleBaseUrl
  482. oRs.Update
  483. sStyleID = oRs("S_ID")
  484. oRs.Close
  486. Response.Write "<br><table border=0 cellspacing=20 align=center>" & _
  487. "<tr valign=top><td><img src='admin/do_ok.gif' border=0></td><td><b><span class=highlight2>样式增加成功！</span></b><br><br><ul>我现在<br><br><li><a href='admin_default.asp'>返回后台管理首页</a><li><a href='?'>返回样式管理</a><li><a href='?action=toolbar&id=" & sStyleID & "'>设置此样式下的工具栏</a></ul></td></tr>" & _
  488. "</table><br><br>"
  490. End Sub
  493. ' 样式修改保存
  494. Sub DoStyleSetSave()
  495. sStyleID = Trim(Request("id"))
  496. If IsNumeric(sStyleID) = True Then
  497. ' 是否存在同名
  498. sSql = "select * from ewebeditor_style where s_name='" & sStyleName & "' and s_id<>" & sStyleID
  499. oRs.Open sSql, oConn, 0, 1
  500. If Not oRs.Eof Then
  501. Go_Error "此样式名已经存在，请用另一个样式名！"
  502. End If
  503. oRs.Close
  505. sSql = "select * from ewebeditor_style where s_id=" & sStyleID
  506. oRs.Open sSql, oConn, 1, 3
  507. If Not oRs.Eof Then
  508. If oRs("S_IsSys") = 1 Then
  509. Go_Error "系统样式，不允许修改！"
  510. End If
  511. Else
  512. Go_Error "无效的样式ID号，请通过页面上的链接进行操作！"
  513. End If
  514. oRs("S_Name") = sStyleName
  515. oRs("S_Dir") = sStyleDir
  516. oRs("S_CSS") = sStyleCSS
  517. oRs("S_UploadDir") = sStyleUploadDir
  518. oRs("S_BaseHref") = sStyleBaseHref
  519. oRs("S_ContentPath") = sStyleContentPath
  520. oRs("S_Width") = sStyleWidth
  521. oRs("S_Height") = sStyleHeight
  522. oRs("S_Memo") = sStyleMemo
  523. oRs("S_ImageExt") = sStyleImageExt
  524. oRs("S_FlashExt") = sStyleFlashExt
  525. oRs("S_MediaExt") = sStyleMediaExt
  526. oRs("S_FileExt") = sStyleFileExt
  527. oRs("S_RemoteExt") = sStyleRemoteExt
  528. oRs("S_ImageSize") = sStyleImageSize
  529. oRs("S_FlashSize") = sStyleFlashSize
  530. oRs("S_MediaSize") = sStyleMediaSize
  531. oRs("S_RemoteSize") = sStyleRemoteSize
  532. oRs("S_FileSize") = sStyleFileSize
  533. oRs("S_StateFlag") = sStyleStateFlag
  534. oRs("S_AutoRemote") = sStyleAutoRemote
  535. oRs("S_ShowBorder") = sStyleShowBorder
  536. oRs("S_UploadObject") = sStyleUploadObject
  537. oRs("S_AutoDir") = sStyleAutoDir
  538. oRs("S_DetectFromWord") = sStyleDetectFromWord
  539. oRs("S_InitMode") = sStyleInitMode
  540. oRs("S_BaseUrl") = sStyleBaseUrl
  541. oRs.Update
  542. oRs.Close
  543. Else
  544. Go_Error "无效的样式ID号，请通过页面上的链接进行操作！"
  545. End If
  547. Response.Write "<br><table border=0 cellspacing=20 align=center>" & _
  548. "<tr valign=top><td><img src='admin/do_ok.gif' border=0></td><td><b><span class=highlight2>样式修改成功！</span></b><br><br><ul>我现在<br><br><li><a href='admin_default.asp'>返回后台管理首页</a><li><a href='?'>返回样式管理</a><li><a href='?action=toolbar&id=" & sStyleID & "'>设置此样式下的工具栏</a></ul></td></tr>" & _
  549. "</table><br><br>"
  551. End Sub
  553. ' 样式删除
  554. Sub DoStyleDel()
  555. If nStyleIsSys = 0 Then
  556. sSql = "delete from ewebeditor_style where s_id=" & sStyleID
  557. oConn.Execute sSql
  558. sSql = "delete from ewebeditor_toolbar where s_id=" & sStyleID
  559. oConn.Execute sSql
  560. End If
  561. End Sub
  563. ' 样式预览
  564. Sub ShowStylePreview()
  565. Response.Write "<html><head>" & _
  566. "<title>样式预览</title>" & _
  567. "<meta http-equiv='Content-Type' content='text/html; charset=gb2312'>" & _
  568. "</head><body>" & _
  569. "<input type=hidden name=content1  value=''>" & _
  570. "<iframe ID='eWebEditor1' src='ewebeditor.asp?id=content1&style=" & sStyleName & "' frameborder=0 scrolling=no width='" & sStyleWidth & "' HEIGHT='" & sStyleHeight & "'></iframe>" & _
  571. "</body></html>"
  572. End Sub
  574. ' 显示引用代码
  575. Sub ShowStyleCode()
  576. Response.Write "<table border=0 cellpadding=5 cellspacing=0 height=20 width='100%'><tr><td align=right><a href='javascript:history.back()'>返回</a></td></tr></table>"
  577. Response.Write "<p class=highlight2>样式（<b>" & outHTML(sStyleName) & "</b>）的最佳调用代码如下（其中XXX按实际关联的表单项进行修改）：</p>"
  578. Response.Write "<textarea rows=5 cols=65 style='width:100%'><IFRAME ID=""eWebEditor1"" SRC=""ewebeditor.asp?id=XXX&style=" & sStyleName & """ FRAMEBORDER=""0"" SCROLLING=""no"" WIDTH=""" & sStyleWidth & """ HEIGHT=""" & sStyleHeight & """></IFRAME></textarea><br><br>"
  579. End Sub
  581. ' 显示工具栏表单列表
  582. Sub ShowToolBarList()
  583. Response.Write "<table border=0 cellpadding=5 cellspacing=0 height=20 width='100%'><tr>" & _
  584. "<td class=highlight2><b>样式（" & outHTML(sStyleName) & "）下的工具栏管理：</b></td>" & _
  585. "<td align=right><a href='?'>返回样式管理</a></td></tr></table>"
  587. Dim s_AddForm, s_ModiForm
  589. ' 增加表单
  590. If nStyleIsSys = 1 Then
  591. s_AddForm = ""
  592. Else
  593. ' 取当前最大排序号
  594. Dim nMaxOrder
  595. sSql = "select max(T_order) from ewebeditor_toolbar where s_id=" & sStyleID
  596. oRs.Open sSql, oConn, 0, 1
  597. If IsNull(oRs(0)) Then
  598. nMaxOrder = 1
  599. Else
  600. nMaxOrder = oRs(0) + 1
  601. End If
  602. oRs.Close
  604. s_AddForm = "<hr width='95%' align=center size=1><table border=0 cellpadding=4 cellspacing=0 align=center>" & _
  605. "<form action='?id=" & sStyleID & "&action=toolbaradd' name='addform' method=post>" & _
  606. "<tr><td>工具栏名：<input type=text name=d_name size=20 class=input value='工具栏" & nMaxOrder & "'> 排序号：<input type=text name=d_order size=5 value='" & nMaxOrder & "' class=input> <input type=submit name=b1 value='新增工具栏'></td></tr>" & _
  607. "</form></table><hr width='95%' align=center size=1>"
  608. End If
  610. ' 修改表单
  611. Dim s_Manage, s_SubmitButton
  612. s_ModiForm = "<form action='?id=" & sStyleID & "&action=toolbarmodi' name=modiform method=post>" & _
  613. "<table border=0 cellpadding=0 cellspacing=0 align=center class=list1>" & _
  614. "<tr align=center><th>ID</th><th>工具栏名</th><th>排序号</th><th>操作</th></tr>"
  615. sSql = "select * from ewebeditor_toolbar where s_id=" & sStyleID & " order by t_order asc"
  616. oRs.Open sSql, oConn, 0, 1
  617. Do While Not oRs.Eof
  618. s_Manage = "<a href='?id=" & sStyleID & "&action=buttonset&toolbarid=" & oRs("t_id") & "'>按钮设置</a>"
  619. If nStyleIsSys <> 1 Then
  620. s_Manage = s_Manage & "|<a href='?id=" & sStyleID & "&action=toolbardel&delid=" & oRs("t_id") & "'>删除</a>"
  621. End If
  622. s_ModiForm = s_ModiForm & "<tr align=center>" & _
  623. "<td>" & oRs("t_id") & "</td>" & _
  624. "<td><input type=text name='d_name" & oRs("t_id") & "' value=""" & inHTML(oRs("t_name")) & """ size=30 class=input></td>" & _
  625. "<td><input type=text name='d_order" & oRs("t_id") & "' value='" & oRs("t_order") & "' size=5 class=input></td>" & _
  626. "<td>" & s_Manage & "</td>" & _
  627. "</tr>"
  628. oRs.MoveNext
  629. Loop
  630. oRs.Close
  631. If nStyleIsSys = 1 Then
  632. s_SubmitButton = ""
  633. Else
  634. s_SubmitButton = "<p align=center><input type=submit name=b1 value=' 修改 '></p>"
  635. End If
  636. s_ModiForm = s_ModiForm & "</table>" & s_SubmitButton & "</form><br><br>"
  638. ' 输出表单
  639. Response.Write s_AddForm & s_ModiForm
  641. End Sub
  643. ' 新增工具栏
  644. Sub DoToolBarAdd()
  645. Dim s_Name, s_Order
  646. s_Name = Trim(Request("d_name"))
  647. s_Order = Trim(Request("d_order"))
  648. If s_Name = "" Or Get_TrueLen(s_Name) > 50 Then
  649. Go_Error "工具栏名不能为空，且长度不能大于50个字符长度！"
  650. End If
  651. If IsNumeric(s_Order) = False Then
  652. Go_Error "无效的工具栏排序号，排序号必须为数字！"
  653. End If
  654. If nStyleIsSys = 1 Then
  655. Go_Error "系统自带样式下的工具栏，不允许新增！"
  656. End If
  657. sSql = "select * from ewebeditor_toolbar where 1=0"
  658. oRs.Open sSql, oConn, 1, 3
  659. oRs.AddNew
  660. oRs("s_id") = sStyleID
  661. oRs("t_name") = s_Name
  662. oRs("t_order") = s_Order
  663. oRs("t_button") = ""
  664. oRs.Update
  665. oRs.Close
  666. Response.Write "<script language=javascript>alert(""工具栏（" & outHTML(s_Name) & "）增加操作成功！"");</script>"
  667. End Sub
  669. ' 修改工具栏
  670. Sub DoToolBarModi()
  671. Dim s_Name, s_Order
  672. If nStyleIsSys = 1 Then
  673. Go_Error "系统自带样式下的工具栏，不允许修改！"
  674. End If
  676. sSql = "select * from ewebeditor_toolbar where s_id=" & sStyleID
  677. oRs.Open sSql, oConn, 1, 3
  678. Do While Not oRs.Eof
  679. s_Name = Trim(Request("d_name" & oRs("t_id")))
  680. s_Order = Trim(Request("d_order" & oRs("t_id")))
  681. If s_Name <> "" And IsNumeric(s_Order) = True Then
  682. If s_Name <> oRs("t_name") Or s_Order <> CStr(oRs("t_Order")) Then
  683. oRs("t_name") = s_Name
  684. oRs("t_order") = s_Order
  685. oRs.Update
  686. End If
  687. End If
  688. oRs.MoveNext
  689. Loop
  690. oRs.Close
  691. Response.Write "<script language=javascript>alert('工具栏修改操作成功！');</script>"
  693. End Sub
  695. ' 删除工具栏
  696. Sub DoToolBarDel()
  697. Dim s_DelID
  698. s_DelID = Trim(Request("delid"))
  699. If nStyleIsSys = 1 Then
  700. Go_Error "系统自带样式下的工具栏，不允许删除！"
  701. End If
  702. If IsNumeric(s_DelID) = True Then
  703. sSql = "delete from ewebeditor_toolbar where s_id=" & sStyleID & " and t_id=" & s_DelID
  704. oConn.Execute sSql
  705. Response.Write "<script language=javascript>alert('工具栏（ID：" & s_DelID & "）删除操作成功！');</script>"
  706. End If
  707. End Sub
  709. ' 初始化工具栏
  710. Sub InitToolBar()
  711. Dim b
  712. b = False
  713. sToolBarID = Trim(Request("toolbarid"))
  714. If IsNumeric(sToolBarID) = True Then
  715. sSql = "select * from ewebeditor_toolbar where s_id=" & sStyleID & " and t_id=" & sToolBarID
  716. oRs.Open sSql, oConn, 0, 1
  717. If Not oRs.Eof Then
  718. sToolBarName = oRs("T_Name")
  719. sToolBarOrder = oRs("T_Order")
  720. sToolBarButton = oRs("T_Button")
  721. b = True
  722. End If
  723. oRs.Close
  724. End If
  725. If b = False Then
  726. Go_Error "无效的工具栏ID号，请通过页面上的链接进行操作！"
  727. End If
  728. End Sub
  730. ' 按钮设置
  731. Sub ShowButtonList()
  732. Dim i, n
  734. ' 导航
  735. Response.Write "<table border=0 cellpadding=5 cellspacing=0 height=30 width='100%'><tr>" & _
  736. "<td><b>当前样式：<span class=highlight2>" & outHTML(sStyleName) & "</span>&nbsp;&nbsp;当前工具栏：<span class=highlight2>" & outHTML(sToolBarName) & "</span></b></td>" & _
  737. "<td align=right><a href='?action=toolbar&id=" & sStyleID & "'>返回工具栏管理</a> | <a href='?'>返回样式管理</a></td>" & _
  738. "</tr></table>"
  740. ' 取所有按钮
  741. Dim aButtonCode(), aButtonTitle(), aButtonImage()
  742. sSql = "select * from ewebeditor_button where b_allowselect=1 order by b_order asc"
  743. oRs.Open sSql, oConn, 0, 1
  744. i = 0
  745. Do While Not oRs.Eof
  746. i = i + 1
  747. Redim Preserve aButtonCode(i)
  748. Redim Preserve aButtonTitle(i)
  749. Redim Preserve aButtonImage(i)
  750. aButtonCode(i) = oRs("B_Code")
  751. aButtonTitle(i) = oRs("B_Title")
  752. aButtonImage(i) = oRs("B_Image")
  753. oRs.MoveNext
  754. Loop
  755. oRs.Close
  758. ' 取可选列表
  759. Dim s_Option1
  760. s_Option1 = ""
  761. For i = 1 To UBound(aButtonCode)
  762. s_Option1 = s_Option1 & "<option value='" & aButtonCode(i) & "'>" & aButtonTitle(i) & "</option>"
  763. Next
  765. ' 取已选列表
  766. Dim aButton, s_Option2, s_Temp
  767. aButton = Split(sToolBarButton, "|")
  768. s_Option2 = ""
  769. For i = 0 To UBound(aButton)
  770. s_Temp = Code2Title(aButton(i), aButtonCode, aButtonTitle)
  771. If s_Temp <> "" Then
  772. s_Option2 = s_Option2 & "<option value='" & aButton(i) & "'>" & s_Temp & "</option>"
  773. End If
  774. Next
  777. '以下为客户端操作选择脚本
  778. '''''''''''''''''''''''''''''''''''
  779. %>
  781. <script language=javascript>
  782. // 加入已选
  783. function Add() {
  784. var sel1=document.myform.d_b1;
  785. var sel2=document.myform.d_b2;
  786. if (sel1.selectedIndex<0) {
  787. alert("请选择一个待选按钮！");
  788. return;
  789. }
  790. sel2.options[sel2.length]=new Option(sel1.options[sel1.selectedIndex].innerHTML,sel1.options[sel1.selectedIndex].value);
  791. }
  793. // 从已选中删除
  794. function Del() {
  795. var sel=document.myform.d_b2;
  796. var nIndex = sel.selectedIndex;
  797. var nLen = sel.length;
  798. if (nLen<1) return;
  799. if (nIndex<0) {
  800. alert("请选择一个已选按钮！");
  801. return;
  802. }
  803. for (var i=nIndex;i<nLen-1;i++) {
  804. sel.options[i].value=sel.options[i+1].value;
  805. sel.options[i].innerHTML=sel.options[i+1].innerHTML;
  806. }
  807. sel.length=nLen-1;
  808. }
  810. // 排序：向上移动
  811. function Up() {
  812. var sel=document.myform.d_b2;
  813. var nIndex = sel.selectedIndex;
  814. var nLen = sel.length;
  815. if ((nLen<1)||(nIndex==0)) return;
  816. if (nIndex<0) {
  817. alert("请选择一个要移动的已选按钮！");
  818. return;
  819. }
  820. var sValue=sel.options[nIndex].value;
  821. var sHTML=sel.options[nIndex].innerHTML;
  822. sel.options[nIndex].value=sel.options[nIndex-1].value;
  823. sel.options[nIndex].innerHTML=sel.options[nIndex-1].innerHTML;
  824. sel.options[nIndex-1].value=sValue;
  825. sel.options[nIndex-1].innerHTML=sHTML;
  826. sel.selectedIndex=nIndex-1;
  827. }
  829. // 排序：向下移动
  830. function Down() {
  831. var sel=document.myform.d_b2;
  832. var nIndex = sel.selectedIndex;
  833. var nLen = sel.length;
  834. if ((nLen<1)||(nIndex==nLen-1)) return;
  835. if (nIndex<0) {
  836. alert("请选择一个要移动的已选按钮！");
  837. return;
  838. }
  839. var sValue=sel.options[nIndex].value;
  840. var sHTML=sel.options[nIndex].innerHTML;
  841. sel.options[nIndex].value=sel.options[nIndex+1].value;
  842. sel.options[nIndex].innerHTML=sel.options[nIndex+1].innerHTML;
  843. sel.options[nIndex+1].value=sValue;
  844. sel.options[nIndex+1].innerHTML=sHTML;
  845. sel.selectedIndex=nIndex+1;
  846. }
  848. // 提交处理
  849. function checkform() {
  850. var sel=document.myform.d_b2;
  851. var nLen = sel.length;
  852. var str="";
  853. for (var i=0;i<nLen;i++) {
  854. if (i>0) str+="|";
  855. str+=sel.options[i].value;
  856. }
  857. document.myform.d_button.value=str;
  858. return true;
  859. }
  861. </script>
  863. <%
  864. '''''''''''''''''''''''''''''''''''
  867. ' 选择设置表单
  868. Dim s_SubmitButton
  869. If nStyleIsSys = 1 Then
  870. s_SubmitButton = ""
  871. Else
  872. s_SubmitButton = "<input type=submit name=b value=' 保存设置 '>"
  873. End If
  874. Response.Write "<table border=0 cellpadding=5 cellspacing=0 align=center>" & _
  875. "<form action='?action=buttonsave&id=" & sStyleID & "&toolbarid=" & sToolBarID & "' method=post name=myform onsubmit='return checkform()'>" & _
  876. "<tr align=center><td>可选按钮</td><td></td><td>已选按钮</td><td></td></tr>" & _
  877. "<tr align=center>" & _
  878. "<td><select name='d_b1' size=20 style='width:200px' ondblclick='Add()'>" & s_Option1 & "</select></td>" & _
  879. "<td><input type=button name=b1 value=' → ' onclick='Add()'><br><br><input type=button name=b1 value=' ← ' onclick='Del()'></td>" & _
  880. "<td><select name='d_b2' size=20 style='width:200px' ondblclick='Del()'>" & s_Option2 & "</select></td>" & _
  881. "<td><input type=button name=b3 value='↑' onclick='Up()'><br><br><br><input type=button name=b4 value='↓' onclick='Down()'></td>" & _
  882. "</tr>" & _
  883. "<input type=hidden name='d_button' value=''>" & _
  884. "<tr><td colspan=4 align=right>" & s_SubmitButton & "</td></tr>" & _
  885. "</form></table>"
  888. ' 显示图片对照表
  889. Response.Write "<p class=highlight1><b>以下是按钮图片对照表（部分下拉框或特殊按钮可能没图）：</b></p>"
  890. Response.Write "<table border=1 cellpadding=3 cellspacing=0 width='100%'>"
  891. n = 0
  892. For i = 1 To UBound(aButtonCode)
  893. n = i Mod 4
  894. If n = 1 Then
  895. Response.Write "<tr>"
  896. End If
  897. Response.Write "<td>"
  898. If aButtonImage(i) <> "" Then
  899. Response.Write "<img border=0 align=absmiddle src='ButtonImage/standard/" & aButtonImage(i) & "'>"
  900. End If
  901. Response.Write aButtonTitle(i)
  902. Response.Write "</td>"
  903. If n = 0 Then
  904. Response.Write "</tr>"
  905. End If
  906. Next
  907. If n > 0 Then
  908. For i = 1 To 4 - n
  909. Response.Write "<td>&nbsp;</td>"
  910. Next
  911. Response.Write "</tr>"
  912. End if
  913. Response.Write "</table><br><br>"
  914. End Sub
  916. ' 由按钮代码得到按钮标题
  917. Function Code2Title(s_Code, a_ButtonCode, a_ButtonTitle)
  918. Dim i
  919. Code2Title = ""
  920. For i = 1 To UBound(a_ButtonCode)
  921. If UCase(a_ButtonCode(i)) = UCase(s_Code) Then
  922. Code2Title = a_ButtonTitle(i)
  923. Exit Function
  924. End If
  925. Next
  926. End Function
  928. ' 按钮设置保存
  929. Sub DoButtonSave()
  930. Dim s_Button
  931. s_Button = Trim(Request("d_button"))
  932. If nStyleIsSys = 1 Then
  933. Go_Error "系统自带样式，不允许对按钮进行修改！"
  934. End If
  936. sSql = "select * from ewebeditor_toolbar where t_id=" & sToolBarID
  937. oRs.Open sSql, oConn, 1, 3
  938. If Not oRs.Eof Then
  939. oRs("T_Button") = s_Button
  940. oRs.Update
  941. End If
  942. oRs.Close
  944. Response.Write "<br><table border=0 cellspacing=20 align=center>" & _
  945. "<tr valign=top><td><img src='admin/do_ok.gif' border=0></td><td><b><span class=highlight2>工具栏按钮设置保存成功！</span></b><br><br><ul>我现在<br><br><li><a href='admin_default.asp'>返回后台管理首页</a><li><a href='?'>返回样式管理</a><li><a href='?action=toolbar&id=" & sStyleID & "'>返回工具栏管理</a><li><a href='?action=buttonset&id=" & sStyleID & "&toolbarid=" & sToolBarID & "'>重新设置此工具栏下的按钮</a></ul></td></tr>" & _
  946. "</table><br><br>"
  948. End Sub
  950. Sub RemoveApplication()
  951. Dim aApplicationName, i
  952. aApplicationName = Application("eWebEditor_ApplicationName")
  953. If IsArray(aApplicationName) = True Then
  954. For i = 1 To UBound(aApplicationName)
  955. Application.Contents.Remove(aApplicationName(i))
  956. Next
  957. Application.Contents.Remove("eWebEditor_ApplicationName")
  958. Application.Contents.Remove("eWebEditor_ApplicationUrl")
  959. End If
  960. End Sub
  962. %>