开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > VxWorks > 查看源码
l_stwotox.s
资源名称：vxwork_src.rar　[点击查看]
上传用户：nvosite88
上传日期：2007-01-17
资源大小：4983k
文件大小：13k
源码类别：

VxWorks

开发平台：

C/C++

l_stwotox.s：源码内容
  1. /* l_stowtox.s - Motorola 68040 FP power-of-two routines (LIB) */
  3. /* Copyright 1991-1993 Wind River Systems, Inc. */
  4. .data
  5. .globl _copyright_wind_river
  6. .long _copyright_wind_river
  8. /*
  9. modification history
  10. --------------------
  11. 01e,21jul93,kdl  added .text (SPR #2372).
  12. 01d,23aug92,jcf  changed bxxx to jxx.
  13. 01c,26may92,rrr  the tree shuffle
  14. 01b,10jan92,kdl  added modification history; general cleanup.
  15. 01a,15aug91,kdl  original version, from Motorola FPSP v2.0.
  16. */
  18. /*
  19. DESCRIPTION
  21. stwotoxsa 3.1 12/10/90
  23. __l_stwotox  --- 2**X
  24. __l_stwotoxd --- 2**X for denormalized X
  25. __l_stentox  --- 10**X
  26. __l_stentoxd --- 10**X for denormalized X
  28. Input: Double-extended number X in location pointed to
  29. by address register a0.
  31. Output: The function values are returned in Fp0.
  33. Accuracy and Monotonicity: The returned result is within 2 ulps in
  34. 64 significant bit, i.e. within 0.5001 ulp to 53 bits if the
  35. result is subsequently rounded to double precision. The
  36. result is provably monotonic in double precision.
  38. Speed: The program __l_stwotox takes approximately 190 cycles and the
  39. program __l_stentox takes approximately 200 cycles.
  41. Algorithm:
  43. twotox
  44. 1. If |X| > 16480, go to ExpBig.
  46. 2. If |X| < 2**(-70), go to ExpSm.
  48. 3. Decompose X as X = N/64 + r where |r| <= 1/128. Furthermore
  49. decompose N as
  50.  N = 64(M + M') + j,  j = 0,1,2,...,63.
  52. 4. Overwrite r := r * log2. Then
  53. 2**X = 2**(M') * 2**(M) * 2**(j/64) * exp(r).
  54. Go to expr to compute that expression.
  56. tentox
  57. 1. If |X| > 16480*log_10(2) (base 10 log of 2), go to ExpBig.
  59. 2. If |X| < 2**(-70), go to ExpSm.
  61. 3. Set y := X*log_2(10)*64 (base 2 log of 10). Set
  62. N := round-to-int(y). Decompose N as
  63.  N = 64(M + M') + j,  j = 0,1,2,...,63.
  65. 4. Define r as
  66. r := ((X - N*L1)-N*L2) * L10
  67. where L1, L2 are the leading and trailing parts of log_10(2)/64
  68. and L10 is the natural log of 10. Then
  69. 10**X = 2**(M') * 2**(M) * 2**(j/64) * exp(r).
  70. Go to expr to compute that expression.
  72. expr
  73. 1. Fetch 2**(j/64) from table as Fact1 and Fact2.
  75. 2. Overwrite Fact1 and Fact2 by
  76. Fact1 := 2**(M) * Fact1
  77. Fact2 := 2**(M) * Fact2
  78. Thus Fact1 + Fact2 = 2**(M) * 2**(j/64).
  80. 3. Calculate P where 1 + P approximates exp(r):
  81. P = r + r*r*(A1+r*(A2+...+r*A5)).
  83. 4. Let AdjFact := 2**(M'). Return
  84. AdjFact * ( Fact1 + ((Fact1*P) + Fact2) ).
  85. Exit.
  87. ExpBig
  88. 1. Generate overflow by Huge * Huge if X > 0|  otherwise, generate
  89. underflow by Tiny * Tiny.
  91. ExpSm
  92. 1. Return 1 + X.
  95. Copyright (C) Motorola, Inc. 1990
  96. All Rights Reserved
  98. THIS IS UNPUBLISHED PROPRIETARY SOURCE CODE OF MOTOROLA
  99. The copyright notice above does not evidence any
  100. actual or intended publication of such source code.
  102. STWOTOX idnt 2,1 Motorola 040 Floating Point Software Package
  104. section 8
  106. NOMANUAL
  107. */
  109. #include "fpsp040L.h"
  111. BOUNDS1: .long 0x3FB98000,0x400D80C0 |... 2^(-70),16480
  112. BOUNDS2: .long 0x3FB98000,0x400B9B07 |... 2^(-70),16480 LOG2/LOG10
  114. L2TEN64: .long 0x406A934F,0x0979A371 |... 64LOG10/LOG2
  115. L10TWO1: .long 0x3F734413,0x509F8000 |... LOG2/64LOG10
  117. L10TWO2: .long 0xBFCD0000,0xC0219DC1,0xDA994FD2,0x00000000
  119. LOG10: .long 0x40000000,0x935D8DDD,0xAAA8AC17,0x00000000
  121. LOG2: .long 0x3FFE0000,0xB17217F7,0xD1CF79AC,0x00000000
  123. EXPA5: .long 0x3F56C16D,0x6F7BD0B2
  124. EXPA4: .long 0x3F811112,0x302C712C
  125. EXPA3: .long 0x3FA55555,0x55554CC1
  126. EXPA2: .long 0x3FC55555,0x55554A54
  127. EXPA1: .long 0x3FE00000,0x00000000,0x00000000,0x00000000
  129. HUGE: .long 0x7FFE0000,0xFFFFFFFF,0xFFFFFFFF,0x00000000
  130. TINY: .long 0x00010000,0xFFFFFFFF,0xFFFFFFFF,0x00000000
  132. EXPTBL:
  133. .long  0x3FFF0000,0x80000000,0x00000000,0x3F738000
  134. .long  0x3FFF0000,0x8164D1F3,0xBC030773,0x3FBEF7CA
  135. .long  0x3FFF0000,0x82CD8698,0xAC2BA1D7,0x3FBDF8A9
  136. .long  0x3FFF0000,0x843A28C3,0xACDE4046,0x3FBCD7C9
  137. .long  0x3FFF0000,0x85AAC367,0xCC487B15,0xBFBDE8DA
  138. .long  0x3FFF0000,0x871F6196,0x9E8D1010,0x3FBDE85C
  139. .long  0x3FFF0000,0x88980E80,0x92DA8527,0x3FBEBBF1
  140. .long  0x3FFF0000,0x8A14D575,0x496EFD9A,0x3FBB80CA
  141. .long  0x3FFF0000,0x8B95C1E3,0xEA8BD6E7,0xBFBA8373
  142. .long  0x3FFF0000,0x8D1ADF5B,0x7E5BA9E6,0xBFBE9670
  143. .long  0x3FFF0000,0x8EA4398B,0x45CD53C0,0x3FBDB700
  144. .long  0x3FFF0000,0x9031DC43,0x1466B1DC,0x3FBEEEB0
  145. .long  0x3FFF0000,0x91C3D373,0xAB11C336,0x3FBBFD6D
  146. .long  0x3FFF0000,0x935A2B2F,0x13E6E92C,0xBFBDB319
  147. .long  0x3FFF0000,0x94F4EFA8,0xFEF70961,0x3FBDBA2B
  148. .long  0x3FFF0000,0x96942D37,0x20185A00,0x3FBE91D5
  149. .long  0x3FFF0000,0x9837F051,0x8DB8A96F,0x3FBE8D5A
  150. .long  0x3FFF0000,0x99E04593,0x20B7FA65,0xBFBCDE7B
  151. .long  0x3FFF0000,0x9B8D39B9,0xD54E5539,0xBFBEBAAF
  152. .long  0x3FFF0000,0x9D3ED9A7,0x2CFFB751,0xBFBD86DA
  153. .long  0x3FFF0000,0x9EF53260,0x91A111AE,0xBFBEBEDD
  154. .long  0x3FFF0000,0xA0B0510F,0xB9714FC2,0x3FBCC96E
  155. .long  0x3FFF0000,0xA2704303,0x0C496819,0xBFBEC90B
  156. .long  0x3FFF0000,0xA43515AE,0x09E6809E,0x3FBBD1DB
  157. .long  0x3FFF0000,0xA5FED6A9,0xB15138EA,0x3FBCE5EB
  158. .long  0x3FFF0000,0xA7CD93B4,0xE965356A,0xBFBEC274
  159. .long  0x3FFF0000,0xA9A15AB4,0xEA7C0EF8,0x3FBEA83C
  160. .long  0x3FFF0000,0xAB7A39B5,0xA93ED337,0x3FBECB00
  161. .long  0x3FFF0000,0xAD583EEA,0x42A14AC6,0x3FBE9301
  162. .long  0x3FFF0000,0xAF3B78AD,0x690A4375,0xBFBD8367
  163. .long  0x3FFF0000,0xB123F581,0xD2AC2590,0xBFBEF05F
  164. .long  0x3FFF0000,0xB311C412,0xA9112489,0x3FBDFB3C
  165. .long  0x3FFF0000,0xB504F333,0xF9DE6484,0x3FBEB2FB
  166. .long  0x3FFF0000,0xB6FD91E3,0x28D17791,0x3FBAE2CB
  167. .long  0x3FFF0000,0xB8FBAF47,0x62FB9EE9,0x3FBCDC3C
  168. .long  0x3FFF0000,0xBAFF5AB2,0x133E45FB,0x3FBEE9AA
  169. .long  0x3FFF0000,0xBD08A39F,0x580C36BF,0xBFBEAEFD
  170. .long  0x3FFF0000,0xBF1799B6,0x7A731083,0xBFBCBF51
  171. .long  0x3FFF0000,0xC12C4CCA,0x66709456,0x3FBEF88A
  172. .long  0x3FFF0000,0xC346CCDA,0x24976407,0x3FBD83B2
  173. .long  0x3FFF0000,0xC5672A11,0x5506DADD,0x3FBDF8AB
  174. .long  0x3FFF0000,0xC78D74C8,0xABB9B15D,0xBFBDFB17
  175. .long  0x3FFF0000,0xC9B9BD86,0x6E2F27A3,0xBFBEFE3C
  176. .long  0x3FFF0000,0xCBEC14FE,0xF2727C5D,0xBFBBB6F8
  177. .long  0x3FFF0000,0xCE248C15,0x1F8480E4,0xBFBCEE53
  178. .long  0x3FFF0000,0xD06333DA,0xEF2B2595,0xBFBDA4AE
  179. .long  0x3FFF0000,0xD2A81D91,0xF12AE45A,0x3FBC9124
  180. .long  0x3FFF0000,0xD4F35AAB,0xCFEDFA1F,0x3FBEB243
  181. .long  0x3FFF0000,0xD744FCCA,0xD69D6AF4,0x3FBDE69A
  182. .long  0x3FFF0000,0xD99D15C2,0x78AFD7B6,0xBFB8BC61
  183. .long  0x3FFF0000,0xDBFBB797,0xDAF23755,0x3FBDF610
  184. .long  0x3FFF0000,0xDE60F482,0x5E0E9124,0xBFBD8BE1
  185. .long  0x3FFF0000,0xE0CCDEEC,0x2A94E111,0x3FBACB12
  186. .long  0x3FFF0000,0xE33F8972,0xBE8A5A51,0x3FBB9BFE
  187. .long  0x3FFF0000,0xE5B906E7,0x7C8348A8,0x3FBCF2F4
  188. .long  0x3FFF0000,0xE8396A50,0x3C4BDC68,0x3FBEF22F
  189. .long  0x3FFF0000,0xEAC0C6E7,0xDD24392F,0xBFBDBF4A
  190. .long  0x3FFF0000,0xED4F301E,0xD9942B84,0x3FBEC01A
  191. .long  0x3FFF0000,0xEFE4B99B,0xDCDAF5CB,0x3FBE8CAC
  192. .long  0x3FFF0000,0xF281773C,0x59FFB13A,0xBFBCBB3F
  193. .long  0x3FFF0000,0xF5257D15,0x2486CC2C,0x3FBEF73A
  194. .long  0x3FFF0000,0xF7D0DF73,0x0AD13BB9,0xBFB8B795
  195. .long  0x3FFF0000,0xFA83B2DB,0x722A033A,0x3FBEF84B
  196. .long  0x3FFF0000,0xFD3E0C0C,0xF486C175,0xBFBEF581
  198. #define N L_SCR1
  200. #define X FP_SCR1
  201. #define XDCARE X+2
  202. #define XFRAC X+4
  204. #define ADJFACT FP_SCR2
  206. #define FACT1 FP_SCR3
  207. #define FACT1HI FACT1+4
  208. #define FACT1LOW  FACT1+8
  210. #define FACT2 FP_SCR4
  211. #define FACT2HI FACT2+4
  212. #define FACT2LOW  FACT2+8
  214. | xref __l_t_unfl
  215. | xref __l_t_ovfl
  216. | xref __l_t_frcinx
  219. .text
  221. .globl __l_stwotoxd
  222. __l_stwotoxd:
  223. |--ENTRY POINT FOR 2**(X) FOR DENORMALIZED ARGUMENT
  225. fmovel d1,fpcr /* set user's rounding mode/precision */
  226. .long 0xf23c4400,0x3f800000 /* fmoves  &0x3F800000,fp0 */
  227. movel a0@,d0
  228. orl #0x00800001,d0
  229. fadds d0,fp0
  230. jra  __l_t_frcinx
  232. .globl __l_stwotox
  233. __l_stwotox:
  234. /* |--ENTRY POINT FOR 2**(X), HERE X IS FINITE, NON-ZERO, AND NOT NAN'S */
  235. fmovemx a0@,fp0-fp0 /* |...lOAD INPUT, do not set cc's */
  237. movel A0@,d0
  238. movew A0@(4),d0
  239. fmovex fp0,a6@(X)
  240. andil #0x7FFFFFFF,d0
  242. cmpil #0x3FB98000,d0 |...|X| >= 2**(-70)?
  243. jge  TWOOK1
  244. jra  EXPBORS
  246. TWOOK1:
  247. cmpil #0x400D80C0,d0 |...|X| > 16480?
  248. jle  TWOMAIN
  249. jra  EXPBORS
  252. TWOMAIN:
  253. |--USUAL CASE, 2^(-70) <= |X| <= 16480
  255. fmovex fp0,fp1
  256. .long 0xf23c44a3,0x42800000 /* fmuls  &0x42800000,fp1 */
  258. fmovel fp1,a6@(N) |...N = ROUND-TO-INT(64 X)
  259. movel d2,a7@-
  260. lea EXPTBL,a1  |...lOAD ADDRESS OF TABLE OF 2^(J/64)
  261. fmovel a6@(N),fp1 |...N --> FLOATING FMT
  262. movel a6@(N),d0
  263. movel d0,d2
  264. andil #0x3F,d0 |...D0 IS J
  265. asll #4,d0 |...DISPLACEMENT FOR 2^(J/64)
  266. addal d0,a1 |...ADDRESS FOR 2^(J/64)
  267. asrl #6,d2 |...d2 IS L, N = 64L + J
  268. movel d2,d0
  269. asrl #1,d0 |...D0 IS M
  270. subl d0,d2 /* |...d2 IS M', N = 64(M+M') + J */
  271. addil #0x3FFF,d2
  272. movew d2,a6@(ADJFACT) /* |...ADJFACT IS 2^(M') */
  273. movel a7@+,d2
  274. |--SUMMARY: a1 IS ADDRESS FOR THE LEADING PORTION OF 2^(J/64),
  275. /* |--D0 IS M WHERE N = 64(M+M') + J. NOTE THAT |M| <= 16140 BY DESIGN. */
  276. /* |--ADJFACT = 2^(M'). */
  277. |--REGISTERS SAVED SO FAR ARE (IN ORDER) fpcr, D0, FP1, a1, AND FP2.
  279. .long 0xf23c44a3,0x3c800000 /* fmuls  &0x3C800000,fp1 */
  280. movel a1@+,a6@(FACT1)
  281. movel a1@+,a6@(FACT1HI)
  282. movel a1@+,a6@(FACT1LOW)
  283. movew a1@+,a6@(FACT2)
  284. clrw a6@(FACT2+2)
  286. fsubx fp1,fp0   |...X - (1/64)*INT(64 X)
  288. movew a1@+,a6@(FACT2HI)
  289. clrw a6@(FACT2HI+2)
  290. clrl a6@(FACT2LOW)
  291. addw d0,a6@(FACT1)
  293. fmulx LOG2,fp0 |...FP0 IS R
  294. addw d0,a6@(FACT2)
  296. jra  expr
  298. EXPBORS:
  299. |--fpcr, D0 SAVED
  300. cmpil #0x3FFF8000,d0
  301. jgt  EXPBIG
  303. EXPSM:
  304. |--|X| IS SMALL, RETURN 1 + X
  306. fmovel d1,fpcr | restore users exceptions
  307. .long 0xf23c4422,0x3f800000 /* fadds  &0x3F800000,fp0 */
  309. jra  __l_t_frcinx
  311. EXPBIG:
  312. |--|X| IS LARGE, GENERATE OVERFLOW IF X > 0|  ELSE GENERATE UNDERFLOW
  313. |--REGISTERS SAVE SO FAR ARE fpcr AND  D0
  314. movel a6@(X),d0
  315. cmpil #0,d0
  316. jlt  EXPNEG
  318. bclr #7,a0@ | t_ovfl expects positive value
  319. jra  __l_t_ovfl
  321. EXPNEG:
  322. bclr #7,a0@ | t_unfl expects positive value
  323. jra  __l_t_unfl
  325. .globl __l_stentoxd
  326. __l_stentoxd:
  327. |--ENTRY POINT FOR 10**(X) FOR DENORMALIZED ARGUMENT
  329. fmovel d1,fpcr /* set user's rounding mode/precision */
  330. .long 0xf23c4400,0x3f800000 /* fmoves  &0x3F800000,fp0 */
  331. movel a0@,d0
  332. orl #0x00800001,d0
  333. fadds d0,fp0
  334. jra  __l_t_frcinx
  336. .globl __l_stentox
  337. __l_stentox:
  338. /* |--ENTRY POINT FOR 10**(X), HERE X IS FINITE, NON-ZERO, AND NOT NAN'S */
  339. fmovemx a0@,fp0-fp0 /* |...lOAD INPUT, do not set cc's */
  341. movel A0@,d0
  342. movew A0@(4),d0
  343. fmovex fp0,a6@(X)
  344. andil #0x7FFFFFFF,d0
  346. cmpil #0x3FB98000,d0 |...|X| >= 2**(-70)?
  347. jge  TENOK1
  348. jra  EXPBORS
  350. TENOK1:
  351. cmpil #0x400B9B07,d0 |...|X| <= 16480*log2/log10 ?
  352. jle  TENMAIN
  353. jra  EXPBORS
  355. TENMAIN:
  356. |--USUAL CASE, 2^(-70) <= |X| <= 16480 LOG 2 / LOG 10
  358. fmovex fp0,fp1
  359. fmuld L2TEN64,fp1 |...X*64*LOG10/LOG2
  361. fmovel fp1,a6@(N) |...N=INT(X*64*LOG10/LOG2)
  362. movel d2,a7@-
  363. lea EXPTBL,a1  |...LOAD ADDRESS OF TABLE OF 2^(J/64)
  364. fmovel a6@(N),fp1 |...N --> FLOATING FMT
  365. movel a6@(N),d0
  366. movel d0,d2
  367. andil #0x3F,d0 |...D0 IS J
  368. asll #4,d0 |...DISPLACEMENT FOR 2^(J/64)
  369. addal d0,a1 |...ADDRESS FOR 2^(J/64)
  370. asrl #6,d2 |...d2 IS L, N = 64L + J
  371. movel d2,d0
  372. asrl #1,d0 |...D0 IS M
  373. subl d0,d2 /* |...d2 IS M', N = 64(M+M') + J */
  374. addil #0x3FFF,d2
  375. movew d2,a6@(ADJFACT) /* |...ADJFACT IS 2^(M') */
  376. movel a7@+,d2
  378. |--SUMMARY: a1 IS ADDRESS FOR THE LEADING PORTION OF 2^(J/64),
  379. /* |--D0 IS M WHERE N = 64(M+M') + J. NOTE THAT |M| <= 16140 BY DESIGN. */
  380. /* |--ADJFACT = 2^(M'). */
  381. |--REGISTERS SAVED SO FAR ARE (IN ORDER) fpcr, D0, FP1, a1, AND FP2.
  383. fmovex fp1,fp2
  385. fmuld L10TWO1,fp1 |...N*(LOG2/64LOG10)_LEAD
  386. movel a1@+,a6@(FACT1)
  388. fmulx L10TWO2,fp2 |...N*(LOG2/64LOG10)_TRAIL
  390. movel a1@+,a6@(FACT1HI)
  391. movel a1@+,a6@(FACT1LOW)
  392. fsubx fp1,fp0 |...X - N L_LEAD
  393. movew a1@+,a6@(FACT2)
  395. fsubx fp2,fp0 |...X - N L_TRAIL
  397. clrw a6@(FACT2+2)
  398. movew a1@+,a6@(FACT2HI)
  399. clrw a6@(FACT2HI+2)
  400. clrl a6@(FACT2LOW)
  402. fmulx LOG10,fp0 |...FP0 IS R
  404. addw d0,a6@(FACT1)
  405. addw d0,a6@(FACT2)
  407. expr:
  408. |--fpcr, FP2, FP3 ARE SAVED IN ORDER AS SHOWN.
  409. /* |--ADJFACT CONTAINS 2**(M'), FACT1 + FACT2 = 2**(M) * 2**(J/64). */
  410. |--FP0 IS R. THE FOLLOWING CODE COMPUTES
  411. /* |-- 2**(M'+M) * 2**(J/64) * EXP(R) */
  413. fmovex fp0,fp1
  414. fmulx fp1,fp1 |...FP1 IS S = R*R
  416. fmoved EXPA5,fp2 |...FP2 IS a5
  417. fmoved EXPA4,fp3 |...FP3 IS a4
  419. fmulx fp1,fp2 |...FP2 IS S*A5
  420. fmulx fp1,fp3 |...FP3 IS S*A4
  422. faddd EXPA3,fp2 |...FP2 IS a3+S*A5
  423. faddd EXPA2,fp3 |...FP3 IS a2+S*A4
  425. fmulx fp1,fp2 |...FP2 IS S*(A3+S*A5)
  426. fmulx fp1,fp3 |...FP3 IS S*(A2+S*A4)
  428. faddd EXPA1,fp2 |...FP2 IS a1+S*(A3+S*A5)
  429. fmulx fp0,fp3 |...FP3 IS R*S*(A2+S*A4)
  431. fmulx fp1,fp2 |...FP2 IS S*(A1+S*(A3+S*A5))
  432. faddx fp3,fp0 |...FP0 IS R+R*S*(A2+S*A4)
  434. faddx fp2,fp0 |...FP0 IS EXP(R) - 1
  437. |--FINAL RECONSTRUCTION PROCESS
  438. |--EXP(X) = 2^M*2^(J/64) + 2^M*2^(J/64)*(EXP(R)-1)  -  (1 OR 0)
  440. fmulx a6@(FACT1),fp0
  441. faddx a6@(FACT2),fp0
  442. faddx a6@(FACT1),fp0
  444. fmovel d1,fpcr | restore users exceptions
  445. clrw a6@(ADJFACT+2)
  446. movel #0x80000000,a6@(ADJFACT+4)
  447. clrl a6@(ADJFACT+8)
  448. fmulx a6@(ADJFACT),fp0 |...FINAL ADJUSTMENT
  450. jra  __l_t_frcinx
  452. | end