开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > VxWorks > 查看源码
slogn.s
资源名称：vxwork_src.rar　[点击查看]
上传用户：nvosite88
上传日期：2007-01-17
资源大小：4983k
文件大小：19k
源码类别：

VxWorks

开发平台：

C/C++

slogn.s：源码内容
  1. /* slogn.s - Motorola 68040 FP natural logarithm routines (EXC) */
  3. /* Copyright 1991-1993 Wind River Systems, Inc. */
  4. .data
  5. .globl _copyright_wind_river
  6. .long _copyright_wind_river
  8. /*
  9. modification history
  10. --------------------
  11. 01e,21jul93,kdl  added .text (SPR #2372).
  12. 01d,23aug92,jcf  changed bxxx to jxx.
  13. 01c,26may92,rrr  the tree shuffle
  14. 01b,10jan92,kdl  added modification history; general cleanup.
  15. 01a,15aug91,kdl  original version, from Motorola FPSP v2.0.
  16. */
  18. /*
  19. DESCRIPTION
  21. slognsa 3.1 12/10/90
  23. __x_slogn computes the natural logarithm of an
  24. input value. __x_slognd does the same except the input value is a
  25. denormalized number. __x_slognp1 computes log(1+X), and __x_slognp1d
  26. computes log(1+X) for denormalized X.
  28. Input: Double-extended value in memory location pointed to by address
  29. register a0.
  31. Output: log(X) or log(1+X) returned in floating-point register Fp0.
  33. Accuracy and Monotonicity: The returned result is within 2 ulps in
  34. 64 significant bit, i.e. within 0.5001 ulp to 53 bits if the
  35. result is subsequently rounded to double precision. The
  36. result is provably monotonic in double precision.
  38. Speed: The program __x_slogn takes approximately 190 cycles for input
  39. argument X such that |X-1| >= 1/16, which is the the usual
  40. situation. For those arguments, __x_slognp1 takes approximately
  41.  210 cycles. For the less common arguments, the program will
  42.  run no worse than 10 slower.
  44. Algorithm:
  45. LOGN:
  46. Step 1. If |X-1| < 1/16, approximate log(X) by an odd polynomial in
  47. u, where u = 2(X-1)/(X+1). Otherwise, move on to Step 2.
  49. Step 2. X = 2**k * Y where 1 <= Y < 2. Define F to be the first seven
  50. significant bits of Y plus 2**(-7), i.e. F = 1xxxxxx1 in base
  51. 2 where the six "x" match those of Y. Note that |Y-F| <= 2**(-7).
  53. Step 3. Define u = (Y-F)/F. Approximate log(1+u) by a polynomial in u,
  54. log(1+u) = poly.
  56. Step 4. Reconstruct log(X) = log( 2**k * Y ) =
  57. k*log(2) + log(F) + log(1+u)
  58. by k*log(2) + (log(F) + poly). The values of log(F) are
  59. calculated beforehand and stored in the program.
  61. lognp1:
  62. Step 1: If |X| < 1/16, approximate log(1+X) by an odd polynomial in
  63. u where u = 2X/(2+X). Otherwise, move on to Step 2.
  65. Step 2: Let 1+X = 2**k * Y, where 1 <= Y < 2. Define F as done in Step 2
  66. of the algorithm for LOGN and compute log(1+X) as
  67. k*log(2) + log(F) + poly where poly approximates log(1+u),
  68. u = (Y-F)/F.
  70. Implementation Notes:
  71. Note 1. There are 64 different possible values for F, thus 64 log(F)'s
  72. need to be tabulated. Moreover, the values of 1/F are also
  73. tabulated so that the division in (Y-F)/F can be performed by a
  74. multiplication.
  76. Note 2. In Step 2 of lognp1, in order to preserved accuracy, the value
  77. Y-F has to be calculated carefully when 1/2 <= X < 3/2.
  79. Note 3. To fully exploit the pipeline, polynomials are usually separated
  80. into two parts evaluated independently before being added up.
  83. Copyright (C) Motorola, Inc. 1990
  84. All Rights Reserved
  86. THIS IS UNPUBLISHED PROPRIETARY SOURCE CODE OF MOTOROLA
  87. The copyright notice above does not evidence any
  88. actual or intended publication of such source code.
  90. __x_slogn IDNT 2,1 Motorola 040 Floating Point Software Package
  92. section 8
  94. NOMANUAL
  95. */
  97. #include "fpsp040E.h"
  99. BOUNDS1:  .long 0x3FFEF07D,0x3FFF8841
  100. BOUNDS2:  .long 0x3FFE8000,0x3FFFC000
  102. LOGOF2: .long 0x3FFE0000,0xB17217F7,0xD1CF79AC,0x00000000
  104. one: .long 0x3F800000
  105. zero: .long 0x00000000
  106. infty: .long 0x7F800000
  107. negone: .long 0xBF800000
  109. LOGA6: .long 0x3FC2499A,0xB5E4040B
  110. LOGA5: .long 0xBFC555B5,0x848CB7DB
  112. LOGA4: .long 0x3FC99999,0x987D8730
  113. LOGA3: .long 0xBFCFFFFF,0xFF6F7E97
  115. LOGA2: .long 0x3FD55555,0x555555A4
  116. LOGA1: .long 0xBFE00000,0x00000008
  118. LOGB5: .long 0x3F175496,0xADD7DAD6
  119. LOGB4: .long 0x3F3C71C2,0xFE80C7E0
  121. LOGB3: .long 0x3F624924,0x928BCCFF
  122. LOGB2: .long 0x3F899999,0x999995EC
  124. LOGB1: .long 0x3FB55555,0x55555555
  125. TWO: .long 0x40000000,0x00000000
  127. LTHOLD: .long 0x3f990000,0x80000000,0x00000000,0x00000000
  129. LOGTBL:
  130. .long  0x3FFE0000,0xFE03F80F,0xE03F80FE,0x00000000
  131. .long  0x3FF70000,0xFF015358,0x833C47E2,0x00000000
  132. .long  0x3FFE0000,0xFA232CF2,0x52138AC0,0x00000000
  133. .long  0x3FF90000,0xBDC8D83E,0xAD88D549,0x00000000
  134. .long  0x3FFE0000,0xF6603D98,0x0F6603DA,0x00000000
  135. .long  0x3FFA0000,0x9CF43DCF,0xF5EAFD48,0x00000000
  136. .long  0x3FFE0000,0xF2B9D648,0x0F2B9D65,0x00000000
  137. .long  0x3FFA0000,0xDA16EB88,0xCB8DF614,0x00000000
  138. .long  0x3FFE0000,0xEF2EB71F,0xC4345238,0x00000000
  139. .long  0x3FFB0000,0x8B29B775,0x1BD70743,0x00000000
  140. .long  0x3FFE0000,0xEBBDB2A5,0xC1619C8C,0x00000000
  141. .long  0x3FFB0000,0xA8D839F8,0x30C1FB49,0x00000000
  142. .long  0x3FFE0000,0xE865AC7B,0x7603A197,0x00000000
  143. .long  0x3FFB0000,0xC61A2EB1,0x8CD907AD,0x00000000
  144. .long  0x3FFE0000,0xE525982A,0xF70C880E,0x00000000
  145. .long  0x3FFB0000,0xE2F2A47A,0xDE3A18AF,0x00000000
  146. .long  0x3FFE0000,0xE1FC780E,0x1FC780E2,0x00000000
  147. .long  0x3FFB0000,0xFF64898E,0xDF55D551,0x00000000
  148. .long  0x3FFE0000,0xDEE95C4C,0xA037BA57,0x00000000
  149. .long  0x3FFC0000,0x8DB956A9,0x7B3D0148,0x00000000
  150. .long  0x3FFE0000,0xDBEB61EE,0xD19C5958,0x00000000
  151. .long  0x3FFC0000,0x9B8FE100,0xF47BA1DE,0x00000000
  152. .long  0x3FFE0000,0xD901B203,0x6406C80E,0x00000000
  153. .long  0x3FFC0000,0xA9372F1D,0x0DA1BD17,0x00000000
  154. .long  0x3FFE0000,0xD62B80D6,0x2B80D62C,0x00000000
  155. .long  0x3FFC0000,0xB6B07F38,0xCE90E46B,0x00000000
  156. .long  0x3FFE0000,0xD3680D36,0x80D3680D,0x00000000
  157. .long  0x3FFC0000,0xC3FD0329,0x06488481,0x00000000
  158. .long  0x3FFE0000,0xD0B69FCB,0xD2580D0B,0x00000000
  159. .long  0x3FFC0000,0xD11DE0FF,0x15AB18CA,0x00000000
  160. .long  0x3FFE0000,0xCE168A77,0x25080CE1,0x00000000
  161. .long  0x3FFC0000,0xDE1433A1,0x6C66B150,0x00000000
  162. .long  0x3FFE0000,0xCB8727C0,0x65C393E0,0x00000000
  163. .long  0x3FFC0000,0xEAE10B5A,0x7DDC8ADD,0x00000000
  164. .long  0x3FFE0000,0xC907DA4E,0x871146AD,0x00000000
  165. .long  0x3FFC0000,0xF7856E5E,0xE2C9B291,0x00000000
  166. .long  0x3FFE0000,0xC6980C69,0x80C6980C,0x00000000
  167. .long  0x3FFD0000,0x82012CA5,0xA68206D7,0x00000000
  168. .long  0x3FFE0000,0xC4372F85,0x5D824CA6,0x00000000
  169. .long  0x3FFD0000,0x882C5FCD,0x7256A8C5,0x00000000
  170. .long  0x3FFE0000,0xC1E4BBD5,0x95F6E947,0x00000000
  171. .long  0x3FFD0000,0x8E44C60B,0x4CCFD7DE,0x00000000
  172. .long  0x3FFE0000,0xBFA02FE8,0x0BFA02FF,0x00000000
  173. .long  0x3FFD0000,0x944AD09E,0xF4351AF6,0x00000000
  174. .long  0x3FFE0000,0xBD691047,0x07661AA3,0x00000000
  175. .long  0x3FFD0000,0x9A3EECD4,0xC3EAA6B2,0x00000000
  176. .long  0x3FFE0000,0xBB3EE721,0xA54D880C,0x00000000
  177. .long  0x3FFD0000,0xA0218434,0x353F1DE8,0x00000000
  178. .long  0x3FFE0000,0xB92143FA,0x36F5E02E,0x00000000
  179. .long  0x3FFD0000,0xA5F2FCAB,0xBBC506DA,0x00000000
  180. .long  0x3FFE0000,0xB70FBB5A,0x19BE3659,0x00000000
  181. .long  0x3FFD0000,0xABB3B8BA,0x2AD362A5,0x00000000
  182. .long  0x3FFE0000,0xB509E68A,0x9B94821F,0x00000000
  183. .long  0x3FFD0000,0xB1641795,0xCE3CA97B,0x00000000
  184. .long  0x3FFE0000,0xB30F6352,0x8917C80B,0x00000000
  185. .long  0x3FFD0000,0xB7047551,0x5D0F1C61,0x00000000
  186. .long  0x3FFE0000,0xB11FD3B8,0x0B11FD3C,0x00000000
  187. .long  0x3FFD0000,0xBC952AFE,0xEA3D13E1,0x00000000
  188. .long  0x3FFE0000,0xAF3ADDC6,0x80AF3ADE,0x00000000
  189. .long  0x3FFD0000,0xC2168ED0,0xF458BA4A,0x00000000
  190. .long  0x3FFE0000,0xAD602B58,0x0AD602B6,0x00000000
  191. .long  0x3FFD0000,0xC788F439,0xB3163BF1,0x00000000
  192. .long  0x3FFE0000,0xAB8F69E2,0x8359CD11,0x00000000
  193. .long  0x3FFD0000,0xCCECAC08,0xBF04565D,0x00000000
  194. .long  0x3FFE0000,0xA9C84A47,0xA07F5638,0x00000000
  195. .long  0x3FFD0000,0xD2420487,0x2DD85160,0x00000000
  196. .long  0x3FFE0000,0xA80A80A8,0x0A80A80B,0x00000000
  197. .long  0x3FFD0000,0xD7894992,0x3BC3588A,0x00000000
  198. .long  0x3FFE0000,0xA655C439,0x2D7B73A8,0x00000000
  199. .long  0x3FFD0000,0xDCC2C4B4,0x9887DACC,0x00000000
  200. .long  0x3FFE0000,0xA4A9CF1D,0x96833751,0x00000000
  201. .long  0x3FFD0000,0xE1EEBD3E,0x6D6A6B9E,0x00000000
  202. .long  0x3FFE0000,0xA3065E3F,0xAE7CD0E0,0x00000000
  203. .long  0x3FFD0000,0xE70D785C,0x2F9F5BDC,0x00000000
  204. .long  0x3FFE0000,0xA16B312E,0xA8FC377D,0x00000000
  205. .long  0x3FFD0000,0xEC1F392C,0x5179F283,0x00000000
  206. .long  0x3FFE0000,0x9FD809FD,0x809FD80A,0x00000000
  207. .long  0x3FFD0000,0xF12440D3,0xE36130E6,0x00000000
  208. .long  0x3FFE0000,0x9E4CAD23,0xDD5F3A20,0x00000000
  209. .long  0x3FFD0000,0xF61CCE92,0x346600BB,0x00000000
  210. .long  0x3FFE0000,0x9CC8E160,0xC3FB19B9,0x00000000
  211. .long  0x3FFD0000,0xFB091FD3,0x8145630A,0x00000000
  212. .long  0x3FFE0000,0x9B4C6F9E,0xF03A3CAA,0x00000000
  213. .long  0x3FFD0000,0xFFE97042,0xBFA4C2AD,0x00000000
  214. .long  0x3FFE0000,0x99D722DA,0xBDE58F06,0x00000000
  215. .long  0x3FFE0000,0x825EFCED,0x49369330,0x00000000
  216. .long  0x3FFE0000,0x9868C809,0x868C8098,0x00000000
  217. .long  0x3FFE0000,0x84C37A7A,0xB9A905C9,0x00000000
  218. .long  0x3FFE0000,0x97012E02,0x5C04B809,0x00000000
  219. .long  0x3FFE0000,0x87224C2E,0x8E645FB7,0x00000000
  220. .long  0x3FFE0000,0x95A02568,0x095A0257,0x00000000
  221. .long  0x3FFE0000,0x897B8CAC,0x9F7DE298,0x00000000
  222. .long  0x3FFE0000,0x94458094,0x45809446,0x00000000
  223. .long  0x3FFE0000,0x8BCF55DE,0xC4CD05FE,0x00000000
  224. .long  0x3FFE0000,0x92F11384,0x0497889C,0x00000000
  225. .long  0x3FFE0000,0x8E1DC0FB,0x89E125E5,0x00000000
  226. .long  0x3FFE0000,0x91A2B3C4,0xD5E6F809,0x00000000
  227. .long  0x3FFE0000,0x9066E68C,0x955B6C9B,0x00000000
  228. .long  0x3FFE0000,0x905A3863,0x3E06C43B,0x00000000
  229. .long  0x3FFE0000,0x92AADE74,0xC7BE59E0,0x00000000
  230. .long  0x3FFE0000,0x8F1779D9,0xFDC3A219,0x00000000
  231. .long  0x3FFE0000,0x94E9BFF6,0x15845643,0x00000000
  232. .long  0x3FFE0000,0x8DDA5202,0x37694809,0x00000000
  233. .long  0x3FFE0000,0x9723A1B7,0x20134203,0x00000000
  234. .long  0x3FFE0000,0x8CA29C04,0x6514E023,0x00000000
  235. .long  0x3FFE0000,0x995899C8,0x90EB8990,0x00000000
  236. .long  0x3FFE0000,0x8B70344A,0x139BC75A,0x00000000
  237. .long  0x3FFE0000,0x9B88BDAA,0x3A3DAE2F,0x00000000
  238. .long  0x3FFE0000,0x8A42F870,0x5669DB46,0x00000000
  239. .long  0x3FFE0000,0x9DB4224F,0xFFE1157C,0x00000000
  240. .long  0x3FFE0000,0x891AC73A,0xE9819B50,0x00000000
  241. .long  0x3FFE0000,0x9FDADC26,0x8B7A12DA,0x00000000
  242. .long  0x3FFE0000,0x87F78087,0xF78087F8,0x00000000
  243. .long  0x3FFE0000,0xA1FCFF17,0xCE733BD4,0x00000000
  244. .long  0x3FFE0000,0x86D90544,0x7A34ACC6,0x00000000
  245. .long  0x3FFE0000,0xA41A9E8F,0x5446FB9F,0x00000000
  246. .long  0x3FFE0000,0x85BF3761,0x2CEE3C9B,0x00000000
  247. .long  0x3FFE0000,0xA633CD7E,0x6771CD8B,0x00000000
  248. .long  0x3FFE0000,0x84A9F9C8,0x084A9F9D,0x00000000
  249. .long  0x3FFE0000,0xA8489E60,0x0B435A5E,0x00000000
  250. .long  0x3FFE0000,0x83993052,0x3FBE3368,0x00000000
  251. .long  0x3FFE0000,0xAA59233C,0xCCA4BD49,0x00000000
  252. .long  0x3FFE0000,0x828CBFBE,0xB9A020A3,0x00000000
  253. .long  0x3FFE0000,0xAC656DAE,0x6BCC4985,0x00000000
  254. .long  0x3FFE0000,0x81848DA8,0xFAF0D277,0x00000000
  255. .long  0x3FFE0000,0xAE6D8EE3,0x60BB2468,0x00000000
  256. .long  0x3FFE0000,0x80808080,0x80808081,0x00000000
  257. .long  0x3FFE0000,0xB07197A2,0x3C46C654,0x00000000
  259. #define ADJK L_SCR1
  261. #define X FP_SCR1
  262. #define XDCARE X+2
  263. #define XFRAC X+4
  265. #define F FP_SCR2
  266. #define FFRAC F+4
  268. #define KLOG2 FP_SCR3
  270. #define SAVEU FP_SCR4
  272. | xref __x_t_frcinx
  273. | xref __x_t_extdnrm
  274. | xref __x_t_operr
  275. | xref __x_t_dz
  278. .text
  280. .globl __x_slognd
  281. __x_slognd:
  282. |--ENTRY POINT FOR LOG(X) FOR DENORMALIZED INPUT
  284. movel #-100,a6@(ADJK) |...INPUT = 2^(ADJK) * fp0
  286. |----normalize the input value by left shifting k bits (k to be determined
  287. |----below), adjusting exponent and storing -k to  ADJK
  288. |----the value TWOTO100 is no longer needed.
  289. |----Note that this code assumes the denormalized input is NON-ZERO.
  291.      moveml d2-d7,A7@- |...save some registers
  292.      movel #0x00000000,d3 |...D3 is exponent of smallest norm. #
  293.      movel A0@(4),d4
  294.      movel A0@(8),d5 |...(D4,d5) is (Hi_X,Lo_X)
  295.      clrl d2 |...D2 used for holding K
  297.      tstl d4
  298.      jne  HiX_not0
  300. HiX_0:
  301.      movel d5,d4
  302.      clrl d5
  303.      movel #32,d2
  304.      clrl d6
  305.      bfffo      d4{#0:#32},d6
  306.      lsll      d6,d4
  307.      addl d6,d2 |...(D3,d4,d5) is normalized
  309.      movel d3,a6@(X)
  310.      movel d4,a6@(XFRAC)
  311.      movel d5,a6@(XFRAC+4)
  312.      negl d2
  313.      movel d2,a6@(ADJK)
  314.      fmovex a6@(X),fp0
  315.      moveml A7@+,d2-d7 |...restore registers
  316.      lea a6@(X),a0
  317.      jra  LOGBGN |...begin regular log(X)
  320. HiX_not0:
  321.      clrl d6
  322.      bfffo d4{#0:#32},d6 |...find first 1
  323.      movel d6,d2 |...get k
  324.      lsll d6,d4
  325.      movel d5,d7 |...a copy of d5
  326.      lsll d6,d5
  327.      negl d6
  328.      addil #32,d6
  329.      lsrl d6,d7
  330.      orl d7,d4 |...(D3,d4,d5) normalized
  332.      movel d3,a6@(X)
  333.      movel d4,a6@(XFRAC)
  334.      movel d5,a6@(XFRAC+4)
  335.      negl d2
  336.      movel d2,a6@(ADJK)
  337.      fmovex a6@(X),fp0
  338.      moveml A7@+,d2-d7 |...restore registers
  339.      lea a6@(X),a0
  340.      jra  LOGBGN |...begin regular log(X)
  343. .globl __x_slogn
  344. __x_slogn:
  345. /* |--ENTRY POINT FOR LOG(X) FOR X FINITE, NON-ZERO, NOT NAN'S */
  347. fmovex A0@,fp0 |...lOAD INPUT
  348. movel #0x00000000,a6@(ADJK)
  350. LOGBGN:
  351. |--fpcr SAVED AND CLEARED, INPUT IS 2^(ADJK)*FP0, FP0 CONTAINS
  352. |--A FINITE, NON-ZERO, NORMALIZED NUMBER.
  354. movel a0@,d0
  355. movew a0@(4),d0
  357. movel a0@,a6@(X)
  358. movel a0@(4),a6@(X+4)
  359. movel a0@(8),a6@(X+8)
  361. cmpil #0,d0 |...CHECK IF X IS NEGATIVE
  362. jlt  LOGNEG |...lOG OF NEGATIVE ARGUMENT IS INVALID
  363. cmp2l BOUNDS1,d0 |...X IS POSITIVE, CHECK IF X IS NEAR 1
  364. jcc  LOGNEAR1 |...BOUNDS IS ROUGHLY [15/16, 17/16]
  366. LOGMAIN:
  367. |--THIS SHOULD BE THE USUAL CASE, X NOT VERY CLOSE TO 1
  369. |--X = 2^(K) * Y, 1 <= Y < 2. THUS, Y = 1.XXXXXXXX....XX IN BINARY.
  370. |--WE DEFINE F = 1.XXXXXX1, I.E. FIRST 7 BITS OF Y AND ATTACH A 1.
  371. |--THE IDEA IS THAT LOG(X) = K*LOG2 + LOG(Y)
  372. |--  = K*LOG2 + LOG(F) + LOG(1 + (Y-F)/F).
  373. |--NOTE THAT U = (Y-F)/F IS VERY SMALL AND THUS APPROXIMATING
  374. |--LOG(1+U) CAN BE VERY EFFICIENT.
  375. |--ALSO NOTE THAT THE VALUE 1/F IS STORED IN A TABLE SO THAT NO
  376. |--DIVISION IS NEEDED TO CALCULATE (Y-F)/F.
  378. |--GET K, Y, F, AND ADDRESS OF 1/F.
  379. asrl #8,d0
  380. asrl #8,d0 |...SHIFTED 16 BITS, BIASED EXPO. OF X
  381. subil #0x3FFF,d0  |...THIS IS K
  382. addl a6@(ADJK),d0 |...ADJUST K, ORIGINAL INPUT MAY BE  DENORM.
  383. lea LOGTBL,a0  |...BASE ADDRESS OF 1/F AND LOG(F)
  384. fmovel d0,fp1 |...CONVERT K TO FLOATING-POINT FORMAT
  386. |--WHILE THE CONVERSION IS GOING ON, WE GET F AND ADDRESS OF 1/F
  387. movel #0x3FFF0000,a6@(X) |...X IS NOW Y, I.E. 2^(-K)*X
  388. movel a6@(XFRAC),a6@(FFRAC)
  389. andil #0xFE000000,a6@(FFRAC) |...FIRST 7 BITS OF Y
  390. oril #0x01000000,a6@(FFRAC) |...GET F: ATTACH A 1 AT THE EIGHTH BIT
  391. movel a6@(FFRAC),d0 |...READY TO GET ADDRESS OF 1/F
  392. andil #0x7E000000,d0
  393. asrl #8,d0
  394. asrl #8,d0
  395. asrl #4,d0 |...SHIFTED 20, d0 IS THE DISPLACEMENT
  396. addal d0,a0 |...A0 IS THE ADDRESS FOR 1/F
  398. fmovex a6@(X),fp0
  399. movel #0x3fff0000,a6@(F)
  400. clrl a6@(F+8)
  401. fsubx a6@(F),fp0 |...Y-F
  402. fmovemx fp2/fp3,a7@- |...SAVE fp2 WHILE fp0 IS NOT READY
  403. |--SUMMARY: FP0 IS Y-F, A0 IS ADDRESS OF 1/F, FP1 IS K
  404. |--REGISTERS SAVED: fpcr, FP1, FP2
  406. LP1CONT1:
  407. |--AN RE-ENTRY POINT FOR LOGNP1
  408. fmulx A0@,fp0 |...FP0 IS U = (Y-F)/F
  409. fmulx LOGOF2,fp1 |...GET K*LOG2 WHILE fp0 IS NOT READY
  410. fmovex fp0,fp2
  411. fmulx fp2,fp2 |...FP2 IS V=U*U
  412. fmovex fp1,a6@(KLOG2) |...PUT K*LOG2 IN MEMEORY, FREE fp1
  414. |--LOG(1+U) IS APPROXIMATED BY
  415. |--U + V*(A1+U*(A2+U*(A3+U*(A4+U*(A5+U*A6))))) WHICH IS
  416. |--[U + V*(A1+V*(A3+V*A5))]  +  [U*V*(A2+V*(A4+V*A6))]
  418. fmovex fp2,fp3
  419. fmovex fp2,fp1
  421. fmuld LOGA6,fp1 |...V*A6
  422. fmuld LOGA5,fp2 |...V*A5
  424. faddd LOGA4,fp1 |...A4+V*A6
  425. faddd LOGA3,fp2 |...A3+V*A5
  427. fmulx fp3,fp1 |...V*(A4+V*A6)
  428. fmulx fp3,fp2 |...V*(A3+V*A5)
  430. faddd LOGA2,fp1 |...A2+V*(A4+V*A6)
  431. faddd LOGA1,fp2 |...A1+V*(A3+V*A5)
  433. fmulx fp3,fp1 |...V*(A2+V*(A4+V*A6))
  434. addal #16,a0 |...ADDRESS OF LOG(F)
  435. fmulx fp3,fp2 |...V*(A1+V*(A3+V*A5)), fp3 RELEASED
  437. fmulx fp0,fp1 |...U*V*(A2+V*(A4+V*A6))
  438. faddx fp2,fp0 |...U+V*(A1+V*(A3+V*A5)), fp2 RELEASED
  440. faddx A0@,fp1 |...lOG(F)+U*V*(A2+V*(A4+V*A6))
  441. fmovemx  a7@+,fp2/fp3 |...RESTORE fp2
  442. faddx fp1,fp0 |...FP0 IS LOG(F) + LOG(1+U)
  444. fmovel d1,fpcr
  445. faddx a6@(KLOG2),fp0 |...FINAL ADD
  446. jra  __x_t_frcinx
  449. LOGNEAR1:
  450. |--REGISTERS SAVED: fpcr, FP1. FP0 CONTAINS THE INPUT.
  451. fmovex fp0,fp1
  452. fsubs one,fp1 |...FP1 IS X-1
  453. fadds one,fp0 |...FP0 IS X+1
  454. faddx fp1,fp1 |...FP1 IS 2(X-1)
  455. |--LOG(X) = LOG(1+U/2)-LOG(1-U/2) WHICH IS AN ODD POLYNOMIAL
  456. |--IN U, U = 2(X-1)/(X+1) = FP1/FP0
  458. LP1CONT2:
  459. |--THIS IS AN RE-ENTRY POINT FOR LOGNP1
  460. fdivx fp0,fp1 |...FP1 IS U
  461. fmovemx fp2/fp3,a7@-  |...SAVE fp2
  462. |--REGISTERS SAVED ARE NOW fpcr,FP1,FP2,FP3
  463. |--LET V=U*U, W=V*V, CALCULATE
  464. |--U + U*V*(B1 + V*(B2 + V*(B3 + V*(B4 + V*B5)))) BY
  465. |--U + U*V*(  [B1 + W*(B3 + W*B5)]  +  [V*(B2 + W*B4)]  )
  466. fmovex fp1,fp0
  467. fmulx fp0,fp0 |...FP0 IS V
  468. fmovex fp1,a6@(SAVEU)  |...STORE U IN MEMORY, FREE fp1
  469. fmovex fp0,fp1
  470. fmulx fp1,fp1 |...FP1 IS W
  472. fmoved LOGB5,fp3
  473. fmoved LOGB4,fp2
  475. fmulx fp1,fp3 |...w*B5
  476. fmulx fp1,fp2 |...w*B4
  478. faddd LOGB3,fp3  |...B3+W*B5
  479. faddd LOGB2,fp2  |...B2+W*B4
  481. fmulx fp3,fp1 |...w*(B3+W*B5), fp3 RELEASED
  483. fmulx fp0,fp2 |...V*(B2+W*B4)
  485. faddd LOGB1,fp1  |...B1+W*(B3+W*B5)
  486. fmulx a6@(SAVEU),fp0  |...FP0 IS U*V
  488. faddx fp2,fp1 |...B1+W*(B3+W*B5) + V*(B2+W*B4), fp2 RELEASED
  489. fmovemx a7@+,fp2/fp3  |...FP2 RESTORED
  491. fmulx fp1,fp0 |...U*V*( [B1+W*(B3+W*B5)] + [V*(B2+W*B4)] )
  493. fmovel d1,fpcr
  494. faddx a6@(SAVEU),fp0
  495. jra  __x_t_frcinx
  496. rts
  498. LOGNEG:
  499. |--REGISTERS SAVED fpcr. LOG(-VE) IS INVALID
  500. jra  __x_t_operr
  502. .globl __x_slognp1d
  503. __x_slognp1d:
  504. |--ENTRY POINT FOR LOG(1+Z) FOR DENORMALIZED INPUT
  505. | Simply return the __x_denorm
  507. jra  __x_t_extdnrm
  509. .globl __x_slognp1
  510. __x_slognp1:
  511. /* |--ENTRY POINT FOR LOG(1+X) FOR X FINITE, NON-ZERO, NOT NAN'S */
  513. fmovex A0@,fp0 |...lOAD INPUT
  514. fabsx fp0 | test magnitude
  515. fcmpx LTHOLD,fp0 | compare with min threshold
  516. fbgt LP1REAL | if greater, continue
  517. fmovel #0,fpsr | clr N flag from compare
  518. fmovel d1,fpcr
  519. fmovex a0@,fp0 | return signed argument
  520. jra  __x_t_frcinx
  522. LP1REAL:
  523. fmovex A0@,fp0 |...lOAD INPUT
  524. movel #0x00000000,a6@(ADJK)
  525. fmovex fp0,fp1 |...FP1 IS INPUT Z
  526. fadds one,fp0 |...X := ROUND(1+Z)
  527. fmovex fp0,a6@(X)
  528. movew a6@(XFRAC),a6@(XDCARE)
  529. movel a6@(X),d0
  530. cmpil #0,d0
  531. jle  LP1NEG0 |...lOG OF ZERO OR -VE
  532. cmp2l BOUNDS2,d0
  533. jcs  LOGMAIN |...BOUNDS2 IS [1/2,3/2]
  534. |--IF 1+Z > 3/2 OR 1+Z < 1/2, THEN X, WHICH IS ROUNDING 1+Z,
  535. |--CONTAINS AT LEAST 63 BITS OF INFORMATION OF Z. IN THAT CASE,
  536. |--SIMPLY INVOKE LOG(X) FOR LOG(1+Z).
  538. LP1NEAR1:
  539. |--NEXT SEE IF EXP(-1/16) < X < EXP(1/16)
  540. cmp2l BOUNDS1,d0
  541. jcs  LP1CARE
  543. LP1ONE16:
  544. |--EXP(-1/16) < X < EXP(1/16). LOG(1+Z) = LOG(1+U/2) - LOG(1-U/2)
  545. |--WHERE U = 2Z/(2+Z) = 2Z/(1+X).
  546. faddx fp1,fp1 |...FP1 IS 2Z
  547. fadds one,fp0 |...FP0 IS 1+X
  548. |--U = FP1/FP0
  549. jra  LP1CONT2
  551. LP1CARE:
  552. |--HERE WE USE THE USUAL TABLE DRIVEN APPROACH. CARE HAS TO BE
  553. |--TAKEN BECAUSE 1+Z CAN HAVE 67 BITS OF INFORMATION AND WE MUST
  554. |--PRESERVE ALL THE INFORMATION. BECAUSE 1+Z IS IN [1/2,3/2],
  555. |--THERE ARE ONLY TWO CASES.
  556. |--CASE 1: 1+Z < 1, THEN K = -1 AND Y-F = (2-F) + 2Z
  557. |--CASE 2: 1+Z > 1, THEN K = 0  AND Y-F = (1-F) + Z
  558. |--ON RETURNING TO LP1CONT1, WE MUST HAVE K IN FP1, ADDRESS OF
  559. |--(1/F) IN A0, Y-F IN FP0, AND FP2 SAVED.
  561. movel a6@(XFRAC),a6@(FFRAC)
  562. andil #0xFE000000,a6@(FFRAC)
  563. oril #0x01000000,a6@(FFRAC) |...F OBTAINED
  564. cmpil #0x3FFF8000,d0 |...SEE IF 1+Z > 1
  565. jge  KISZERO
  567. KISNEG1:
  568. fmoves TWO,fp0
  569. movel #0x3fff0000,a6@(F)
  570. clrl a6@(F+8)
  571. fsubx a6@(F),fp0 |...2-F
  572. movel a6@(FFRAC),d0
  573. andil #0x7E000000,d0
  574. asrl #8,d0
  575. asrl #8,d0
  576. asrl #4,d0 |...D0 CONTAINS DISPLACEMENT FOR 1/F
  577. faddx fp1,fp1 |...GET 2Z
  578. fmovemx fp2/fp3,a7@- |...SAVE fp2
  579. faddx fp1,fp0 |...FP0 IS Y-F = (2-F)+2Z
  580. lea LOGTBL,a0 |...A0 IS ADDRESS OF 1/F
  581. addal d0,a0
  582. fmoves negone,fp1 |...FP1 IS K = -1
  583. jra  LP1CONT1
  585. KISZERO:
  586. fmoves one,fp0
  587. movel #0x3fff0000,a6@(F)
  588. clrl a6@(F+8)
  589. fsubx a6@(F),fp0 |...1-F
  590. movel a6@(FFRAC),d0
  591. andil #0x7E000000,d0
  592. asrl #8,d0
  593. asrl #8,d0
  594. asrl #4,d0
  595. faddx fp1,fp0 |...FP0 IS Y-F
  596. fmovemx fp2/fp3,a7@- |...FP2 SAVED
  597. lea LOGTBL,a0
  598. addal d0,a0   |...A0 IS ADDRESS OF 1/F
  599. fmoves zero,fp1 |...FP1 IS K = 0
  600. jra  LP1CONT1
  602. LP1NEG0:
  603. |--fpcr SAVED. D0 IS X IN COMPACT FORM.
  604. cmpil #0,d0
  605. jlt  LP1NEG
  606. LP1ZERO:
  607. fmoves negone,fp0
  609. fmovel d1,fpcr
  610. jra  __x_t_dz
  612. LP1NEG:
  613. fmoves zero,fp0
  615. fmovel d1,fpcr
  616. jra  __x_t_operr
  618. | end