开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > VxWorks > 查看源码
util.s
资源名称：vxwork_src.rar　[点击查看]
上传用户：nvosite88
上传日期：2007-01-17
资源大小：4983k
文件大小：19k
源码类别：

VxWorks

开发平台：

C/C++

util.s：源码内容
  1. /* util.s - Motorola 68040 FP utility routines (EXC) */
  3. /* Copyright 1991-1993 Wind River Systems, Inc. */
  4. .data
  5. .globl _copyright_wind_river
  6. .long _copyright_wind_river
  8. /*
  9. modification history
  10. --------------------
  11. 01f,21jul93,kdl  added .text (SPR #2372).
  12. 01e,23aug92,jcf  changed bxxx to jxx.
  13. 01d,26may92,rrr  the tree shuffle
  14. 01c,10jan92,kdl  general cleanup.
  15. 01b,17dec91,kdl  put in changes from Motorola v3.7 (FPSP v2.1):
  16.  handle implied precision in __x_ovf_r_k;
  17.  comment-out __x_check_force routine.
  18. 01a,15aug91,kdl  original version, from Motorola FPSP v2.0;
  19.  changed {byte,word,long}_d{0-7} labels to avoid
  20.  confusion when converting to mit format.
  21. */
  23. /*
  24. DESCRIPTION
  27. utilsa 3.3 4/26/91
  29. This file contains routines used by other programs.
  31. __x_ovf_res: used by overflow to force the correct
  32.      result. __x_ovf_r_k, __x_ovf_r_x2, __x_ovf_r_x3 are
  33.      derivatives of this routine.
  34. __x_get_fline: get user's opcode word
  35. __x_g_dfmtou: returns the destination format.
  36. __x_g_opcls: returns the opclass of the float instruction.
  37. __x_g_rndpr: returns the rounding precision.
  38. __x_reg_dest: write byte, word, or long data to Dn
  41. Copyright (C) Motorola, Inc. 1990
  42. All Rights Reserved
  44. THIS IS UNPUBLISHED PROPRIETARY SOURCE CODE OF MOTOROLA
  45. The copyright notice above does not evidence any
  46. actual or intended publication of such source code.
  48. UTIL idnt    2,1 Motorola 040 Floating Point Software Package
  50. section 8
  52. NOMANUAL
  53. */
  55. #include "fpsp040E.h"
  57. | xref __x_mem_read
  59. .globl __x_g_dfmtou
  60. .globl __x_g_opcls
  61. .globl __x_g_rndpr
  62. .globl __x_get_fline
  63. .globl __x_reg_dest
  65. |
  66. | Final result table for __x_ovf_res. Note that the negative counterparts
  67. | are unnecessary as __x_ovf_res always returns the sign separately from
  68. | the exponent.
  69. | | +inf
  70. EXT_PINF: .long 0x7fff0000,0x00000000,0x00000000,0x00000000
  71. | | largest +ext
  72. EXT_PLRG: .long 0x7ffe0000,0xffffffff,0xffffffff,0x00000000
  73. | | largest magnitude +sgl in ext
  74. SGL_PLRG: .long 0x407e0000,0xffffff00,0x00000000,0x00000000
  75. | | largest magnitude +dbl in ext
  76. DBL_PLRG: .long 0x43fe0000,0xffffffff,0xfffff800,0x00000000
  77. | | largest -ext
  79. tblovfl:
  80. .long EXT_RN
  81. .long EXT_RZ
  82. .long EXT_RM
  83. .long EXT_RP
  84. .long SGL_RN
  85. .long SGL_RZ
  86. .long SGL_RM
  87. .long SGL_RP
  88. .long DBL_RN
  89. .long DBL_RZ
  90. .long DBL_RM
  91. .long DBL_RP
  92. .long error
  93. .long error
  94. .long error
  95. .long error
  97. | .globl __x_check_force
  98. |
  99. |  __x_check_force --- check the rounding precision of the instruction
  100. |
  101. | This entry point is used by the exception handlers.
  102. |
  103. | Check the CMDREG1B or CMDREG3B command word to decide the rounding
  104. | precision of the instruction.
  105. |
  106. | Input: rounding precision in a6@(USER_FPCR).
  107. | Output: a6@(USER_FPCR) is possibly modified to reflect the
  108. | rounding precision of the instruction.
  109. | Register Usage: d0 is scratch register.
  111. |__x_check_force:
  112. | btst #E3,a6@(E_BYTE) | check for nu exception
  113. | jeq  e1_exc | it is cu exception
  114. |e3_exc:
  115. | movew a6@(CMDREG3B),d0 | get the command word
  116. | andiw #0x00000060,d0 | clear all bits except 6 and 5
  117. | cmpil #0x00000040,d0
  118. | jeq  f_sgl | force precision is single
  119. | cmpil #0x00000060,d0
  120. | jeq  f_dbl | force precision is double
  121. | movew a6@(CMDREG3B),d0 | get the command word again
  122. | andil #0x7f,d0 | clear all except operation
  123. | cmpil #0x33,d0
  124. | jeq  f_sglmd | fsglmul or fsgldiv
  125. | cmpil #0x30,d0
  126. | jeq  f_sglmd
  127. | rts
  128. |e1_exc:
  129. | movew a6@(CMDREG1B),d0 | get command word
  130. | andil #0x00000044,d0 | clear all bits except 6 and 2
  131. | cmpil #0x00000040,d0
  132. | jeq  f_sgl | the instruction is force single
  133. | cmpil #0x00000044,d0
  134. | jeq  f_dbl | the instruction is force double
  135. | movew a6@(CMDREG1B),d0 | again get the command word
  136. | andil #0x0000007f,d0 | clear all except the op code
  137. | cmpil #0x00000027,d0
  138. | jeq  f_sglmd | fsglmul
  139. | cmpil  #0x00000024,d0
  140. | jeq  f_sglmd | fsgldiv
  141. | rts
  142. |f_sgl:
  143. | andib #0x3f,a6@(fpcr_MODE) | single precision
  144. | orib #0x40,a6@(fpcr_MODE)
  145. | rts
  146. |f_dbl:
  147. | andib #0x3f,a6@(fpcr_MODE)
  148. | orib #0x80,a6@(fpcr_MODE)
  149. | rts
  150. |f_sglmd:
  151. | andib #0x3f,a6@(fpcr_MODE)
  152. | rts
  154. |
  155. | __x_ovf_r_k --- overflow result calculation
  156. |
  157. | This entry point is used by kernel_ex.
  158. |
  159. | This forces the destination precision to be extended
  160. |
  161. | Input: operand in ETEMP
  162. | Output: a result is in ETEMP (internal extended format)
  163. |
  165. .text
  167. .globl __x_ovf_r_k
  168. __x_ovf_r_k:
  169. lea a6@(ETEMP),a0 | a0 points to source operand
  170. bclr #sign_bit,a6@(ETEMP_EX)
  171. sne a6@(ETEMP_SGN) | convert to internal IEEE format
  173. |
  174. | __x_ovf_r_x2 --- overflow result calculation
  175. |
  176. | This entry point used by x_ovfl.  (opclass 0 and 2)
  177. |
  178. | Input a0  points to an operand in the internal extended format
  179. | Output a0  points to the result in the internal extended format
  180. |
  181. | This sets the round precision according to the user fpcr unless the
  182. | instruction is fsgldiv or fsglmul or fsadd, fdadd, fsub, fdsub, fsmul,
  183. | fdmul, fsdiv, fddiv, fssqrt, fsmove, fdmove, fsabs, fdabs, fsneg, fdneg.
  184. | If the instruction is fsgldiv of fsglmul, the rounding precision must be
  185. | extended.  If the instruction is not fsgldiv or fsglmul but a force-
  186. | precision instruction, the rounding precision is then set to the force
  187. | precision.
  189. .globl __x_ovf_r_x2
  190. __x_ovf_r_x2:
  191. btst #E3,a6@(E_BYTE) | check for nu exception
  192. jeq  ovf_e1_exc | it is cu exception
  193. ovf_e3_exc:
  194. movew a6@(CMDREG3B),d0 | get the command word
  195. andiw #0x00000060,d0 | clear all bits except 6 and 5
  196. cmpil #0x00000040,d0
  197. jeq  ovff_sgl | force precision is single
  198. cmpil #0x00000060,d0
  199. jeq  ovff_dbl | force precision is double
  200. movew a6@(CMDREG3B),d0 | get the command word again
  201. andil #0x7f,d0 | clear all except operation
  202. cmpil #0x33,d0
  203. jeq  ovf_fsgl | fsglmul or fsgldiv
  204. cmpil #0x30,d0
  205. jeq  ovf_fsgl
  206. jra  ovf_fpcr | instruction is none of the above
  207. | | use fpcr
  208. ovf_e1_exc:
  209. movew a6@(CMDREG1B),d0 | get command word
  210. andil #0x00000044,d0 | clear all bits except 6 and 2
  211. cmpil #0x00000040,d0
  212. jeq  ovff_sgl | the instruction is force single
  213. cmpil #0x00000044,d0
  214. jeq  ovff_dbl | the instruction is force double
  215. movew a6@(CMDREG1B),d0 | again get the command word
  216. andil #0x0000007f,d0 | clear all except the op code
  217. cmpil #0x00000027,d0
  218. jeq  ovf_fsgl | fsglmul
  219. cmpil  #0x00000024,d0
  220. jeq  ovf_fsgl | fsgldiv
  221. jra  ovf_fpcr | none of the above, use fpcr
  222. |
  223. |
  224. | Inst is either fsgldiv or fsglmul.  Force extended precision.
  225. |
  226. ovf_fsgl:
  227. clrl d0
  228. jra  __x_ovf_res
  230. ovff_sgl:
  231. movel #0x00000001,d0 | set single
  232. jra  __x_ovf_res
  233. ovff_dbl:
  234. movel #0x00000002,d0 | set double
  235. jra  __x_ovf_res
  236. |
  237. | The precision is in the fpcr.
  238. |
  239. ovf_fpcr:
  240. bfextu a6@(fpcr_MODE){#0:#2},d0 | set round precision
  241. jra  __x_ovf_res
  243. |
  244. |
  245. | __x_ovf_r_x3 --- overflow result calculation
  246. |
  247. | This entry point used by x_ovfl. (opclass 3 only)
  248. |
  249. | Input a0  points to an operand in the internal extended format
  250. | Output a0  points to the result in the internal extended format
  251. |
  252. | This sets the round precision according to the destination size.
  253. |
  254. .globl __x_ovf_r_x3
  255. __x_ovf_r_x3:
  256. bsrl __x_g_dfmtou | get dest fmt in d0{1:0}
  257. | | for fmovout, the destination format
  258. | | is the rounding precision
  260. |
  261. | __x_ovf_res --- overflow result calculation
  262. |
  263. | Input:
  264. | a0  points to operand in internal extended format
  265. | Output:
  266. | a0  points to result in internal extended format
  267. |
  268. .globl __x_ovf_res
  269. __x_ovf_res:
  270. lsll #2,d0 | move round precision to d0{3:2}
  271. bfextu a6@(fpcr_MODE){#2:#2},d1 | set round mode
  272. orl d1,d0 | index is fmt:mode in d0{3:0}
  273. lea tblovfl,a1 | load a1 with table address
  274. movel a1@(d0:w:4),a1 | use d0 as index to the table
  275. jmp a1@ | go to the correct routine
  276. |
  277. |case DEST_FMT = EXT
  278. |
  279. EXT_RN:
  280. lea EXT_PINF,a1 | answer is +/- infinity
  281. bset #inf_bit,a6@(FPSR_CC)
  282. jra  set_sign | now go set the sign
  283. EXT_RZ:
  284. lea EXT_PLRG,a1 | answer is +/- large number
  285. jra  set_sign | now go set the sign
  286. EXT_RM:
  287. tstb a0@(LOCAL_SGN) | if negative overflow
  288. jeq  e_rm_pos
  289. e_rm_neg:
  290. lea EXT_PINF,a1 | answer is negative infinity
  291. orl #neginf_mask,a6@(USER_FPSR)
  292. jra  end_ovfr
  293. e_rm_pos:
  294. lea EXT_PLRG,a1 | answer is large positive number
  295. jra  end_ovfr
  296. EXT_RP:
  297. tstb a0@(LOCAL_SGN) | if negative overflow
  298. jeq  e_rp_pos
  299. e_rp_neg:
  300. lea EXT_PLRG,a1 | answer is large negative number
  301. bset #neg_bit,a6@(FPSR_CC)
  302. jra  end_ovfr
  303. e_rp_pos:
  304. lea EXT_PINF,a1 | answer is positive infinity
  305. bset #inf_bit,a6@(FPSR_CC)
  306. jra  end_ovfr
  307. |
  308. |case DEST_FMT = DBL
  309. |
  310. DBL_RN:
  311. lea EXT_PINF,a1 | answer is +/- infinity
  312. bset #inf_bit,a6@(FPSR_CC)
  313. jra  set_sign
  314. DBL_RZ:
  315. lea DBL_PLRG,a1 | answer is +/- large number
  316. jra  set_sign | now go set the sign
  317. DBL_RM:
  318. tstb a0@(LOCAL_SGN) | if negative overflow
  319. jeq  d_rm_pos
  320. d_rm_neg:
  321. lea EXT_PINF,a1 | answer is negative infinity
  322. orl #neginf_mask,a6@(USER_FPSR)
  323. jra  end_ovfr | inf is same for all precisions (ext,dbl,sgl)
  324. d_rm_pos:
  325. lea DBL_PLRG,a1 | answer is large positive number
  326. jra  end_ovfr
  327. DBL_RP:
  328. tstb a0@(LOCAL_SGN) | if negative overflow
  329. jeq  d_rp_pos
  330. d_rp_neg:
  331. lea DBL_PLRG,a1 | answer is large negative number
  332. bset #neg_bit,a6@(FPSR_CC)
  333. jra  end_ovfr
  334. d_rp_pos:
  335. lea EXT_PINF,a1 | answer is positive infinity
  336. bset #inf_bit,a6@(FPSR_CC)
  337. jra  end_ovfr
  338. |
  339. |case DEST_FMT = SGL
  340. |
  341. SGL_RN:
  342. lea EXT_PINF,a1 | answer is +/-  infinity
  343. bset #inf_bit,a6@(FPSR_CC)
  344. jra  set_sign
  345. SGL_RZ:
  346. lea SGL_PLRG,a1 | anwer is +/- large number
  347. jra  set_sign
  348. SGL_RM:
  349. tstb a0@(LOCAL_SGN) | if negative overflow
  350. jeq  s_rm_pos
  351. s_rm_neg:
  352. lea EXT_PINF,a1 | answer is negative infinity
  353. orl #neginf_mask,a6@(USER_FPSR)
  354. jra  end_ovfr
  355. s_rm_pos:
  356. lea SGL_PLRG,a1 | answer is large positive number
  357. jra  end_ovfr
  358. SGL_RP:
  359. tstb a0@(LOCAL_SGN) | if negative overflow
  360. jeq  s_rp_pos
  361. s_rp_neg:
  362. lea SGL_PLRG,a1 | answer is large negative number
  363. bset #neg_bit,a6@(FPSR_CC)
  364. jra  end_ovfr
  365. s_rp_pos:
  366. lea EXT_PINF,a1 | answer is postive infinity
  367. bset #inf_bit,a6@(FPSR_CC)
  368. jra  end_ovfr
  370. set_sign:
  371. tstb a0@(LOCAL_SGN) | if negative overflow
  372. jeq  end_ovfr
  373. neg_sign:
  374. bset #neg_bit,a6@(FPSR_CC)
  376. end_ovfr:
  377. movew a1@(LOCAL_EX),a0@(LOCAL_EX) | do not overwrite sign
  378. movel a1@(LOCAL_HI),a0@(LOCAL_HI)
  379. movel a1@(LOCAL_LO),a0@(LOCAL_LO)
  380. rts
  383. |
  384. | ERROR
  385. |
  386. error:
  387. rts
  388. |
  389. | __x_get_fline --- get f-line opcode of interrupted instruction
  390. |
  391. | Returns opcode in the low word of d0.
  392. |
  393. __x_get_fline:
  394. movel a6@(USER_fpi),a0 | opcode address
  395. movel #0,a7@- | reserve a word on the stack
  396. lea a7@(2),a1 | point to low word of temporary
  397. movel #2,d0 | count
  398. bsrl __x_mem_read
  399. movel a7@+,d0
  400. rts
  401. |
  402. |  __x_g_rndpr --- put rounding precision in d0{1:0}
  403. |
  404. | valid return codes are:
  405. | 00 - extended
  406. | 01 - single
  407. | 10 - double
  408. |
  409. | begin
  410. | get rounding precision (cmdreg3b{6:5})
  411. | begin
  412. |  case opclass = 011 (move out)
  413. | get destination format - this is the also the rounding precision
  414. |
  415. |  case opclass = 0x0
  416. | if E3
  417. |     *case RndPr(from cmdreg3b{6:5} = 11  then RND_PREC = DBL
  418. |     *case RndPr(from cmdreg3b{6:5} = 10  then RND_PREC = SGL
  419. |      case RndPr(from cmdreg3b{6:5} = 00 | 01
  420. | use precision from fpcr{7:6}
  421. | case 00 then RND_PREC = EXT
  422. | case 01 then RND_PREC = SGL
  423. | case 10 then RND_PREC = DBL
  424. | else E1
  425. |      use precision in fpcr{7:6}
  426. |      case 00 then RND_PREC = EXT
  427. |      case 01 then RND_PREC = SGL
  428. |      case 10 then RND_PREC = DBL
  429. | end
  430. |
  431. __x_g_rndpr:
  432. bsrl __x_g_opcls | get opclass in d0{2:0}
  433. cmpw #0x0003,d0 | check for opclass 011
  434. jne  op_0x0
  436. |
  437. | For move out instructions (opclass 011) the destination format
  438. | is the same as the rounding precision.  Pass results from __x_g_dfmtou.
  439. |
  440. bsrl  __x_g_dfmtou
  441. rts
  442. op_0x0:
  443. btst #E3,a6@(E_BYTE)
  444. jeq  unf_e1_exc | branch to e1 underflow
  445. unf_e3_exc:
  446. movel a6@(CMDREG3B),d0 | rounding precision in d0{10:9}
  447. bfextu d0{#9:#2},d0 | move the rounding prec bits to d0{1:0}
  448. cmpil #0x2,d0
  449. jeq  unff_sgl | force precision is single
  450. cmpil #0x3,d0 | force precision is double
  451. jeq  unff_dbl
  452. movew a6@(CMDREG3B),d0 | get the command word again
  453. andil #0x7f,d0 | clear all except operation
  454. cmpil #0x33,d0
  455. jeq  unf_fsgl | fsglmul or fsgldiv
  456. cmpil #0x30,d0
  457. jeq  unf_fsgl | fsgldiv or fsglmul
  458. jra  unf_fpcr
  459. unf_e1_exc:
  460. movel a6@(CMDREG1B),d0 | get 32 bits off the stack, 1st 16 bits
  461. | | are the command word
  462. andil #0x00440000,d0 | clear all bits except bits 6 and 2
  463. cmpil #0x00400000,d0
  464. jeq  unff_sgl | force single
  465. cmpil #0x00440000,d0 | force double
  466. jeq  unff_dbl
  467. movel a6@(CMDREG1B),d0 | get the command word again
  468. andil #0x007f0000,d0 | clear all bits except the operation
  469. cmpil #0x00270000,d0
  470. jeq  unf_fsgl | fsglmul
  471. cmpil #0x00240000,d0
  472. jeq  unf_fsgl | fsgldiv
  473. jra  unf_fpcr
  475. |
  476. | Convert to return format.  The values from cmdreg3b and the return
  477. | values are:
  478. | cmdreg3b return      precision
  479. | -------- ------      ---------
  480. |   00,01   0 ext
  481. |    10   1 sgl
  482. |    11   2 dbl
  483. | Force single
  484. |
  485. unff_sgl:
  486. movel #1,d0 | return 1
  487. rts
  488. |
  489. | Force double
  490. |
  491. unff_dbl:
  492. movel #2,d0 | return 2
  493. rts
  494. |
  495. | Force extended
  496. |
  497. unf_fsgl:
  498. movel #0,d0
  499. rts
  500. |
  501. | Get rounding precision set in fpcr{7:6}.
  502. |
  503. unf_fpcr:
  504. movel a6@(USER_FPCR),d0  | rounding precision bits in d0{7:6}
  505. bfextu d0{#24:#2},d0 | move the rounding prec bits to d0{1:0}
  506. rts
  507. |
  508. | __x_g_opcls --- put opclass in d0{2:0}
  509. |
  510. __x_g_opcls:
  511. btst #E3,a6@(E_BYTE)
  512. jeq  opc_1b | if set, go to cmdreg1b
  513. opc_3b:
  514. clrl d0 | if E3, only opclass 0x0 is possible
  515. rts
  516. opc_1b:
  517. movel a6@(CMDREG1B),d0
  518. bfextu d0{#0:#3},d0 | shift opclass bits d0{31:29} to d0{2:0}
  519. rts
  520. |
  521. | __x_g_dfmtou --- put destination format in d0{1:0}
  522. |
  523. | If E1, the format is from cmdreg1b{12:10}
  524. | If E3, the format is extended.
  525. |
  526. | Dest. Fmt.
  527. | extended  010 -> 00
  528. | single    001 -> 01
  529. | double    101 -> 10
  530. |
  531. __x_g_dfmtou:
  532. btst #E3,a6@(E_BYTE)
  533. jeq  op011
  534. clrl d0 | if E1, size is always ext
  535. rts
  536. op011:
  537. movel a6@(CMDREG1B),d0
  538. bfextu d0{#3:#3},d0 | dest fmt from cmdreg1b{12:10}
  539. cmpb #1,d0 | check for single
  540. jne  not_sgl
  541. movel #1,d0
  542. rts
  543. not_sgl:
  544. cmpb #5,d0 | check for double
  545. jne  not_dbl
  546. movel #2,d0
  547. rts
  548. not_dbl:
  549. clrl d0 | must be extended
  550. rts
  552. |
  553. |
  554. | Final result table for __x_unf_sub. Note that the negative counterparts
  555. | are unnecessary as __x_unf_sub always returns the sign separately from
  556. | the exponent.
  557. | | +zero
  558. EXT_PZRO: .long 0x00000000,0x00000000,0x00000000,0x00000000
  559. | | +zero
  560. SGL_PZRO: .long 0x3f810000,0x00000000,0x00000000,0x00000000
  561. | | +zero
  562. DBL_PZRO: .long 0x3c010000,0x00000000,0x00000000,0x00000000
  563. | | smallest +ext denorm
  564. EXT_PSML: .long 0x00000000,0x00000000,0x00000001,0x00000000
  565. | | smallest +sgl denorm
  566. SGL_PSML: .long 0x3f810000,0x00000100,0x00000000,0x00000000
  567. | | smallest +dbl denorm
  568. DBL_PSML: .long 0x3c010000,0x00000000,0x00000800,0x00000000
  569. |
  570. | UNF_SUB --- underflow result calculation
  571. |
  572. | Input:
  573. | d0  contains round precision
  574. | a0 points to input operand in the internal extended format
  575. |
  576. | Output:
  577. | a0  points to correct internal extended precision result.
  578. |
  580. tblunf:
  581. .long uEXT_RN
  582. .long uEXT_RZ
  583. .long uEXT_RM
  584. .long uEXT_RP
  585. .long uSGL_RN
  586. .long uSGL_RZ
  587. .long uSGL_RM
  588. .long uSGL_RP
  589. .long uDBL_RN
  590. .long uDBL_RZ
  591. .long uDBL_RM
  592. .long uDBL_RP
  593. .long uDBL_RN
  594. .long uDBL_RZ
  595. .long uDBL_RM
  596. .long uDBL_RP
  598. .globl __x_unf_sub
  599. __x_unf_sub:
  600. lsll #2,d0 | move round precision to d0{3:2}
  601. bfextu a6@(fpcr_MODE){#2:#2},d1 | set round mode
  602. orl d1,d0 | index is fmt:mode in d0{3:0}
  603. lea tblunf,a1 | load a1 with table address
  604. movel a1@(d0:w:4),a1 | use d0 as index to the table
  605. jmp a1@ | go to the correct routine
  606. |
  607. |case DEST_FMT = EXT
  608. |
  609. uEXT_RN:
  610. lea EXT_PZRO,a1 | answer is +/- zero
  611. bset #z_bit,a6@(FPSR_CC)
  612. jra  uset_sign | now go set the sign
  613. uEXT_RZ:
  614. lea EXT_PZRO,a1 | answer is +/- zero
  615. bset #z_bit,a6@(FPSR_CC)
  616. jra  uset_sign | now go set the sign
  617. uEXT_RM:
  618. tstb a0@(LOCAL_SGN) | if negative underflow
  619. jeq  ue_rm_pos
  620. ue_rm_neg:
  621. lea EXT_PSML,a1 | answer is negative smallest denorm
  622. bset #neg_bit,a6@(FPSR_CC)
  623. jra  end_unfr
  624. ue_rm_pos:
  625. lea EXT_PZRO,a1 | answer is positive zero
  626. bset #z_bit,a6@(FPSR_CC)
  627. jra  end_unfr
  628. uEXT_RP:
  629. tstb a0@(LOCAL_SGN) | if negative underflow
  630. jeq  ue_rp_pos
  631. ue_rp_neg:
  632. lea EXT_PZRO,a1 | answer is negative zero
  633. oril #negz_mask,a6@(USER_FPSR)
  634. jra  end_unfr
  635. ue_rp_pos:
  636. lea EXT_PSML,a1 | answer is positive smallest denorm
  637. jra  end_unfr
  638. |
  639. |case DEST_FMT = DBL
  640. |
  641. uDBL_RN:
  642. lea DBL_PZRO,a1 | answer is +/- zero
  643. bset #z_bit,a6@(FPSR_CC)
  644. jra  uset_sign
  645. uDBL_RZ:
  646. lea DBL_PZRO,a1 | answer is +/- zero
  647. bset #z_bit,a6@(FPSR_CC)
  648. jra  uset_sign | now go set the sign
  649. uDBL_RM:
  650. tstb a0@(LOCAL_SGN) | if negative overflow
  651. jeq  ud_rm_pos
  652. ud_rm_neg:
  653. lea DBL_PSML,a1 | answer is smallest denorm negative
  654. bset #neg_bit,a6@(FPSR_CC)
  655. jra  end_unfr
  656. ud_rm_pos:
  657. lea DBL_PZRO,a1 | answer is positive zero
  658. bset #z_bit,a6@(FPSR_CC)
  659. jra  end_unfr
  660. uDBL_RP:
  661. tstb a0@(LOCAL_SGN) | if negative overflow
  662. jeq  ud_rp_pos
  663. ud_rp_neg:
  664. lea DBL_PZRO,a1 | answer is negative zero
  665. oril #negz_mask,a6@(USER_FPSR)
  666. jra  end_unfr
  667. ud_rp_pos:
  668. lea DBL_PSML,a1 | answer is smallest denorm negative
  669. jra  end_unfr
  670. |
  671. |case DEST_FMT = SGL
  672. |
  673. uSGL_RN:
  674. lea SGL_PZRO,a1 | answer is +/- zero
  675. bset #z_bit,a6@(FPSR_CC)
  676. jra  uset_sign
  677. uSGL_RZ:
  678. lea SGL_PZRO,a1 | answer is +/- zero
  679. bset #z_bit,a6@(FPSR_CC)
  680. jra  uset_sign
  681. uSGL_RM:
  682. tstb a0@(LOCAL_SGN) | if negative overflow
  683. jeq  us_rm_pos
  684. us_rm_neg:
  685. lea SGL_PSML,a1 | answer is smallest denorm negative
  686. bset #neg_bit,a6@(FPSR_CC)
  687. jra  end_unfr
  688. us_rm_pos:
  689. lea SGL_PZRO,a1 | answer is positive zero
  690. bset #z_bit,a6@(FPSR_CC)
  691. jra  end_unfr
  692. uSGL_RP:
  693. tstb a0@(LOCAL_SGN) | if negative overflow
  694. jeq  us_rp_pos
  695. us_rp_neg:
  696. lea SGL_PZRO,a1 | answer is negative zero
  697. oril #negz_mask,a6@(USER_FPSR)
  698. jra  end_unfr
  699. us_rp_pos:
  700. lea SGL_PSML,a1 | answer is smallest denorm positive
  701. jra  end_unfr
  703. uset_sign:
  704. tstb a0@(LOCAL_SGN) | if negative overflow
  705. jeq  end_unfr
  706. uneg_sign:
  707. bset #neg_bit,a6@(FPSR_CC)
  709. end_unfr:
  710. movew a1@(LOCAL_EX),a0@(LOCAL_EX) | be careful not to overwrite sign
  711. movel a1@(LOCAL_HI),a0@(LOCAL_HI)
  712. movel a1@(LOCAL_LO),a0@(LOCAL_LO)
  713. rts
  714. |
  715. | __x_reg_dest --- write byte, word, or long data to Dn
  716. |
  717. |
  718. | Input:
  719. | L_SCR1: Data
  720. | d1:     data size and dest register number formatted as:
  721. |
  722. | 32 5    4     3     2     1     0
  723. |       -----------------------------------------------
  724. |       |        0        |    Size   |  Dest Reg #   |
  725. |       -----------------------------------------------
  726. |
  727. | Size is:
  728. | 0 - Byte
  729. | 1 - Word
  730. | 2 - Long/Single
  731. |
  732. pregdst:
  733. .long __byte_d0
  734. .long __byte_d1
  735. .long __byte_d2
  736. .long __byte_d3
  737. .long __byte_d4
  738. .long __byte_d5
  739. .long __byte_d6
  740. .long __byte_d7
  741. .long __word_d0
  742. .long __word_d1
  743. .long __word_d2
  744. .long __word_d3
  745. .long __word_d4
  746. .long __word_d5
  747. .long __word_d6
  748. .long __word_d7
  749. .long __long_d0
  750. .long __long_d1
  751. .long __long_d2
  752. .long __long_d3
  753. .long __long_d4
  754. .long __long_d5
  755. .long __long_d6
  756. .long __long_d7
  758. __x_reg_dest:
  759. lea pregdst,a0
  760. movel a0@(d1:w:4),a0
  761. jmp a0@
  763. __byte_d0:
  764. moveb a6@(L_SCR1),a6@(USER_D0+3)
  765. rts
  766. __byte_d1:
  767. moveb a6@(L_SCR1),a6@(USER_D1+3)
  768. rts
  769. __byte_d2:
  770. moveb a6@(L_SCR1),d2
  771. rts
  772. __byte_d3:
  773. moveb a6@(L_SCR1),d3
  774. rts
  775. __byte_d4:
  776. moveb a6@(L_SCR1),d4
  777. rts
  778. __byte_d5:
  779. moveb a6@(L_SCR1),d5
  780. rts
  781. __byte_d6:
  782. moveb a6@(L_SCR1),d6
  783. rts
  784. __byte_d7:
  785. moveb a6@(L_SCR1),d7
  786. rts
  787. __word_d0:
  788. movew a6@(L_SCR1),a6@(USER_D0+2)
  789. rts
  790. __word_d1:
  791. movew a6@(L_SCR1),a6@(USER_D1+2)
  792. rts
  793. __word_d2:
  794. movew a6@(L_SCR1),d2
  795. rts
  796. __word_d3:
  797. movew a6@(L_SCR1),d3
  798. rts
  799. __word_d4:
  800. movew a6@(L_SCR1),d4
  801. rts
  802. __word_d5:
  803. movew a6@(L_SCR1),d5
  804. rts
  805. __word_d6:
  806. movew a6@(L_SCR1),d6
  807. rts
  808. __word_d7:
  809. movew a6@(L_SCR1),d7
  810. rts
  811. __long_d0:
  812. movel a6@(L_SCR1),a6@(USER_D0)
  813. rts
  814. __long_d1:
  815. movel a6@(L_SCR1),a6@(USER_D1)
  816. rts
  817. __long_d2:
  818. movel a6@(L_SCR1),d2
  819. rts
  820. __long_d3:
  821. movel a6@(L_SCR1),d3
  822. rts
  823. __long_d4:
  824. movel a6@(L_SCR1),d4
  825. rts
  826. __long_d5:
  827. movel a6@(L_SCR1),d5
  828. rts
  829. __long_d6:
  830. movel a6@(L_SCR1),d6
  831. rts
  832. __long_d7:
  833. movel a6@(L_SCR1),d7
  834. rts
  835. | end