开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > VxWorks > 查看源码
gen_except.s
资源名称：vxwork_src.rar　[点击查看]
上传用户：nvosite88
上传日期：2007-01-17
资源大小：4983k
文件大小：14k
源码类别：

VxWorks

开发平台：

C/C++

gen_except.s：源码内容
  1. /* gen_except.s - Motorola 68040 FP exception detection (EXC) */
  3. /* Copyright 1991-1993 Wind River Systems, Inc. */
  4. .data
  5. .globl _copyright_wind_river
  6. .long _copyright_wind_river
  8. /*
  9. modification history
  10. --------------------
  11. 01g,21jul93,kdl  added .text (SPR #2372).
  12. 01f,23aug92,jcf  changed bxxx to jxx.
  13. 01e,20aug92,kdl  put in changes from Motorola v3.7 (from FPSP 2.2):
  14.  added workaround for hardware bug #1384.
  15. 01d,26may92,rrr  the tree shuffle
  16. 01c,10jan92,kdl  added modification history; general cleanup.
  17. 01b,16dec91,kdl  put in changes from Motorola v3.6 (from FPSP 2.1):
  18.  add translation of CMDREG1B to CMDREG3B; add check
  19.  for new version number in unimp frame.
  20. 01a,15aug91,kdl  original version, from Motorola FPSP v2.0; added
  21.  missing comment symbols.
  22. */
  24. /*
  25. DESCRIPTION
  28. gen_exceptsa 3.4 4/26/91
  31. __x_gen_except --- FPSP routine to detect reportable exceptions
  33. This routine compares the exception enable byte of the
  34. user_fpcr on the stack with the exception status byte
  35. of the user_fpsr.
  37. Any routine which may report an exceptions must load
  38. the stack frame in memory with the exceptional operand(s).
  40. Priority for exceptions is:
  42. Highest: bsun
  43. snan
  44. operr
  45. ovfl
  46. unfl
  47. dz
  48. inex2
  49. Lowest: inex1
  51. Note: The IEEE standard specifies that inex2 is to be
  52. reported if ovfl occurs and the ovfl enable bit is not
  53. set but the inex2 enable bit is.
  56. Copyright (C) Motorola, Inc. 1990
  57. All Rights Reserved
  59. THIS IS UNPUBLISHED PROPRIETARY SOURCE CODE OF MOTOROLA
  60. The copyright notice above does not evidence any
  61. actual or intended publication of such source code.
  63. GEN_EXCEPT    idnt    2,1 Motorola 040 Floating Point Software Package
  65. section 8
  67. NOMANUAL
  68. */
  70. #include "fpsp040E.h"
  72. | xref __x_real_trace
  73. | xref __x_fpsp_done
  74. | xref __x_fpsp_fmt_error
  76. exc_tbl:
  77. .long __x_bsun_exc
  78. .long commonE1
  79. .long commonE1
  80. .long __x_ovfl_unfl
  81. .long __x_ovfl_unfl
  82. .long commonE1
  83. .long commonE3
  84. .long commonE3
  85. .long no_match
  87. .globl __x_gen_except
  89. .text
  91. __x_gen_except:
  92. cmpib #IDLE_SIZE-4,a7@(1) | test for idle frame
  93. jeq  do_check | go handle idle frame
  94. cmpib #UNIMP_40_SIZE-4,a7@(1) | test for orig unimp frame
  95. jeq  unimp_x | go handle unimp frame
  96. cmpib #UNIMP_41_SIZE-4,a7@(1) | test for rev unimp frame
  97. jeq  unimp_x | go handle unimp frame
  98. cmpib #BUSY_SIZE-4,a7@(1) | if size <> 0x60, fmt error
  99. jne  __x_fpsp_fmt_error
  100. lea a7@(BUSY_SIZE+LOCAL_SIZE),a1 | init a1 so fpsp040E.h
  101. | | equates will work
  102. | Fix up the new busy frame with entries from the unimp frame
  103. |
  104. movel a6@(ETEMP_EX),a1@(ETEMP_EX)  | copy etemp from unimp
  105. movel a6@(ETEMP_HI),a1@(ETEMP_HI)  | frame to busy frame
  106. movel a6@(ETEMP_LO),a1@(ETEMP_LO)
  107. movel a6@(CMDREG1B),a1@(CMDREG1B)  | set inst in frame to unimp
  108. movel a6@(CMDREG1B),d0 | fix cmd1b to make it
  109. andl #0x03c30000,d0 | work for cmd3b
  110. bfextu a6@(CMDREG1B){#13:#1},d1 | extract bit 2
  111. lsll #5,d1
  112. swap d1
  113. orl d1,d0 | put it in the right place
  114. bfextu a6@(CMDREG1B){#10:#3},d1 | extract bit 3,4,5
  115. lsll #2,d1
  116. swap d1
  117. orl d1,d0 | put them in the right place
  118. movel d0,a1@(CMDREG3B) | in the busy frame
  119. |
  120. | Or in the FPSR from the emulation with the USER_FPSR on the stack.
  121. |
  122. fmovel FPSR,d0
  123. orl d0,a6@(USER_FPSR)
  124. movel a6@(USER_FPSR),a1@(FPSR_SHADOW) | set exc bits
  125. orl #sx_mask,a1@(E_BYTE)
  126. jra  do_clean
  128. |
  129. | Frame is an unimp frame possible resulting from an fmovel <ea>,fp0
  130. | that caused an exception
  131. |
  132. | a1 is modified to point into the new frame allowing fpsp equates
  133. | to be valid.
  134. |
  135. unimp_x:
  136. cmpib #UNIMP_40_SIZE-4,a7@(1) | test for orig unimp frame
  137. jne  test_rev
  138. lea a7@(UNIMP_40_SIZE+LOCAL_SIZE),a1
  139. jra  unimp_con
  140. test_rev:
  141. cmpib #UNIMP_41_SIZE-4,a7@(1) | test for rev unimp frame
  142. jne  __x_fpsp_fmt_error | if not 0x28 or 0x30
  143. lea a7@(UNIMP_41_SIZE+LOCAL_SIZE),a1
  145. unimp_con:
  146. |
  147. | Fix up the new unimp frame with entries from the old unimp frame
  148. |
  149. movel a6@(CMDREG1B),a1@(CMDREG1B)  | set inst in frame to unimp
  150. |
  151. | Or in the FPSR from the emulation with the USER_FPSR on the stack.
  152. |
  153. fmovel FPSR,d0
  154. orl d0,a6@(USER_FPSR)
  155. jra  do_clean
  157. |
  158. | Frame is idle, so check for exceptions reported through
  159. | USER_FPSR and set the unimp frame accordingly.
  160. | A7 must be incremented to the point before the
  161. | idle fsave vector to the unimp vector.
  162. |
  164. do_check:
  165. addl #4,a7 | point a7 back to unimp frame
  166. |
  167. | Or in the FPSR from the emulation with the USER_FPSR on the stack.
  168. |
  169. fmovel FPSR,d0
  170. orl d0,a6@(USER_FPSR)
  171. |
  172. | On a busy frame, we must clear the nmnexc bits.
  173. |
  174. cmpib #BUSY_SIZE-4,a7@(1) | check frame type
  175. jne  check_fr | if busy, clr nmnexc
  176. clrw a6@(NMNEXC) | clr nmnexc # nmcexc
  177. btst #5,a6@(CMDREG1B) | test for fmovel out
  178. jne  frame_com
  179. movel a6@(USER_FPSR),a6@(FPSR_SHADOW) | set exc bits
  180. orl #sx_mask,a6@(E_BYTE)
  181. jra  frame_com
  183. check_fr:
  184. cmpb #UNIMP_40_SIZE-4,a7@(1)
  185. jeq  frame_com
  186. clrw a6@(NMNEXC)
  187. frame_com:
  188. moveb a6@(fpcr_ENABLE),d0 | get fpcr enable byte
  189. andb a6@(FPSR_EXCEPT),d0 | and in the fpsr exc byte
  190. bfffo d0{#24:#8},d1 | test for first set bit
  191. lea exc_tbl,a0 | load jmp table address
  192. subib #24,d1 | normalize bit offset to 0-8
  193. movel a0@(d1:w:4),a0 | load routine address based
  194. | | based on first enabled exc
  195. jmp a0@ | jump to routine
  196. |
  197. | Bsun is not possible in unimp or unsupp
  198. |
  199. __x_bsun_exc:
  200. jra  do_clean
  201. |
  202. | The typical work to be done to the unimp frame to report an
  203. | exception is to set the E1/E3 byte and clr the U flag.
  204. | commonE1 does this for E1 exceptions, which are snan,
  205. | operr, and dz.  commonE3 does this for E3 exceptions, which
  206. | are inex2 and inex1, and also clears the E1 exception bit
  207. | left over from the unimp exception.
  208. |
  209. commonE1:
  210. bset #E1,a6@(E_BYTE) | set E1 flag
  211. jra  commonE | go clean and exit
  213. commonE3:
  214. tstb a6@(UFLG_TMP) | test flag for unsup/unimp state
  215. jne  unsE3
  216. uniE3:
  217. bset #E3,a6@(E_BYTE) | set E3 flag
  218. bclr #E1,a6@(E_BYTE) | clr E1 from unimp
  219. jra  commonE
  221. unsE3:
  222. tstb a6@(RES_FLG)
  223. jne  unsE3_0
  224. unsE3_1:
  225. bset #E3,a6@(E_BYTE) | set E3 flag
  226. unsE3_0:
  227. bclr #E1,a6@(E_BYTE) | clr E1 flag
  228. movel a6@(CMDREG1B),d0
  229. andl #0x03c30000,d0 | work for cmd3b
  230. bfextu a6@(CMDREG1B){#13:#1},d1 | extract bit 2
  231. lsll #5,d1
  232. swap d1
  233. orl d1,d0 | put it in the right place
  234. bfextu a6@(CMDREG1B){#10:#3},d1 | extract bit 3,4,5
  235. lsll #2,d1
  236. swap d1
  237. orl d1,d0 | put them in the right place
  238. movel d0,a6@(CMDREG3B) | in the busy frame
  240. commonE:
  241. bclr #UFLAG,a6@(T_BYTE) | clr U flag from unimp
  242. jra  do_clean | go clean and exit
  243. |
  244. | No bits in the enable byte match existing exceptions.  Check for
  245. | the case of the ovfl exc without the ovfl enabled, but with
  246. | inex2 enabled.
  247. |
  248. no_match:
  249. btst #__x_inex2_bit,a6@(fpcr_ENABLE) | check for ovfl/inex2 case
  250. jeq  no_exc | if clear, exit
  251. btst #__x_ovfl_bit,a6@(FPSR_EXCEPT)  | now check ovfl
  252. jeq  no_exc | if clear, exit
  253. jra  __x_ovfl_unfl | go to __x_unfl_ovfl to determine if
  254. | | it is an unsupp or unimp exc
  256. | No exceptions are to be reported.  If the instruction was
  257. | unimplemented, no FPU restore is necessary.  If it was
  258. | unsupported, we must perform the restore.
  259. no_exc:
  260. tstb a6@(UFLG_TMP) | test flag for unsupp/unimp state
  261. jeq  uni_no_exc
  262. uns_no_exc:
  263. tstb a6@(RES_FLG) | check if frestore is needed
  264. jne  do_clean  | if clear, no frestore needed
  265. uni_no_exc:
  266. moveml a6@(USER_DA),d0-d1/a0-a1
  267. fmovemx a6@(USER_FP0),fp0-fp3
  268. fmoveml a6@(USER_FPCR),fpcr/fpsr/fpi
  269. unlk a6
  270. jra  finish_up
  271. |
  272. | Unsupported Data Type Handler:
  273. | Ovfl:
  274. |   An fmoveout that results in an overflow is reported this way.
  275. | Unfl:
  276. |   An fmoveout that results in an underflow is reported this way.
  277. |
  278. | Unimplemented Instruction Handler:
  279. | Ovfl:
  280. |   Only scosh, setox, ssinh, stwotox, and scale can set overflow in
  281. |   this manner.
  282. | Unfl:
  283. |   Stwotox, setox, and scale can set underflow in this manner.
  284. |   Any of the other Library Routines such that f(x)=x in which
  285. |   x is an extended denorm can report an underflow exception.
  286. |   It is the responsibility of the exception-causing exception
  287. |   to make sure that WBTEMP is correct.
  288. |
  289. |   The exceptional operand is in FP_SCR1.
  290. |
  291. __x_ovfl_unfl:
  292. tstb a6@(UFLG_TMP) | test flag for unsupp/unimp state
  293. jeq  ofuf_con
  294. |
  295. | The caller was from an unsupported data type trap.  Test if the
  296. | caller set CU_ONLY.  If so, the exceptional operand is expected in
  297. | FPTEMP, rather than WBTEMP.
  298. |
  299. tstb a6@(CU_ONLY) | test if inst is cu-only
  300. jeq  unsE3
  301. | movew #0xfe,a6@(CU_SAVEPC)
  302. clrb a6@(CU_SAVEPC)
  303. bset #E1,a6@(E_BYTE) | set E1 exception flag
  304. movew a6@(ETEMP_EX),a6@(FPTEMP_EX)
  305. movel a6@(ETEMP_HI),a6@(FPTEMP_HI)
  306. movel a6@(ETEMP_LO),a6@(FPTEMP_LO)
  307. bset #fptemp15_bit,a6@(DTAG) | set fpte15
  308. bclr #UFLAG,a6@(T_BYTE) | clr U flag from unimp
  309. jra  do_clean | go clean and exit
  311. ofuf_con:
  312. moveb a7@,a6@(VER_TMP) | save version number
  313. cmpib #BUSY_SIZE-4,a7@(1) | check for busy frame
  314. jeq  busy_fr | if unimp, grow to busy
  315. cmpib #VER_40,a7@ | test for orig unimp frame
  316. jne  try_41 | if not, test for rev frame
  317. moveql #13,d0 | need to zero 14 lwords
  318. jra  ofuf_fin
  319. try_41:
  320. cmpib #VER_41,a7@ | test for rev unimp frame
  321. jne  __x_fpsp_fmt_error | if neither, exit with error
  322. moveql #11,d0 | need to zero 12 lwords
  324. ofuf_fin:
  325. clrl a7@
  326. loop1:
  327. clrl a7@- | clear and dec a7
  328. dbra d0,loop1
  329. moveb a6@(VER_TMP),a7@
  330. moveb #BUSY_SIZE-4,a7@(1) | write busy fmt word.
  331. busy_fr:
  332. movel a6@(FP_SCR1),a6@(WBTEMP_EX) | write
  333. movel a6@(FP_SCR1+4),a6@(WBTEMP_HI) | execptional op to
  334. movel a6@(FP_SCR1+8),a6@(WBTEMP_LO) | wbtemp
  335. bset #E3,a6@(E_BYTE) | set E3 flag
  336. bclr #E1,a6@(E_BYTE) | make sure E1 is clear
  337. bclr #UFLAG,a6@(T_BYTE) | clr U flag
  338. movel a6@(USER_FPSR),a6@(FPSR_SHADOW)
  339. orl #sx_mask,a6@(E_BYTE)
  340. movel a6@(CMDREG1B),d0 | fix cmd1b to make it
  341. andl #0x03c30000,d0 | work for cmd3b
  342. bfextu a6@(CMDREG1B){#13:#1},d1 | extract bit 2
  343. lsll #5,d1
  344. swap d1
  345. orl d1,d0 | put it in the right place
  346. bfextu a6@(CMDREG1B){#10:#3},d1 | extract bit 3,4,5
  347. lsll #2,d1
  348. swap d1
  349. orl d1,d0 | put them in the right place
  350. movel d0,a6@(CMDREG3B) | in the busy frame
  352. |
  353. | Check if the frame to be restored is busy or unimp.
  354. |** NOTE *** Bug fix for errata (0d43b #3)
  355. | If the frame is unimp, we must create a busy frame to
  356. | fix the bug with the nmnexc bits in cases in which they
  357. | are set by a previous instruction and not cleared by
  358. | the save. The frame will be unimp only if the final
  359. | instruction in an emulation routine caused the exception
  360. | by doing an fmovel <ea>,fp0.  The exception operand, in
  361. | internal format, is in fptemp.
  362. |
  363. do_clean:
  364. cmpib #UNIMP_40_SIZE-4,a7@(1)
  365. jne  do_con
  366. moveql #13,d0 | in orig, need to zero 14 lwords
  367. jra  do_build
  368. do_con:
  369. cmpib #UNIMP_41_SIZE-4,a7@(1)
  370. jne  do_restore | frame must be busy
  371. moveql #11,d0 | in rev, need to zero 12 lwords
  373. do_build:
  374. moveb a7@,a6@(VER_TMP)
  375. clrl a7@
  376. loop2:
  377. clrl a7@- | clear and dec a7
  378. dbra d0,loop2
  379. |
  380. | Use a1 as pointer into new frame.  a6 is not correct if an unimp or
  381. | busy frame was created as the result of an exception on the final
  382. | instruction of an emulation routine.
  383. |
  384. | We need to set the nmcexc bits if the exception is E1. Otherwise,
  385. | the exc taken will be inex2.
  386. |
  387. lea a7@(BUSY_SIZE+LOCAL_SIZE),a1 | init a1 for new frame
  388. moveb a6@(VER_TMP),a7@ | write busy fmt word
  389. moveb #BUSY_SIZE-4,a7@(1)
  390. movel a6@(FP_SCR1),a1@(WBTEMP_EX)  | write
  391. movel a6@(FP_SCR1+4),a1@(WBTEMP_HI) | exceptional op to
  392. movel a6@(FP_SCR1+8),a1@(WBTEMP_LO) | wbtemp
  393. | btst #E1,a1@(E_BYTE)
  394. | jeq  do_restore
  395. bfextu a6@(USER_FPSR){#17:#4},d0 | get snan/operr/ovfl/unfl bits
  396. bfins d0,a1@(NMCEXC){#4:#4} | and insert them in nmcexc
  397. movel a6@(USER_FPSR),a1@(FPSR_SHADOW) | set exc bits
  398. orl #sx_mask,a1@(E_BYTE)
  400. do_restore:
  401. moveml a6@(USER_DA),d0-d1/a0-a1
  402. fmovemx a6@(USER_FP0),fp0-fp3
  403. fmoveml a6@(USER_FPCR),fpcr/fpsr/fpi
  404. frestore a7@+
  405. tstb a6@(RES_FLG) | RES_FLG indicates a "continuation" frame
  406. jeq  cont
  407. bsrl bug1384
  408. cont:
  409. unlk a6
  410. |
  411. | If trace mode enabled, then go to trace handler.  This handler
  412. /* | cannot have any fp instructions.  If there are fp inst's and an  */
  413. | exception has been restored into the machine then the exception
  414. | will occur upon execution of the fp inst.  This is not desirable
  415. | in the kernel (supervisor mode).  See MC68040 manual Section 9.3.8.
  416. |
  417. finish_up:
  418. btst #7,a7@ | test T1 in SR
  419. jne  g_trace
  420. btst #6,a7@ | test T0 in SR
  421. jne  g_trace
  422. jra  __x_fpsp_done
  423. |
  424. | Change integer stack to look like trace stack
  425. | The address of the instruction that caused the
  426. | exception is already in the integer stack (is
  427. | the same as the saved friar)
  428. |
  429. | If the current frame is already a 6-word stack then all
  430. | that needs to be done is to change the vector# to TRACE.
  431. | If the frame is only a 4-word stack (meaning we got here
  432. | on an Unsupported data type exception), then we need to grow
  433. | the stack an extra 2 words and get the fpi from the FPU.
  434. |
  435. g_trace:
  436. bftst a7@(EXC_VEC-4){#0:#4}
  437. jne  g_easy
  439. subw #4,sp |  make room
  440. movel a7@(4),a7@
  441. movel a7@(8),a7@(4)
  442. subw #BUSY_SIZE,sp
  443. fsave a7@
  444. fmovel fpi,a7@(BUSY_SIZE+EXC_EA-4)
  445. frestore a7@
  446. addw #BUSY_SIZE,sp
  448. g_easy:
  449. movew #TRACE_VEC,a7@(EXC_VEC-4)
  450. jra  __x_real_trace
  451. |
  452. |
  453. |  This is a work-around for hardware bug 1384.
  454. |
  455. bug1384:
  456. link a5,#0
  457. fsave a7@-
  458. cmpib #0x41,a7@ |  check for correct frame
  459. jeq  frame_41
  460. jgt  nofix |  if more advanced mask, do nada
  462. frame_40:
  463. tstb a7@(1) |  check to see if idle
  464. jne  notidle
  465. idle40:
  466. clrl a7@ |  get rid of old fsave frame
  467.         movel  d1,a6@(USER_D1)  |  save d1
  468. movew #8,d1 |  place unimp frame instead
  469. loop40: clrl a7@-
  470. dbra d1,loop40
  471.         movel  a6@(USER_D1),d1  |  restore d1
  472. movel #0x40280000,a7@-
  473. frestore a7@+
  474. unlk   a5
  475. rts
  477. frame_41:
  478. tstb a7@(1) |  check to see if idle
  479. jne  notidle
  480. idle41:
  481. clrl a7@ |  get rid of old fsave frame
  482.         movel  d1,a6@(USER_D1)  |  save d1
  483. movew #10,d1 |  place unimp frame instead
  484. loop41: clrl a7@-
  485. dbra d1,loop41
  486.         movel  a6@(USER_D1),d1  |  restore d1
  487. movel #0x41300000,a7@-
  488. frestore a7@+
  489. unlk a5
  490. rts
  492. notidle:
  493. bclr #etemp15_bit,a5@(-40) 
  494. frestore a7@+
  495. unlk a5
  496. rts
  498. nofix:
  499. frestore a7@+
  500. unlk a5
  501. rts
  503. | end