开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 游戏 > 模拟服务器 > 查看源码
Cpu.asm
资源名称：fcSOURCE.rar　[点击查看]
上传用户：luhy168
上传日期：2022-01-10
资源大小：240k
文件大小：59k
源码类别：

模拟服务器

开发平台：

Visual C++

Cpu.asm：源码内容
  1. ;-------------------------------------------------------------------------------
  2. ; Name: Cpu.asm
  3. ; Desc: The cpu core written in assembly.
  4. ;-------------------------------------------------------------------------------
  6. .486
  7. .MODEL FLAT
  10. ; Public symbols so other files may use these functions.
  11. PUBLIC RunCPU
  14. ; Constants
  15. RUNCPU_STEP EQU 01h
  16. RUNCPU_RUN  EQU 02h
  19. ; The CPU structure from Cpu.h
  20. _NES6502 STRUCT 4
  21. A              DB ?             ; The Accumulator register on the 6502.
  22. X              DB ?             ; The X Index register on the 6502.
  23. Y              DB ?             ; The Y Index register on the 6502.
  24. S              DB ?             ; The stack pointer on the 6502.
  25. F              DB ?             ; The flags register on the 6502.
  26. P              DW ?             ; The program counter on the 6502.
  27. Memory         DB 08000h dup(?) ; All the memory on the NES except the PRG-ROM.
  28. pbyPRGROMBank1 DD ?             ; Points to the first PRG-ROM bank on the NES cartridge.
  29. pbyPRGROMBank2 DD ?             ; Points to the second PRG-ROM bank on the NES cartridge.
  30. byCycles       DB ?             ; Number of cycles left until the end of the scanline.
  31. _NES6502 ENDS
  34. ; External variables/functions needed.
  35. .FARDATA?
  36. EXTRN ?CPU@@3UtagNES6502@@A       :_NES6502
  37. EXTRN ?GetMemoryByte@@YGEG@Z      :PROC
  38. EXTRN ?GetMemoryPointer@@YGPAEG@Z :PROC
  39. EXTRN ?ReadMemory@@YGEG@Z         :PROC
  40. EXTRN ?WriteMemory@@YGXGE@Z       :PROC
  42. CPU EQU ?CPU@@3UtagNES6502@@A
  46. .DATA
  50. ; Holds the address of all the instructions. This way,
  51. ; whatever the opcode is, we immediately know where to
  52. ; jump to execute it.
  53. adwOpcodeJumpTable dd  _00, _01, _??, _??, _??, _05, _06, _??
  54.                    dd  _08, _09, _0A, _??, _??, _0D, _0E, _??
  55.                    dd  _10, _11, _??, _??, _??, _15, _16, _??
  56.                    dd  _18, _19, _??, _??, _??, _1D, _1E, _??
  57.                    dd  _20, _21, _??, _??, _24, _25, _26, _??
  58.                    dd  _28, _29, _2A, _??, _2C, _2D, _2E, _??
  59.                    dd  _30, _31, _??, _??, _??, _35, _36, _??
  60.                    dd  _38, _39, _??, _??, _??, _3D, _3E, _??
  61.                    dd  _40, _41, _??, _??, _??, _45, _46, _??
  62.                    dd  _48, _49, _4A, _??, _4C, _4D, _4E, _??
  63.                    dd  _50, _51, _??, _??, _??, _55, _56, _??
  64.                    dd  _58, _59, _??, _??, _??, _5D, _5E, _??
  65.                    dd  _60, _61, _??, _??, _??, _65, _66, _??
  66.                    dd  _68, _69, _6A, _??, _6C, _6D, _6E, _??
  67.                    dd  _70, _71, _??, _??, _??, _75, _76, _??
  68.                    dd  _78, _79, _??, _??, _??, _7D, _7E, _??
  69.                    dd  _??, _81, _??, _??, _84, _85, _86, _??
  70.                    dd  _88, _??, _8A, _??, _8C, _8D, _8E, _??
  71.                    dd  _90, _91, _??, _??, _94, _95, _96, _??
  72.                    dd  _98, _99, _9A, _??, _??, _9D, _??, _??
  73.                    dd  _A0, _A1, _A2, _??, _A4, _A5, _A6, _??
  74.                    dd  _A8, _A9, _AA, _??, _AC, _AD, _AE, _??
  75.                    dd  _B0, _B1, _??, _??, _B4, _B5, _B6, _??
  76.                    dd  _B8, _B9, _BA, _??, _BC, _BD, _BE, _??
  77.                    dd  _C0, _C1, _??, _??, _C4, _C5, _C6, _??
  78.                    dd  _C8, _C9, _CA, _??, _CC, _CD, _CE, _??
  79.                    dd  _D0, _D1, _??, _??, _??, _D5, _D6, _??
  80.                    dd  _D8, _D9, _??, _??, _??, _DD, _DE, _??
  81.                    dd  _E0, _E1, _??, _??, _E4, _E5, _E6, _??
  82.                    dd  _E8, _E9, _??, _??, _EC, _ED, _EE, _??
  83.                    dd  _F0, _F1, _??, _??, _??, _F5, _F6, _??
  84.                    dd  _F8, _F9, _??, _??, _??, _FD, _FE, _??
  87. ; Number of cycles for each opcode. 
  88. abyOpcodeCycles db  7, 6, 0, 0, 0, 3, 5, 0, 3, 2, 2, 0, 0, 4, 6, 0
  89.                 db  2, 5, 0, 0, 0, 4, 6, 0, 2, 4, 0, 0, 0, 4, 7, 0
  90.                 db  6, 6, 0, 0, 3, 3, 5, 0, 4, 2, 2, 0, 4, 4, 6, 0
  91.                 db  2, 5, 0, 0, 0, 4, 6, 0, 2, 4, 0, 0, 0, 4, 7, 0
  92.                 db  13, 6, 0, 0, 0, 3, 5, 0, 3, 2, 2, 0, 3, 4, 6, 0
  93.                 db  2, 5, 0, 0, 0, 4, 6, 0, 2, 4, 0, 0, 0, 4, 7, 0
  94.                 db  6, 6, 0, 0, 0, 3, 5, 0, 4, 2, 2, 0, 5, 4, 6, 0
  95.                 db  2, 5, 0, 0, 0, 4, 6, 0, 2, 4, 0, 0, 0, 4, 7, 0
  96.                 db  0, 6, 0, 0, 3, 3, 3, 0, 2, 0, 2, 0, 4, 4, 4, 0
  97.                 db  2, 6, 0, 0, 4, 4, 4, 0, 2, 5, 2, 0, 0, 5, 0, 0
  98.                 db  2, 6, 2, 2, 3, 3, 3, 2, 2, 2, 2, 2, 4, 4, 4, 2
  99.                 db  2, 5, 2, 2, 4, 4, 4, 2, 2, 4, 2, 2, 4, 4, 4, 2
  100.                 db  2, 6, 2, 2, 3, 3, 5, 2, 2, 2, 2, 2, 4, 4, 6, 2
  101.                 db  2, 5, 2, 2, 2, 4, 6, 2, 2, 4, 2, 2, 2, 4, 7, 2
  102.                 db  2, 6, 2, 2, 3, 3, 5, 2, 2, 2, 2, 2, 4, 4, 6, 2
  103.                 db  2, 5, 2, 2, 2, 4, 6, 2, 2, 4, 2, 2, 2, 4, 7, 2
  104.     
  106. ; The number of bytes for each opcode. The default length is one
  107. ; so the PC will increment if a bad opcode or a NOP is executed
  108. abyOpcodeBytes db 0, 2, 1, 1, 1, 2, 2, 1, 1, 2, 1, 1, 1, 3, 3, 1
  109.                db 2, 2, 1, 1, 1, 2, 2, 1, 1, 3, 1, 1, 1, 3, 3, 1
  110.                db 0, 2, 1, 1, 2, 2, 2, 1, 1, 2, 1, 1, 3, 3, 3, 1
  111.                db 2, 2, 1, 1, 1, 2, 2, 1, 1, 3, 1, 1, 1, 3, 3, 1
  112.                db 0, 2, 1, 1, 1, 2, 2, 1, 1, 2, 1, 1, 0, 3, 3, 1
  113.                db 2, 2, 1, 1, 1, 2, 2, 1, 1, 3, 1, 1, 1, 3, 3, 1
  114.                db 1, 2, 1, 1, 1, 2, 2, 1, 1, 2, 1, 1, 0, 3, 3, 1
  115.                db 2, 2, 1, 1, 1, 2, 2, 1, 1, 3, 1, 1, 1, 3, 3, 1
  116.                db 1, 2, 1, 1, 2, 2, 2, 1, 1, 1, 1, 1, 3, 3, 3, 1
  117.                db 2, 2, 1, 1, 2, 2, 2, 1, 1, 3, 1, 1, 1, 3, 1, 1
  118.                db 2, 2, 2, 1, 2, 2, 2, 1, 1, 2, 1, 1, 3, 3, 3, 1
  119.                db 2, 2, 1, 1, 2, 2, 2, 1, 1, 3, 1, 1, 3, 3, 3, 1
  120.                db 2, 2, 1, 1, 2, 2, 2, 1, 1, 2, 1, 1, 3, 3, 3, 1
  121.                db 2, 2, 1, 1, 1, 2, 2, 1, 1, 3, 1, 1, 1, 3, 3, 1
  122.                db 2, 2, 1, 1, 2, 2, 2, 1, 1, 2, 1, 1, 3, 3, 3, 1
  123.                db 2, 2, 1, 1, 1, 2, 2, 1, 1, 3, 1, 1, 1, 3, 3, 1
  126. ; Used to set the zero and the sign flags.  
  127. ; Just a lookup table for all the possible values.
  128. abyZNTable db 02h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h
  129.            db 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h
  130.            db 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h
  131.            db 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h
  132.            db 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h
  133.            db 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h
  134.            db 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h
  135.            db 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h, 00h
  136.            db 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h
  137.            db 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h
  138.            db 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h
  139.            db 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h
  140.            db 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h
  141.            db 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h
  142.            db 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h
  143.            db 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h, 80h
  148. .CODE
  152. ;******************************************************************************
  153. ;*                                                                            *
  154. ;* Macros for reading/writing memory                                          *
  155. ;*                                                                            *
  156. ;******************************************************************************
  158. GET_MEMORY_BYTE MACRO wParam:REQ
  159. xor edx, edx
  160. mov dx, wParam
  161. push edx
  162. call ?GetMemoryByte@@YGEG@Z
  163. and eax, 000000FFh
  164. ENDM
  166. GET_MEMORY_POINTER MACRO wParam:REQ
  167. xor edx, edx
  168. mov dx, wParam
  169. push edx
  170. call ?GetMemoryPointer@@YGPAEG@Z
  171. ENDM
  173. READ_MEMORY MACRO wParam:REQ
  174. movzx edx, wParam
  175. push edx
  176. call ?ReadMemory@@YGEG@Z
  177. and eax, 000000FFh
  178. ENDM
  180. ; NOTE: Since I don't know enough about writting macros to make
  181. ; sure that wParam isn't edx, you'll just have to make sure
  182. ; you never call this macro with edx as the wParam or it
  183. ; will not work right.
  184. WRITE_MEMORY MACRO wParam:REQ, byData:REQ
  185. movzx edx, byData
  186. push edx
  187. movzx edx, wParam
  188. push edx
  189. call ?WriteMemory@@YGXGE@Z
  190. ENDM
  192. ; Push a byte onto the NES's stack.
  193. PUSH_BYTE MACRO byData:REQ
  194. ; The stacks address space is 100h-1FFh
  195. mov cl, CPU.S
  196. mov ch, 1
  197. WRITE_MEMORY cx, byData
  198. dec CPU.S
  199. ENDM
  201. ; Pop a byte from the NES's stack.
  202. POP_BYTE MACRO byDest:REQ
  203. ; The stacks address space is 100h-1FFh
  204. inc CPU.S
  205. mov cl, CPU.S
  206. mov ch, 1
  207. GET_MEMORY_BYTE cx
  208. mov byDest, al
  209. ENDM
  212. ;******************************************************************************
  213. ;*                                                                            *
  214. ;* Macro for setting/clearing the flags register on the 6502                  *
  215. ;******************************************************************************
  217. MODIFYFLAGS MACRO Sign, Overflow, Zero, Carry
  219. ; Clear all the flags if they are passed.
  220. pushfd
  221. IFNB <Sign>
  222. and CPU.F, 01111111b
  223. ENDIF
  224. IFNB <Overflow>
  225. and CPU.F, 10111111b
  226. ENDIF
  227. IFNB <Zero>
  228. and CPU.F, 11111101b
  229. ENDIF
  230. IFNB <Carry>
  231. and CPU.F, 11111110b
  232. ENDIF
  233. popfd
  235. ; Set the flags that are passed to the macro.
  237. IFNB <Sign>
  238. pushfd
  239. sets dl
  240. shl dl, 7
  241. or CPU.F, dl
  242. popfd
  243. ENDIF
  244. IFNB <Overflow>
  245. pushfd
  246. seto dl
  247. shl dl, 6
  248. or CPU.F, dl
  249. popfd
  250. ENDIF
  251. IFNB <Zero>
  252. pushfd
  253. setz dl
  254. shl dl, 1
  255. or CPU.F, dl
  256. popfd
  257. ENDIF
  258. IFNB <Carry>
  259. pushfd
  260. setc dl
  261. or CPU.F, dl
  262. popfd
  263. ENDIF
  264. ENDM
  267. ;******************************************************************************
  268. ;*                                                                            *
  269. ;*                        Addressing mode macros                              *
  270. ;*                                                                            *
  271. ;******************************************************************************
  273. ;1) Immediate
  274. ;
  275. ;   In this mode the operand's value is given in the instruction itself. In
  276. ;   assembly language this is indicated by "#" before the operand.
  277. ;   eg.  LDA #$0A - means "load the accumulator with the hex value 0A"
  278. ;   In machine code different modes are indicated by different codes. So LDA
  279. ;   would be translated into different codes depending on the addressing mode.
  280. ;   In this mode, it is: $A9 $0A
  282. GET_ADDR_IMMEDIATE MACRO
  283. ; Move the PC address up by one.
  284. mov di, CPU.P
  285. inc di
  287. ; Now get the memory byte to be used as immediate data.
  288. GET_MEMORY_BYTE di
  289. ENDM
  291. ;2 & 3) Absolute and Zero-page Absolute
  292. ;  In these modes the operands address is given.
  293. ;  eg.  LDA $31F6 - (assembler)
  294. ;       $AD $31F6 - (machine code)
  295. ;  If the address is on zero page - i.e. any address where the high byte is
  296. ;  00 - only 1 byte is needed for the address. The processor automatically
  297. ;  fills the 00 high byte.
  298. ;  eg.  LDA $F4
  299. ;       $A5 $F4
  300. ;  Note the different instruction codes for the different modes.
  301. ;  Note also that for 2 byte addresses, the low byte is store first, eg.
  302. ;  LDA $31F6 is stored as three bytes in memory, $AD $F6 $31.
  303. ;  Zero-page absolute is usually just called zero-page.
  305. GET_ADDR_ZEROPAGE MACRO
  306. ; Increment the PC address.
  307. mov di, CPU.P
  308. inc di
  310. ; Get the byte that is the address of the byte to be read.
  311. GET_MEMORY_BYTE di
  312. ENDM
  314. GET_ADDR_ABSOLUTE MACRO
  315. mov di, CPU.P
  317. ; Get the low address byte.
  318. inc di
  319. GET_MEMORY_BYTE di
  320. mov bl, al
  322. ; Get the high address byte.
  323. inc di
  324. GET_MEMORY_BYTE di
  325. mov bh, al
  326. ENDM
  328. ; 4) Implied
  329. ; No operand addresses are required for this mode. They are implied by the
  330. ; instruction.
  331. ; eg.  TAX - (transfer accumulator contents to X-register)
  332. ;      $AA
  333. ;
  334. ; 5) Accumulator
  335. ; In this mode the instruction operates on data in the accumulator, so no
  336. ; operands are needed.
  337. ; eg.  LSR - logical bit shift right
  338. ;      $4A
  340. ; 6 & 7) Indexed and Zero-page Indexed
  341. ; In these modes the address given is added to the value in either the X or
  342. ; Y index register to give the actual address of the operand.
  343. ; eg.  LDA $31F6, Y
  344. ;      $D9 $31F6
  345. ;      LDA $31F6, X
  346. ;      $DD $31F6
  347. ; Note that the different operation codes determine the index register used.
  348. ; In the zero-page version, you should note that the X and Y registers are
  349. ; not interchangeable. Most instructions which can be used with zero-page
  350. ; indexing do so with X only.
  351. ; eg.  LDA $20, X
  352. ;      $B5 $20
  354. GET_ADDR_ZEROPAGE_X MACRO
  355.     ; Get the normal zero page address
  356. GET_ADDR_ZEROPAGE
  358. ; Now add the X register to the address.
  359. add al, CPU.X
  360. ENDM
  362. GET_ADDR_ZEROPAGE_Y MACRO
  363.     ; Get the normal zero page address
  364. GET_ADDR_ZEROPAGE
  366. ; Now add the Y register to the address.
  367. add al, CPU.Y
  368. ENDM
  370. GET_ADDR_ABSOLUTE_X MACRO
  371. ; Get the normal absolute page address.
  372. GET_ADDR_ABSOLUTE
  374. ; Now add the X register to the address.
  375. xor ax, ax
  376. mov al, CPU.X
  377.     add bx, ax
  378. ENDM
  380. GET_ADDR_ABSOLUTE_Y MACRO
  381. ; Get the normal absolute page address.
  382. GET_ADDR_ABSOLUTE
  384. ; Now add the Y register to the address.
  385. xor ax, ax
  386. mov al, CPU.Y
  387.     add bx, ax
  388. ENDM
  391. ;  8) Indirect
  392. ;  This mode applies only to the JMP instruction - JuMP to new location. It is
  393. ;  indicated by parenthesis around the operand. The operand is the address of
  394. ;  the bytes whose value is the new location.
  395. ;  eg.  JMP ($215F)
  396. ;  Assume the following -        byte      value
  397. ;                                $215F     $76
  398. ;                                $2160     $30
  399. ;  This instruction takes the value of bytes $215F, $2160 and uses that as the
  400. ;  address to jump to - i.e. $3076 (remember that addresses are stored with
  401. ;  low byte first).
  403. GET_ADDR_INDIRECT MACRO
  404. ; Get the address of the value to set the PC to.
  405. GET_ADDR_ABSOLUTE 
  407. ; Get the value to store in the PC register.
  408. mov di, bx
  409. GET_MEMORY_BYTE di
  410. mov bl, al
  411. inc di
  412. GET_MEMORY_BYTE di
  413. mov bh, al
  414. ENDM
  417. ;  9) Pre-indexed indirect
  418. ;  In this mode a zer0-page address is added to the contents of the X-register
  419. ;  to give the address of the bytes holding the address of the operand. The
  420. ;  indirection is indicated by parenthesis in assembly language.
  421. ;  eg.  LDA ($3E, X)
  422. ;       $A1 $3E
  423. ;  Assume the following -        byte      value
  424. ;                                X-reg.    $05
  425. ;                                $0043     $15
  426. ;                                $0044     $24
  427. ;                                $2415     $6E
  428. ;
  429. ;  Then the instruction is executed by:
  430. ;  (i)   adding $3E and $05 = $0043
  431. ;  (ii)  getting address contained in bytes $0043, $0044 = $2415
  432. ;  (iii) loading contents of $2415 - i.e. $6E - into accumulator
  433. ;
  434. ;  Note a) When adding the 1-byte address and the X-register, wrap around
  435. ;          addition is used - i.e. the sum is always a zero-page address.
  436. ;          eg. FF + 2 = 0001 not 0101 as you might expect.
  437. ;          DON'T FORGET THIS WHEN EMULATING THIS MODE.
  438. ;       b) Only the X register is used in this mode.
  440. GET_ADDR_PREINDEXED MACRO
  441. ; The first part is just like zero-paged x addressing,
  442. ; but lets save the address for later use.
  443. GET_ADDR_ZEROPAGE_X
  444. mov di, ax
  446. ; Now that we have the address of our address, we can
  447. ; get our real address. (thats confusing...hehe)
  448. GET_MEMORY_BYTE di
  449. mov bl, al
  450. inc di
  451. GET_MEMORY_BYTE di
  452. mov bh, al
  453. ENDM
  456. ; 10) Post-indexed indirect
  457. ; In this mode the contents of a zero-page address (and the following byte)
  458. ; give the indirect addressm which is added to the contents of the Y-register
  459. ; to yield the actual address of the operand. Again, inassembly language,
  460. ; the instruction is indicated by parenthesis.
  461. ; eg.  LDA ($4C), Y
  462. ; Note that the parenthesis are only around the 2nd byte of the instruction
  463. ; since it is the part that does the indirection.
  464. ; Assume the following -        byte       value
  465. ;                               $004C      $00
  466. ;                               $004D      $21
  467. ;                               Y-reg.     $05
  468. ;                               $2105      $6D
  469. ; Then the instruction above executes by:
  470. ; (i)   getting the address in bytes $4C, $4D = $2100
  471. ; (ii)  adding the contents of the Y-register = $2105
  472. ; (111) loading the contents of the byte $2105 - i.e. $6D into the
  473. ;       accumulator.
  474. ; Note: only the Y-register is used in this mode.
  476. GET_ADDR_POSTINDEXED MACRO
  477. ; Move to the next byte.
  478. mov di, CPU.P
  479. inc di
  481. ; Get the address of our first address.
  482. GET_MEMORY_BYTE di
  483. mov di, ax
  485. ; Now get the address to add the y register to.
  486. GET_MEMORY_BYTE di
  487. mov bl, al
  488. inc di
  489. GET_MEMORY_BYTE di
  490. mov bh, al
  492. ; Finally add the contents of the y register to the address.
  493. xor ax, ax
  494. mov al, CPU.Y
  495. add bx, ax
  496. ENDM
  499. ; 11) Relative
  500. ; This mode is used with Branch-on-Condition instructions. It is probably
  501. ; the mode you will use most often. A 1 byte value is added to the program
  502. ; counter, and the program continues execution from that address. The 1
  503. ; byte number is treated as a signed number - i.e. if bit 7 is 1, the number
  504. ; given byt bits 0-6 is negative; if bit 7 is 0, the number is positive. This
  505. ; enables a branch displacement of up to 127 bytes in either direction.
  506. ; eg  bit no.  7 6 5 4 3 2 1 0    signed value          unsigned value
  507. ;     value    1 0 1 0 0 1 1 1    -39                   $A7
  508. ;     value    0 0 1 0 0 1 1 1    +39                   $27
  509. ; Instruction example:
  510. ;   BEQ $A7
  511. ;   $F0 $A7
  512. ; This instruction will check the zero status bit. If it is set, 39 decimal
  513. ; will be subtracted from the program counter and execution continues from
  514. ; that address. If the zero status bit is not set, execution continues from
  515. ; the following instruction.
  516. ; Notes:  a) The program counter points to the start of the instruction
  517. ; after the branch instruction before the branch displacement is added.
  518. ; Remember to take this into account when calculating displacements.
  519. ;         b) Branch-on-condition instructions work by checking the relevant
  520. ; status bits in the status register. Make sure that they have been set or
  521. ; unset as you want them. This is often done using a CMP instruction.
  522. ;         c) If you find you need to branch further than 127 bytes, use the
  523. ; opposite branch-on-condition and a JMP.
  525. GET_ADDR_RELATIVE MACRO
  526. ; Move the PC address up by one.
  527. mov di, CPU.P
  528. inc di
  530. ; Now get the memory byte to be used as a relative address.
  531. GET_MEMORY_BYTE di
  532. ENDM
  536. ;******************************************************************************
  537. ;*                                                                            *
  538. ;* Instruction macros                                                         *
  539. ;*                                                                            *
  540. ;******************************************************************************
  544. ; ********************************************************************
  545. ; *          ADC. Opcodes 69, 65, 75, 6D, 7D, 79, 61, 71             *
  546. ; ********************************************************************
  547. CPU_ADC MACRO Operand:REQ
  548. ; Move the NES's carry flag into the real cpu's carry flag.
  549. mov dl, CPU.F
  550. shr dl, 1
  552. ; Now add the operand to the A register with the carry flag.
  553. adc CPU.A, Operand
  554. MODIFYFLAGS S, V, Z, C
  555. ENDM
  557. ; ********************************************************************
  558. ; *          AND. Opcodes 29, 25, 35, 2D, 3D, 39, 21, 31             *
  559. ; ********************************************************************
  561. CPU_AND MACRO Operand:REQ
  562. ; Perform the operation.
  563. and CPU.A, Operand
  565. ; Test and set/clear the sign and zero flags.
  566. MODIFYFLAGS S, , Z,
  567. ENDM
  569. ; ********************************************************************
  570. ; *          ASL. Opcodes 0A, 06, 16, 0E, 1E                         *
  571. ; ********************************************************************
  572. CPU_ASL MACRO Operand:REQ
  573. ; Perform the operation.
  574. shl BYTE PTR [Operand], 1
  575. MODIFYFLAGS , , , C
  577. mov al, [Operand]
  578. test al, al
  580. ; Test and set/clear the flags.
  581. MODIFYFLAGS S, , Z, 
  582. ENDM
  584. ; ********************************************************************
  585. ; *          BCC. Opcode 90                                          *
  586. ; ********************************************************************
  587. CPU_BCC MACRO Operand:REQ
  588. ; Test the carry flag.
  589. test CPU.F, 1
  591. ; If the carry flag is clear, then branch.
  592. .IF ZERO?
  593. ; If the operand is negative we subtract it from the PC,
  594. ; otherwise we need to add it to the PC.
  595. .IF Operand & 10000000b
  596. mov di, 0100h
  597. sub di, Operand
  598. sub CPU.P, di
  599. .ELSE
  600. add CPU.P, Operand
  601. .ENDIF
  602. .ENDIF
  603. ENDM
  605. ; ********************************************************************
  606. ; *          BCS. Opcode B0                                          *
  607. ; ********************************************************************
  608. CPU_BCS MACRO Operand:REQ
  609. ; Test the carry flag.
  610. test CPU.F, 00000001b
  612. ; If the carry flag is set, then branch.
  613. .IF !ZERO?
  614. ; If the operand is negative we subtract it from the PC,
  615. ; otherwise we need to add it to the PC.
  616. .IF Operand & 10000000b
  617. mov di, 0100h
  618. sub di, Operand
  619. sub CPU.P, di
  620. .ELSE
  621. add CPU.P, Operand
  622. .ENDIF
  623. .ENDIF
  624. ENDM
  626. ; ********************************************************************
  627. ; *          BEQ. Opcode F0                                          *
  628. ; ********************************************************************
  629. CPU_BEQ MACRO Operand:REQ
  630. ; Test the zero flag.
  631. test CPU.F, 00000010b
  633. ; If the zero flag is set, then branch.
  634. .IF !ZERO?
  635. ; If the operand is negative we subtract it from the PC,
  636. ; otherwise we need to add it to the PC.
  637. .IF Operand & 10000000b
  638. mov di, 0100h
  639. sub di, Operand
  640. sub CPU.P, di
  641. .ELSE
  642. add CPU.P, Operand
  643. .ENDIF
  644. .ENDIF
  645. ENDM
  647. ; ********************************************************************
  648. ; *          BIT. Opcodes 24, 2C                                     *
  649. ; ********************************************************************
  650. CPU_BIT MACRO Operand:REQ
  651. ; Save the operand for later and perform the bit operation
  652. ; which is really just an add instruction.
  653. mov dl, Operand
  654. and CPU.A, Operand
  656. ; Test and set/clear the zero flag.
  657. MODIFYFLAGS S, , Z,
  659. ; Bit 7 of the operand is transferred to the sign flag.
  660. ; Bit 6 of the operand is transferred to the overflow flag.
  661. and dl, 11000000b
  662. and CPU.F, 00111111b
  663. or CPU.F, dl
  664. ENDM
  666. ; ********************************************************************
  667. ; *          BMI. Opcode 30                                          *
  668. ; ********************************************************************
  669. CPU_BMI MACRO Operand:REQ
  670. ; Test the sign flag.
  671. test CPU.F, 10000000b
  673. ; If the sign flag is set, then branch.
  674. .IF !ZERO?
  675. ; If the operand is negative we subtract it from the PC,
  676. ; otherwise we need to add it to the PC.
  677. .IF Operand & 10000000b
  678. mov di, 0100h
  679. sub di, Operand
  680. sub CPU.P, di
  681. .ELSE
  682. add CPU.P, Operand
  683. .ENDIF
  684. .ENDIF
  685. ENDM
  687. ; ********************************************************************
  688. ; *          BNE. Opcode D0                                          *
  689. ; ********************************************************************
  690. CPU_BNE MACRO Operand:REQ
  691. ; Test the zero flag.
  692. test CPU.F, 00000010b
  694. ; If the zero flag is clear, then branch.
  695. .IF ZERO?
  696. ; If the operand is negative we subtract it from the PC,
  697. ; otherwise we need to add it to the PC.
  698. .IF Operand & 10000000b
  699. mov di, 0100h
  700. sub di, Operand
  701. sub CPU.P, di
  702. .ELSE
  703. add CPU.P, Operand
  704. .ENDIF
  705. .ENDIF
  706. ENDM
  708. ; ********************************************************************
  709. ; *          BPL. Opcode 10                                          *
  710. ; ********************************************************************
  711. CPU_BPL MACRO Operand:REQ
  712. ; Test the sign flag.
  713. test CPU.F, 10000000b
  715. ; If the sign flag is clear, then branch.
  716. .IF ZERO?
  717. ; If the operand is negative we subtract it from the PC,
  718. ; otherwise we need to add it to the PC.
  719. .IF Operand & 10000000b
  720. mov di, 0100h
  721. sub di, Operand
  722. sub CPU.P, di
  723. .ELSE
  724. add CPU.P, Operand
  725. .ENDIF
  726. .ENDIF
  727. ENDM
  729. ; ********************************************************************
  730. ; *          BRK. Opcode 00                                          *
  731. ; ********************************************************************
  732. CPU_BRK MACRO
  733. ; Push the PC+2 onto the stack high byte first.
  734. mov bx, CPU.P
  735. add bx, 2
  736. PUSH_BYTE bh
  737. PUSH_BYTE bl
  739. ; Push the flags onto the stack.
  740. PUSH_BYTE CPU.F
  742. ; Set the new PC address byte getting the address from the
  743. ; break vector on the PRG-ROM.
  744. GET_MEMORY_BYTE 0FFFEh
  745. mov bl, al
  746. GET_MEMORY_BYTE 0FFFFh
  747. mov bh, al
  748. mov CPU.P, bx
  750. ; Set the break flag.
  751. or CPU.F, 00010000b
  752. ENDM
  754. ; ********************************************************************
  755. ; *          BVC. Opcode 50                                          *
  756. ; ********************************************************************
  757. CPU_BVC MACRO Operand:REQ
  758. ; Test the overflow flag.
  759. test CPU.F, 01000000b
  761. ; If the overflow flag is clear, then branch.
  762. .IF ZERO?
  763. ; If the operand is negative we subtract it from the PC,
  764. ; otherwise we need to add it to the PC.
  765. .IF Operand & 10000000b
  766. mov di, 0100h
  767. sub di, Operand
  768. sub CPU.P, di
  769. .ELSE
  770. add CPU.P, Operand
  771. .ENDIF
  772. .ENDIF
  773. ENDM
  775. ; ********************************************************************
  776. ; *          BVS. Opcode 70                                          *
  777. ; ********************************************************************
  778. CPU_BVS MACRO Operand:REQ
  779. ; Test the overflow flag.
  780. test CPU.F, 01000000b
  782. ; If the overflow flag is set, then branch.
  783. .IF !ZERO?
  784. ; If the operand is negative we subtract it from the PC,
  785. ; otherwise we need to add it to the PC.
  786. .IF Operand & 10000000b
  787. mov di, 0100h
  788. sub di, Operand
  789. sub CPU.P, di
  790. .ELSE
  791. add CPU.P, Operand
  792. .ENDIF
  793. .ENDIF
  794. ENDM
  796. ; ********************************************************************
  797. ; *          CLC. Opcode 18                                          *
  798. ; ********************************************************************
  799. CPU_CLC MACRO
  800. ; Clear the carry flag.
  801. and CPU.F, 11111110b
  802. ENDM
  804. ; ********************************************************************
  805. ; *          CLD. Opcode D8                                          *
  806. ; ********************************************************************
  807. CPU_CLD MACRO
  808. ; Clear the decimal flag.
  809. and CPU.F, 11110111b
  810. ENDM
  812. ; ********************************************************************
  813. ; *          CLI. Opcode 58                                          *
  814. ; ********************************************************************
  815. CPU_CLI MACRO
  816. ; Clear the interrupt flag.
  817. and CPU.F, 11111011b
  818. ENDM
  820. ; ********************************************************************
  821. ; *          CLV. Opcode B8                                          *
  822. ; ********************************************************************
  823. CPU_CLV MACRO
  824. ; Clear the overflow flag.
  825. and CPU.F, 10111111b
  826. ENDM
  828. ; ********************************************************************
  829. ; *          CMP. Opcodes C9, C5, D5, CD, DD, D9, C1, D1             *
  830. ; *          CPX. Opcodes E0, E4, EC                                 *
  831. ; *          CPY. Opcodes C0, C4, CC                                 *
  832. ; ********************************************************************
  833. CPU_CP? MACRO byReg:REQ, Operand:REQ
  834. ; Compare and reverse the carry flag becuase the 6502 is
  835. ; opposite the Intel when it comes to subtraction.
  836. cmp byReg, Operand
  837. cmc
  838. MODIFYFLAGS S, , Z, C
  839. ENDM
  841. ; ********************************************************************
  842. ; *          DEC. Opcodes C6, D6, CE, DE                             *
  843. ; ********************************************************************
  844. CPU_DEC MACRO pbyMem:REQ
  845. ; Decrement the memory.
  846. dec BYTE PTR [pbyMem]
  848. ; Now set the flags accordingly.
  849. MODIFYFLAGS S, , Z,
  850. ENDM
  852. ; ********************************************************************
  853. ; *          DEX. Opcode  CA                                         *
  854. ; ********************************************************************
  855. CPU_DEX MACRO
  856. ; Decrement the register.
  857. dec CPU.X
  859. ; Now set the flags accordingly.
  860. MODIFYFLAGS S, , Z,
  861. ENDM
  863. ; ********************************************************************
  864. ; *          DEY. Opcode  88                                         *
  865. ; ********************************************************************
  866. CPU_DEY MACRO
  867. ; Decrement the register.
  868. dec CPU.Y
  870. ; Now set the flags accordingly.
  871. MODIFYFLAGS S, , Z,
  872. ENDM
  874. ; ********************************************************************
  875. ; *          EOR. Opcodes 49, 45, 55, 4D, 5D, 59, 41, 51             *
  876. ; ********************************************************************
  877. CPU_EOR MACRO Operand:REQ
  878. ; Perform the operation.
  879. xor CPU.A, Operand
  881. ; Test and set/clear the sign and zero flags.
  882. MODIFYFLAGS S, , Z,
  883. ENDM
  885. ; ********************************************************************
  886. ; *          INC. Opcodes E6, F6, EE, FE                             *
  887. ; ********************************************************************
  888. CPU_INC MACRO pbyMem:REQ
  889. ; Increment the memory.
  890. inc BYTE PTR [pbyMem]
  892. ; Now set the flags accordingly.
  893. MODIFYFLAGS S, , Z,
  894. ENDM
  896. ; ********************************************************************
  897. ; *          INX. Opcode E8                                          *
  898. ; ********************************************************************
  899. CPU_INX MACRO
  900. ; Increment the register.
  901. inc CPU.X
  903. ; Now set the flags accordingly.
  904. MODIFYFLAGS S, , Z,
  905. ENDM
  907. ; ********************************************************************
  908. ; *          INY. Opcode C8                                          *
  909. ; ********************************************************************
  910. CPU_INY MACRO
  911. ; Increment the register.
  912. inc CPU.Y
  914. ; Now set the flags accordingly.
  915. MODIFYFLAGS S, , Z,
  916. ENDM
  918. ; ********************************************************************
  919. ; *          JMP. Opcodes 4C, 6C                                     *
  920. ; ********************************************************************
  921. CPU_JMP MACRO Operand:REQ
  922. ; Set the new PC address.
  923. mov CPU.P, Operand
  924. ENDM
  926. ; ********************************************************************
  927. ; *          JSR. Opcode 20                                          *
  928. ; ********************************************************************
  929. CPU_JSR MACRO Operand:REQ
  930. ; Save the operand so it doesn't get overwritten.
  931. push Operand
  933. ; Push the PC+2 onto the stack high byte first.
  934. mov bx, CPU.P
  935. add bx, 2
  936. PUSH_BYTE bh
  937. PUSH_BYTE bl
  939. ; Restore the operand set the new PC address.
  940. pop Operand
  941. mov CPU.P, Operand
  942. ENDM
  944. ; ********************************************************************
  945. ; *          LDA. Opcodes A9, A5, B5, AD, BD, B9, A1, B1             *
  946. ; *          LDX. Opcodes A2, A6, B6, AE, BE                         *
  947. ; *          LDY. Opcodes A0, A4, B4, AC, BC                         *
  948. ; ********************************************************************
  949. CPU_LD? MACRO byReg:REQ, byData:REQ
  950. ; Move the operand into the A register.
  951. mov byReg, byData
  952. mov al, byReg
  953. test al, al
  955. ; Test and Set/Clear the sign and zero flags.
  956. MODIFYFLAGS S, , Z,
  957. ENDM
  959. ; ********************************************************************
  960. ; *          LSR. Opcodes 4A, 46, 56, 4E, 5E                         *
  961. ; ********************************************************************
  962. CPU_LSR MACRO Operand:REQ
  963. ; Perform the operation.
  964. shr BYTE PTR [Operand], 1
  965. MODIFYFLAGS , , , C
  967. mov al, [Operand]
  968. test al, al
  970. ; Test and set/clear the flags.
  971. MODIFYFLAGS S, , Z, 
  972. ENDM
  974. ; ********************************************************************
  975. ; *          ORA. Opcodes 09, 05, 15, 0D, 1D, 19, 01, 11             *
  976. ; ********************************************************************
  977. CPU_ORA MACRO Operand:REQ
  978. ; Perform the operation.
  979. or CPU.A, Operand
  981. ; Test and set/clear the sign and zero flags.
  982. MODIFYFLAGS S, , Z,
  983. ENDM
  985. ; ********************************************************************
  986. ; *          PHA. Opcode 48                                          *
  987. ; ********************************************************************
  988. CPU_PHA MACRO
  989. ; Push the A register onto the stack.
  990. PUSH_BYTE CPU.A
  991. ENDM
  993. ; ********************************************************************
  994. ; *          PHP. Opcode 08                                          *
  995. ; ********************************************************************
  996. CPU_PHP MACRO
  997. ; Push the flags register onto the stack.
  998. PUSH_BYTE CPU.F
  999. ENDM
  1001. ; ********************************************************************
  1002. ; *          PLA. Opcode 68                                          *
  1003. ; ********************************************************************
  1004. CPU_PLA MACRO
  1005. ; Pop the A register from the stack.
  1006. POP_BYTE CPU.A
  1008. ; Now set the flags
  1009. mov al, CPU.A
  1010. test al, al
  1011. MODIFYFLAGS S, , Z, 
  1012. ENDM
  1014. ; ********************************************************************
  1015. ; *          PLP. Opcode 28                                          *
  1016. ; ********************************************************************
  1017. CPU_PLP MACRO
  1018. ; Pop the flags register from the stack.
  1019. POP_BYTE CPU.F
  1020. ENDM
  1022. ; ********************************************************************
  1023. ; *          ROL. Opcodes 2A, 26, 36, 2E, 3E                         *
  1024. ; ********************************************************************
  1025. CPU_ROL MACRO Operand:REQ
  1026. ; Set/clear the carry flag on the real cpu.
  1027. mov dl, CPU.F
  1028. shr dl, 1
  1030. ; Perform the operation.
  1031. rcl BYTE PTR [Operand], 1
  1032. MODIFYFLAGS , , , C
  1034. mov al, [Operand]
  1035. test al, al
  1037. ; Test and set/clear the flags.
  1038. MODIFYFLAGS S, , Z, 
  1039. ENDM
  1041. ; ********************************************************************
  1042. ; *          ROR. Opcodes 6A, 66, 76, 6E, 7E                         *
  1043. ; ********************************************************************
  1044. CPU_ROR MACRO Operand:REQ
  1045. ; Set/clear the carry flag on the real cpu.
  1046. mov dl, CPU.F
  1047. shr dl, 1
  1049. ; Perform the operation.
  1050. rcr BYTE PTR [Operand], 1
  1051. MODIFYFLAGS , , , C
  1053. mov al, [Operand]
  1054. test al, al
  1056. ; Test and set/clear the flags.
  1057. MODIFYFLAGS S, , Z, 
  1058. ENDM
  1060. ; ********************************************************************
  1061. ; *          RTI. Opcode 4D                                          *
  1062. ; ********************************************************************
  1063. CPU_RTI MACRO
  1064. ; Pop the flags register from the stack.
  1065. POP_BYTE CPU.F
  1067. ; Pop the PC from the stack low byte first.
  1068. POP_BYTE bl
  1069. POP_BYTE bh
  1071. ; Set the PC to the new address.
  1072. mov CPU.P, bx
  1073. ENDM
  1075. ; ********************************************************************
  1076. ; *          RTS. Opcode 60                                          *
  1077. ; ********************************************************************
  1078. CPU_RTS MACRO
  1079. ; Pop the PC from the stack low byte first.
  1080. POP_BYTE bl
  1081. POP_BYTE bh
  1083. ; Set the PC to the new address.
  1084. mov CPU.P, bx
  1085. ENDM
  1087. ; ********************************************************************
  1088. ; *          SBC. Opcodes E9, E5, F5, ED, FD, F9, E1, F1             *
  1089. ; ********************************************************************
  1090. CPU_SBC MACRO Operand:REQ
  1091. ; Move the NES's carry flag into the real cpu's carry flag.
  1092. mov dl, CPU.F
  1093. shr dl, 1
  1094. cmc
  1096. ; Now subtract the operand from the A register with the carry flag.
  1097. sbb CPU.A, Operand
  1098. cmc
  1099. MODIFYFLAGS S, V, Z, C
  1100. ENDM
  1102. ; ********************************************************************
  1103. ; *          SEC. Opcode 38                                          *
  1104. ; ********************************************************************
  1105. CPU_SEC MACRO
  1106. ; Set the carry flag.
  1107. or CPU.F, 00000001b
  1108. ENDM
  1110. ; ********************************************************************
  1111. ; *          SED. Opcode F8                                          *
  1112. ; ********************************************************************
  1113. CPU_SED MACRO
  1114. ; Set the decimal flag.
  1115. or CPU.F, 00001000b
  1116. ENDM
  1118. ; ********************************************************************
  1119. ; *          SEI. Opcode 78                                          *
  1120. ; ********************************************************************
  1121. CPU_SEI MACRO
  1122. ; Set the interrupt flag.
  1123. or CPU.F, 00000100b
  1124. ENDM
  1126. ; ********************************************************************
  1127. ; *             STA. Opcodes 85, 95, 8D, 9D, 99, 81, 91              *
  1128. ; *             STX. Opcodes 86, 96, 8E                              *
  1129. ; *             STY. Opcodes 84, 94, 8C                              *
  1130. ; ********************************************************************
  1131. CPU_ST? MACRO wAddress:REQ, byData:REQ
  1132. WRITE_MEMORY wAddress, byData
  1133. ENDM
  1135. ; ********************************************************************
  1136. ; *          TAX. Opcode AA                                          *
  1137. ; ********************************************************************
  1138. CPU_TAX MACRO
  1139. ; Transfer the A register to the X register.
  1140. mov al, CPU.A
  1141. mov CPU.X, al
  1142. test al, al
  1144. ; Set/clear the sign and zero flags.
  1145. MODIFYFLAGS S, , Z,
  1146. ENDM
  1148. ; ********************************************************************
  1149. ; *          TAY. Opcode A8                                          *
  1150. ; ********************************************************************
  1151. CPU_TAY MACRO
  1152. ; Transfer the A register to the Y register.
  1153. mov al, CPU.A
  1154. mov CPU.Y, al
  1155. test al, al
  1157. ; Set/clear the sign and zero flags.
  1158. MODIFYFLAGS S, , Z,
  1159. ENDM
  1161. ; ********************************************************************
  1162. ; *          TSX. Opcode BA                                          *
  1163. ; ********************************************************************
  1164. CPU_TSX MACRO
  1165. ; Transfer the SP register to the X register.
  1166. mov al, CPU.S
  1167. mov CPU.X, al
  1168. test al, al
  1170. ; Set/clear the sign and zero flags.
  1171. MODIFYFLAGS S, , Z,
  1172. ENDM
  1174. ; ********************************************************************
  1175. ; *          TXA. Opcode 8A                                          *
  1176. ; ********************************************************************
  1177. CPU_TXA MACRO
  1178. ; Transfer the X register to the A register.
  1179. mov al, CPU.X
  1180. mov CPU.A, al
  1181. test al, al
  1183. ; Set/clear the sign and zero flags.
  1184. MODIFYFLAGS S, , Z,
  1185. ENDM
  1187. ; ********************************************************************
  1188. ; *          TXS. Opcode 9A                                          *
  1189. ; ********************************************************************
  1190. CPU_TXS MACRO
  1191. ; Transfer the X register to the SP register.
  1192. mov al, CPU.X
  1193. mov CPU.S, al
  1194. ENDM
  1196. ; ********************************************************************
  1197. ; *          TYA. Opcode 98                                          *
  1198. ; ********************************************************************
  1199. CPU_TYA MACRO
  1200. ; Transfer the Y register to the A register.
  1201. mov al, CPU.Y
  1202. mov CPU.A, al
  1203. test al, al
  1205. ; Set/clear the sign and zero flags.
  1206. MODIFYFLAGS S, , Z,
  1207. ENDM
  1213. ;******************************************************************************
  1214. ;* Name: _RunCPU
  1215. ;* Desc: TBA
  1216. ;******************************************************************************
  1217. RunCPU PROC C dwFlags : DWORD
  1219. LOCAL dwOpcode : DWORD ; Temporary storage for our opcode.
  1221.     ; Save all the registers before entering.
  1222. pushad
  1224. RunCPU_RunAgain:
  1226.     ; Get the opcode byte.
  1227. GET_MEMORY_BYTE CPU.P
  1229.     ; Save the opcode for later use and then jump to the
  1230. ; correct opcode using the jump table defined above.
  1231. and eax, 000000FFh
  1232. mov dwOpcode, eax
  1233.     jmp [adwOpcodeJumpTable+eax*4]
  1236. ;********************************** ADC ***************************************
  1237. ; Add memory to the accumulator with the carry bit as well.
  1239. _69::
  1240. GET_ADDR_IMMEDIATE
  1241. CPU_ADC al
  1242. jmp _??
  1244. _65::
  1245. GET_ADDR_ZEROPAGE
  1246. GET_MEMORY_BYTE ax
  1247. CPU_ADC al
  1248. jmp _??
  1250. _75::
  1251. GET_ADDR_ZEROPAGE_X
  1252. GET_MEMORY_BYTE ax
  1253. CPU_ADC al
  1254. jmp _??
  1256. _6D::
  1257. GET_ADDR_ABSOLUTE
  1258. GET_MEMORY_BYTE bx
  1259. CPU_ADC al
  1260.     jmp _??
  1262. _79::
  1263. GET_ADDR_ABSOLUTE_Y
  1264. GET_MEMORY_BYTE bx
  1265. CPU_ADC al
  1266.     jmp _??
  1268. _7D::
  1269. GET_ADDR_ABSOLUTE_X
  1270. GET_MEMORY_BYTE bx
  1271. CPU_ADC al
  1272.     jmp _??
  1274. _61::
  1275. GET_ADDR_PREINDEXED
  1276. GET_MEMORY_BYTE bx
  1277. CPU_ADC al
  1278.     jmp _??
  1280. _71::
  1281. GET_ADDR_POSTINDEXED
  1282. GET_MEMORY_BYTE bx
  1283. CPU_ADC al
  1284.     jmp _??
  1286. ;********************************** AND ***************************************
  1287. ; For all the addressing modes except for immediate, get the address 
  1288. ; of the byte to AND A with, then use that address to get the byte
  1289. ; and perform the AND operation with it. For the immediate mode,
  1290. ; just AND the byte with the A register.
  1292. _29::
  1293. GET_ADDR_IMMEDIATE
  1294. CPU_AND al
  1295. jmp _??
  1297. _25::
  1298. GET_ADDR_ZEROPAGE
  1299. GET_MEMORY_BYTE ax
  1300. CPU_AND al
  1301. jmp _??
  1303. _35::
  1304. GET_ADDR_ZEROPAGE_X
  1305. GET_MEMORY_BYTE ax
  1306. CPU_AND al
  1307. jmp _??
  1309. _2D::
  1310. GET_ADDR_ABSOLUTE
  1311. GET_MEMORY_BYTE bx
  1312.     CPU_AND al
  1313.     jmp _??
  1315. _39::
  1316. GET_ADDR_ABSOLUTE_Y
  1317. GET_MEMORY_BYTE bx
  1318.     CPU_AND al
  1319.     jmp _??
  1321. _3D::
  1322. GET_ADDR_ABSOLUTE_X
  1323. GET_MEMORY_BYTE bx
  1324.     CPU_AND al
  1325.     jmp _??
  1327. _21::
  1328. GET_ADDR_PREINDEXED
  1329. GET_MEMORY_BYTE bx
  1330.     CPU_AND al
  1331.     jmp _??
  1333. _31::
  1334. GET_ADDR_POSTINDEXED
  1335. GET_MEMORY_BYTE bx
  1336.     CPU_AND al
  1337.     jmp _??
  1339. ;********************************** ASL ***************************************
  1340. ; Perform a logical shift left with least significant bit being filled
  1341. ; with a zero and the most significant bit going into the carry.
  1342. _0A::
  1343. mov ebx, OFFSET (CPU.A)
  1344. CPU_ASL ebx
  1345. jmp _??
  1347. _06::
  1348. GET_ADDR_ZEROPAGE
  1349. GET_MEMORY_POINTER ax
  1350. mov ebx, eax
  1351. CPU_ASL ebx
  1352. jmp _??
  1354. _16::
  1355. GET_ADDR_ZEROPAGE_X
  1356. GET_MEMORY_POINTER ax
  1357. mov ebx, eax
  1358. CPU_ASL ebx
  1359. jmp _??
  1361. _0E::
  1362. GET_ADDR_ABSOLUTE
  1363. GET_MEMORY_POINTER bx
  1364. mov ebx, eax
  1365. CPU_ASL ebx
  1366. jmp _??
  1368. _1E::
  1369. GET_ADDR_ABSOLUTE_X
  1370. GET_MEMORY_POINTER bx
  1371. mov ebx, eax
  1372. CPU_ASL ebx
  1373. jmp _??
  1375. ;********************************** BCC ***************************************
  1376. ; Branches to a memory location if the carry flag is clear.
  1377. _90::
  1378. GET_ADDR_RELATIVE
  1379. CPU_BCC ax
  1380. jmp _??
  1382. ;********************************** BCS ***************************************
  1383. ; Branches to a memory location if the carry flag is set.
  1384. _B0::
  1385. GET_ADDR_RELATIVE
  1386. CPU_BCS ax
  1387. jmp _??
  1389. ;********************************** BEQ ***************************************
  1390. ; Branches to a memory location if the zero flag is set.
  1391. _F0::
  1392. GET_ADDR_RELATIVE
  1393. CPU_BEQ ax
  1394. jmp _??
  1396. ;********************************** BIT ***************************************
  1397. ; Ands the operand with the A register and transfers bit 7 and 6 to 
  1398. ; the flags register.
  1400. _24::
  1401. GET_ADDR_ZEROPAGE
  1402. GET_MEMORY_BYTE ax
  1403. CPU_BIT al
  1404. jmp _??
  1406. _2C::
  1407. GET_ADDR_ABSOLUTE
  1408. GET_MEMORY_BYTE bx
  1409. CPU_BIT al
  1410. jmp _??
  1412. ;********************************** BMI ***************************************
  1413. ; Branches to a memory location if the sign flag is set.
  1414. _30::
  1415. GET_ADDR_RELATIVE
  1416. CPU_BMI ax
  1417. jmp _??
  1419. ;********************************** BNE ***************************************
  1420. ; Branches to a memory location if the zero flag is clear.
  1421. _D0::
  1422. GET_ADDR_RELATIVE
  1423. CPU_BNE ax
  1424. jmp _??
  1426. ;********************************** BPL ***************************************
  1427. ; Branches to a memory location if the sign flag is clear.
  1428. _10::
  1429. GET_ADDR_RELATIVE
  1430. CPU_BPL ax
  1431. jmp _??
  1433. ;********************************** BRK ***************************************
  1434. ; Push the PC and flags onto the stack and then jump to the word 
  1435. ; address specified in the PRG-ROM at $FFFE
  1436. _00::
  1437. CPU_BRK
  1438. jmp _??
  1440. ;********************************** BVC ***************************************
  1441. ; Branches to a memory location if the overflow flag is clear.
  1442. _50::
  1443. GET_ADDR_RELATIVE
  1444. CPU_BVC ax
  1445. jmp _??
  1447. ;********************************** BVS ***************************************
  1448. ; Branches to a memory location if the overflow flag is set.
  1449. _70::
  1450. GET_ADDR_RELATIVE
  1451. CPU_BVS ax
  1452. jmp _??
  1454. ;********************************** CLC ***************************************
  1455. ; Clears the carry flag.
  1456. _18::
  1457. CPU_CLC
  1458. jmp _??
  1460. ;********************************** CLD ***************************************
  1461. ; Clears the decimal flag.
  1462. _D8::
  1463. CPU_CLD
  1464. jmp _??
  1466. ;********************************** CLI ***************************************
  1467. ; Clears the interrupt flag.
  1468. _58::
  1469. CPU_CLI
  1470. jmp _??
  1472. ;********************************** CLV ***************************************
  1473. ; Clears the overflow flag.
  1474. _B8::
  1475. CPU_CLV
  1476. jmp _??
  1478. ;********************************** CMP ***************************************
  1479. ; Compares memory with the A register by using subtraction.
  1481. _C9::
  1482. GET_ADDR_IMMEDIATE
  1483. CPU_CP? CPU.A, al
  1484. jmp _??
  1486. _C5::
  1487. GET_ADDR_ZEROPAGE
  1488. GET_MEMORY_BYTE ax
  1489. CPU_CP? CPU.A, al
  1490. jmp _??
  1492. _D5::
  1493. GET_ADDR_ZEROPAGE_X
  1494. GET_MEMORY_BYTE ax
  1495. CPU_CP? CPU.A, al
  1496. jmp _??
  1498. _CD::
  1499. GET_ADDR_ABSOLUTE
  1500. GET_MEMORY_BYTE bx
  1501. CPU_CP? CPU.A, al
  1502.     jmp _??
  1504. _D9::
  1505. GET_ADDR_ABSOLUTE_Y
  1506. GET_MEMORY_BYTE bx
  1507. CPU_CP? CPU.A, al
  1508.     jmp _??
  1510. _DD::
  1511. GET_ADDR_ABSOLUTE_X
  1512. GET_MEMORY_BYTE bx
  1513. CPU_CP? CPU.A, al
  1514.     jmp _??
  1516. _C1::
  1517. GET_ADDR_PREINDEXED
  1518. GET_MEMORY_BYTE bx
  1519. CPU_CP? CPU.A, al
  1520.     jmp _??
  1522. _D1::
  1523. GET_ADDR_POSTINDEXED
  1524. GET_MEMORY_BYTE bx
  1525. CPU_CP? CPU.A, al
  1526.     jmp _??
  1528. ;********************************** CPX ***************************************
  1529. ; Compares memory with the X register by using subtraction.
  1531. _E0::
  1532. GET_ADDR_IMMEDIATE
  1533. CPU_CP? CPU.X, al
  1534. jmp _??
  1536. _E4:: 
  1537. GET_ADDR_ZEROPAGE
  1538. GET_MEMORY_BYTE ax
  1539.     CPU_CP? CPU.X, al
  1540. jmp _??
  1542. _EC::
  1543. GET_ADDR_ABSOLUTE
  1544. GET_MEMORY_BYTE bx
  1545.     CPU_CP? CPU.X, al
  1546.     jmp _??
  1548. ;********************************** CPY ***************************************
  1549. ; Compares memory with the Y register by using subtraction.
  1551. _C0::
  1552. GET_ADDR_IMMEDIATE
  1553. CPU_CP? CPU.Y, al
  1554. jmp _??
  1556. _C4:: 
  1557. GET_ADDR_ZEROPAGE
  1558. GET_MEMORY_BYTE ax
  1559.     CPU_CP? CPU.Y, al
  1560. jmp _??
  1562. _CC::
  1563. GET_ADDR_ABSOLUTE
  1564. GET_MEMORY_BYTE bx
  1565.     CPU_CP? CPU.Y, al
  1566.     jmp _??
  1568. ;********************************** DEC ***************************************
  1569. ; Decrement the value in memory by 1.
  1571. _C6::
  1572. GET_ADDR_ZEROPAGE
  1573. GET_MEMORY_POINTER ax
  1574. mov ebx, eax
  1575. CPU_DEC ebx
  1576. jmp _??
  1577. _D6::
  1578. GET_ADDR_ZEROPAGE_X
  1579. GET_MEMORY_POINTER ax
  1580. mov ebx, eax
  1581. CPU_DEC ebx
  1582. jmp _??
  1584. _CE::
  1585. GET_ADDR_ABSOLUTE
  1586. GET_MEMORY_POINTER bx
  1587. mov ebx, eax
  1588. CPU_DEC ebx
  1589. jmp _??
  1591. _DE::
  1592. GET_ADDR_ABSOLUTE_X
  1593. GET_MEMORY_POINTER bx
  1594. mov ebx, eax
  1595. CPU_DEC ebx
  1596. jmp _??
  1598. ;********************************** DEX ***************************************
  1599. ; Decrement the value in the X register by one.
  1600. _CA::
  1601. CPU_DEX
  1602. jmp _??
  1604. ;********************************** DEY ***************************************
  1605. ; Decrement the value in the Y register by one.
  1606. _88::
  1607. CPU_DEY
  1608. jmp _??
  1610. ;********************************** EOR ***************************************
  1611. ; Perform a logical exclusive or operation on the memory and the A register
  1612. ; storing the result in the A register.
  1613. _49::
  1614. GET_ADDR_IMMEDIATE
  1615. CPU_EOR al
  1616. jmp _??
  1618. _45::
  1619. GET_ADDR_ZEROPAGE
  1620. GET_MEMORY_BYTE ax
  1621. CPU_EOR al
  1622. jmp _??
  1624. _55::
  1625. GET_ADDR_ZEROPAGE_X
  1626. GET_MEMORY_BYTE ax
  1627. CPU_EOR al
  1628. jmp _??
  1630. _4D::
  1631. GET_ADDR_ABSOLUTE
  1632. GET_MEMORY_BYTE bx
  1633. CPU_EOR al
  1634.     jmp _??
  1636. _59::
  1637. GET_ADDR_ABSOLUTE_Y
  1638. GET_MEMORY_BYTE bx
  1639. CPU_EOR al
  1640.     jmp _??
  1642. _5D::
  1643. GET_ADDR_ABSOLUTE_X
  1644. GET_MEMORY_BYTE bx
  1645. CPU_EOR al
  1646.     jmp _??
  1648. _41::
  1649. GET_ADDR_PREINDEXED
  1650. GET_MEMORY_BYTE bx
  1651. CPU_EOR al
  1652.     jmp _??
  1654. _51::
  1655. GET_ADDR_POSTINDEXED
  1656. GET_MEMORY_BYTE bx
  1657. CPU_EOR al
  1658.     jmp _??
  1660. ;********************************** INC ***************************************
  1661. ; Increment the value in memory by 1.
  1663. _E6::
  1664. GET_ADDR_ZEROPAGE
  1665. GET_MEMORY_POINTER ax
  1666. mov ebx, eax
  1667. CPU_INC ebx
  1668. jmp _??
  1669. _F6::
  1670. GET_ADDR_ZEROPAGE_X
  1671. GET_MEMORY_POINTER ax
  1672. mov ebx, eax
  1673. CPU_INC ebx
  1674. jmp _??
  1676. _EE::
  1677. GET_ADDR_ABSOLUTE
  1678. GET_MEMORY_POINTER bx
  1679. mov ebx, eax
  1680. CPU_INC ebx
  1681. jmp _??
  1683. _FE::
  1684. GET_ADDR_ABSOLUTE_X
  1685. GET_MEMORY_POINTER bx
  1686. mov ebx, eax
  1687. CPU_INC ebx
  1688. jmp _??
  1690. ;********************************** INX ***************************************
  1691. ; Increment the value in the X register by one.
  1692. _E8::
  1693. CPU_INX
  1694. jmp _??
  1696. ;********************************** INY ***************************************
  1697. ; Increment the value in the Y register by one.
  1698. _C8::
  1699. CPU_INY
  1700. jmp _??
  1702. ;********************************** JMP ***************************************
  1703. ; Get the value to set the PC to and store that value in the PC register.
  1705. _4C::
  1706. GET_ADDR_ABSOLUTE
  1707. CPU_JMP bx
  1708. jmp _??
  1710. _6C::
  1711. GET_ADDR_INDIRECT
  1712. CPU_JMP bx
  1713. jmp _??
  1715. ;********************************** JSR ***************************************
  1716. ; Get the value to set the PC to and store that value in the PC register.
  1717. ; Save the return address on the stack.
  1718. _20::
  1719. GET_ADDR_ABSOLUTE
  1720. CPU_JSR bx
  1721. jmp _??
  1723. ;********************************** LDA ***************************************
  1724. ; For all the addressing modes except for immediate, get the address 
  1725. ; to read memory from, then read memory and load it into the A register.
  1726. ; For the immediate mode just load the byte into the A register.
  1728. _A9::
  1729. GET_ADDR_IMMEDIATE
  1730. CPU_LD? CPU.A, al
  1731. jmp _??
  1733. _A5::
  1734. GET_ADDR_ZEROPAGE
  1735. READ_MEMORY ax
  1736.     CPU_LD? CPU.A, al
  1737. jmp _??
  1739. _B5::
  1740. GET_ADDR_ZEROPAGE_X
  1741. READ_MEMORY ax
  1742.     CPU_LD? CPU.A, al
  1743. jmp _??
  1745. _AD::
  1746. GET_ADDR_ABSOLUTE
  1747. READ_MEMORY bx
  1748.     CPU_LD? CPU.A, al
  1749.     jmp _??
  1751. _B9::
  1752. GET_ADDR_ABSOLUTE_Y
  1753. READ_MEMORY bx
  1754.     CPU_LD? CPU.A, al
  1755.     jmp _??
  1757. _BD::
  1758. GET_ADDR_ABSOLUTE_X
  1759. READ_MEMORY bx
  1760.     CPU_LD? CPU.A, al
  1761.     jmp _??
  1763. _A1::
  1764. GET_ADDR_PREINDEXED
  1765. READ_MEMORY bx
  1766.     CPU_LD? CPU.A, al
  1767.     jmp _??
  1769. _B1::
  1770. GET_ADDR_POSTINDEXED
  1771. READ_MEMORY bx
  1772.     CPU_LD? CPU.A, al
  1773.     jmp _??
  1776. ;********************************** LDX ***************************************
  1777. ; For all the addressing modes except for immediate, get the address 
  1778. ; to read memory from, then read memory and load it into the X register.
  1779. ; For the immediate mode just load the byte into the X register.
  1781. _A2::
  1782. GET_ADDR_IMMEDIATE
  1783. CPU_LD? CPU.X, al
  1784. jmp _??
  1786. _A6:: 
  1787. GET_ADDR_ZEROPAGE
  1788. READ_MEMORY ax
  1789.     CPU_LD? CPU.X, al
  1790. jmp _??
  1792. _B6::
  1793. GET_ADDR_ZEROPAGE_Y
  1794. READ_MEMORY ax
  1795.     CPU_LD? CPU.X, al
  1796. jmp _??
  1798. _AE::
  1799. GET_ADDR_ABSOLUTE
  1800. READ_MEMORY bx
  1801.     CPU_LD? CPU.X, al
  1802.     jmp _??
  1804. _BE::
  1805. GET_ADDR_ABSOLUTE_Y
  1806. READ_MEMORY bx
  1807.     CPU_LD? CPU.X, al
  1808.     jmp _??
  1810. ;********************************** LDY ***************************************
  1811. ; For all the addressing modes except for immediate, get the address 
  1812. ; to read memory from, then read memory and load it into the Y register.
  1813. ; For the immediate mode just load the byte into the Y register.
  1815. _A0::
  1816. GET_ADDR_IMMEDIATE
  1817. CPU_LD? CPU.Y, al
  1818. jmp _??
  1820. _A4:: 
  1821. GET_ADDR_ZEROPAGE
  1822. READ_MEMORY ax
  1823.     CPU_LD? CPU.Y, al
  1824. jmp _??
  1826. _B4::
  1827. GET_ADDR_ZEROPAGE_X
  1828. READ_MEMORY ax
  1829.     CPU_LD? CPU.Y, al
  1830. jmp _??
  1832. _AC::
  1833. GET_ADDR_ABSOLUTE
  1834. READ_MEMORY bx
  1835.     CPU_LD? CPU.Y, al
  1836.     jmp _??
  1838. _BC::
  1839. GET_ADDR_ABSOLUTE_X
  1840. READ_MEMORY bx
  1841.     CPU_LD? CPU.Y, al
  1842.     jmp _??
  1844. ;********************************** LSR ***************************************
  1845. ; Perform a logical shift right with most significant bit being filled
  1846. ; with a zero and the least significant bit going into the carry.
  1847. _4A::
  1848. mov ebx, OFFSET (CPU.A)
  1849. CPU_LSR ebx
  1850. jmp _??
  1852. _46::
  1853. GET_ADDR_ZEROPAGE
  1854. GET_MEMORY_POINTER ax
  1855. mov ebx, eax
  1856. CPU_LSR ebx
  1857. jmp _??
  1859. _56::
  1860. GET_ADDR_ZEROPAGE_X
  1861. GET_MEMORY_POINTER ax
  1862. mov ebx, eax
  1863. CPU_LSR ebx
  1864. jmp _??
  1866. _4E::
  1867. GET_ADDR_ABSOLUTE
  1868. GET_MEMORY_POINTER bx
  1869. mov ebx, eax
  1870. CPU_LSR ebx
  1871. jmp _??
  1873. _5E::
  1874. GET_ADDR_ABSOLUTE_X
  1875. GET_MEMORY_POINTER bx
  1876. mov ebx, eax
  1877. CPU_LSR ebx
  1878. jmp _??
  1880. ;********************************** ORA ***************************************
  1881. ; Perform a logical or operation on the memory and the A register
  1882. ; storing the result in the A register.
  1883. _09::
  1884. GET_ADDR_IMMEDIATE
  1885. CPU_ORA al
  1886. jmp _??
  1888. _05::
  1889. GET_ADDR_ZEROPAGE
  1890. GET_MEMORY_BYTE ax
  1891. CPU_ORA al
  1892. jmp _??
  1894. _15::
  1895. GET_ADDR_ZEROPAGE_X
  1896. GET_MEMORY_BYTE ax
  1897. CPU_ORA al
  1898. jmp _??
  1900. _0D::
  1901. GET_ADDR_ABSOLUTE
  1902. GET_MEMORY_BYTE bx
  1903. CPU_ORA al
  1904.     jmp _??
  1906. _19::
  1907. GET_ADDR_ABSOLUTE_Y
  1908. GET_MEMORY_BYTE bx
  1909. CPU_ORA al
  1910.     jmp _??
  1912. _1D::
  1913. GET_ADDR_ABSOLUTE_X
  1914. GET_MEMORY_BYTE bx
  1915. CPU_ORA al
  1916.     jmp _??
  1918. _01::
  1919. GET_ADDR_PREINDEXED
  1920. GET_MEMORY_BYTE bx
  1921. CPU_ORA al
  1922.     jmp _??
  1924. _11::
  1925. GET_ADDR_POSTINDEXED
  1926. GET_MEMORY_BYTE bx
  1927. CPU_ORA al
  1928.     jmp _??
  1930. ;********************************** PHA ***************************************
  1931. ; Pushes the A register onto the stack.
  1932. _48::
  1933. CPU_PHA
  1934. jmp _??
  1936. ;********************************** PHP ***************************************
  1937. ; Pushes the flags register onto the stack.
  1938. _08::
  1939. CPU_PHP
  1940. jmp _??
  1942. ;********************************** PLA ***************************************
  1943. ; Pops the A register from the stack.
  1944. _68::
  1945. CPU_PLA
  1946. jmp _??
  1948. ;********************************** PLP ***************************************
  1949. ; Pops the flags register from the stack.
  1950. _28::
  1951. CPU_PLP
  1952. jmp _??
  1954. ;********************************** ROL ***************************************
  1955. ; Perform a rotate left with most significant bit going into the carry flag
  1956. ; and the least significant bit coming from the carry flag.
  1957. _2A::
  1958. mov ebx, OFFSET (CPU.A)
  1959. CPU_ROL ebx
  1960. jmp _??
  1962. _26::
  1963. GET_ADDR_ZEROPAGE
  1964. GET_MEMORY_POINTER ax
  1965. mov ebx, eax
  1966. CPU_ROL ebx
  1967. jmp _??
  1969. _36::
  1970. GET_ADDR_ZEROPAGE_X
  1971. GET_MEMORY_POINTER ax
  1972. mov ebx, eax
  1973. CPU_ROL ebx
  1974. jmp _??
  1976. _2E::
  1977. GET_ADDR_ABSOLUTE
  1978. GET_MEMORY_POINTER bx
  1979. mov ebx, eax
  1980. CPU_ROL ebx
  1981. jmp _??
  1983. _3E::
  1984. GET_ADDR_ABSOLUTE_X
  1985. GET_MEMORY_POINTER bx
  1986. mov ebx, eax
  1987. CPU_ROL ebx
  1988. jmp _??
  1990. ;********************************** ROR ***************************************
  1991. ; Perform a rotate right with least significant bit going into the carry flag
  1992. ; and the most significant bit coming from the carry flag.
  1993. _6A::
  1994. mov ebx, OFFSET (CPU.A)
  1995. CPU_ROR ebx
  1996. jmp _??
  1998. _66::
  1999. GET_ADDR_ZEROPAGE
  2000. GET_MEMORY_POINTER ax
  2001. mov ebx, eax
  2002. CPU_ROR ebx
  2003. jmp _??
  2005. _76::
  2006. GET_ADDR_ZEROPAGE_X
  2007. GET_MEMORY_POINTER ax
  2008. mov ebx, eax
  2009. CPU_ROR ebx
  2010. jmp _??
  2012. _6E::
  2013. GET_ADDR_ABSOLUTE
  2014. GET_MEMORY_POINTER bx
  2015. mov ebx, eax
  2016. CPU_ROR ebx
  2017. jmp _??
  2019. _7E::
  2020. GET_ADDR_ABSOLUTE_X
  2021. GET_MEMORY_POINTER bx
  2022. mov ebx, eax
  2023. CPU_ROR ebx
  2024. jmp _??
  2026. ;********************************** RTI ***************************************
  2027. ; Return from an interrupt.
  2028. _40::
  2029. CPU_RTI
  2030. jmp _??
  2032. ;********************************** RTS ***************************************
  2033. ; Return from an subroutine.
  2034. _60::
  2035. CPU_RTS
  2036. jmp _??
  2038. ;********************************** SBC ***************************************
  2039. ; Subtract memory from the accumulator and with the carry bit as well.
  2041. _E9::
  2042. GET_ADDR_IMMEDIATE
  2043. CPU_SBC al
  2044. jmp _??
  2046. _E5::
  2047. GET_ADDR_ZEROPAGE
  2048. GET_MEMORY_BYTE ax
  2049. CPU_SBC al
  2050. jmp _??
  2052. _F5::
  2053. GET_ADDR_ZEROPAGE_X
  2054. GET_MEMORY_BYTE ax
  2055. CPU_SBC al
  2056. jmp _??
  2058. _ED::
  2059. GET_ADDR_ABSOLUTE
  2060. GET_MEMORY_BYTE bx
  2061. CPU_SBC al
  2062.     jmp _??
  2064. _F9::
  2065. GET_ADDR_ABSOLUTE_Y
  2066. GET_MEMORY_BYTE bx
  2067. CPU_SBC al
  2068.     jmp _??
  2070. _FD::
  2071. GET_ADDR_ABSOLUTE_X
  2072. GET_MEMORY_BYTE bx
  2073. CPU_SBC al
  2074.     jmp _??
  2076. _E1::
  2077. GET_ADDR_PREINDEXED
  2078. GET_MEMORY_BYTE bx
  2079. CPU_SBC al
  2080.     jmp _??
  2082. _F1::
  2083. GET_ADDR_POSTINDEXED
  2084. GET_MEMORY_BYTE bx
  2085. CPU_SBC al
  2086.     jmp _??
  2087.     
  2088. ;********************************** SEC ***************************************
  2089. ; Set the carry flag.
  2090. _38::
  2091. CPU_SEC
  2092. jmp _??
  2094. ;********************************** SED ***************************************
  2095. ; Set the decimal flag.
  2096. _F8::
  2097. CPU_SED
  2098. jmp _??
  2100. ;********************************** SEI ***************************************
  2101. ; Set the interrupt flag.
  2102. _78::
  2103. CPU_SEI
  2104. jmp _??
  2106. ;********************************** STA ***************************************
  2107. ; For all the addressing modes, get the address to write the A register
  2108. ; to, then store the A register into that memory address.
  2110. _85::
  2111. GET_ADDR_ZEROPAGE
  2112.     CPU_ST? ax, CPU.A
  2113. jmp _??
  2115. _95::
  2116. GET_ADDR_ZEROPAGE_X
  2117.     CPU_ST? ax, CPU.A
  2118. jmp _??
  2120. _8D::
  2121. GET_ADDR_ABSOLUTE
  2122.     CPU_ST? bx, CPU.A
  2123.     jmp _??
  2125. _99::
  2126. GET_ADDR_ABSOLUTE_Y
  2127.     CPU_ST? bx, CPU.A
  2128.     jmp _??
  2130. _9D::
  2131. GET_ADDR_ABSOLUTE_X
  2132.     CPU_ST? bx, CPU.A
  2133.     jmp _??
  2135. _81::
  2136. GET_ADDR_PREINDEXED
  2137.     CPU_ST? bx, CPU.A
  2138.     jmp _??
  2140. _91::
  2141. GET_ADDR_POSTINDEXED
  2142.     CPU_ST? bx, CPU.A
  2143.     jmp _??
  2146. ;********************************** STX ***************************************
  2148. ; For all the addressing modes, get the address to write the X register
  2149. ; to, then store the X register into that memory address.
  2151. _86::
  2152. GET_ADDR_ZEROPAGE
  2153.     CPU_ST? ax, CPU.X
  2154. jmp _??
  2156. _96::
  2157. GET_ADDR_ZEROPAGE_Y
  2158.     CPU_ST? ax, CPU.X
  2159. jmp _??
  2161. _8E::
  2162. GET_ADDR_ABSOLUTE
  2163.     CPU_ST? bx, CPU.X
  2164.     jmp _??
  2167. ;********************************** STY ***************************************
  2169. ; For all the addressing modes, get the address to write the Y register
  2170. ; to, then store the Y register into that memory address.
  2172. _84::
  2173. GET_ADDR_ZEROPAGE
  2174.     CPU_ST? ax, CPU.Y
  2175. jmp _??
  2177. _94::
  2178. GET_ADDR_ZEROPAGE_X
  2179.     CPU_ST? ax, CPU.Y
  2180. jmp _??
  2182. _8C::
  2183. GET_ADDR_ABSOLUTE
  2184.     CPU_ST? bx, CPU.Y
  2185.     jmp _??
  2187. ;********************************** TAX ***************************************
  2188. ; Transfers the A register to the X register.
  2189. _AA::
  2190. CPU_TAX
  2191. jmp _??
  2193. ;********************************** TAY ***************************************
  2194. ; Transfers the A register to the YX register.
  2195. _A8::
  2196. CPU_TAY
  2197. jmp _??
  2199. ;********************************** TSX ***************************************
  2200. ; Transfers the S register to the X register.
  2201. _BA::
  2202. CPU_TSX
  2203. jmp _??
  2205. ;********************************** TXA ***************************************
  2206. ; Transfers the X register to the A register.
  2207. _8A::
  2208. CPU_TXA
  2209. jmp _??
  2211. ;********************************** TXS ***************************************
  2212. ; Transfers the X register to the S register.
  2213. _9A::
  2214. CPU_TXS
  2215. jmp _??
  2217. ;********************************** TYA ***************************************
  2218. ; Transfers the Y register to the A register.
  2219. _98::
  2220. CPU_TYA
  2221. jmp _??
  2223. _??::
  2224.     
  2225. ; When the instruction is finished me must subtract the
  2226. ; number of cycles the instruction takes and add the
  2227. ; number of bytes for the instruction to the PC.
  2228. xor ax, ax
  2229. mov ebx, dwOpcode
  2230.     mov al, [abyOpcodeCycles+ebx]
  2231.     sub CPU.byCycles, al
  2232.     mov al, [abyOpcodeBytes+ebx]
  2233.     add CPU.P, ax
  2235. ; In step mode, we execute one instruction and then exit
  2236. ; the function to let an external module control what
  2237. ; happens next. In run mode, we run until the cpu cycles
  2238. ; are less that zero and then let an external module 
  2239. ; control what happens next.
  2240. .IF dwFlags == RUNCPU_STEP
  2241. jmp RunCPU_End
  2242. .ELSEIF dwFlags == RUNCPU_RUN
  2243. cmp CPU.byCycles, 0
  2244. jg RunCPU_RunAgain
  2245. .ENDIF
  2247.     ; We're done now so pop all the flags and return.
  2248. RunCPU_End:
  2249. popad
  2250.     ret
  2252. RunCPU ENDP
  2254. END