开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 行业应用 > 金融证券系统 > 查看源码
Cole.afl
资源名称：AFL_collection.rar　[点击查看]
上传用户：shiqiang
上传日期：2009-06-12
资源大小：1289k
文件大小：5k
源码类别：

金融证券系统

开发平台：

Others

Cole.afl：源码内容
  1. //------------------------------------------------------------------------------
  2. //
  3. //  Formula Name:    Cole
  4. //  Author/Uploader: Marek Chlopek 
  5. //  E-mail:          mchlopek@post.pl
  6. //  Date/Time Added: 2001-10-17 02:53:15
  7. //  Origin:          
  8. //  Keywords:        
  9. //  Level:           basic
  10. //  Flags:           system,indicator
  11. //  Formula URL:     http://www.amibroker.com/library/formula.php?id=127
  12. //  Details URL:     http://www.amibroker.com/library/detail.php?id=127
  13. //
  14. //------------------------------------------------------------------------------
  15. //
  16. //  Cole Trading Method
  17. //
  18. //  Rally, Reaction, Inside, Outside and Rally with Volume, Reaction with
  19. //  Volume formulas
  20. //
  21. //------------------------------------------------------------------------------
  23. /* COLE.AFL v 1.00 17/10/2001
  24. /* Cole Trading Method
  25. /* Developed by Roger Cole
  26. /* From Technical Analysis of Stocks and Commodities, V8:12 (460-463), by Alan Friedman
  27. /* Indicator developed and coded by Marek Chlopek, October 2001
  28. /* Support from Tomasz Janeczko and Amibroker Mailing List members - THANKS!!! */
  30. /* ************************************************************************** */
  31. /* Cole Trading Method description
  32. /* A up signal is formed when a stock makes three Rally Days in a row with larger volume on each day
  33. /* A down signal is formed when a stock makes three Reaction Days in a row with larger volume on each day
  34. /* Inside and Outside Days are ignored */
  36. /* ************************************************************************** */
  37. /* Cole Trading Method Indicator development description
  38. /* Cole Trading Method measures two independent signals: day status (Rally, Reaction, Inside, Outside) and volume,
  39. /* therefore two independent sub-indicators have been implemented:
  40. /* ColeDay - counts number of days in a row when Rally (positive) or Reaction (negative)
  41. /* ColeVolume - counts number of days with higher volume, always positive */
  43. /* ************************************************************************** */
  44. /* Cole's Trading Day Status definition */
  45. RY  = H >  Ref(H, -1) AND L >= Ref(L, -1); // Rally Day
  46. RX  = H <= Ref(H, -1) AND L <  Ref(L, -1); // Reaction Day
  47. IN  = H <= Ref(H, -1) AND L >= Ref(L, -1); // Inside Day
  48. OUT = H >  Ref(H, -1) AND L <  Ref(L, -1); // Outside Day
  50. VolRY = Ref(V, - BarsSince(RY));
  51. VolRX = Ref(V, - BarsSince(RX));
  52. RYwithVol  = RY  AND V > IIF(RY, Ref(VolRY, -1), VolRY);  // Rally Day with Volume
  53. RXwithVol  = RX  AND V > IIF(RX, Ref(VolRX, -1), VolRX);  // Reaction Day with Volume
  55. /* ************************************************************************** */
  56. /* ColeDay - counts number of Rally Days in a row (positive) or Reaction Days in a row (negative)
  57. /* When Rally ColeDay increases by 1 unless the first Rally Day then ColeDay = 1
  58. /* When Reaction ColeDay decreases by 1 unless the first Reaction Day then ColeDay = -1
  59. /* When Inside Day or Outside Day then ColeDay stays unchanged */
  60. PeriodRY = BarsSince(NOT RY);
  61. PeriodRX = BarsSince(NOT RX);
  62. ColeDay  = ValueWhen(RX or RY, Sum(RY, PeriodRY) - Sum(RX, PeriodRX));
  64. /* ************************************************************************** */
  65. /* ColeVolume - counts number of days with higher volume, always positive
  66. /* When volume higher than previous day volume ColeVolume increases by 1
  67. /* When volume lower previous day volume then ColeVolume = 1
  68. /* When Inside Day or Outside Day then ColeVolume stays unchanged */
  69. PeriodV    = BarsSince(V < Ref(V, -1) AND (RX or RY));
  70. ColeVolume = ValueWhen(RX or RY, Sum (RX+RY, PeriodV) +1);
  72. /* ************************************************************************** */
  73. /* Trading Signals in Cole Trading Method
  74. /* Buy Signal  - when a stock makes three Rally Days in a row with larger volume on each day
  75. /* Sell Signal - when a stock makes three Reaction Days in a row with larger volume on each day */
  76. Buy   = ColeDay >= 3  AND ColeVolume >= 3;
  77. Sell  = ColeDay <= -3 AND ColeVolume >= 3;
  78. Cover = Buy;
  79. Short = Sell;
  81. /* ************************************************************************** */
  82. /* Graphic presentation in Amibroker */
  83. maxgraph = 2;
  84. graph0 = ColeDay;
  85. graph1 = ColeVolume;
  86. title = name() + " - ColeDay = " + WriteVal(graph0, 1.0) + "; ColeVolume = " + WriteVal(graph1, 1.0);
  88. /* ************************************************************************** */
  89. /* Exploration in Amibroker */
  90. filter = 1;
  91. numcolumns = 9;
  92. column0 = H; column0name = "H"; column0format = 1.2;
  93. column1 = L; column1name = "L"; column1format = 1.2;
  94. column2 = V; column2name = "V"; column2format = 1.0;
  95. column3 = RY; column3name = "RY"; column3format = 1.0;
  96. column4 = RX; column4name = "RX"; column4format = 1.0;
  97. column5 = IN; column5name = "IN"; column5format = 1.0;
  98. column6 = OUT; column6name = "OUT"; column6format = 1.0;
  99. column7 = ColeDay; column7name = "ColeDay"; column7format = 1.0;
  100. column8 = ColeVolume; column8name = "ColeVolume"; column8format = 1.0;
  102. /* ************************************************************************** */
  103. /* END COLE Indicator Formula */