WEB源码(ASP,PHP,...)

开发平台：
ASP/ASPX

MemberSaveReg.asp：源码内容
							﻿<% response.charset="utf-8" %>
<!--#include file="../skweb/Const.asp"-->
<!--#include file="../skweb/ConnSiteData.asp"-->
<!--#include file="../skweb/Function.asp"-->
<!--#include file="../skweb/Md5.asp"-->
<%
dim MemName,RealName,Sex,Password,vPassword,Question,Answer,Company,Address,ZipCode,Telephone,Fax,Mobile,Email,HomePage,VerifyCode
dim rs,sql,rsRepeat
MemName=trim(request.form("MemName"))
RealName=trim(request.form("RealName"))
Sex=trim(request.form("Sex"))
Password=trim(request.form("Password"))
vPassword=trim(request.form("vPassword"))
Question=trim(request.form("Question"))
Answer=trim(request.form("Answer"))
Company=trim(request.form("Company"))
Address=trim(request.form("Address"))
ZipCode=trim(request.form("ZipCode"))
Telephone=trim(request.form("Telephone"))
Fax=trim(request.form("Fax"))
Mobile=trim(request.form("Mobile"))
Email=trim(request.form("Email"))
HomePage=trim(request.form("HomePage"))
dim ErrMessage,ErrMsg(11),FindErr(11),i
  ErrMsg(0)="·登录名错误，由0-9,a-z,-_任意组合3-16个的字符串"
  ErrMsg(1)="·登录名重复，请换一个试试"
  ErrMsg(2)="·设置密码长度应为6-16个任意字符串"
  ErrMsg(3)="·设置密码和确定密码不一致"
  ErrMsg(4)="·密码提示问题长度应为3-100个任意字符串"
  ErrMsg(5)="·密码提示答案长度应为3-100个任意字符串"
  ErrMsg(6)="·单位名称、地址长度不能超过100个字符"
  ErrMsg(7)="·邮编长度不能超过20个字符"
  ErrMsg(8)="·真实姓名、电话、传真、移动电话、网址不能超过50个字符"
  ErrMsg(9)="·电子邮箱格式不正确"
  ErrMsg(10)="·电子邮箱已经被注册过"
if not IsValidMemName(MemName) then
  FindErr(0)=true
else
  set rsRepeat = conn.execute("select MemName from sk_Members where MemName='" & MemName & "'")
  if not (rsRepeat.bof and rsRepeat.eof) then FindErr(1)=true
end if
if not (6<=len(Password) and len(Password)<=16) then
  FindErr(2)=true
end if
if Password<>vPassword then
  FindErr(3)=true
end if
if not (3<=len(Question) and len(Question)<=100) then
  FindErr(4)=true
end if
if not (3<=len(Answer) and len(Answer)<=100) then
  FindErr(5)=true
end if
if len(Company)>100 or len(Address)>100 then
  FindErr(6)=true
end if
if len(ZipCode)>20 then
  FindErr(7)=true
end if
if len(RealName)>50 or len(Telephone)>50 or len(Fax)>50 or len(Mobile)>50 or len(HomePage)>50 then
  FindErr(8)=true
end if
if not IsValidEmail(Email) then
  FindErr(9)=true
else
  set rsRepeat = conn.execute("select MemName from sk_Members where Email='" & Email & "'")
  if not (rsRepeat.bof and rsRepeat.eof) then FindErr(10)=true
end if
for i = 0 to UBound(FindErr)
  if FindErr(i)=true then
    ErrMessage=ErrMessage+ErrMsg(i)+"<br>"
  end if
next
if not (ErrMessage="" or isnull(ErrMessage)) then
  WriteMsg(ErrMessage)
  response.end
end if
set rs = server.createobject("adodb.recordset")
sql="select * from sk_Members"
rs.open sql,conn,1,3
rs.addnew
rs("MemName")=MemName
rs("RealName")=StrReplace(RealName)
rs("Sex")=Sex
rs("Password")=Md5(Password)
rs("Question")=StrReplace(Question)
rs("Answer")=Md5(Answer)
rs("Company")=StrReplace(Company)
rs("Address")=StrReplace(Address)
rs("ZipCode")=StrReplace(ZipCode)
rs("Telephone")=StrReplace(Telephone)
rs("Fax")=StrReplace(Fax)
rs("Mobile")=StrReplace(Mobile)
rs("Email")=Email
rs("HomePage")=StrReplace(HomePage)
rs("GroupID")="20080808080808888"
rs("GroupName")=GroupName("20080808080808888")
rs("AddTime")=now()
rs.update
rs.close
set rs=nothing
session("MemName")=MemName
session("GroupID")="20080808080808888"
session("MemLogin")="Succeed"
session.timeout=10
WriteMsg("·注册成功，返回首页<a href='../index.asp'><font color='red'>[以会员方式浏览]</font></a>")
function GroupName(GroupID)
  dim rs,sql
  set rs = server.createobject("adodb.recordset")
  sql="select * from sk_MemGroup where GroupID='"&GroupID&"'"
  rs.open sql,conn,1,1
  GroupName=rs("GroupName")
  rs.close
  set rs=nothing
end function
%>
 

						