开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > VxWorks > 查看源码
unixALib.s
资源名称：vxwork_src.rar　[点击查看]
上传用户：nvosite88
上传日期：2007-01-17
资源大小：4983k
文件大小：9k
源码类别：

VxWorks

开发平台：

C/C++

unixALib.s：源码内容
  1. /* unixALib.s - network assembly language routines */
  3. /* Copyright 1995-2000 Wind River Systems, Inc. */
  5. .data
  6. .global _copyright_wind_river
  7. .long _copyright_wind_river
  9. /*
  10. modification history
  11. --------------------
  12. 01q,21aug00,hk   merge SH7729 to SH7700. simplify CPU conditionals.
  13. 01p,28mar00,hk   added .type directive to function names.
  14. 01o,17mar00,zl   made use of alignment macro _ALIGN_TEXT
  15. 01n,05oct99,zl   updated cksum for little endian release.
  16. 01m,25feb99,hk   simplified CPU conditional in default of shld instruction.
  17. 01l,14sep98,hk   simplified CPU conditionals.
  18. 01k,16jul98,st   added SH7750 support.
  19. 01k,08may98,jmc  added support for SH-DSP and SH3-DSP.
  20. 01j,25apr97,hk   changed SH704X to SH7040.
  21. 01i,05aug96,hk   simpified PORTABLE control. deleted unnecessary comments.
  22.  added shld optimization to csLongBoundary.
  23. 01h,29jul96,hk   changed to use 'mova', added DEBUG_LOCAL_SYMBOLS option.
  24. 01g,10jul96,ja   added support for SH7700.
  25. 01f,23jan96,hk   changed bf/s machine code in csLongLoop to use bf.s.
  26. 01e,18dec95,hk   added support for SH704X.
  27. 01d,19may95,hk   tweaking a little. worked around 'mova' alignment problem.
  28. 01c,15may95,hk   optimized.
  29. 01b,12may95,hk   mostly optimized.
  30. 01a,08may95,hk   written based on mc68k-01t.
  31. */
  33. /* optimized version available for the SH family */
  35. #if (defined(PORTABLE) || (CPU_FAMILY != SH))
  36. #define unixALib_PORTABLE
  37. #endif
  39. #ifndef unixALib_PORTABLE
  41. #define _ASMLANGUAGE
  42. #include "vxWorks.h"
  43. #include "asm.h"
  45. /* internals */
  47. .global _cksum
  48. .global __insque
  49. .global __remque
  50. #undef DEBUG_LOCAL_SYMBOLS
  51. #ifdef DEBUG_LOCAL_SYMBOLS
  52. .global csEvenSum
  53. .global csEvenBoundary
  54. .global csLongBoundary
  55. .global csLongLoop
  56. .global csStartLoop
  57. .global csFoldAddT
  58. .global csChkSwapped
  59. .global csNotSwapped
  60. .global csLastSum
  61. .global csLastFold
  62. #endif /* DEBUG_LOCAL_SYMBOLS */
  64. .text
  66. /**************************************************************************
  67. *
  68. * cksum - compute check sum
  69. *
  70. * return 16bit one's complement sum of 'sum' and the 16bit one's
  71. * complement sum of the string 'string' of byte length 'len'.
  72. * Complicated by 'len' or 'sumlen' not being even.
  74. * #define FOLD { lBox.asLong = cSum;  cSum = lBox.asShort[0] + lBox.asShort[1];
  75. *                cSum > 0xffff ? cSum -= 0xffff : cSum; }
  77. * int cksum
  78. *   (
  79. *   int       cSum, /@ previously calculated checksum  @/
  80. *   u_short * mPtr, /@ address of string to be summed  @/
  81. *   int       mLen, /@ length  of string to be summed  @/
  82. *   int       sLen /@ previously summed string length @/
  83. *   )
  84. *   {
  85. *   int                                            swapped = 0;
  86. *   union { char    asChar [2]; u_short asShort; } sBox;
  87. *   union { u_short asShort[2]; long    asLong;  } lBox;
  88. *
  89. *   if (sLen & 0x1)
  90. * {
  91. * sBox.asChar[0] = 0;
  92. * sBox.asChar[1] = *(char *)mPtr; /@  sBox [0:B] @/
  93. * cSum += sBox.asShort; /@  sBox [_:_] @/
  94. * mPtr = (u_short *)((char *)mPtr + 1);
  95. * mLen--;
  96. * }
  97. *   if ((1 & (int)mPtr) && (mLen > 0)) /@ odd boundary            @/
  98. * { /@                         @/
  99. * FOLD; cSum <<= 8; swapped = 1; /@ swap byte order         @/
  100. * /@                         @/
  101. * sBox.asChar[0] = *(u_char *)mPtr; /@  sBox [X:_] @/
  102. * mPtr = (u_short *)((char *)mPtr + 1); /@                         @/
  103. * mLen--; /@ force even boundary     @/
  104. * }
  105. *   while ((mLen -= 2) >= 0) cSum += *mPtr++; /@ sum up                  @/
  106. * /@ mLen: -2 or -1          @/
  107. *   if (swapped)
  108. * { /@ sum is byte-swapped     @/
  109. * FOLD; cSum <<= 8; swapped = 0; /@ return to normal order  @/
  110. *
  111. * if (mLen == -1)
  112. *     { /@ swapped, mLen was even. @/
  113. *     sBox.asChar[1] = *(char *)mPtr; /@  sBox [X:Y] @/
  114. *     cSum += sBox.asShort; /@  sBox [_:_] @/
  115. *     }
  116. * else{ /@ swapped, mLen was odd.  @/
  117. *     sBox.asChar[1] = 0; /@  sBox [X:0] @/
  118. *     cSum += sBox.asShort; /@  sBox [_:_] @/
  119. *     }
  120. * }
  121. *   else{
  122. * if (mLen == -1)
  123. *     { /@ not swapped, mLen was odd. @/
  124. *     sBox.asChar[0] = *(char *)mPtr; /@                            @/
  125. *     sBox.asChar[1] = 0; /@  sBox [A:0]    @/
  126. *     cSum += sBox.asShort; /@  sBox [_:_]    @/
  127. *     }
  128. * else; /@ not swapped, mLen was even.@/
  129. * }
  130. *   FOLD;
  131. *   return (cSum & 0xffff);
  132. *   }
  134. */
  135. .align _ALIGN_TEXT
  136. .type _cksum,@function
  137. /* r4: cSum      */
  138. /* r5: mPtr      */
  139. /* r6: mLen (>0) */
  140. _cksum: /* r7: sLen      */
  141. mov r7,r0
  142. mov #0,r7 /* r7: swapped = 0 */
  143. tst #0x1,r0
  144. bt csEvenSum
  146. mov.b @r5+,r1;
  147. add #-1,r6 /* r6: mLen--     */
  148. extu.b r1,r1 /* r1: 0x000000XX */
  149. #if (_BYTE_ORDER == _LITTLE_ENDIAN)
  150. shll8 r1 /* r1: 0x0000XX00 */
  151. #endif
  152. add r1,r4 /* r4: 0x0001ZZZZ */
  153. csEvenSum: /* r6: mLen (>=0) */
  154. mov r5,r0 /* r5: mPtr */
  155. tst #0x1,r0
  156. bt csEvenBoundary /*     no swap */
  158. cmp/pl r6 /* r6: mLen */
  159. bf csEvenBoundary /*     no swap */
  161. /*-- odd boundary, do swap --*/ /* r4: 0x0001ZZZZ */
  162. shll8 r4 /* r4: 0x01ZZZZ00 */
  163. extu.w r4,r2 /* r2: 0x0000ZZ00 */
  164. shlr16 r4 /* r4: 0x000001ZZ */
  165. add r2,r4 /* r4: 0x0001VVVV */
  166. mov #1,r7
  167. rotr r7 /* r7: 0x80000000 (swapped) */
  168. mov.b @r5+,r3
  169. add #-1,r6 /* r6: mLen-- */
  170. extu.b r3,r3
  171. #if (_BYTE_ORDER == _BIG_ENDIAN)
  172. shll8 r3 /* r3: 0x0000XX00 */
  173. #endif
  174. or r3,r7 /* r7: 0x8000XX00 (swapped | sBox) */
  175. /*-- forced even, swapped --*/
  177. csEvenBoundary:
  178. mov r5,r0 /* r0: mPtr */
  179. tst #0x2,r0 /*     long boundary?               */
  180. bt csLongBoundary /*     if yes, go to long-add stage */
  182. add #-2,r6 /* r6: mLen -= 2 */
  183. mov r6,r0 /* r0: mLen (used at csChkSwapped) */
  184. cmp/pz r6
  185. bf csChkSwapped
  187. mov.w @r5+,r1
  188. extu.w r1,r1
  189. add r1,r4 /*     overflow not possible */
  191. csLongBoundary: /* r6: mLen                      */
  192. mov r6,r0 /*     find fractions of a chunk */
  193. and #0x3c,r0
  194. neg r0,r2 /* r2: offset from ckStartLoop */
  195. mova csStartLoop,r0 /* (csStartLoop must be long aligned) */
  196. add r0,r2
  197. mov r6,r0
  198. and #0x3,r0 /* r0: mLen % 4 */
  199. #if (CPU==SH7000 || CPU==SH7600)
  200. shlr2 r6
  201. shlr2 r6
  202. shlr2 r6
  203. #else
  204. mov #-6,r1
  205. shld r1,r6 /* r6: mLen/64 */
  206. #endif
  207. add #1,r6 /* r6: mLen/64 + 1 */
  208. jmp @r2;
  209. clrt /*     clear T */
  210. /* r7: (swapped | sBox) */
  211. /* r6: mLen/64 + 1      */
  212. /* r5: mPtr             */
  213. /* r4: cSum             */
  214. /* r3: T-bit storage    */
  215. /* r2:                  */
  216. /* r1:                  */
  217. /* r0: mLen % 4         */
  218. .align 2
  219. #if (CPU==SH7000)
  220. nop
  221. csLongLoop:
  222. rotr r3 /* restore T */
  223. #else
  224. csLongLoop:
  225. #endif
  226. mov.l @r5+,r1; addc r1,r4
  227. mov.l @r5+,r1; addc r1,r4
  228. mov.l @r5+,r1; addc r1,r4
  229. mov.l @r5+,r1; addc r1,r4
  230. mov.l @r5+,r1; addc r1,r4
  231. mov.l @r5+,r1; addc r1,r4
  232. mov.l @r5+,r1; addc r1,r4
  233. mov.l @r5+,r1; addc r1,r4
  234. mov.l @r5+,r1; addc r1,r4
  235. mov.l @r5+,r1; addc r1,r4
  236. mov.l @r5+,r1; addc r1,r4
  237. mov.l @r5+,r1; addc r1,r4
  238. mov.l @r5+,r1; addc r1,r4
  239. mov.l @r5+,r1; addc r1,r4
  240. mov.l @r5+,r1; addc r1,r4
  241. mov.l @r5+,r1; addc r1,r4
  242. csStartLoop:
  243. movt r3 /* save T */
  244. #if (CPU==SH7000)
  245. add #-1,r6
  246. tst r6,r6
  247. bf csLongLoop
  248. #else
  249. dt r6
  250. bf.s csLongLoop
  251. rotr r3 /*     restore T */
  252. rotl r3 /*     save T */
  253. #endif
  254. /* r0: mLen ( 0,  1, 2, 3) */
  255. add #-2,r0 /* r0: mLen (-2, -1, 0, 1) */
  256. cmp/pz r0
  257. bf csFoldAddT
  258. /* r0: mLen ( 0,  1) */
  259. mov.w @r5+,r1
  260. rotr r3 /*     restore T */
  261. extu.w r1,r1
  262. addc r1,r4
  263. movt r3 /*     save T */
  264. add #-2,r0
  265. csFoldAddT: /* r0: mLen (-2, -1) */
  266. extu.w r4,r2 /* r2: 0x0000FFFF */
  267. shlr16 r4 /* r4: 0x0000FFFF */
  268. add r2,r4 /* r4: 0x0001FFFE */
  269. add r3,r4 /* r4: 0x0001FFFF */
  271. csChkSwapped: /* r0: mLen (-1, -2) */
  272. cmp/pz r7 /* r7: swapped ?  */
  273. extu.w r7,r3 /* r3: 0x0000XX00 */
  274. bt csNotSwapped
  275. /* r4: 0xFFFFFFFF */ /* unswap */
  276. extu.w r4,r2 /* r2: 0x0000FFFF */
  277. shlr16 r4 /* r4: 0x0000FFFF */
  278. add r2,r4 /* r4: 0x0001FFFE */
  279. shll8 r4 /* r4: 0x01FFFE00 */
  281. cmp/eq #-1,r0 /* r0:(mLen == -1)? */
  282. bf csLastSum /* r3: 0x0000XX00 */
  284. mov.b @r5,r1
  285. extu.b r1,r1 /* r1: 0x000000YY */
  286. #if (_BYTE_ORDER == _LITTLE_ENDIAN)
  287. shll8 r1 /* r3: 0x0000YY00 */
  288. #endif
  289. bra csLastSum;
  290. or r1,r3 /* r3: 0x0000XXYY */
  292. csNotSwapped:
  293. cmp/eq #-1,r0 /* r0:(mLen == -1)? */
  294. bf csLastFold
  296. mov.b @r5,r3
  297. extu.b r3,r3
  298. #if (_BYTE_ORDER == _BIG_ENDIAN)
  299. shll8 r3 /* r3: 0x0000AA00 */
  300. #endif
  301. csLastSum:
  302. add r3,r4 /* r4: cSum += sBox.asShort   */
  303. /*     overflow not possible. */
  304. csLastFold: /* r4: 0xFFFFFFFF */
  305. extu.w r4,r2 /* r2: 0x0000FFFF */
  306. shlr16 r4 /* r4: 0x0000FFFF */
  307. add r2,r4 /* r4: 0x0001FFFE */
  309. extu.w r4,r0 /* r0: 0x0000FFFE */
  310. shlr16 r4 /* r4: 0x00000001 */
  311. rts;
  312. add r4,r0 /* r0: 0x0000FFFF */
  314. /****************************************************************************
  315. *
  316. * insque - insert a node into a linked list
  317. *
  318. */
  319. .align _ALIGN_TEXT
  320. .type __insque,@function
  322. /* r4: pNode */
  323. __insque: /* r5: pPrev */
  324. mov.l   @r5,r0; /* r0: pNext           = pPrev->next */
  325. mov.l   r4,@r5 /*     pPrev->next     = pNode */
  326. mov.l   r4,@(4,r0) /*     pNext->previous = pNode */
  327. mov.l   r0,@r4 /*     pNode->next     = pNext */
  328. rts; /* */
  329. mov.l   r5,@(4,r4) /*     pNode->previous = pPrev */
  331. /****************************************************************************
  332. *
  333. * remque - delete a node from a linked list
  334. *
  335. * NOTE: This routine is only used by remque() in h/net/systm.h
  336. */
  337. .align _ALIGN_TEXT
  338. .type __remque,@function
  340. __remque:        /* r4: pNode       */
  341. mov.l   @r4,r0;        /* r0: pNode->next       */
  342. mov.l   @(4,r4),r1;    /* r1: pNode->previous       */
  343. mov.l   r0,@r1        /*     pNode->previous->next = pNode->next     */
  344. rts;        /*       */
  345. mov.l   r1,@(4,r0)     /*     pNode->next->previous = pNode->previous */
  347. #endif /* !unixALib_PORTABLE */