开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 电子书籍 > VC书籍 > 查看源码
text_fdct_mmx.c
资源名称：VC++视频传输.rar　[点击查看]
上传用户：hxb_1234
上传日期：2010-03-30
资源大小：8328k
文件大小：13k
源码类别：

VC书籍

开发平台：

Visual C++

text_fdct_mmx.c：源码内容
  1. #define INP eax
  2. #define OUT ecx
  3. #define TABLE ebx
  4. #define TABLEF ebx  
  5. #define round_frw_row edx
  6. #define x0 INP + 0*16
  7. #define x1 INP + 1*16
  8. #define x2 INP + 2*16
  9. #define x3 INP + 3*16
  10. #define x4 INP + 4*16
  11. #define x5 INP + 5*16
  12. #define x6 INP + 6*16
  13. #define x7 INP + 7*16
  14. #define y0 OUT + 0*16
  15. #define y1 OUT + 1*16
  16. #define y2 OUT + 2*16
  17. #define y3 OUT + 3*16
  18. #define y4 OUT + 4*16
  19. #define y5 OUT + 5*16
  20. #define y6 OUT + 6*16
  21. #define y7 OUT + 7*16
  22. #define BITS_FRW_ACC 3 
  23. #define SHIFT_FRW_COL BITS_FRW_ACC
  24. #define SHIFT_FRW_ROW (BITS_FRW_ACC + 17)
  25. #define SHIFT_FRW_ROW_CLIP2 (4)  
  26. #define SHIFT_FRW_ROW_CLIP1 ( SHIFT_FRW_ROW - SHIFT_FRW_ROW_CLIP2 )
  27. #define RND_FRW_ROW (1 << (SHIFT_FRW_ROW-1))
  28. #define RND_FRW_COL (1 << (SHIFT_FRW_COL-1))
  29. const static __int64 one_corr = 0x0001000100010001;
  30. const static long r_frw_row[2] = {RND_FRW_ROW, RND_FRW_ROW };
  31. const static short tg_all_16[] = {
  32. 13036, 13036, 13036, 13036,
  33. 27146, 27146, 27146, 27146,
  34. -21746, -21746, -21746, -21746,
  35. -19195, -19195, -19195, -19195,
  36. 23170, 23170, 23170, 23170 };
  37. #define tg_1_16 (TABLEF + 0)
  38. #define tg_2_16 (TABLEF + 8)
  39. #define tg_3_16 (TABLEF + 16)
  40. #define cos_4_16 (TABLEF + 24)
  41. #define ocos_4_16 (TABLEF + 32)
  42.     
  43. static const short tab_frw_01234567[] = {  
  44.     
  45.     16384, 16384, 21407, -8867,     
  46.     16384, 16384, 8867, -21407,     
  47.     16384, -16384, 8867, 21407,     
  48.     -16384, 16384, -21407, -8867,   
  49.     22725, 12873, 19266, -22725,    
  50.     19266, 4520, -4520, -12873,     
  51.     12873, 4520, 4520, 19266,       
  52.     -22725, 19266, -12873, -22725,  
  53.     
  54.     22725, 22725, 29692, -12299,    
  55.     22725, 22725, 12299, -29692,    
  56.     22725, -22725, 12299, 29692,    
  57.     -22725, 22725, -29692, -12299,  
  58.     31521, 17855, 26722, -31521,    
  59.     26722, 6270, -6270, -17855,     
  60.     17855, 6270, 6270, 26722,       
  61.     -31521, 26722, -17855, -31521,  
  62.     
  63.     21407, 21407, 27969, -11585,    
  64.     21407, 21407, 11585, -27969,    
  65.     21407, -21407, 11585, 27969,    
  66.     -21407, 21407, -27969, -11585,  
  67.     29692, 16819, 25172, -29692,    
  68.     25172, 5906, -5906, -16819,     
  69.     16819, 5906, 5906, 25172,       
  70.     -29692, 25172, -16819, -29692,  
  71.     
  72.     19266, 19266, 25172, -10426,    
  73.     19266, 19266, 10426, -25172,    
  74.     19266, -19266, 10426, 25172,    
  75.     -19266, 19266, -25172, -10426,  
  76.     26722, 15137, 22654, -26722,    
  77.     22654, 5315, -5315, -15137,     
  78.     15137, 5315, 5315, 22654,       
  79.     -26722, 22654, -15137, -26722,  
  80.     
  81.     16384, 16384, 21407, -8867,     
  82.     16384, 16384, 8867, -21407,     
  83.     16384, -16384, 8867, 21407,     
  84.     -16384, 16384, -21407, -8867,   
  85.     22725, 12873, 19266, -22725,    
  86.     19266, 4520, -4520, -12873,     
  87.     12873, 4520, 4520, 19266,       
  88.     -22725, 19266, -12873, -22725,  
  89.     
  90.     19266, 19266, 25172, -10426,    
  91.     19266, 19266, 10426, -25172,    
  92.     19266, -19266, 10426, 25172,    
  93.     -19266, 19266, -25172, -10426,  
  94.     26722, 15137, 22654, -26722,    
  95.     22654, 5315, -5315, -15137,     
  96.     15137, 5315, 5315, 22654,       
  97.     -26722, 22654, -15137, -26722,  
  98.     
  99.     21407, 21407, 27969, -11585,    
  100.     21407, 21407, 11585, -27969,    
  101.     21407, -21407, 11585, 27969,    
  102.     -21407, 21407, -27969, -11585,  
  103.     29692, 16819, 25172, -29692,    
  104.     25172, 5906, -5906, -16819,     
  105.     16819, 5906, 5906, 25172,       
  106.     -29692, 25172, -16819, -29692,  
  107.     
  108.     22725, 22725, 29692, -12299,    
  109.     22725, 22725, 12299, -29692,    
  110.     22725, -22725, 12299, 29692,    
  111.     -22725, 22725, -29692, -12299,  
  112.     31521, 17855, 26722, -31521,    
  113.     26722, 6270, -6270, -17855,     
  114.     17855, 6270, 6270, 26722,       
  115.     -31521, 26722, -17855, -31521   
  116. };
  117. void
  118. fdct_mm32( short *blk )
  119. {
  120.     static __int64 xt70[2]; 
  121.     static int a0, a1, a2, a3, b0, b1, b2, b3;
  122.     static short *sptr, *optr, *tf; 
  123.     static short *xt = (short *) &xt70[0];
  124.     static int j;
  125.     
  126.     const static short _tg_1_16   = 13036;  
  127.     const static short _tg_2_16   = 27146;  
  128.     const static short _tg_3_16   =-21746;  
  129.     const static short _cos_4_16  =-19195;  
  130.     const static short _ocos_4_16 = 23170;  
  131.     const static short _one_corr  =     1;  
  132.     static short t0, t1, t2, t3, t4, t5, t6, t7;
  133.     static short tp03, tm03, tp12, tm12, tp65, tm65;
  134.     static short tp465, tm465, tp765, tm765;
  135.     __asm {
  136.     
  137.     
  138.     
  139.     
  140.     
  141.     
  142.     
  143.     
  144.     
  145.     
  146.     
  147. mov INP, dword ptr [blk]; ;
  148.     ;
  149.     lea TABLEF, dword ptr [tg_all_16];
  150.     mov OUT, INP;
  151.     
  152.     
  153.     
  154. mmx32_fdct_col03: 
  155.     movq mm0, [x1] ; 0 ; x1
  156.      ;
  157.     movq mm1, [x6] ; 1 ; x6
  158.      movq mm2, mm0 ; 2 ; x1
  159.     movq mm3, [x2] ; 3 ; x2
  160.      paddsw mm0, mm1 ; t1 = x[1] + x[6]
  161.     movq mm4, [x5] ; 4 ; x5
  162.      psllw mm0, SHIFT_FRW_COL ; t1
  163.     movq mm5, [x0] ; 5 ; x0
  164.      paddsw mm4, mm3 ; t2 = x[2] + x[5]
  165.     paddsw mm5, [x7] ; t0 = x[0] + x[7]
  166.      psllw mm4, SHIFT_FRW_COL ; t2
  167.     movq mm6, mm0 ; 6 ; t1
  168.      psubsw mm2, mm1 ; 1 ; t6 = x[1] - x[6]
  169.     movq mm1, qword ptr [tg_2_16] ; 1 ; tg_2_16
  170.      psubsw mm0, mm4 ; tm12 = t1 - t2
  171.     movq mm7, [x3] ; 7 ; x3
  172.      pmulhw mm1, mm0 ; tm12*tg_2_16
  173.     paddsw mm7, [x4] ; t3 = x[3] + x[4]
  174.      psllw mm5, SHIFT_FRW_COL ; t0
  175.     paddsw mm6, mm4 ; 4 ; tp12 = t1 + t2
  176.      psllw mm7, SHIFT_FRW_COL ; t3
  177.     movq mm4, mm5 ; 4 ; t0
  178.      psubsw mm5, mm7 ; tm03 = t0 - t3
  179.     paddsw mm1, mm5 ; y2 = tm03 + tm12*tg_2_16
  180.      paddsw mm4, mm7 ; 7 ; tp03 = t0 + t3
  181.     por mm1, qword ptr one_corr ; correction y2 +0.5
  182.      psllw mm2, SHIFT_FRW_COL+1 ; t6
  183.     pmulhw mm5, qword ptr [tg_2_16] ; tm03*tg_2_16
  184.      movq mm7, mm4 ; 7 ; tp03
  185.     psubsw mm3, [x5] ; t5 = x[2] - x[5]
  186.      psubsw mm4, mm6 ; y4 = tp03 - tp12
  187.     movq [y2], mm1 ; 1 ; save y2
  188.      paddsw mm7, mm6 ; 6 ; y0 = tp03 + tp12
  189.      
  190.     movq mm1, [x3] ; 1 ; x3
  191.      psllw mm3, SHIFT_FRW_COL+1 ; t5
  192.     psubsw mm1, [x4] ; t4 = x[3] - x[4]
  193.      movq mm6, mm2 ; 6 ; t6
  194.     
  195.     movq [y4], mm4 ; 4 ; save y4
  196.      paddsw mm2, mm3 ; t6 + t5
  197.     pmulhw mm2, qword ptr [ocos_4_16] ; tp65 = (t6 + t5)*cos_4_16
  198.      psubsw mm6, mm3 ; 3 ; t6 - t5
  199.     pmulhw mm6, qword ptr [ocos_4_16] ; tm65 = (t6 - t5)*cos_4_16
  200.      psubsw mm5, mm0 ; 0 ; y6 = tm03*tg_2_16 - tm12
  201.     por mm5, qword ptr one_corr ; correction y6 +0.5
  202.      psllw mm1, SHIFT_FRW_COL ; t4
  203.     por mm2, qword ptr one_corr ; correction tp65 +0.5
  204.      movq mm4, mm1 ; 4 ; t4
  205.     movq mm3, [x0] ; 3 ; x0
  206.      paddsw mm1, mm6 ; tp465 = t4 + tm65
  207.     psubsw mm3, [x7] ; t7 = x[0] - x[7]
  208.      psubsw mm4, mm6 ; 6 ; tm465 = t4 - tm65
  209.     movq mm0, qword ptr [tg_1_16] ; 0 ; tg_1_16
  210.      psllw mm3, SHIFT_FRW_COL ; t7
  211.     movq mm6, qword ptr [tg_3_16] ; 6 ; tg_3_16
  212.      pmulhw mm0, mm1 ; tp465*tg_1_16
  213.     movq [y0], mm7 ; 7 ; save y0
  214.      pmulhw mm6, mm4 ; tm465*tg_3_16
  215.     movq [y6], mm5 ; 5 ; save y6
  216.      movq mm7, mm3 ; 7 ; t7
  217.     movq mm5, qword ptr [tg_3_16] ; 5 ; tg_3_16
  218.      psubsw mm7, mm2 ; tm765 = t7 - tp65
  219.     paddsw mm3, mm2 ; 2 ; tp765 = t7 + tp65
  220.      pmulhw mm5, mm7 ; tm765*tg_3_16
  221.     paddsw mm0, mm3 ; y1 = tp765 + tp465*tg_1_16
  222.      paddsw mm6, mm4 ; tm465*tg_3_16
  223.     pmulhw mm3, qword ptr [tg_1_16] ; tp765*tg_1_16
  224.      ;
  225.     por mm0, qword ptr one_corr ; correction y1 +0.5
  226.      paddsw mm5, mm7 ; tm765*tg_3_16
  227.     psubsw mm7, mm6 ; 6 ; y3 = tm765 - tm465*tg_3_16
  228.      add INP, 0x08   ; 
  229.     movq [y1], mm0 ; 0 ; save y1
  230.      paddsw mm5, mm4 ; 4 ; y5 = tm765*tg_3_16 + tm465
  231.     movq [y3], mm7 ; 7 ; save y3
  232.      psubsw mm3, mm1 ; 1 ; y7 = tp765*tg_1_16 - tp465
  233.     movq [y5], mm5 ; 5 ; save y5
  234.   mmx32_fdct_col47: 
  235.     movq mm0, [x1] ; 0 ; x1
  236.      ;
  237.     movq [y7], mm3 ; 3 ; save y7 (columns 0-4)
  238.      ;
  239.     movq mm1, [x6] ; 1 ; x6
  240.      movq mm2, mm0 ; 2 ; x1
  241.     movq mm3, [x2] ; 3 ; x2
  242.      paddsw mm0, mm1 ; t1 = x[1] + x[6]
  243.     movq mm4, [x5] ; 4 ; x5
  244.      psllw mm0, SHIFT_FRW_COL ; t1
  245.     movq mm5, [x0] ; 5 ; x0
  246.      paddsw mm4, mm3 ; t2 = x[2] + x[5]
  247.     paddsw mm5, [x7] ; t0 = x[0] + x[7]
  248.      psllw mm4, SHIFT_FRW_COL ; t2
  249.     movq mm6, mm0 ; 6 ; t1
  250.      psubsw mm2, mm1 ; 1 ; t6 = x[1] - x[6]
  251.     movq mm1, qword ptr [tg_2_16] ; 1 ; tg_2_16
  252.      psubsw mm0, mm4 ; tm12 = t1 - t2
  253.     movq mm7, [x3] ; 7 ; x3
  254.      pmulhw mm1, mm0 ; tm12*tg_2_16
  255.     paddsw mm7, [x4] ; t3 = x[3] + x[4]
  256.      psllw mm5, SHIFT_FRW_COL ; t0
  257.     paddsw mm6, mm4 ; 4 ; tp12 = t1 + t2
  258.      psllw mm7, SHIFT_FRW_COL ; t3
  259.     movq mm4, mm5 ; 4 ; t0
  260.      psubsw mm5, mm7 ; tm03 = t0 - t3
  261.     paddsw mm1, mm5 ; y2 = tm03 + tm12*tg_2_16
  262.      paddsw mm4, mm7 ; 7 ; tp03 = t0 + t3
  263.     por mm1, qword ptr one_corr ; correction y2 +0.5
  264.      psllw mm2, SHIFT_FRW_COL+1 ; t6
  265.     pmulhw mm5, qword ptr [tg_2_16] ; tm03*tg_2_16
  266.      movq mm7, mm4 ; 7 ; tp03
  267.     psubsw mm3, [x5] ; t5 = x[2] - x[5]
  268.      psubsw mm4, mm6 ; y4 = tp03 - tp12
  269.     movq [y2+8], mm1 ; 1 ; save y2
  270.      paddsw mm7, mm6 ; 6 ; y0 = tp03 + tp12
  271.      
  272.     movq mm1, [x3] ; 1 ; x3
  273.      psllw mm3, SHIFT_FRW_COL+1 ; t5
  274.     psubsw mm1, [x4] ; t4 = x[3] - x[4]
  275.      movq mm6, mm2 ; 6 ; t6
  276.     
  277.     movq [y4+8], mm4 ; 4 ; save y4
  278.      paddsw mm2, mm3 ; t6 + t5
  279.     pmulhw mm2, qword ptr [ocos_4_16] ; tp65 = (t6 + t5)*cos_4_16
  280.      psubsw mm6, mm3 ; 3 ; t6 - t5
  281.     pmulhw mm6, qword ptr [ocos_4_16] ; tm65 = (t6 - t5)*cos_4_16
  282.      psubsw mm5, mm0 ; 0 ; y6 = tm03*tg_2_16 - tm12
  283.     por mm5, qword ptr one_corr ; correction y6 +0.5
  284.      psllw mm1, SHIFT_FRW_COL ; t4
  285.     por mm2, qword ptr one_corr ; correction tp65 +0.5
  286.      movq mm4, mm1 ; 4 ; t4
  287.     movq mm3, [x0] ; 3 ; x0
  288.      paddsw mm1, mm6 ; tp465 = t4 + tm65
  289.     psubsw mm3, [x7] ; t7 = x[0] - x[7]
  290.      psubsw mm4, mm6 ; 6 ; tm465 = t4 - tm65
  291.     movq mm0, qword ptr [tg_1_16] ; 0 ; tg_1_16
  292.      psllw mm3, SHIFT_FRW_COL ; t7
  293.     movq mm6, qword ptr [tg_3_16] ; 6 ; tg_3_16
  294.      pmulhw mm0, mm1 ; tp465*tg_1_16
  295.     movq [y0+8], mm7 ; 7 ; save y0
  296.      pmulhw mm6, mm4 ; tm465*tg_3_16
  297.     movq [y6+8], mm5 ; 5 ; save y6
  298.      movq mm7, mm3 ; 7 ; t7
  299.     movq mm5, qword ptr [tg_3_16] ; 5 ; tg_3_16
  300.      psubsw mm7, mm2 ; tm765 = t7 - tp65
  301.     paddsw mm3, mm2 ; 2 ; tp765 = t7 + tp65
  302.      pmulhw mm5, mm7 ; tm765*tg_3_16
  303.     paddsw mm0, mm3 ; y1 = tp765 + tp465*tg_1_16
  304.      paddsw mm6, mm4 ; tm465*tg_3_16
  305.     pmulhw mm3, qword ptr [tg_1_16] ; tp765*tg_1_16
  306.      ;
  307.     por mm0, qword ptr one_corr ; correction y1 +0.5
  308.      paddsw mm5, mm7 ; tm765*tg_3_16
  309.     psubsw mm7, mm6 ; 6 ; y3 = tm765 - tm465*tg_3_16
  310.      ;
  311.     movq [y1+8], mm0 ; 0 ; save y1
  312.      paddsw mm5, mm4 ; 4 ; y5 = tm765*tg_3_16 + tm465
  313.     movq [y3+8], mm7 ; 7 ; save y3
  314.      psubsw mm3, mm1 ; 1 ; y7 = tp765*tg_1_16 - tp465
  315.     movq [y5+8], mm5 ; 5 ; save y5
  316.     movq [y7+8], mm3 ; 3 ; save y7
  317.   
  318.   
  319.     
  320.   
  321.   
  322.   
  323.   
  324.   
  325.   
  326.   
  327.   
  328. mov INP, dword ptr [blk]; ;
  329.  mov edi, 0x08;
  330. lea TABLE, dword ptr [tab_frw_01234567]; 
  331.  mov OUT, INP;
  332. lea round_frw_row, dword ptr [r_frw_row];
  334.   lp_mmx_fdct_row1:
  335.     movd mm5, dword ptr [INP+12]; 
  336.     punpcklwd mm5, dword ptr [INP+8] 
  337.     movq mm2, mm5;     
  338.     psrlq mm5, 32;     
  339.     movq mm0, qword ptr [INP]; 
  340.     punpcklwd mm5, mm2;
  341.     movq mm1, mm0;     
  342.     paddsw mm0, mm5;   
  343.     psubsw mm1, mm5;   
  344.     movq mm2, mm0;     
  345.     
  346.     
  347.     punpcklwd mm0, mm1;
  348.     punpckhwd mm2, mm1;
  349.     movq mm1, mm2;     
  350.     ;
  351.     movq mm2, mm0 ; 2 ; x3 x2 x1 x0
  352.     movq mm3, qword ptr [TABLE] ; 3 ; w06 w04 w02 w00
  353.     punpcklwd mm0, mm1 ; x5 x1 x4 x0
  354.     movq mm5, mm0 ; 5 ; x5 x1 x4 x0
  355.     punpckldq mm0, mm0 ; x4 x0 x4 x0  [ xt2 xt0 xt2 xt0 ]
  356.     movq mm4, qword ptr [TABLE+8] ; 4 ; w07 w05 w03 w01
  357.     punpckhwd mm2, mm1 ; 1 ; x7 x3 x6 x2
  358.     pmaddwd mm3, mm0 ; x4*w06+x0*w04 x4*w02+x0*w00
  359.     movq mm6, mm2 ; 6 ; x7 x3 x6 x2
  360.     movq mm1, qword ptr [TABLE+32] ; 1 ; w22 w20 w18 w16
  361.     punpckldq mm2, mm2 ; x6 x2 x6 x2  [ xt3 xt1 xt3 xt1 ]
  362.     pmaddwd mm4, mm2 ; x6*w07+x2*w05 x6*w03+x2*w01
  363.     punpckhdq mm5, mm5 ; x5 x1 x5 x1  [ xt6 xt4 xt6 xt4 ]
  364.     pmaddwd mm0, qword ptr [TABLE+16] ; x4*w14+x0*w12 x4*w10+x0*w08
  365.     punpckhdq mm6, mm6 ; x7 x3 x7 x3  [ xt7 xt5 xt7 xt5 ]
  366.     movq mm7, qword ptr [TABLE+40] ; 7 ; w23 w21 w19 w17
  367.     pmaddwd mm1, mm5 ; x5*w22+x1*w20 x5*w18+x1*w16
  368.     paddd mm3, qword ptr [round_frw_row] ; +rounder (y2,y0)
  369.     pmaddwd mm7, mm6 ; x7*w23+x3*w21 x7*w19+x3*w17
  370.     pmaddwd mm2, qword ptr [TABLE+24] ; x6*w15+x2*w13 x6*w11+x2*w09
  371.     paddd mm3, mm4 ; 4 ; a1=sum(even1) a0=sum(even0) 
  372.     pmaddwd mm5, qword ptr [TABLE+48] ; x5*w30+x1*w28 x5*w26+x1*w24
  373.     ;
  374.     pmaddwd mm6, qword ptr [TABLE+56] ; x7*w31+x3*w29 x7*w27+x3*w25
  375.     paddd mm1, mm7 ; 7 ; b1=sum(odd1) b0=sum(odd0) 
  376.     paddd mm0, qword ptr [round_frw_row] ; +rounder (y6,y4)
  377.     psrad mm3, SHIFT_FRW_ROW_CLIP1 ;
  378.     paddd mm1, qword ptr [round_frw_row] ; +rounder (y3,y1)
  379.     paddd mm0, mm2 ; 2 ; a3=sum(even3) a2=sum(even2) 
  380.     paddd mm5, qword ptr [round_frw_row] ; +rounder (y7,y5)
  381.     psrad mm1, SHIFT_FRW_ROW_CLIP1 ;
  382.     paddd mm5, mm6 ; 6 ; b3=sum(odd3) b2=sum(odd2) 
  383.     psrad mm0, SHIFT_FRW_ROW_CLIP1 ;
  384.     add OUT, 16;  
  385.     psrad mm5, SHIFT_FRW_ROW_CLIP1;
  386.     add INP, 16;  
  387.     packssdw mm3, mm0 ;
  388.     packssdw mm1, mm5 ;
  389.     movq mm6, mm3;    
  390.     punpcklwd mm3, mm1; 
  391.     sub edi, 0x01;   
  392.     
  393.     punpckhwd mm6, mm1; 
  394.     add TABLE,64;  
  395.     psraw mm3, SHIFT_FRW_ROW_CLIP2;  
  396.     psraw mm6, SHIFT_FRW_ROW_CLIP2;  
  397.     movq qword ptr [OUT-16], mm3 ; 1 ; save y3 y2 y1 y0
  398.     movq qword ptr [OUT-8], mm6 ; 7 ; save y7 y6 y5 y4
  399.     cmp edi, 0x00;
  400.     jg lp_mmx_fdct_row1;  
  401.     emms;
  402.     }
  403.     
  404.   
  405. }