开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > VxWorks > 查看源码
l_do_func.s
资源名称：vxwork_src.rar　[点击查看]
上传用户：nvosite88
上传日期：2007-01-17
资源大小：4983k
文件大小：14k
源码类别：

VxWorks

开发平台：

C/C++

l_do_func.s：源码内容
  1. /* l_do_func.s - Motorola 68040 FP routine jump table (LIB) */
  3. /* Copyright 1991-1993 Wind River Systems, Inc. */
  4. .data
  5. .globl _copyright_wind_river
  6. .long _copyright_wind_river
  8. /*
  9. modification history
  10. --------------------
  11. 01g,31may96,ms   updated to mototorola version 2.3
  12. 01f,14jun95,tpr  changed fbxx to fbxxl.
  13. 01e,21jul93,kdl  added .text (SPR #2372).
  14. 01d,23aug92,jcf  changed bxxx to jxx.
  15. 01c,26may92,rrr  the tree shuffle
  16. 01b,09jan92,kdl  added modification history; general cleanup.
  17. 01a,15aug91,kdl  original version, from Motorola FPSP v2.0.
  18. /
  20. /*
  21. DESCRIPTION
  23. __l_do_funcsa 3.4 2/18/91
  25. Do_func performs the unimplemented operation.  The operation
  26. to be performed is determined from the lower 7 bits of the
  27. extension word (except in the case of fmovecr and fsincos).
  28. The opcode and tag bits form an index into a jump table in
  29. tbldosa.  Cases of zero, infinity and NaN are handled in
  30. __l_do_func by forcing the default result.  Normalized and
  31. denormalized (there are no unnormalized numbers at this
  32. point) are passed onto the emulation code.
  34. CMDREG1B and STAG are extracted from the fsave frame
  35. and combined to form the table index.  The function called
  36. will start with a0 pointing to the ETEMP operand.  Dyadic
  37. functions can find FPTEMP at a0@(-12).
  39. Called functions return their result in fp0.  Sincos returns
  40. sin(x) in fp0 and cos(x) in fp1.
  43. Copyright (C) Motorola, Inc. 1990
  44. All Rights Reserved
  46. THIS IS UNPUBLISHED PROPRIETARY SOURCE CODE OF MOTOROLA
  47. The copyright notice above does not evidence any
  48. actual or intended publication of such source code.
  50. DO_FUNC idnt    2,1 Motorola 040 Floating Point Software Package
  52. section 8
  54. NOMANUAL
  55. */
  57. #include "fpsp040L.h"
  59. | xref __l_t_dz2
  60. | xref __l_t_operr
  61. | xref __l_t_inx2
  62. | xref  __l_t_resdnrm
  63. | xref __l_dst_nan
  64. | xref __l_src_nan
  65. | xref __l_nrm_set
  66. | xref __l_sto_cos
  68. | xref __l_slognp1,__l_slogn,__l_slog10,__l_slog2
  69. | xref __l_slognd,__l_slog10d,__l_slog2d
  70. | xref __l_smod,__l_srem
  71. | xref __l_sscale
  73. PONE: .long 0x3fff0000,0x80000000,0x00000000 | +1
  74. MONE: .long 0xbfff0000,0x80000000,0x00000000 | -1
  75. PZERO: .long 0x00000000,0x00000000,0x00000000 | +0
  76. MZERO: .long 0x80000000,0x00000000,0x00000000 | -0
  77. PINF: .long 0x7fff0000,0x00000000,0x00000000 | +inf
  78. MINF: .long 0xffff0000,0x00000000,0x00000000 | -inf
  79. QNAN: .long 0x7fff0000,0xffffffff,0xffffffff | non-signaling nan
  80. PPIBY2:  .long 0x3FFF0000,0xC90FDAA2,0x2168C235 | +PI/2
  81. MPIBY2:  .long 0xbFFF0000,0xC90FDAA2,0x2168C235 | -PI/2
  83. |
  84. | These routines load forced values into fp0.  They are called
  85. | by index into tbldo.
  86. |
  87. | Load a signed zero to fp0 and set inex2/ainex
  88. |
  90. .text
  92. .globl __l_snzrinx
  93. __l_snzrinx:
  94. btst #sign_bit,a0@(LOCAL_EX) | get sign of source operand
  95. jne  ld_mzinx | if negative, branch
  96. bsrl __l_ld_pzero | bsr so we can return and set inx
  97. jra  __l_t_inx2 | now, set the inx for the next inst
  98. ld_mzinx:
  99. bsrl __l_ld_mzero | if neg, load neg zero, return here
  100. jra  __l_t_inx2 | now, set the inx for the next inst
  101. |
  102. | Load a signed zero to fp0|  do not set inex2/ainex
  103. |
  104. .globl __l_szero
  105. __l_szero:
  106. btst #sign_bit,a0@(LOCAL_EX) | get sign of source operand
  107. jne  __l_ld_mzero | if neg, load neg zero
  108. jra  __l_ld_pzero | load positive zero
  109. |
  110. | Load a signed infinity to fp0|  do not set inex2/ainex
  111. |
  112. .globl __l_sinf
  113. __l_sinf:
  114. btst #sign_bit,a0@(LOCAL_EX) | get sign of source operand
  115. jne  __l_ld_minf | if negative branch
  116. jra  __l_ld_pinf
  117. |
  118. | Load a signed one to fp0|  do not set inex2/ainex
  119. |
  120. .globl __l_sone
  121. __l_sone:
  122. btst #sign_bit,a0@(LOCAL_EX) | check sign of source
  123. jne  __l_ld_mone
  124. jra  __l_ld_pone
  125. |
  126. | Load a signed pi/2 to fp0|  do not set inex2/ainex
  127. |
  128. .globl __l_spi_2
  129. __l_spi_2:
  130. btst #sign_bit,a0@(LOCAL_EX) | check sign of source
  131. jne  __l_ld_mpi2
  132. jra  __l_ld_ppi2
  133. |
  134. | Load either a +0 or +inf for plus/minus operand
  135. |
  136. .globl __l_szr_inf
  137. __l_szr_inf:
  138. btst #sign_bit,a0@(LOCAL_EX) | check sign of source
  139. jne  __l_ld_pzero
  140. jra  __l_ld_pinf
  141. |
  142. | Result is either an operr or +inf for plus/minus operand
  143. | [Used by __l_slogn, __l_slognp1, __l_slog10, and __l_slog2]
  144. |
  145. .globl __l_sopr_inf
  146. __l_sopr_inf:
  147. btst #sign_bit,a0@(LOCAL_EX) | check sign of source
  148. jne  __l_t_operr
  149. jra  __l_ld_pinf
  150. |
  151. | FLOGNP1
  152. |
  153. .globl __l_sslognp1
  154. __l_sslognp1:
  155. fmovemx a0@,fp0-fp0
  156. fcmpb #-1,fp0
  157. fbgtl __l_slognp1
  158. fbeql __l_t_dz2 | if = -1, divide by zero exception
  159. fmovel #0,FPSR | clr N flag
  160. jra  __l_t_operr | take care of operands < -1
  161. |
  162. | FETOXM1
  163. |
  164. .globl __l_setoxm1i
  165. __l_setoxm1i:
  166. btst #sign_bit,a0@(LOCAL_EX) | check sign of source
  167. jne  __l_ld_mone
  168. jra  __l_ld_pinf
  169. |
  170. | FLOGN
  171. |
  172. | Test for 1.0 as an input argument, returning +zero.  Also check
  173. | the sign and return operr if negative.
  174. |
  175. .globl __l_sslogn
  176. __l_sslogn:
  177. btst #sign_bit,a0@(LOCAL_EX)
  178. jne  __l_t_operr | take care of operands < 0
  179. cmpiw #0x3fff,a0@(LOCAL_EX)  | test for 1.0 input
  180. jne  __l_slogn
  181. cmpil #0x80000000,a0@(LOCAL_HI)
  182. jne  __l_slogn
  183. tstl a0@(LOCAL_LO)
  184. jne  __l_slogn
  185. fmovex PZERO,fp0
  186. rts
  188. .globl __l_sslognd
  189. __l_sslognd:
  190. btst #sign_bit,a0@(LOCAL_EX)
  191. jeq  __l_slognd
  192. jra  __l_t_operr | take care of operands < 0
  194. |
  195. | FLOG10
  196. |
  197. .globl __l_sslog10
  198. __l_sslog10:
  199. btst #sign_bit,a0@(LOCAL_EX)
  200. jne  __l_t_operr | take care of operands < 0
  201. cmpiw #0x3fff,a0@(LOCAL_EX)  | test for 1.0 input
  202. jne  __l_slog10
  203. cmpil #0x80000000,a0@(LOCAL_HI)
  204. jne  __l_slog10
  205. tstl a0@(LOCAL_LO)
  206. jne  __l_slog10
  207. fmovex PZERO,fp0
  208. rts
  210. .globl __l_sslog10d
  211. __l_sslog10d:
  212. btst #sign_bit,a0@(LOCAL_EX)
  213. jeq  __l_slog10d
  214. jra  __l_t_operr | take care of operands < 0
  216. |
  217. | FLOG2
  218. |
  219. .globl __l_sslog2
  220. __l_sslog2:
  221. btst #sign_bit,a0@(LOCAL_EX)
  222. jne  __l_t_operr | take care of operands < 0
  223. cmpiw #0x3fff,a0@(LOCAL_EX)  | test for 1.0 input
  224. jne  __l_slog2
  225. cmpil #0x80000000,a0@(LOCAL_HI)
  226. jne  __l_slog2
  227. tstl a0@(LOCAL_LO)
  228. jne  __l_slog2
  229. fmovex PZERO,fp0
  230. rts
  232. .globl __l_sslog2d
  233. __l_sslog2d:
  234. btst #sign_bit,a0@(LOCAL_EX)
  235. jeq  __l_slog2d
  236. jra  __l_t_operr | take care of operands < 0
  238. |
  239. | FMOD
  240. |
  241. __l_pmodt:
  242. | | 0x21 fmod
  243. | | dtag,stag
  244. .long __l_smod |   00,00  norm,norm = normal
  245. .long __l_smod_oper |   00,01  norm,zero = nan with operr
  246. .long __l_smod_fpn |   00,10  norm,inf  = fpn
  247. .long __l_smod_snan |   00,11  norm,nan  = nan
  248. .long __l_smod_zro |   01,00  zero,norm = +-zero
  249. .long __l_smod_oper |   01,01  zero,zero = nan with operr
  250. .long __l_smod_zro |   01,10  zero,inf  = +-zero
  251. .long __l_smod_snan |   01,11  zero,nan  = nan
  252. .long __l_smod_oper |   10,00  inf,norm  = nan with operr
  253. .long __l_smod_oper |   10,01  inf,zero  = nan with operr
  254. .long __l_smod_oper |   10,10  inf,inf   = nan with operr
  255. .long __l_smod_snan |   10,11  inf,nan   = nan
  256. .long __l_smod_dnan |   11,00  nan,norm  = nan
  257. .long __l_smod_dnan |   11,01  nan,zero  = nan
  258. .long __l_smod_dnan |   11,10  nan,inf   = nan
  259. .long __l_smod_dnan |   11,11  nan,nan   = nan
  261. .globl __l_pmod
  262. __l_pmod:
  263. clr.b FPSR_QBYTE(a6)      | clear quotient field
  264. bfextu a6@(STAG){#0:#3},d0 | stag = d0
  265. bfextu a6@(DTAG){#0:#3},d1 | dtag = d1
  267. |
  268. | Alias extended denorms to norms for the jump table.
  269. |
  270. bclr #2,d0
  271. bclr #2,d1
  273. lslb #2,d1
  274. orb d0,d1 | d1{3:2} = dtag, d1{1:0} = stag
  275. | | Tag values:
  276. | | 00 = norm or denorm
  277. | | 01 = zero
  278. | | 10 = inf
  279. | | 11 = nan
  280. lea __l_pmodt,a1
  281. movel a1@(d1:w:4),a1
  282. jmp a1@
  284. __l_smod_snan:
  285. jra  __l_src_nan
  286. __l_smod_dnan:
  287. jra  __l_dst_nan
  288. __l_smod_oper:
  289. jra  __l_t_operr
  290. __l_smod_zro:
  291. moveb a6@(ETEMP),d1 | get sign of src op
  292. moveb a6@(FPTEMP),d0 | get sign of dst op
  293. eorb d0,d1 | get exor of sign bits
  294. btst #7,d1 | test for sign
  295. jeq  __l_smod_zsn | if clr, do not set sign big
  296. bset #q_sn_bit,a6@(FPSR_QBYTE) | set q-byte sign bit
  297. __l_smod_zsn:
  298. btst #7,d0 | test if + or -
  299. jeq  __l_ld_pzero | if pos then load +0
  300. jra  __l_ld_mzero | else neg load -0
  302. __l_smod_fpn:
  303. moveb a6@(ETEMP),d1 | get sign of src op
  304. moveb a6@(FPTEMP),d0 | get sign of dst op
  305. eorb d0,d1 | get exor of sign bits
  306. btst #7,d1 | test for sign
  307. jeq  __l_smod_fsn | if clr, do not set sign big
  308. bset #q_sn_bit,a6@(FPSR_QBYTE) | set q-byte sign bit
  309. __l_smod_fsn:
  310. tstb a6@(DTAG) | filter out denormal destination case
  311. jpl  __l_smod_nrm |
  312. lea a6@(FPTEMP),a0 | a0<- addr(FPTEMP)
  313. jra  __l_t_resdnrm | force UNFL(but exact) result
  314. __l_smod_nrm:
  315. fmovel a6@(USER_FPCR),fpcr  /* | use user's rmode and precision */
  316. fmovex a6@(FPTEMP),fp0 | return dest to fp0
  317. rts
  319. |
  320. | FREM
  321. |
  322. __l_premt:
  323. | | 0x25 frem
  324. | | dtag,stag
  325. .long __l_srem |   00,00  norm,norm = normal
  326. .long __l_srem_oper |   00,01  norm,zero = nan with operr
  327. .long __l_srem_fpn |   00,10  norm,inf  = fpn
  328. .long __l_srem_snan |   00,11  norm,nan  = nan
  329. .long __l_srem_zro |   01,00  zero,norm = +-zero
  330. .long __l_srem_oper |   01,01  zero,zero = nan with operr
  331. .long __l_srem_zro |   01,10  zero,inf  = +-zero
  332. .long __l_srem_snan |   01,11  zero,nan  = nan
  333. .long __l_srem_oper |   10,00  inf,norm  = nan with operr
  334. .long __l_srem_oper |   10,01  inf,zero  = nan with operr
  335. .long __l_srem_oper |   10,10  inf,inf   = nan with operr
  336. .long __l_srem_snan |   10,11  inf,nan   = nan
  337. .long __l_srem_dnan |   11,00  nan,norm  = nan
  338. .long __l_srem_dnan |   11,01  nan,zero  = nan
  339. .long __l_srem_dnan |   11,10  nan,inf   = nan
  340. .long __l_srem_dnan |   11,11  nan,nan   = nan
  342. .globl __l_prem
  343. __l_prem:
  344. clr.b FPSR_QBYTE(a6)      | clear quotient field
  345. bfextu a6@(STAG){#0:#3},d0 | stag = d0
  346. bfextu a6@(DTAG){#0:#3},d1 | dtag = d1
  347. |
  348. | Alias extended denorms to norms for the jump table.
  349. |
  350. bclr #2,d0
  351. bclr #2,d1
  353. lslb #2,d1
  354. orb d0,d1 | d1{3:2} = dtag, d1{1:0} = stag
  355. | | Tag values:
  356. | | 00 = norm or denorm
  357. | | 01 = zero
  358. | | 10 = inf
  359. | | 11 = nan
  360. lea __l_premt,a1
  361. movel a1@(d1:w:4),a1
  362. jmp a1@
  364. __l_srem_snan:
  365. jra  __l_src_nan
  366. __l_srem_dnan:
  367. jra  __l_dst_nan
  368. __l_srem_oper:
  369. jra  __l_t_operr
  370. __l_srem_zro:
  371. moveb a6@(ETEMP),d1 | get sign of src op
  372. moveb a6@(FPTEMP),d0 | get sign of dst op
  373. eorb d0,d1 | get exor of sign bits
  374. btst #7,d1 | test for sign
  375. jeq  __l_srem_zsn | if clr, do not set sign big
  376. bset #q_sn_bit,a6@(FPSR_QBYTE) | set q-byte sign bit
  377. __l_srem_zsn:
  378. btst #7,d0 | test if + or -
  379. jeq  __l_ld_pzero | if pos then load +0
  380. jra  __l_ld_mzero | else neg load -0
  382. __l_srem_fpn:
  383. moveb a6@(ETEMP),d1 | get sign of src op
  384. moveb a6@(FPTEMP),d0 | get sign of dst op
  385. eorb d0,d1 | get exor of sign bits
  386. btst #7,d1 | test for sign
  387. jeq  __l_srem_fsn | if clr, do not set sign big
  388. bset #q_sn_bit,a6@(FPSR_QBYTE) | set q-byte sign bit
  389. __l_srem_fsn:
  390. tstb a6@(DTAG) | filter out denormal destination case
  391. jpl  __l_srem_nrm |
  392. lea a6@(FPTEMP),a0 | a0<- addr(FPTEMP)
  393. jra  __l_t_resdnrm | force UNFL(but exact) result
  394. __l_srem_nrm:
  395. fmovel a6@(USER_FPCR),fpcr  /* | use user's rmode and precision */
  396. fmovex a6@(FPTEMP),fp0 | return dest to fp0
  397. rts
  398. |
  399. | FSCALE
  400. |
  401. __l_pscalet:
  402. | | 0x26 fscale
  403. | | dtag,stag
  404. .long __l_sscale |   00,00  norm,norm = result
  405. .long __l_sscale |   00,01  norm,zero = fpn
  406. .long scl_opr |   00,10  norm,inf  = nan with operr
  407. .long scl_snan |   00,11  norm,nan  = nan
  408. .long scl_zro |   01,00  zero,norm = +-zero
  409. .long scl_zro |   01,01  zero,zero = +-zero
  410. .long scl_opr |   01,10  zero,inf  = nan with operr
  411. .long scl_snan |   01,11  zero,nan  = nan
  412. .long scl_inf |   10,00  inf,norm  = +-inf
  413. .long scl_inf |   10,01  inf,zero  = +-inf
  414. .long scl_opr |   10,10  inf,inf   = nan with operr
  415.   .long scl_snan |   10,11  inf,nan   = nan
  416.   .long scl_dnan |   11,00  nan,norm  = nan
  417.   .long scl_dnan |   11,01  nan,zero  = nan
  418.   .long scl_dnan |   11,10  nan,inf   = nan
  419. .long scl_dnan |   11,11  nan,nan   = nan
  421. .globl __l_pscale
  422. __l_pscale:
  423. bfextu a6@(STAG){#0:#3},d0 | stag in d0
  424. bfextu a6@(DTAG){#0:#3},d1 | dtag in d1
  425. bclr #2,d0 | alias  denorm into norm
  426. bclr #2,d1 | alias  denorm into norm
  427. lslb #2,d1
  428. orb d0,d1 | d1{4:2} = dtag, d1{1:0} = stag
  429. | | dtag values     stag values:
  430. | | 000 = norm      00 = norm
  431. | | 001 = zero  01 = zero
  432. | | 010 = inf  10 = inf
  433. | | 011 = nan  11 = nan
  434. | | 100 = dnrm
  435. |
  436. |
  437. lea __l_pscalet,a1 | load start of jump table
  438. movel a1@(d1:w:4),a1 | load a1 with label depending on tag
  439. jmp a1@ | go to the routine
  441. scl_opr:
  442. jra  __l_t_operr
  444. scl_dnan:
  445. jra  __l_dst_nan
  447. scl_zro:
  448. btst #sign_bit,a6@(FPTEMP_EX) | test if + or -
  449. jeq  __l_ld_pzero | if pos then load +0
  450. jra  __l_ld_mzero | if neg then load -0
  451. scl_inf:
  452. btst #sign_bit,a6@(FPTEMP_EX) | test if + or -
  453. jeq  __l_ld_pinf | if pos then load +inf
  454. jra  __l_ld_minf | else neg load -inf
  455. scl_snan:
  456. jra  __l_src_nan
  457. |
  458. | FSINCOS
  459. |
  460. .globl __l_ssincosz
  461. __l_ssincosz:
  462. btst #sign_bit,a6@(ETEMP) | get sign
  463. jeq  sincosp
  464. fmovex MZERO,fp0
  465. jra  sincoscom
  466. sincosp:
  467. fmovex PZERO,fp0
  468. sincoscom:
  469.    fmovemx PONE,fp1-fp1 | do not allow FPSR to be affected
  470. jra  __l_sto_cos | store cosine result
  472. .globl __l_ssincosi
  473. __l_ssincosi:
  474. fmovex QNAN,fp1 | load NAN
  475. bsrl __l_sto_cos | store cosine result
  476. fmovex QNAN,fp0 | load NAN
  477. jra  __l_t_operr
  479. .globl __l_ssincosnan
  480. __l_ssincosnan:
  481. movel a6@(ETEMP_EX),a6@(FP_SCR1)
  482. movel a6@(ETEMP_HI),a6@(FP_SCR1+4)
  483. movel a6@(ETEMP_LO),a6@(FP_SCR1+8)
  484. bset #signan_bit,a6@(FP_SCR1+4)
  485. fmovemx a6@(FP_SCR1),fp1-fp1
  486. bsrl __l_sto_cos
  487. jra  __l_src_nan
  488. |
  489. | This code forces default values for the zero, inf, and nan cases
  490. | in the transcendentals code.  The CC bits must be set in the
  491. | stacked FPSR to be correctly reported.
  492. |
  493. |**Returns +PI/2
  494. .globl __l_ld_ppi2
  495. __l_ld_ppi2:
  496. fmovex PPIBY2,fp0 | load +pi/2
  497. jra  __l_t_inx2 | set inex2 exc
  499. |**Returns -PI/2
  500. .globl __l_ld_mpi2
  501. __l_ld_mpi2:
  502. fmovex MPIBY2,fp0 | load -pi/2
  503. orl #neg_mask,a6@(USER_FPSR) | set N bit
  504. jra  __l_t_inx2 | set inex2 exc
  506. |**Returns +inf
  507. .globl __l_ld_pinf
  508. __l_ld_pinf:
  509. fmovex PINF,fp0 | load +inf
  510. orl #inf_mask,a6@(USER_FPSR) | set I bit
  511. rts
  513. |**Returns -inf
  514. .globl __l_ld_minf
  515. __l_ld_minf:
  516. fmovex MINF,fp0 | load -inf
  517. orl #neg_mask+inf_mask,a6@(USER_FPSR) | set N and I bits
  518. rts
  520. |**Returns +1
  521. .globl __l_ld_pone
  522. __l_ld_pone:
  523. fmovex PONE,fp0 | load +1
  524. rts
  526. |**Returns -1
  527. .globl __l_ld_mone
  528. __l_ld_mone:
  529. fmovex MONE,fp0 | load -1
  530. orl #neg_mask,a6@(USER_FPSR) | set N bit
  531. rts
  533. |**Returns +0
  534. .globl __l_ld_pzero
  535. __l_ld_pzero:
  536. fmovex PZERO,fp0 | load +0
  537. orl #z_mask,a6@(USER_FPSR) | set Z bit
  538. rts
  540. |**Returns -0
  541. .globl __l_ld_mzero
  542. __l_ld_mzero:
  543. fmovex MZERO,fp0 | load -0
  544. orl #neg_mask+z_mask,a6@(USER_FPSR) | set N and Z bits
  545. rts
  547. | end