开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 操作系统开发 > 查看源码
APISUPT.ASM
资源名称：840.rar　[点击查看]
上传用户：dcs7469208
上传日期：2010-01-02
资源大小：443k
文件大小：5k
源码类别：

操作系统开发

开发平台：

DOS

APISUPT.ASM：源码内容
  1. ; File:
  2. ;                         apisupt.asm
  3. ; Description:
  4. ;     Assembly support routines for stack manipulation, etc.
  5. ;
  6. ;                       Copyright (c) 1995
  7. ;                       Pasquale J. Villani
  8. ;                       All Rights Reserved
  9. ;
  10. ; This file is part of DOS-C.
  11. ;
  12. ; DOS-C is free software; you can redistribute it and/or
  13. ; modify it under the terms of the GNU General Public License
  14. ; as published by the Free Software Foundation; either version
  15. ; 2, or (at your option) any later version.
  16. ;
  17. ; DOS-C is distributed in the hope that it will be useful, but
  18. ; WITHOUT ANY WARRANTY; without even the implied warranty of
  19. ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See
  20. ; the GNU General Public License for more details.
  21. ;
  22. ; You should have received a copy of the GNU General Public
  23. ; License along with DOS-C; see the file COPYING.  If not,
  24. ; write to the Free Software Foundation, 675 Mass Ave,
  25. ; Cambridge, MA 02139, USA.
  26. ;
  27. ; $Logfile:   C:/dos-c/src/kernel/apisupt.asv  $
  28. ;
  29. ; $Header:   C:/dos-c/src/kernel/apisupt.asv   1.3   16 Jan 1997 12:46:44   patv  $
  30. ;
  31. ; $Log:   C:/dos-c/src/kernel/apisupt.asv  $
  32. ;
  33. ;   Rev 1.3   16 Jan 1997 12:46:44   patv
  34. ;pre-Release 0.92 feature additions
  35. ;
  36. ;   Rev 1.2   29 May 1996 21:03:38   patv
  37. ;bug fixes for v0.91a
  38. ;
  39. ;   Rev 1.1   01 Sep 1995 17:54:26   patv
  40. ;First GPL release.
  41. ;
  42. ;   Rev 1.0   02 Jul 1995  9:04:50   patv
  43. ;Initial revision.
  44. ;
  46. page    60,132
  47. title   Assembly support routines for stack manipulation, etc.
  49. IFDEF ??version
  50. _TEXT           segment byte public 'CODE'
  51. DGROUP          group   _DATA,_BSS,_BSSEND              ; small model
  52. assume  cs:_TEXT,ds:DGROUP,ss:DGROUP
  53. _TEXT           ends
  55. _DATA           segment word public 'DATA'
  56. _DATA           ends
  58. _BSS            segment word public 'BSS'
  59. _BSS            ends
  61. _BSSEND         segment byte public 'STACK'
  62. _BSSEND         ends
  64. ELSE
  65. _TEXT           segment byte public 'CODE'
  66. _TEXT           ends
  68. _DATA           segment word public 'DATA'
  69. _DATA           ends
  71. CONST           segment word public 'CONST'
  72. CONST           ends
  74. _BSS            segment word public 'BSS'
  75. _BSS            ends
  77. _BSSEND         segment byte public 'STACK'
  78. _BSSEND         ends
  80. DGROUP          group   CONST,_DATA,_BSS,_BSSEND        ; small/tiny model
  81. assume  ds:DGROUP, ss:DGROUP
  82. ENDIF
  84. extrn   _api_sp:word            ; api stacks - for context
  85. extrn   _api_ss:word            ; switching
  86. extrn   _usr_sp:word            ; user stacks
  87. extrn   _usr_ss:word
  89. _TEXT           segment
  90. assume  cs: _TEXT
  91. public  _set_stack
  92. ;
  93. ; void far set_stack(void) - 
  94. ;       save current stack and setup our local stack
  95. ;
  96. _set_stack      proc    far
  98. ; save foreground stack
  100. ; we need to get the return values from the stack 
  101. ; since the current stack will change
  102. pop     ax                      ;get return offset
  103. pop     bx                      ;get return segment
  105. ; Save the flags so that we can restore correct interrupt
  106. ; state later. We need to disable interrupts so that we
  107. ; don't trash memory with new sp-old ss combination
  108. pushf
  109. pop     dx
  110. cli
  112. ; save bp
  113. push    bp
  115. mov     cx, sp
  116. neg     cx
  118. ; save away foreground process' stack
  119. push    word ptr DGROUP:_usr_ss
  120. push    word ptr DGROUP:_usr_sp
  122. mov     word ptr DGROUP:_usr_ss,ss
  123. mov     word ptr DGROUP:_usr_sp,sp
  125. ; setup our local stack
  126. mov     ss,word ptr DGROUP:_api_ss
  127. mov     sp,word ptr DGROUP:_api_sp
  129. add     cx, sp
  130. add     bp, cx
  132. ; setup for ret
  133. push    bx  
  134. push    ax
  136. ; now restore interrupt state
  137. push    dx
  138. popf
  140. ret
  142. _set_stack      endp
  144. ;
  145. ; void far restore_stack(void) - 
  146. ;       restore foreground stack, throw ours away 
  147. ;
  148. public  _restore_stack
  149. _restore_stack  proc    far
  151. ; we need to get the return values from the stack 
  152. ; since the current stack will change
  153. pop     cx                      ;get return offset
  154. pop     bx                      ;get return segment
  156. ; Save the flags so that we can restore correct interrupt
  157. ; state later. We need to disable interrupts so that we
  158. ; don't trash memory with new sp-old ss combination
  159. pushf
  160. pop     dx
  161. cli
  163. ; save background stack
  164. mov     word ptr DGROUP:_api_ss,ss
  165. mov     word ptr DGROUP:_api_sp,sp
  167. ; restore foreground stack here
  168. mov     ss,word ptr DGROUP:_usr_ss
  169. mov     sp,word ptr DGROUP:_usr_sp
  171. pop     word ptr DGROUP:_usr_sp
  172. pop     word ptr DGROUP:_usr_ss
  174. ; make bp relative to our stack frame
  175. pop     bp
  176. ;mov     bp,sp   
  178. ; setup for ret
  179. push    bx 
  180. push    cx
  181.     
  182. ; now restore interrupt state
  183. push    dx
  184. popf
  186. ret
  187. _restore_stack  endp
  189. _TEXT           ends
  191. end