开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > VxWorks > 查看源码
l_srem_mod.s
资源名称：vxwork_src.rar　[点击查看]
上传用户：nvosite88
上传日期：2007-01-17
资源大小：4983k
文件大小：12k
源码类别：

VxWorks

开发平台：

C/C++

l_srem_mod.s：源码内容
  1. /* l_srem_mods.s - Motorola 68040 FP modulo/remainder routines (LIB) */
  3. /* Copyright 1991-1993 Wind River Systems, Inc. */
  4. .data
  5. .globl _copyright_wind_river
  6. .long _copyright_wind_river
  8. /*
  9. modification history
  10. --------------------
  11. 01f,21jul93,kdl  added .text (SPR #2372).
  12. 01e,23aug92,jcf  changed bxxx to jxx.
  13. 01d,26may92,rrr  the tree shuffle
  14. 01c,10jan92,kdl  added modification history; general cleanup.
  15. 01b,01jan92,jcf  reversed order of cmp <reg>,<reg>
  16. 01a,15aug91,kdl  original version, from Motorola FPSP v2.0.
  17. */
  19. /*
  20. DESCRIPTION
  22. srem_modsa 3.1 12/10/90
  24.  WIND RIVER MODIFICATION HISTORY
  26.       The entry point sMOD computes the floating point MOD of the
  27.       input values X and Y. The entry point sREM computes the floating
  28.       point (IEEE) REM of the input values X and Y.
  30.       INPUT
  31.       -----
  32.       Double-extended value Y is pointed to by address in register
  33.       A0. Double-extended value X is located in A0@(-12). The values
  34.       of X and Y are both nonzero and finite|  although either or both
  35.       of them can be denormalized. The special cases of zeros, NaNs,
  36.       and infinities are handled elsewhere.
  38.       OUTPUT
  39.       ------
  40.       FREM(X,Y) or FMOD(X,Y), depending on entry point.
  42.        ALGORITHM
  43.        ---------
  45.        Step 1.  Save and strip signs of X and Y: signX := sign(X),
  46.                 signY := sign(Y), X := |X|, Y := |Y|,
  47.                 signQ := signX EOR signY. Record whether MOD or REM
  48.                 is requested.
  50.        Step 2.  Set L := expo(X)-expo(Y), k := 0, Q := 0.
  51.                 If (L < 0) then
  52.                    R := X, go to Step 4.
  53.                 else
  54.                    R := 2^(-L)X, j := L.
  55.                 endif
  57.        Step 3.  Perform MOD(X,Y)
  58.             3.1 If R = Y, go to Step 9.
  59.             3.2 If R > Y, then { R := R - Y, Q := Q + 1}
  60.             3.3 If j = 0, go to Step 4.
  61.             3.4 k := k + 1, j := j - 1, Q := 2Q, R := 2R. Go to
  62.                 Step 3.1.
  64.        Step 4.  At this point, R = X - QY = MOD(X,Y). Set
  65.                 Last_Subtract := false (used in Step 7 below). If
  66.                 MOD is requested, go to Step 6.
  68.        Step 5.  R = MOD(X,Y), but REM(X,Y) is requested.
  69.             5.1 If R < Y/2, then R = MOD(X,Y) = REM(X,Y). Go to
  70.                 Step 6.
  71.             5.2 If R > Y/2, then { set Last_Subtract := true,
  72.                 Q := Q + 1, Y := signY*Y }. Go to Step 6.
  73.             5.3 This is the tricky case of R = Y/2. If Q is odd,
  74.                 then { Q := Q + 1, signX := -signX }.
  76.        Step 6.  R := signX*R.
  78.        Step 7.  If Last_Subtract = true, R := R - Y.
  80.        Step 8.  Return signQ, last 7 bits of Q, and R as required.
  82.        Step 9.  At this point, R = 2^(-j)*X - Q Y = Y. Thus,
  83.                 X = 2^(j)*(Q+1)Y. set Q := 2^(j)*(Q+1),
  84.                 R := 0. Return signQ, last 7 bits of Q, and R.
  88. Copyright (C) Motorola, Inc. 1990
  89. All Rights Reserved
  91. THIS IS UNPUBLISHED PROPRIETARY SOURCE CODE OF MOTOROLA
  92. The copyright notice above does not evidence any
  93. actual or intended publication of such source code.
  95. SREM_MOD    idnt    2,1 Motorola 040 Floating Point Software Package
  97. section    8
  99. NOMANUAL
  100. */
  102. #include "fpsp040L.h"
  104. #define Mod_Flag   L_SCR3
  105. #define SignY      FP_SCR3+4
  106. #define SignX      FP_SCR3+8
  107. #define SignQ      FP_SCR3+12
  108. #define Sc_Flag    FP_SCR4
  110. #define Y          FP_SCR1
  111. #define Y_Hi       Y+4
  112. #define Y_Lo       Y+8
  114. #define R          FP_SCR2
  115. #define R_Hi       R+4
  116. #define R_Lo       R+8
  119. Scale:     .long 0x00010000,0x80000000,0x00000000,0x00000000
  121. | xref __l_t_avoid_unsupp
  124. .text
  126.         .globl        __l_smod
  127. __l_smod:
  129.    movel               #0,a6@(Mod_Flag)
  130.    jra                 Mod_Rem
  132.         .globl        __l_srem
  133. __l_srem:
  135.    movel               #1,a6@(Mod_Flag)
  137. Mod_Rem:
  138. |..Save sign of X and Y
  139.    moveml              d2-d7,A7@-     |...save data registers
  140.    movew               A0@,d3
  141.    movew               d3,a6@(SignY)
  142.    andil               #0x00007FFF,d3   |...Y := |Y|
  144. |
  145.    movel               A0@(4),d4
  146.    movel               A0@(8),d5        |...(D3,d4,d5) is |Y|
  148.    tstl                d3
  149.    jne                 Y_Normal
  151.    movel               #0x00003FFE,d3 |...0x3FFD + 1
  152.    tstl                d4
  153.    jne                 HiY_not0
  155. HiY_0:
  156.    movel               d5,d4
  157.    clrl                d5
  158.    subil               #32,d3
  159.    clrl                d6
  160.    bfffo                d4{#0:#32},d6
  161.    lsll                d6,d4
  162.    subl                d6,d3           |...(D3,d4,d5) is normalized
  163. |                                       |...with bias 0x7FFD
  164.    jra                 Chk_X
  166. HiY_not0:
  167.    clrl                d6
  168.    bfffo                d4{#0:#32},d6
  169.    subl                d6,d3
  170.    lsll                d6,d4
  171.    movel               d5,d7           |...a copy of d5
  172.    lsll                d6,d5
  173.    negl                d6
  174.    addil               #32,d6
  175.    lsrl                d6,d7
  176.    orl                 d7,d4           |...(D3,d4,d5) normalized
  177. |                                       |...with bias 0x7FFD
  178.    jra                 Chk_X
  180. Y_Normal:
  181.    addil               #0x00003FFE,d3   |...(D3,d4,d5) normalized
  182. |                                       |...with bias 0x7FFD
  184. Chk_X:
  185.    movew               A0@(-12),d0
  186.    movew               d0,a6@(SignX)
  187.    movew               a6@(SignY),d1
  188.    eorl                d0,d1
  189.    andil               #0x00008000,d1
  190.    movew               d1,a6@(SignQ) |...sign(Q) obtained
  191.    andil               #0x00007FFF,d0
  192.    movel               A0@(-8),d1
  193.    movel               A0@(-4),d2       |...(D0,d1,d2) is |X|
  194.    tstl                d0
  195.    jne                 X_Normal
  196.    movel               #0x00003FFE,d0
  197.    tstl                d1
  198.    jne                 HiX_not0
  200. HiX_0:
  201.    movel               d2,d1
  202.    clrl                d2
  203.    subil               #32,d0
  204.    clrl                d6
  205.    bfffo                d1{#0:#32},d6
  206.    lsll                d6,d1
  207.    subl                d6,d0           |...(D0,d1,d2) is normalized
  208. |                                       |...with bias 0x7FFD
  209.    jra                 Init
  211. HiX_not0:
  212.    clrl                d6
  213.    bfffo                d1{#0:#32},d6
  214.    subl                d6,d0
  215.    lsll                d6,d1
  216.    movel               d2,d7           |...a copy of d2
  217.    lsll                d6,d2
  218.    negl                d6
  219.    addil               #32,d6
  220.    lsrl                d6,d7
  221.    orl                 d7,d1           |...(D0,d1,d2) normalized
  222. |                                       |...with bias 0x7FFD
  223.    jra                 Init
  225. X_Normal:
  226.    addil               #0x00003FFE,d0   |...(D0,d1,d2) normalized
  227. |                                       |...with bias 0x7FFD
  229. Init:
  230. |
  231.    movel               d3,a6@(L_SCR1)   |...save biased expo(Y)
  232.    movel d0,a6@(L_SCR2) | save d0
  233.    subl                d3,d0           |...l := expo(X)-expo(Y)
  234. |   Movel               D0,L            |...D0 is j
  235.    clrl                d6              |...D6 := carry <- 0
  236.    clrl                d3              |...D3 is Q
  237.    moveal              #0,a1           |...A1 is k|  j+k=L, Q=0
  239. |..(Carry,D1,D2) is R
  240.    tstl                d0
  241.    jge                 Mod_Loop
  243. |..expo(X) < expo(Y). Thus X = mod(X,Y)
  244. |
  245.    movel a6@(L_SCR2),d0 | restore d0
  246.    jra                 Get_Mod
  248. |..At this point  R = 2^(-L)X|  Q = 0|  k = 0|  and  k+j = L
  251. Mod_Loop:
  252.    tstl                d6              |...test carry bit
  253.    jgt                 R_GT_Y
  255. |..At this point carry = 0, R = (D1,D2), Y = (D4,D5)
  256.    cmpl                d1,d4           |...compare hi(R) and hi(Y)
  257.    jne                 R_NE_Y
  258.    cmpl                d2,d5           |...compare lo(R) and lo(Y)
  259.    jne                 R_NE_Y
  261. |..At this point, R = Y
  262.    jra                 Rem_is_0
  264. R_NE_Y:
  265. |..use the borrow of the previous compare
  266.    jcs                 R_LT_Y          |...borrow is set iff R < Y
  268. R_GT_Y:
  269. |..If Carry is set, then Y < (Carry,D1,D2) < 2Y. Otherwise, Carry = 0
  270. |..and Y < (D1,D2) < 2Y. Either way, perform R - Y
  271.    subl                d5,d2           |...lo(R) - lo(Y)
  272.    subxl               d4,d1           |...hi(R) - hi(Y)
  273.    clrl                d6              |...clear carry
  274.    addql               #1,d3           |...Q := Q + 1
  276. R_LT_Y:
  277. |..At this point, Carry=0, R < Y. R = 2^(k-L)X - QY|  k+j = L|  j >= 0.
  278.    tstl                d0              |...see if j = 0.
  279.    jeq                 PostLoop
  281.    addl                d3,d3           |...Q := 2Q
  282.    addl                d2,d2           |...lo(R) = 2lo(R)
  283.    roxll               #1,d1           |...hi(R) = 2hi(R) + carry
  284.    scs                 d6              |...set Carry if 2(R) overflows
  285.    addql               #1,a1           |...k := k+1
  286.    subql               #1,d0           |...j := j - 1
  287. |..At this point, R=(Carry,D1,D2) = 2^(k-L)X - QY, j+k=L, j >= 0, R < 2Y.
  289.    jra                 Mod_Loop
  291. PostLoop:
  292. |..k = L, j = 0, Carry = 0, R = (D1,D2) = X - QY, R < Y.
  294. |..normalize R.
  295.    movel               a6@(L_SCR1),d0           |...new biased expo of R
  296.    tstl                d1
  297.    jne                 HiR_not0
  299. HiR_0:
  300.    movel               d2,d1
  301.    clrl                d2
  302.    subil               #32,d0
  303.    clrl                d6
  304.    bfffo                d1{#0:#32},d6
  305.    lsll                d6,d1
  306.    subl                d6,d0           |...(D0,d1,d2) is normalized
  307. |                                       |...with bias 0x7FFD
  308.    jra                 Get_Mod
  310. HiR_not0:
  311.    clrl                d6
  312.    bfffo                d1{#0:#32},d6
  313.    jmi                 Get_Mod         |...already normalized
  314.    subl                d6,d0
  315.    lsll                d6,d1
  316.    movel               d2,d7           |...a copy of d2
  317.    lsll                d6,d2
  318.    negl                d6
  319.    addil               #32,d6
  320.    lsrl                d6,d7
  321.    orl                 d7,d1           |...(D0,d1,d2) normalized
  323. |
  324. Get_Mod:
  325.    cmpil #0x000041FE,d0
  326.    jge  No_Scale
  327. Do_Scale:
  328.    movew d0,a6@(R)
  329.    clrw a6@(R+2)
  330.    movel d1,a6@(R_Hi)
  331.    movel d2,a6@(R_Lo)
  332.    movel a6@(L_SCR1),d6
  333.    movew d6,a6@(Y)
  334.    clrw a6@(Y+2)
  335.    movel d4,a6@(Y_Hi)
  336.    movel d5,a6@(Y_Lo)
  337.    fmovex a6@(R),fp0 |...no exception
  338.    movel #1,a6@(Sc_Flag)
  339.    jra  ModOrRem
  340. No_Scale:
  341.    movel d1,a6@(R_Hi)
  342.    movel d2,a6@(R_Lo)
  343.    subil #0x3FFE,d0
  344.    movew d0,a6@(R)
  345.    clrw a6@(R+2)
  346.    movel a6@(L_SCR1),d6
  347.    subil #0x3FFE,d6
  348.    movel d6,a6@(L_SCR1)
  349.    fmovex a6@(R),fp0
  350.    movew d6,a6@(Y)
  351.    movel d4,a6@(Y_Hi)
  352.    movel d5,a6@(Y_Lo)
  353.    movel #0,a6@(Sc_Flag)
  355. |
  358. ModOrRem:
  359.    movel               a6@(Mod_Flag),d6
  360.    jeq                 Fix_Sign
  362.    movel               a6@(L_SCR1),d6           |...new biased expo(Y)
  363.    subql               #1,d6           |...biased expo(Y/2)
  364.    cmpl                d0,d6
  365.    jlt                 Fix_Sign
  366.    jgt                 Last_Sub
  368.    cmpl                d1,d4
  369.    jne                 Not_EQ
  370.    cmpl                d2,d5
  371.    jne                 Not_EQ
  372.    jra                 Tie_Case
  374. Not_EQ:
  375.    jcs                 Fix_Sign
  377. Last_Sub:
  378. |
  379.    fsubx a6@(Y),fp0 |...no exceptions
  380.    addql               #1,d3           |...Q := Q + 1
  382. |
  384. Fix_Sign:
  385. |..Get sign of X
  386.    movew               a6@(SignX),d6
  387.    jge  Get_Q
  388.    fnegx fp0
  390. |..Get Q
  391. |
  392. Get_Q:
  393.    clrl d6
  394.    movew               a6@(SignQ),d6        |...D6 is sign(Q)
  395.    movel               #8,d7
  396.    lsrl                d7,d6
  397.    andil               #0x0000007F,d3   |...7 bits of Q
  398.    orl                 d6,d3           |...sign and bits of Q
  399.    swap                 d3
  400.    fmovel              fpsr,d6
  401.    andil               #0xFF00FFFF,d6
  402.    orl                 d3,d6
  403.    fmovel              d6,fpsr         |...put Q in fpsr
  405. |
  406. Restore:
  407.    moveml              A7@+,d2-d7
  408.    fmovel              a6@(USER_FPCR),fpcr
  409.    movel               a6@(Sc_Flag),d0
  410.    jeq                 Finish
  411.    fmulx pc@(Scale),fp0 |...may cause underflow
  412.    jra  __l_t_avoid_unsupp | check for denorm as a
  413. | | result of the scaling
  415. Finish:
  416. fmovex fp0,fp0 | capture exceptions # round
  417. rts
  419. Rem_is_0:
  420. |..R = 2^(-j)X - Q Y = Y, thus R = 0 and quotient = 2^j (Q+1)
  421.    addql               #1,d3
  422.    cmpil               #8,d0           |...D0 is j
  423.    jge                 Q_Big
  425.    lsll                d0,d3
  426.    jra                 Set_R_0
  428. Q_Big:
  429.    clrl                d3
  431. Set_R_0:
  432.    .long 0xf23c4400,0x00000000  /* fmoves &0x00000000,fp0 */
  433.    movel #0,a6@(Sc_Flag)
  434.    jra                 Fix_Sign
  436. Tie_Case:
  437. |..Check parity of Q
  438.    movel               d3,d6
  439.    andil               #0x00000001,d6
  440.    tstl                d6
  441.    jeq                 Fix_Sign |...Q is even
  443. |..Q is odd, Q := Q + 1, signX := -signX
  444.    addql               #1,d3
  445.    movew               a6@(SignX),d6
  446.    eoril               #0x00008000,d6
  447.    movew               d6,a6@(SignX)
  448.    jra                 Fix_Sign
  450. |   end