开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > VxWorks > 查看源码
scale.s
资源名称：vxwork_src.rar　[点击查看]
上传用户：nvosite88
上传日期：2007-01-17
资源大小：4983k
文件大小：10k
源码类别：

VxWorks

开发平台：

C/C++

scale.s：源码内容
  1. /* scale.s - Motorola 68040 FP scaling routines (EXC) */
  3. /* Copyright 1991-1993 Wind River Systems, Inc. */
  4. .data
  5. .globl _copyright_wind_river
  6. .long _copyright_wind_river
  8. /*
  9. modification history
  10. --------------------
  11. 01f,21jul93,kdl  added .text (SPR #2372).
  12. 01e,23aug92,jcf  changed bxxx to jxx.
  13. 01d,26may92,rrr  the tree shuffle
  14. 01c,10jan92,kdl  added modification history; general cleanup.
  15. 01b,30dec91,kdl  put in changes from Motorola v3.3 (FPSP v2.1):
  16.    clear the exceptional operand for zero underflow.
  17. 01a,15aug91,kdl  original version, from Motorola FPSP v2.0.
  18. */
  20. /*
  21. DESCRIPTION
  23. scalesa 3.2 2/18/91
  25. The entry point sSCALE computes the destination operand
  26. scaled by the source operand.  If the absoulute value of
  27. the source operand is (>= 2^14) an overflow or underflow
  28. is returned.
  30. The entry point __x_sscale is called from __x_do_func to emulate
  31. the fscale unimplemented instruction.
  33. Input: Double-extended destination operand in FPTEMP,
  34. double-extended source operand in ETEMP.
  36. Output: The function returns scale(X,Y) to fp0.
  38. Modifies: fp0.
  40. Algorithm:
  42. Copyright (C) Motorola, Inc. 1990
  43. All Rights Reserved
  45. THIS IS UNPUBLISHED PROPRIETARY SOURCE CODE OF MOTOROLA
  46. The copyright notice above does not evidence any
  47. actual or intended publication of such source code.
  49. SCALE    idnt    2,1 Motorola 040 Floating Point Software Package
  51. section 8
  53. NOMANUAL
  54. */
  56. #include "fpsp040E.h"
  58. | xref __x_t_ovfl2
  59. | xref __x_t_unfl
  60. | xref __x_round
  61. | xref __x_t_resdnrm
  63. SRC_BNDS: .word 0x3fff,0x400c
  65. |
  66. | This entry point is used by the unimplemented instruction exception
  67. | handler.
  68. |
  69. |
  70. |
  71. | FSCALE
  72. |
  74. .text
  76. .globl __x_sscale
  77. __x_sscale:
  78. fmovel #0,fpcr | clr user enabled exc
  79. clrl d1
  80. movew a6@(FPTEMP),d1 | get dest exponent
  81. smi a6@(L_SCR1) | use L_SCR1 to hold sign
  82. andil #0x7fff,d1 | strip sign
  83. movew a6@(ETEMP),d0 | check src bounds
  84. andiw #0x7fff,d0 | clr sign bit
  85. cmp2w SRC_BNDS,d0
  86. jcc  src_in
  87. cmpiw #0x400c,d0 | test for too large
  88. jge  src_out
  89. |
  90. | The source input is below 1, so we check for denormalized numbers
  91. | and set unfl.
  92. |
  93. src_small:
  94. moveb a6@(DTAG),d0
  95. andib #0xe0,d0
  96. tstb d0
  97. jeq  no_denorm
  98. st a6@(STORE_FLG) | dest already contains result
  99. orl #__x_unfl_mask,a6@(USER_FPSR) | set UNFL
  100. den_done:
  101. lea a6@(FPTEMP),a0
  102. jra  __x_t_resdnrm
  103. no_denorm:
  104. fmovel a6@(USER_FPCR),fpcr
  105. fmovex a6@(FPTEMP),fp0 | simply return dest
  106. rts
  109. |
  110. | Source is within 2^14 range.  To perform the int operation,
  111. | move it to d0.
  112. |
  113. src_in:
  114. fmovex a6@(ETEMP),fp0 | move in src for int
  115. fmovel #rz_mode,fpcr | force rz for src conversion
  116. fmovel fp0,d0 | int src to d0
  117. fmovel #0,FPSR | clr status from above
  118. tstw a6@(ETEMP) | check src sign
  119. jlt  src_neg
  120. |
  121. | Source is positive.  Add the src to the dest exponent.
  122. | The result can be denormalized, if src = 0, or overflow,
  123. | if the result of the add sets a bit in the upper word.
  124. |
  125. src_pos:
  126. tstw d1 | check for denorm
  127. jeq  dst_dnrm
  128. addl d0,d1 | add src to dest exp
  129. jeq  __x_denorm | if zero, result is denorm
  130. cmpil #0x7fff,d1 | test for overflow
  131. jge  __x_ovfl
  132. tstb a6@(L_SCR1)
  133. jeq  spos_pos
  134. orw #0x8000,d1
  135. spos_pos:
  136. movew d1,a6@(FPTEMP) | result in FPTEMP
  137. fmovel a6@(USER_FPCR),fpcr
  138. fmovex a6@(FPTEMP),fp0 | write result to fp0
  139. rts
  140. __x_ovfl:
  141. tstb a6@(L_SCR1)
  142. jeq  sovl_pos
  143. orw #0x8000,d1
  144. sovl_pos:
  145. movew a6@(FPTEMP),a6@(ETEMP) | result in ETEMP
  146. movel a6@(FPTEMP_HI),a6@(ETEMP_HI)
  147. movel a6@(FPTEMP_LO),a6@(ETEMP_LO)
  148. jra  __x_t_ovfl2
  150. __x_denorm:
  151. tstb a6@(L_SCR1)
  152. jeq  den_pos
  153. orw #0x8000,d1
  154. den_pos:
  155. tstl a6@(FPTEMP_HI) | check j bit
  156. jlt  nden_exit | if set, not denorm
  157. movew d1,a6@(ETEMP) | input expected in ETEMP
  158. movel a6@(FPTEMP_HI),a6@(ETEMP_HI)
  159. movel a6@(FPTEMP_LO),a6@(ETEMP_LO)
  160. orl #__x_unfl_bit,a6@(USER_FPSR) | set unfl
  161. lea a6@(ETEMP),a0
  162. jra  __x_t_resdnrm
  163. nden_exit:
  164. movew d1,a6@(FPTEMP) | result in FPTEMP
  165. fmovel a6@(USER_FPCR),fpcr
  166. fmovex a6@(FPTEMP),fp0 | write result to fp0
  167. rts
  169. |
  170. | Source is negative.  Add the src to the dest exponent.
  171. | (The result exponent will be reduced).  The result can be
  172. | denormalized.
  173. |
  174. src_neg:
  175. addl d0,d1 | add src to dest
  176. jeq  __x_denorm | if zero, result is denorm
  177. jlt  fix_dnrm | if negative, result is
  178. | | needing denormalization
  179. tstb a6@(L_SCR1)
  180. jeq  __x_sneg_pos
  181. orw #0x8000,d1
  182. __x_sneg_pos:
  183. movew d1,a6@(FPTEMP) | result in FPTEMP
  184. fmovel a6@(USER_FPCR),fpcr
  185. fmovex a6@(FPTEMP),fp0 | write result to fp0
  186. rts
  189. |
  190. | The result exponent is below denorm value.  Test for catastrophic
  191. | underflow and force zero if true.  If not, try to shift the
  192. | mantissa right until a zero exponent exists.
  193. |
  194. fix_dnrm:
  195. cmpiw #0xffc0,d1 | lower bound for normalization
  196. jlt  fix_unfl | if lower, catastrophic unfl
  197. movew d1,d0 | use d0 for exp
  198. movel d2,a7@- | free d2 for norm
  199. movel a6@(FPTEMP_HI),d1
  200. movel a6@(FPTEMP_LO),d2
  201. clrl a6@(L_SCR2)
  202. fix_loop:
  203. addw #1,d0 | drive d0 to 0
  204. lsrl #1,d1 | while shifting the
  205. roxrl #1,d2 | mantissa to the right
  206. jcc  no_carry
  207. st a6@(L_SCR2) | use L_SCR2 to capture inex
  208. no_carry:
  209. tstw d0 | it is finished when
  210. jlt  fix_loop | d0 is zero or the mantissa
  211. tstb a6@(L_SCR2)
  212. jeq  tst_zero
  213. orl #__x_unfl_inx_mask,a6@(USER_FPSR)
  214. | | set unfl, aunfl, ainex
  215. |
  216. | Test for zero. If zero, simply use fmovel to return +/- zero
  217. | to the fpu.
  218. |
  219. tst_zero:
  220. clrw a6@(FPTEMP_EX)
  221. tstb a6@(L_SCR1) | test for sign
  222. jeq  tst_con
  223. orw #0x8000,a6@(FPTEMP_EX) | set sign bit
  224. tst_con:
  225. movel d1,a6@(FPTEMP_HI)
  226. movel d2,a6@(FPTEMP_LO)
  227. movel a7@+,d2
  228. tstl d1
  229. jne  not_zero
  230. tstl a6@(FPTEMP_LO)
  231. jne  not_zero
  232. |
  233. | Result is zero.  Check for rounding mode to set lsb.  If the
  234. | mode is rp, and the zero is positive, return smallest denorm.
  235. | If the mode is rm, and the zero is negative, return smallest
  236. | negative denorm.
  237. |
  238. btst #5,a6@(fpcr_MODE) | test if rm or rp
  239. jeq  no_dir
  240. btst #4,a6@(fpcr_MODE) | check which one
  241. jeq  zer_rm
  242. zer_rp:
  243. tstb a6@(L_SCR1) | check sign
  244. jne  no_dir | if set, neg op, no inc
  245. movel #1,a6@(FPTEMP_LO) | set lsb
  246. jra  sm_dnrm
  247. zer_rm:
  248. tstb a6@(L_SCR1) | check sign
  249. jeq  no_dir | if clr, neg op, no inc
  250. movel #1,a6@(FPTEMP_LO) | set lsb
  251. orl #neg_mask,a6@(USER_FPSR) | set N
  252. jra  sm_dnrm
  253. no_dir:
  254. fmovel a6@(USER_FPCR),fpcr
  255. fmovex a6@(FPTEMP),fp0 /* | use fmovel to set cc's */
  256. rts
  258. |
  259. | The rounding mode changed the zero to a smallest denorm. Call
  260. | __x_t_resdnrm with exceptional operand in ETEMP.
  261. |
  262. sm_dnrm:
  263. movel a6@(FPTEMP_EX),a6@(ETEMP_EX)
  264. movel a6@(FPTEMP_HI),a6@(ETEMP_HI)
  265. movel a6@(FPTEMP_LO),a6@(ETEMP_LO)
  266. lea a6@(ETEMP),a0
  267. jra  __x_t_resdnrm
  269. |
  270. | Result is still denormalized.
  271. |
  272. not_zero:
  273. orl #__x_unfl_mask,a6@(USER_FPSR) | set unfl
  274. tstb a6@(L_SCR1) | check for sign
  275. jeq  fix_exit
  276. orl #neg_mask,a6@(USER_FPSR) | set N
  277. fix_exit:
  278. jra  sm_dnrm
  281. |
  282. | The result has underflowed to zero. Return zero and set
  283. | unfl, aunfl, and ainex.
  284. |
  285. fix_unfl:
  286. orl #__x_unfl_inx_mask,a6@(USER_FPSR)
  287. btst #5,a6@(fpcr_MODE) | test if rm or rp
  288. jeq  no_dir2
  289. btst #4,a6@(fpcr_MODE) | check which one
  290. jeq  zer_rm2
  291. zer_rp2:
  292. tstb a6@(L_SCR1) | check sign
  293. jne  no_dir2 | if set, neg op, no inc
  294. clrl a6@(FPTEMP_EX)
  295. clrl a6@(FPTEMP_HI)
  296. movel #1,a6@(FPTEMP_LO) | set lsb
  297. jra  sm_dnrm | return smallest denorm
  298. zer_rm2:
  299. tstb a6@(L_SCR1) | check sign
  300. jeq  no_dir2 | if clr, neg op, no inc
  301. movew #0x8000,a6@(FPTEMP_EX)
  302. clrl a6@(FPTEMP_HI)
  303. movel #1,a6@(FPTEMP_LO) | set lsb
  304. orl #neg_mask,a6@(USER_FPSR) | set N
  305. jra  sm_dnrm | return smallest denorm
  307. no_dir2:
  308. tstb a6@(L_SCR1)
  309. jge  pos_zero
  310. neg_zero:
  311. clrl a6@(FP_SCR1) | clear the exceptional operand
  312. clrl a6@(FP_SCR1+4) | for __x_gen_except.
  313. clrl a6@(FP_SCR1+8)
  314. .long 0xf23c4400,0x80000000 /*  fmoves  &0x80000000,fp0 */
  315. rts
  316. pos_zero:
  317. clrl a6@(FP_SCR1) | clear the exceptional operand
  318. clrl a6@(FP_SCR1+4) | for __x_gen_except.
  319. clrl a6@(FP_SCR1+8)
  320. .long 0xf23c4400,0x00000000 /*  fmoves  &0x00000000,fp0 */
  321. rts
  323. |
  324. | The destination is a denormalized number.  It must be handled
  325. | by first shifting the bits in the mantissa until it is normalized,
  326. | then adding the remainder of the source to the exponent.
  327. |
  328. dst_dnrm:
  329. moveml d2/d3,a7@-
  330. movew a6@(FPTEMP_EX),d1
  331. movel a6@(FPTEMP_HI),d2
  332. movel a6@(FPTEMP_LO),d3
  333. dst_loop:
  334. tstl d2 | test for normalized result
  335. jlt  dst_norm | exit loop if so
  336. tstl d0 | otherwise, test shift count
  337. jeq  dst_fin | if zero, shifting is done
  338. subil #1,d0 | dec src
  339. lsll #1,d3
  340. roxll #1,d2
  341. jra  dst_loop
  342. |
  343. | Destination became normalized.  Simply add the remaining
  344. | portion of the src to the exponent.
  345. |
  346. dst_norm:
  347. addw d0,d1 | dst is normalized|  add src
  348. tstb a6@(L_SCR1)
  349. jeq  dnrm_pos
  350. orl #0x8000,d1
  351. dnrm_pos:
  352. movemw d1,a6@(FPTEMP_EX)
  353. moveml d2,a6@(FPTEMP_HI)
  354. moveml d3,a6@(FPTEMP_LO)
  355. fmovel a6@(USER_FPCR),fpcr
  356. fmovex a6@(FPTEMP),fp0
  357. moveml a7@+,d2/d3
  358. rts
  360. |
  361. | Destination remained denormalized.  Call t_excdnrm with
  362. | exceptional operand in ETEMP.
  363. |
  364. dst_fin:
  365. tstb a6@(L_SCR1) | check for sign
  366. jeq  dst_exit
  367. orl #neg_mask,a6@(USER_FPSR) | set N
  368. orl #0x8000,d1
  369. dst_exit:
  370. movemw d1,a6@(ETEMP_EX)
  371. moveml d2,a6@(ETEMP_HI)
  372. moveml d3,a6@(ETEMP_LO)
  373. orl #__x_unfl_mask,a6@(USER_FPSR) | set unfl
  374. moveml a7@+,d2/d3
  375. lea a6@(ETEMP),a0
  376. jra  __x_t_resdnrm
  378. |
  379. | Source is outside of 2^14 range.  Test the sign and branch
  380. | to the appropriate exception handler.
  381. |
  382. src_out:
  383. tstb a6@(L_SCR1)
  384. jeq  scro_pos
  385. orl #0x8000,d1
  386. scro_pos:
  387. movel a6@(FPTEMP_HI),a6@(ETEMP_HI)
  388. movel a6@(FPTEMP_LO),a6@(ETEMP_LO)
  389. tstw a6@(ETEMP)
  390. jlt  res_neg
  391. res_pos:
  392. movew d1,a6@(ETEMP) | result in ETEMP
  393. jra  __x_t_ovfl2
  394. res_neg:
  395. movew d1,a6@(ETEMP) | result in ETEMP
  396. lea a6@(ETEMP),a0
  397. jra  __x_t_unfl
  398. | end