WEB源码(ASP,PHP,...)

开发平台：
ASP/ASPX

jobs.cs：源码内容
							<%
  
function ContentList()
  dim SortPath
      SortPath=request.QueryString("SortPath")
  dim idCount'记录总数
  dim pages'每页条数
      pages=25
  dim pagec'总页数
  dim page'页码
      page=clng(request("Page"))
  dim pagenc'每页显示的分页页码数量=pagenc*2+1
      pagenc=2
  dim pagenmax'每页显示的分页的最大页码
  dim pagenmin'每页显示的分页的最小页码
  dim datafrom'数据表名
      datafrom="sk_Jobs"
  dim datawhere'数据条件
      datawhere="where ViewFlag "
  dim sqlid'本页需要用到的id
  dim Myself,PATH_INFO,QUERY_STRING'本页地址和参数
      PATH_INFO = request.servervariables("PATH_INFO")
	  QUERY_STRING = request.ServerVariables("QUERY_STRING")'
      if QUERY_STRING = "" then
	    Myself = PATH_INFO & "?"
	  elseif Instr(PATH_INFO & "?" & QUERY_STRING,"Page=")=0 then
	    Myself= PATH_INFO & "?" & QUERY_STRING & "&"
	  else
	    Myself = Left(PATH_INFO & "?" & QUERY_STRING,Instr(PATH_INFO & "?" & QUERY_STRING,"Page=")-1)
	  end if
  dim taxis'排序的语句 asc,desc
      taxis="order by id desc "
  dim i'用于循环的整数
  dim rs,sql'sql语句
  '获取记录总数
  sql="select count(ID) as idCount from ["& datafrom &"]" & datawhere
  set rs=server.createobject("adodb.recordset")
  rs.open sql,conn,0,1
  idCount=rs("idCount")
  '获取记录总数
  if(idcount>0) then'如果记录总数=0,则不处理
    if(idcount mod pages=0)then'如果记录总数除以每页条数有余数,则=记录总数/每页条数+1
	  pagec=int(idcount/pages)'获取总页数
   	else
      pagec=int(idcount/pages)+1'获取总页数
    end if
	'获取本页需要用到的id============================================
    '读取所有记录的id数值,因为只有id所以速度很快
    sql="select id from ["& datafrom &"] " & datawhere & taxis
    set rs=server.createobject("adodb.recordset")
    rs.open sql,conn,1,1
    rs.pagesize = pages '每页显示记录数
    if page < 1 then page = 1
    if page > pagec then page = pagec
    if pagec > 0 then rs.absolutepage = page  
    for i=1 to rs.pagesize
	  if rs.eof then exit for  
	  if(i=1)then
	    sqlid=rs("id")
	  else
	    sqlid=sqlid &","&rs("id")
	  end if
	  rs.movenext
    next
  '获取本页需要用到的id结束============================================
  end if
  Response.Write "<table width='100%' border='0' cellpadding='5' cellspacing='1' bgcolor='#CCCCCC'>"
  Response.Write "  <tr>" &_
                 "    <td width='4%' bgcolor='#EEEEEE' align='center'>NO</td>" &_
                 "    <td width='45%' bgcolor='#EEEEEE' align='center'>职位名称</td>" &_
                 "    <td width='10%' bgcolor='#EEEEEE' align='center'>招聘人数</td>" &_
                 "    <td width='12%' bgcolor='#EEEEEE' align='center'>工作地点</td>" &_
                 "    <td width='23%' bgcolor='#EEEEEE' align='center'>简历提交日期</td>" &_
                 "    <td width='6%' bgcolor='#EEEEEE' align='center'>查看</td>" &_
                 "  </tr>"
  if(idcount>0 and sqlid<>"") then'如果记录总数=0,则不处理
    '用in刷选本页所语言的数据,仅读取本页所需的数据,所以速度快
    sql="select * from ["& datafrom &"] where id in("& sqlid &") "&taxis
    set rs=server.createobject("adodb.recordset")
    rs.open sql,conn,0,1
	dim JobNO
	JobNO=1
    while not rs.eof '填充数据到表格
    Response.Write "  <tr>" &_
                   "    <td bgcolor='#FFFFFF' align='center'>"&JobNO&"</td>" &_
                   "    <td bgcolor='#FFFFFF'><a href='JobsView.asp?ID="&rs("ID")&"'>"&rs("JobName")&"</a></td>" &_
                   "    <td bgcolor='#FFFFFF'>"&rs("JobNumber")&"</td>" &_
                   "    <td bgcolor='#FFFFFF'>"&rs("JobAddress")&"</td>" &_
                   "    <td bgcolor='#FFFFFF'>"&FormatDate(rs("AddTime"),13)&"-"&FormatDate(rs("EndDate"),13)&"</td>" &_
                   "    <td bgcolor='#FFFFFF'>"&rs("ClickNumber")&"</td>" &_
                   "  </tr>"	
	  rs.movenext
	  JobNO=JobNO+1
    wend
  else
    response.write "<tr><td align='center' colspan='6' bgcolor='#FFFFFF'>暂无相关信息</td></tr></table>"
	exit function
  end if
  Response.Write "<tr>" & vbCrLf
  Response.Write "<td colspan='6' align='right' bgcolor='#FFFFFF'>" & vbCrLf
  Response.Write "共计：<font color='#ff6600'>"&idcount&"</font>条记录&nbsp;页次：<font color='#ff6600'>"&page&"</font></strong>/"&pagec&"&nbsp;每页：<font color='#ff6600'>"&pages&"</font>条&nbsp;&nbsp;&nbsp;&nbsp;" & vbCrLf
  pagenmin=page-pagenc '计算页码开始值
  pagenmax=page+pagenc '计算页码结束值
  if(pagenmin<1) then pagenmin=1 '如果页码开始值小于1则=1
  if(page>1) then response.write ("<a href='"& myself &"Page=1'><font style='FONT-SIZE: 14px; FONT-FAMILY: Webdings'>9</font></a>&nbsp;") '如果页码大于1则显示(第一页)
  if(pagenmin>1) then response.write ("<a href='"& myself &"Page="& page-(pagenc*2+1) &"'><font style='FONT-SIZE: 14px; FONT-FAMILY: Webdings'>7</font></a>&nbsp;") '如果页码开始值大于1则显示(更前)
  if(pagenmax>pagec) then pagenmax=pagec '如果页码结束值大于总页数,则=总页数
  for i = pagenmin to pagenmax'循环输出页码
	if(i=page) then
	  response.write ("&nbsp;<font color='#ff6600'>"& i &"</font>&nbsp;")
	else
	  response.write ("[<a href="& myself &"Page="& i &">"& i &"</a>]")
	end if
  next
  if(pagenmax<pagec) then response.write ("&nbsp;<a href='"& myself &"Page="& page+(pagenc*2+1) &"'><font style='FONT-SIZE: 14px; FONT-FAMILY: Webdings'>8</font></a>&nbsp;") '如果页码结束值小于总页数则显示(更后)
  if(page<pagec) then response.write ("<a href='"& myself &"Page="& pagec &"'><font style='FONT-SIZE: 14px; FONT-FAMILY: Webdings'>:</font></a>") '如果页码小于总页数则显示(最后页)	
  Response.Write "</td>" & vbCrLf
  Response.Write "</tr>" & vbCrLf
  Response.Write "</table>" & vbCrLf
  rs.close
  set rs=nothing
end function 
%>
<%
function WebMenu()
  response.write "<div class='l2'><a href='JobsList.asp'>招聘信息</a></div>"
  response.write "<div class='l2'><a href='../user/MemberTalent.asp' rel='facebox'>我的应聘</a></div>"
end function
function WebContent()
  dim ID
  ID=request.QueryString("ID")
  if ID="" or (not isnumeric(ID)) then
    response.write "<div align='center'>数据读取异常错误</div>"
    exit function
  end if
  dim rs,sql
  set rs = server.createobject("adodb.recordset")
  sql="select * from sk_Jobs where ViewFlag and ID="&ID
  rs.open sql,conn,1,3
  response.write"<table width='100%' border='0' cellspacing='0' cellpadding='0'>"
  if rs.bof and rs.eof then
    response.write "<tr><td>暂无相关信息</td></tr>"
  else
    response.write "<tr><td colspan='2'><hr width='100%' size='1' noshade='noshade' color='#CCCCCC'></td></tr>"
    response.write "<tr><td width='420'>职位名称：<font style='font-weight: bold;color: #1874CD'>"&rs("JobName")&"</font></td>"
    response.write "<td width='184'>工作地点："&rs("JobAddress")&"</td></tr>"
    response.write "<tr><td>招聘人数："&rs("JobNumber")&"</td>"
    response.write "<td>工资待遇："&rs("Emolument")&"</td></tr>"
    response.write "<tr><td>有 效 期："&FormatDate(rs("AddTime"),13)&"-"&FormatDate(rs("EndDate"),13)&"</td>"
    response.write "<td>提交简历：<a href='user/TalentWrite.asp?JobID="&rs("ID")&"&JobName="&server.urlencode(rs("JobName"))&"' rel='facebox'><img src='../img/Jobs_resume_up.gif' border='0' align='absmiddle'></a></td></tr>"
    response.write "<tr><td height='22' bgcolor='#EEEEEE' colspan='2'><img src='../img/Pro_information_title.gif'></td></tr>"
    response.write "<tr><td colspan='2' height='12'></td></tr>"
    response.write "<tr><td colspan='2' width='604'>"&rs("Content")&"</td></tr>"
	rs("ClickNumber")=rs("ClickNumber")+1
    response.write "<tr><td class='ListTitle' colspan='2'></td></tr>" 
    response.write "<tr><td>点击次数："&rs("ClickNumber")&"</td>"
	response.write "<td align='right'><a href='#TOP'><img src='../img/Button_top_01.gif' align='absbottom' border='0'></a></td></tr>" 
	rs.update	   
  end if
  response.write"</table>"
  rs.close
  set rs=nothing
end function
%>

						