开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 行业应用 > 金融证券系统 > 查看源码
CandleStochastics.afl
资源名称：AFL_collection.rar　[点击查看]
上传用户：shiqiang
上传日期：2009-06-12
资源大小：1289k
文件大小：4k
源码类别：

金融证券系统

开发平台：

Others

CandleStochastics.afl：源码内容
  1. //------------------------------------------------------------------------------
  2. //
  3. //  Formula Name:    CandleStochastics
  4. //  Author/Uploader: Jim Varney 
  5. //  E-mail:          
  6. //  Date/Time Added: 2001-06-19 01:31:57
  7. //  Origin:          
  8. //  Keywords:        Candlesticks Stochastics
  9. //  Level:           medium
  10. //  Flags:           exploration
  11. //  Formula URL:     http://www.amibroker.com/library/formula.php?id=26
  12. //  Details URL:     http://www.amibroker.com/library/detail.php?id=26
  13. //
  14. //------------------------------------------------------------------------------
  15. //
  16. //  "CandleStochastics" is an Exploration that combines Stochastics with a scan
  17. //  for 7 different candlestick patterns (Dark Cloud Cover, Piercing Line,
  18. //  Morning and Evening Doji Stars, Hammer, and Engulfing). A Buy signal occurs
  19. //  when the 14-4 Stochastic is at or below 20 and at least one bullish candle
  20. //  pattern is detected. Sell signals happen at 80 or better and if there's a
  21. //  bearish candle pattern.
  22. //
  23. //------------------------------------------------------------------------------
  25. /* -- CANDLESTOCHASTICS  -- */
  26. /* -- Written by Jim Varney  -- */
  27. /*
  28. This Exploration combines Stochastics with a scan for 7 different candlestick patterns (Dark Cloud Cover, Piercing Line, Morning and Evening Doji Stars, Hammer, and Engulfing).
  30. Buy Signal: Stochastic at or below 20 and at least one bullish candle pattern.
  31. Sell Signal: Stochastic at or above 80 and at least one bearish candle pattern.
  33. Vol Index: this column is the ratio of today's volume to the 14-day average volume.
  34. This column should be sorted Descending. The best signals are occur when VolIndex is at least 2 or higher.
  36. PCL[up]: Piercing Line, "up" signifies Bullish.
  37. MDS[up]: Morning Doji Star
  38. BLE[up]: Bullish Engulfing
  39. HAM[up]: Hammer
  40. BRE[dn]: Bearish Engulfing, "dn" signifies Bearish.
  41. DCC[dn]: Dark Cloud Cover
  42. EDS[dn]: Evening Doji Star
  44. A "1" in the column signifies TRUE, a "0" indicates no signal.
  46. ------------------------------------------------------------------*/
  48. /* Minimum Price and 14 day Avg Volume Values for Filter */
  49. minPrice = 3;     //change as needed
  50. minVol = 50000;   //change as needed
  52. VolAvg = ma( v, 14 );
  53. VolumeIdx = v / VolAvg;
  54. AvgRange = sum( abs(O-C),15 )/15;
  56. /* Candle Codes */
  57. White = iif((C>O) AND ((C-O)>=0.8*(H-L)),1,0) AND (C-O)>AvgRange;
  58. Black = iif((C<O) AND ((O-C)>=0.8*(H-L)),1,0) AND (O-C)>AvgRange;
  59. Doji  = iif(abs(O-C)<=0.1*(H-L),1,0);
  61. /* Dark Cloud Cover [Bear] */
  62. DCC = iif(ref(White, -1) AND Black AND C<=ref(((H+L)/2),-1)
  63. AND O>ref(C,-1), 1,0);
  65. /* Piercing Line [Bull] */
  66. PL = iif(ref(Black, -1) AND White AND C>=ref(((H+L)/2),-1)
  67. AND O<ref(C,-1), 1,0);
  69. /* Evening Doji Star [Bear] */
  70. EDS = iif(ref(White, -2) AND ref(Doji, -1) AND Black AND
  71. C<=ref(((H+L)/2),-2), 1,0);
  73. /* Morning Doji Star [Bull] */
  74. MDS = iif(ref(Black, -2) AND ref(Doji, -1) AND White AND
  75. C>=ref(((H+L)/2),-2), 1,0);
  77. /* Hammer [Bull] */
  78. HAM = iif( (H-L > 1.5*AvgRange) AND (C > (H+L)/2)  AND (O > C) AND 
  79. (VolumeIdx > 2), 1, 0);
  81. /* Bearish Engulfing */
  82. BRE = iif(Black AND ref(White, -1) AND (C < ref(O, -1))  AND (O > ref(C, -1)), 1,0);
  84. /* Bullish Engulfing */
  85. BLE = iif(White AND ref(Black, -1) AND (C > ref(O,-1))  AND (O < ref(C,-1)), 1,0);
  88. /* Stochastics 14-4 */
  90. ss = ma(stochk(14),4);
  91. StochBuy = iif(ss<=20, 1, 0);
  92. StochSell = iif(ss>=80, 1, 0);
  94. /* Exploration Columns for Sorting */
  96. NumColumns = 9;
  98. Column0 = V;
  99. Column1 = VolumeIdx;
  100. Column2 = PL;
  101. Column3 = MDS;
  102. Column4 = BLE;
  103. Column5 = HAM;
  104. Column6 = BRE;
  105. Column7 = DCC;
  106. Column8 = EDS;
  108. Column0Name = "Volume"; 
  109. Column1Name = "Vol Idx";
  110. Column2Name = "PCL[up]";
  111. Column3Name = "MDS[up]";
  112. Column4Name = "BLE[up]";
  113. Column5Name = "HAM[up]";
  114. Column6Name = "BRE[dn]";
  115. Column7Name = "DCC[dn]";
  116. Column8Name = "EDS[dn]";
  118. Column0format = 1.0;
  119. Column1format = 1.1;
  120. Column2format = 1.0;
  121. Column3format = 1.0;
  122. Column4format = 1.0;
  123. Column5format = 1.0;
  124. Column6format = 1.0;
  125. Column7format = 1.0;
  126. Column8format = 1.0;
  129. /* Filter */
  131. Filter = ((C > minPrice) AND (VolAvg >= minVol)) AND (StochBuy AND (PL or MDS or BLE or HAM)) OR (StochSell AND (BRE or DCC or EDS));
  134. /* Buy and Sell */
  136. Buy = iif((StochBuy > 0) AND (PL + MDS + HAM + BLE > 0), 1, 0);
  137. Sell = iif((StochSell > 0) AND (BRE + DCC + EDS > 0), 1, 0);