开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > VxWorks > 查看源码
wdbDbgALib.s
资源名称：vxwork_src.rar　[点击查看]
上传用户：nvosite88
上传日期：2007-01-17
资源大小：4983k
文件大小：8k
源码类别：

VxWorks

开发平台：

C/C++

wdbDbgALib.s：源码内容
  1. /* wdbDbgALib.s - i80x86 debugging aids assembly interface */
  3. /* Copyright 1984-2002 Wind River Systems, Inc. */
  5. /*
  6. modification history
  7. --------------------
  8. 01f,30may02,hdn  added WDB_CTX_LOAD that is _wdbDbgCtxLoad() (spr 75694)
  9. 01e,23aug01,hdn  added FUNC/FUNC_LABEL, replaced .align w .balign
  10.  fixed stack adjustment bug in wdbDbgBpStub.
  11. 01d,08jan98,dbt  modified for new breakpoint scheme. Added hardware
  12.  breakpoints support
  13. 01c,01jun93,hdn  updated to 5.1.
  14.   - fixed #else and #endif
  15.   - changed VOID to void
  16.   - changed ASMLANGUAGE to _ASMLANGUAGE
  17.   - changed copyright notice
  18. 01b,13oct92,hdn  debugged.
  19. 01a,08jul92,hdn  written based on TRON version.
  20. */
  22. /*
  23. DESCRIPTION
  24. This module contains assembly language routines needed for the debug
  25. package and the i80x86 exception vectors. 
  27. .ne 24
  28. PICTURE OF STACK GROWING
  29. .CS
  30.   
  31.  sp_5 ---------
  32. sp_1(pointer to ESF0)
  33.  sp_4 ---------
  34. sp_2(pointer to REGS)
  35. ---------
  36. 0 or 1
  37.   fp/sp_3 ---------  ---------
  38.      fp  fp
  39.      sp_2 ---------  ---------
  40. db0 db0
  41.  |   |
  42. db7 db7
  43.     edi edi
  44.      |   |
  45.     eax eax
  46.   sp_1 ---------  ---------  ---------
  47.  EIP EIP EIP
  48. ---------  ---------  ---------
  49.  CS  CS  CS
  50. ---------  ---------  ---------
  51.  EFLAGS     EFLAGS     EFLAGS
  52. ---------  ---------  ---------
  53.   
  54.      fig.1      fig.2      fig.3
  55. .CE 
  56.   
  57. SEE ALSO: dbgLib(1), "Debugging"
  58. */
  60. #define _ASMLANGUAGE
  61. #include "vxWorks.h"
  62. #include "asm.h"
  63. #include "wdb/wdbDbgLib.h"
  66. .data
  67. .globl FUNC(copyright_wind_river)
  68. .long FUNC(copyright_wind_river)
  71. /* externals */
  73. .globl FUNC(wdbDbgPreBreakpoint) /* breakpoint processing routine */
  74. .globl FUNC(wdbDbgPreTrace) /* trace processing routine */
  75. .globl  VAR(wdbDbgCtxPc) /* saved PC */
  76. .globl  VAR(wdbDbgCtxCs) /* saved CS */
  77. .globl  VAR(wdbDbgCtxEsp) /* saved ESP */
  78. .globl  VAR(sysCsSuper) /* task level CS */
  81. /* internals */
  83. .globl GTEXT(wdbDbgBpStub) /* breakpoint exceptions handler */
  84. .globl GTEXT(wdbDbgTraceStub) /* trace exceptions handler */
  85. .globl GTEXT(wdbDbgRegsSet) /* set Debug Registers */
  86. .globl GTEXT(_wdbDbgCtxLoad) /* load the new context */
  89. .text
  90. .balign 16
  92. /****************************************************************************
  93. *
  94. * wdbDbgBpStub - software breakpoint handling
  95. *
  96. * This routine is attached to the breakpoint trap (default int $3).  It
  97. * saves the entire task context on the stack and calls wdbDbgBreakpoint () to 
  98. * handle the event.
  99. *
  100. * NOMANUAL
  101. */
  103. FUNC_LABEL(wdbDbgBpStub) /* sp_1: breakpoint trap driver */
  104. pushal /* sp_2: save regs */
  105. movl %db7,%eax
  106. pushl %eax
  107. movl %db6,%eax
  108. pushl %eax
  109. movl %db3,%eax
  110. pushl %eax
  111. movl %db2,%eax
  112. pushl %eax
  113. movl %db1,%eax
  114. pushl %eax
  115. movl %db0,%eax
  116. pushl %eax
  118. movl %esp,%eax /*     : sp points to saved regs */
  119. pushl %ebp /*     : save a frame-pointer */
  120. movl %esp,%ebp /* sp_3: make a frame-pointer */
  121. decl SAVED_REGS+0x4(%ebp) /*     : adjust saved program counter */
  122. pushl $0 /*     : push FALSE is hardware break */
  123. pushl %eax /* sp_4: push pointer to saved regs */
  124. leal SAVED_REGS+0x4(%ebp),%eax
  125. pushl %eax /* sp_5: push pointer to saved info */
  126. call FUNC(wdbDbgPreBreakpoint) /*     : do breakpoint handling */
  128. /* we only return if the breakpoint was hit at interrupt level */
  130. addl $0x10,%esp /* sp_2: pop the params,frame-pointer */
  131. addl $ SAVED_DBGREGS,%esp /*     : pop saved debug registers */
  132. popal /* sp_1: restore regs */
  133. iret
  135. /**************************************************************************
  136. *
  137. * wdbDbgTraceStub - hardware breakpoint and trace exception handling
  138. *
  139. * This routine is attached to the i80x86 trace exception vector.  It saves the
  140. * entire task context on the stack and calls wdbDbgTrace () to handle the event.
  141. * This handler is for any of these situations:
  142. *     (1) Single step. Trap BS=1
  143. *     (2) Hardware instruction breakpoint. Falt Bn=1
  144. *     (3) Hardware data breakpoint. Trap Bn=1
  145. *
  146. * NOMANUAL
  147. */
  149. .balign 16,0x90
  150. FUNC_LABEL(wdbDbgTraceStub) /* sp_1: trace trap driver */
  151. andl $0xfffffeff,0x8(%esp) /* clear TraceFlag in saved EFLAGS */
  152. pushal /* sp_2: save regs */
  153. movl %db7,%eax
  154. pushl %eax
  155. movl %db6,%eax
  156. pushl %eax
  157. movl %db3,%eax
  158. pushl %eax
  159. movl %db2,%eax
  160. pushl %eax
  161. movl %db1,%eax
  162. pushl %eax
  163. movl %db0,%eax
  164. pushl %eax
  166. movl %esp,%eax /*     : sp points to saved regs */
  167. pushl %ebp /*     : save a frame-pointer */
  168. movl %esp,%ebp /* sp_3: make a frame-pointer */
  169. pushl $1 /*     : push TRUE is hardware break */
  170. pushl %eax /* sp_4: push pointer to saved regs */
  171. leal SAVED_REGS+4(%ebp),%eax
  172. pushl %eax /* sp_5: push pointer to saved info */
  174. movl %db6,%eax /* get DR6 debug status reg */
  176. movl %db6,%eax /* get DR6 debug status reg */
  177. xorl %edx,%edx
  178. movl %edx,%db7 /* clear DR7 debug control reg */
  179. movl %edx,%db6 /* clear DR6 debug status reg */
  180. movl %edx,%db3 /* clear DR3 debug reg */
  181. movl %edx,%db2 /* clear DR2 debug reg */
  182. movl %edx,%db1 /* clear DR1 debug reg */
  183. movl %edx,%db0 /* clear DR0 debug reg */
  185. btl $14,%eax /* is it a trace-exception ? */
  186. jc wdbDbgTrace0 /* if yes, jump wdbDbgTrace0 */
  187. orl $0x00010000,SAVED_REGS+12(%ebp) /* set ResumeFlag */
  188. call FUNC(wdbDbgPreBreakpoint) /* do breakpoint handling */
  189. jmp wdbDbgTrace1
  191. .balign 16,0x90
  192. wdbDbgTrace0:
  193. call FUNC(wdbDbgPreTrace) /* do trace handling */
  195. wdbDbgTrace1:
  196. /* we returned from wdbDbgTrace if this was a CONTINUE or the break
  197.  * was hit at interrupt level
  198.  */
  200. addl $0x10,%esp /* sp_2: pop the params,frame-pointer */
  201. popl %eax
  202. movl %eax,%db0
  203. popl %eax
  204. movl %eax,%db1
  205. popl %eax
  206. movl %eax,%db2
  207. popl %eax
  208. movl %eax,%db3
  209. popl %eax
  210. xorl %eax,%eax
  211. movl %eax,%db6 /* clear status bits in DR6 */
  212. popl %eax
  213. movl %eax,%db7
  214. popal /* sp_1: restore regs */
  215. iret
  217. /**************************************************************************
  218. *
  219. * wdbDbgRegsSet - set the debug registers
  220. *
  221. * This routine set hardware breakpoint registers.
  222. *
  223. * SEE ALSO: "i80x86 32-Bit Microprocessor User's Manual"
  225. * void wdbDbgRegsSet (pReg)
  226. *     int *pReg; /* pointer to saved registers *
  228. */
  230. .balign 16,0x90
  231. FUNC_LABEL(wdbDbgRegsSet)
  233. pushl %ebp
  234. movl %esp,%ebp
  236. movl ARG1(%ebp),%edx
  238. movl 0(%edx),%eax
  239. movl %eax,%db0
  240. movl 4(%edx),%eax
  241. movl %eax,%db1
  242. movl 8(%edx),%eax
  243. movl %eax,%db2
  244. movl 12(%edx),%eax
  245. movl %eax,%db3
  246. movl 16(%edx),%eax
  247. movl %eax,%db6
  248. movl 20(%edx),%eax
  249. movl %eax,%db7
  251. leave
  252. ret
  254. /*******************************************************************************
  255. *
  256. * _wdbDbgCtxLoad - Load a new context in the current task
  257. *
  258. * This is just like longjmp, but every register must be loaded.
  259. * You could also look at this as half a context switch.
  260. *
  261. * RETURNS: Never returns
  263. * void _wdbDbgCtxLoad
  264. *     (
  265. *     REG_SET * pRegs /@ Context to load @/
  266. *     )
  268. */
  270. .balign 16,0x90
  271. FUNC_LABEL(_wdbDbgCtxLoad)
  272. movl SP_ARG1(%esp),%eax
  274. movl 0x00(%eax),%edi /* load 5 registers */
  275. movl 0x04(%eax),%esi
  276. movl 0x08(%eax),%ebp
  277. movl 0x10(%eax),%ebx
  278. movl 0x18(%eax),%ecx
  280. cli /* LOCK INTERRUPTS */
  282. movl 0x0c(%eax),%esp /* load the stack pointer */
  284. pushl 0x20(%eax) /* push EFLAGS */
  286. /*
  287.  * Restoring the previous CS(code selector) is required
  288.  * to go back to the int-level context.  This happens
  289.  * when we switch back to the system from the external
  290.  * agent.  To do this, the CS should be included in the
  291.  * REG_SET.  In the mean time, the CS in the breakpoint 
  292.  * and trace exception stack frame is saved in the 
  293.  * handler and restored here.  To find the right REG_SET, 
  294.  * the saved PC(program counter) and ESP(stack pointer) 
  295.  * are compared to ones in REG_SET beforehand.
  296.  */
  298. movl 0x24(%eax),%edx /* get the PC in REG_SET */
  299. cmpl FUNC(wdbDbgCtxPc),%edx /* compare the PC */
  300. jne wdbDbgCtxLoad0 /* jump if different */
  301. movl 0x0c(%eax),%edx /* get the ESP in REG_SET */
  302. cmpl FUNC(wdbDbgCtxEsp),%edx /* compare the ESP */
  303. jne wdbDbgCtxLoad0 /* jump if different */
  305. pushl FUNC(wdbDbgCtxCs) /* push the previous CS */
  306. jmp wdbDbgCtxLoad1
  308. wdbDbgCtxLoad0:
  309. pushl FUNC(sysCsSuper) /* push the task level CS */
  311. wdbDbgCtxLoad1:
  312. pushl 0x24(%eax) /* push PC */
  314. movl 0x14(%eax),%edx /* load remaining 2 registers */
  315. movl 0x1c(%eax),%eax
  317. iret /* UNLOCK INTERRUPTS */