开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > VxWorks > 查看源码
get_op.s
资源名称：vxwork_src.rar　[点击查看]
上传用户：nvosite88
上传日期：2007-01-17
资源大小：4983k
文件大小：21k
源码类别：

VxWorks

开发平台：

C/C++

get_op.s：源码内容
  1. /* get_op.s - Motorola 68040 FP get opclass routine (EXC) */
  3. /* Copyright 1991-1993 Wind River Systems, Inc. */
  4. .data
  5. .globl _copyright_wind_river
  6. .long _copyright_wind_river
  8. /*
  9. modification history
  10. --------------------
  11. 01f,31may96,ms   updated to mototorola version 2.3
  12. 01e,21jul93,kdl  added .text (SPR #2372).
  13. 01d,23aug92,jcf  changed bxxx to jxx.
  14. 01c,26may92,rrr  the tree shuffle
  15. 01b,10jan92,kdl  added modification history; general cleanup.
  16. 01a,15aug91,kdl  original version, from Motorola FPSP v2.0.
  17. */
  19. /*
  20. DESCRIPTION
  23. get_opsa 3.5 4/26/91
  25.  Description: This routine is called by the unsupported format/data
  26. type exception handler ('unsupp' - vector 55) and the unimplemented
  27. instruction exception handler ('unimp' - vector 11).  'get_op'
  28. determines the opclass (0, 2, or 3) and branches to the
  29. opclass handler routine.  See 68881/2 User's Manual table 4-11
  30. for a description of the opclasses.
  32. For UNSUPPORTED data/format (exception vector 55) and for
  33. UNIMPLEMENTED instructions (exception vector 11) the following
  34. applies:
  36. - For unnormormalized numbers (opclass 0, 2, or 3) the
  37. number(s) is normalized and the operand type tag is updated.
  39. - For a packed number (opclass 2) the number is unpacked and the
  40. operand type tag is updated.
  42. - For denormalized numbers (opclass 0 or 2) the number(s) is not
  43. changed but passed to the next module.  The next module for
  44. unimp is __x_do_func, the next module for unsupp is __x_res_func.
  46. For UNSUPPORTED data/format (exception vector 55) only the
  47. following applies:
  49. - If there is a move out with a packed number (opclass 3) the
  50. number is packed and written to user memory.  For the other
  51. opclasses the number(s) are written back to the fsave stack
  52. and the instruction is then restored back into the '040.  The
  53. '040 is then able to complete the instruction.
  55. For example:
  56. faddx fpm,fpn where the fpm contains an unnormalized number.
  57. The '040 takes an unsupported data trap and gets to this
  58. routine.  The number is normalized, put back on the stack and
  59. then an frestore is done to restore the instruction back into
  60. the '040.  The '040 then re-executes the faddx fpm,fpn with
  61. a normalized number in the source and the instruction is
  62. successful.
  64. Next consider if in the process of normalizing the un-
  65. normalized number it becomes a denormalized number.  The
  66. routine which converts the unnorm to a norm (called mk_norm)
  67. detects this and tags the number as a denorm.  The routine
  68. __x_res_func sees the denorm tag and converts the denorm to a
  69. norm.  The instruction is then restored back into the '040
  70. which re_executess the instruction.
  73. Copyright (C) Motorola, Inc. 1990
  74. All Rights Reserved
  76. THIS IS UNPUBLISHED PROPRIETARY SOURCE CODE OF MOTOROLA
  77. The copyright notice above does not evidence any
  78. actual or intended publication of such source code.
  80. GET_OP    idnt    2,1 Motorola 040 Floating Point Software Package
  82. section 8
  84. NOMANUAL
  85. */
  87. #include "fpsp040E.h"
  89. .globl __x_PIRN,__x_PIRZRM,__x_PIRP
  90. .globl __x_SMALRN,__x_SMALRZRM,__x_SMALRP
  91. .globl __x_BIGRN,__x_BIGRZRM,__x_BIGRP
  93. __x_PIRN:
  94. .long 0x40000000,0xc90fdaa2,0x2168c235    | pi
  95. __x_PIRZRM:
  96. .long 0x40000000,0xc90fdaa2,0x2168c234    | pi
  97. __x_PIRP:
  98. .long 0x40000000,0xc90fdaa2,0x2168c235    | pi
  100. |round to nearest
  101. __x_SMALRN:
  102. .long 0x3ffd0000,0x9a209a84,0xfbcff798    | log10(2)
  103. .long 0x40000000,0xadf85458,0xa2bb4a9a    | e
  104. .long 0x3fff0000,0xb8aa3b29,0x5c17f0bc    | log2(e)
  105. .long 0x3ffd0000,0xde5bd8a9,0x37287195    | log10(e)
  106. .long 0x00000000,0x00000000,0x00000000    | 0.0
  107. | round to zero; round to negative infinity
  108. __x_SMALRZRM:
  109. .long 0x3ffd0000,0x9a209a84,0xfbcff798    | log10(2)
  110. .long 0x40000000,0xadf85458,0xa2bb4a9a    | e
  111. .long 0x3fff0000,0xb8aa3b29,0x5c17f0bb    | log2(e)
  112. .long 0x3ffd0000,0xde5bd8a9,0x37287195    | log10(e)
  113. .long 0x00000000,0x00000000,0x00000000    | 0.0
  114. | round to positive infinity
  115. __x_SMALRP:
  116. .long 0x3ffd0000,0x9a209a84,0xfbcff799    | log10(2)
  117. .long 0x40000000,0xadf85458,0xa2bb4a9b    | e
  118. .long 0x3fff0000,0xb8aa3b29,0x5c17f0bc    | log2(e)
  119. .long 0x3ffd0000,0xde5bd8a9,0x37287195    | log10(e)
  120. .long 0x00000000,0x00000000,0x00000000    | 0.0
  122. |round to nearest
  123. __x_BIGRN:
  124. .long 0x3ffe0000,0xb17217f7,0xd1cf79ac    | ln(2)
  125. .long 0x40000000,0x935d8ddd,0xaaa8ac17    | ln(10)
  126. .long 0x3fff0000,0x80000000,0x00000000    | 10 ^ 0
  128. .globl __x_PTENRN
  129. __x_PTENRN:
  130. .long 0x40020000,0xA0000000,0x00000000    | 10 ^ 1
  131. .long 0x40050000,0xC8000000,0x00000000    | 10 ^ 2
  132. .long 0x400C0000,0x9C400000,0x00000000    | 10 ^ 4
  133. .long 0x40190000,0xBEBC2000,0x00000000    | 10 ^ 8
  134. .long 0x40340000,0x8E1BC9BF,0x04000000    | 10 ^ 16
  135. .long 0x40690000,0x9DC5ADA8,0x2B70B59E    | 10 ^ 32
  136. .long 0x40D30000,0xC2781F49,0xFFCFA6D5    | 10 ^ 64
  137. .long 0x41A80000,0x93BA47C9,0x80E98CE0    | 10 ^ 128
  138. .long 0x43510000,0xAA7EEBFB,0x9DF9DE8E    | 10 ^ 256
  139. .long 0x46A30000,0xE319A0AE,0xA60E91C7    | 10 ^ 512
  140. .long 0x4D480000,0xC9767586,0x81750C17    | 10 ^ 1024
  141. .long 0x5A920000,0x9E8B3B5D,0xC53D5DE5    | 10 ^ 2048
  142. .long 0x75250000,0xC4605202,0x8A20979B    | 10 ^ 4096
  143. |round to minus infinity
  144. __x_BIGRZRM:
  145. .long 0x3ffe0000,0xb17217f7,0xd1cf79ab    | ln(2)
  146. .long 0x40000000,0x935d8ddd,0xaaa8ac16    | ln(10)
  147. .long 0x3fff0000,0x80000000,0x00000000    | 10 ^ 0
  149. .globl __x_PTENRM
  150. __x_PTENRM:
  151. .long 0x40020000,0xA0000000,0x00000000    | 10 ^ 1
  152. .long 0x40050000,0xC8000000,0x00000000    | 10 ^ 2
  153. .long 0x400C0000,0x9C400000,0x00000000    | 10 ^ 4
  154. .long 0x40190000,0xBEBC2000,0x00000000    | 10 ^ 8
  155. .long 0x40340000,0x8E1BC9BF,0x04000000    | 10 ^ 16
  156. .long 0x40690000,0x9DC5ADA8,0x2B70B59D    | 10 ^ 32
  157. .long 0x40D30000,0xC2781F49,0xFFCFA6D5    | 10 ^ 64
  158. .long 0x41A80000,0x93BA47C9,0x80E98CDF    | 10 ^ 128
  159. .long 0x43510000,0xAA7EEBFB,0x9DF9DE8D    | 10 ^ 256
  160. .long 0x46A30000,0xE319A0AE,0xA60E91C6    | 10 ^ 512
  161. .long 0x4D480000,0xC9767586,0x81750C17    | 10 ^ 1024
  162. .long 0x5A920000,0x9E8B3B5D,0xC53D5DE5    | 10 ^ 2048
  163. .long 0x75250000,0xC4605202,0x8A20979A    | 10 ^ 4096
  164. |round to positive infinity
  165. __x_BIGRP:
  166. .long 0x3ffe0000,0xb17217f7,0xd1cf79ac    | ln(2)
  167. .long 0x40000000,0x935d8ddd,0xaaa8ac17    | ln(10)
  168. .long 0x3fff0000,0x80000000,0x00000000    | 10 ^ 0
  170. .globl __x_PTENRP
  171. __x_PTENRP:
  172. .long 0x40020000,0xA0000000,0x00000000    | 10 ^ 1
  173. .long 0x40050000,0xC8000000,0x00000000    | 10 ^ 2
  174. .long 0x400C0000,0x9C400000,0x00000000    | 10 ^ 4
  175. .long 0x40190000,0xBEBC2000,0x00000000    | 10 ^ 8
  176. .long 0x40340000,0x8E1BC9BF,0x04000000    | 10 ^ 16
  177. .long 0x40690000,0x9DC5ADA8,0x2B70B59E    | 10 ^ 32
  178. .long 0x40D30000,0xC2781F49,0xFFCFA6D6    | 10 ^ 64
  179. .long 0x41A80000,0x93BA47C9,0x80E98CE0    | 10 ^ 128
  180. .long 0x43510000,0xAA7EEBFB,0x9DF9DE8E    | 10 ^ 256
  181. .long 0x46A30000,0xE319A0AE,0xA60E91C7    | 10 ^ 512
  182. .long 0x4D480000,0xC9767586,0x81750C18    | 10 ^ 1024
  183. .long 0x5A920000,0x9E8B3B5D,0xC53D5DE6    | 10 ^ 2048
  184. .long 0x75250000,0xC4605202,0x8A20979B    | 10 ^ 4096
  186. | xref __x_nrm_zero
  187. | xref __x_decbin
  188. | xref __x_round
  190. .globl    __x_get_op
  191. .globl    __x_uns_getop
  192. .globl    __x_uni_getop
  194. .text
  196. __x_get_op:
  197. clrb a6@(DY_MO_FLG)
  198. tstb a6@(UFLG_TMP) | test flag for unsupp/unimp state
  199. jeq  __x_uni_getop
  201. __x_uns_getop:
  202. btst #direction_bit,a6@(CMDREG1B)
  203. jne  opclass3 | branch if a fmovel out (any kind)
  204. btst #6,a6@(CMDREG1B)
  205. jeq  uns_notpacked
  207. bfextu a6@(CMDREG1B){#3:#3},d0
  208. cmpb #3,d0
  209. jeq  pack_source | check for a packed src op, branch if so
  210. uns_notpacked:
  211. bsrl chk_dy_mo | set the dyadic/monadic flag
  212. tstb a6@(DY_MO_FLG)
  213. jeq  src_op_ck | if monadic, go check src op
  214. | | else, check dst op (fall through)
  216. btst #7,a6@(DTAG)
  217. jeq  src_op_ck | if dst op is norm, check src op
  218. jra  dst_ex_dnrm | else, handle destination unnorm/dnrm
  220. __x_uni_getop:
  221. bfextu a6@(CMDREG1B){#0:#6},d0 | get opclass and src fields
  222. cmpil #0x17,d0 | if op class and size fields are 0x17,
  223. | | it is FMOVECR|  if not, continue
  224. |
  225. | If the instruction is fmovecr, exit __x_get_op.  It is handled
  226. | in __x_do_func and smovecrsa.
  227. |
  228. jne  not_fmovecr | handle fmovecr as an unimplemented inst
  229. rts
  231. not_fmovecr:
  232. btst #E1,a6@(E_BYTE) | if set, there is a packed operand
  233. jne  pack_source | check for packed src op, branch if so
  235. | The following lines of are coded to optimize on normalized operands
  236. moveb a6@(STAG),d0
  237. orb a6@(DTAG),d0 | check if either of STAG/DTAG msb set
  238. jmi  dest_op_ck | if so, some op needs to be fixed
  239. rts
  241. dest_op_ck:
  242. btst #7,a6@(DTAG) | check for unsupported data types in
  243. jeq  src_op_ck | the destination, if not, check src op
  244. bsrl chk_dy_mo | set dyadic/monadic flag
  245. tstb a6@(DY_MO_FLG) |
  246. jeq  src_op_ck | if monadic, check src op
  247. |
  248. | At this point, destination has an extended denorm or unnorm.
  249. |
  250. dst_ex_dnrm:
  251. movew a6@(FPTEMP_EX),d0 | get destination exponent
  252. andiw #0x7fff,d0 | mask sign, check if exp = 0000
  253. jeq  src_op_ck | if denorm then check source op.
  254. | | denorms are taken care of in __x_res_func
  255. | | (unsupp) or __x_do_func (unimp)
  256. | | else unnorm fall through
  257. lea a6@(FPTEMP),a0 | point a0 to dop - used in mk_norm
  258. bsrl mk_norm | go normalize - mk_norm returns:
  259. | | L_SCR1{7:5} = operand tag
  260. | |  (000 = norm, 100 = denorm)
  261. | | L_SCR1{4} = fpte15 or ete15
  262. | |  0 = exp >  0x3fff
  263. | |  1 = exp <= 0x3fff
  264. | | and puts the normalized num back
  265. | | on the fsave stack
  266. |
  267. moveb a6@(L_SCR1),a6@(DTAG) | write the new tag # fpte15
  268. | | to the fsave stack and fall
  269. | | through to check source operand
  270. |
  271. src_op_ck:
  272. btst #7,a6@(STAG)
  273. jeq  end_getop | check for unsupported data types on the
  274. | | source operand
  275. btst #5,a6@(STAG)
  276. jne  src_sd_dnrm | if bit 5 set, handle sgl/dbl denorms
  277. |
  278. | At this point only unnorms or extended denorms are possible.
  279. |
  280. src_ex_dnrm:
  281. movew a6@(ETEMP_EX),d0 | get source exponent
  282. andiw #0x7fff,d0 | mask sign, check if exp = 0000
  283. jeq  end_getop | if denorm then exit, denorms are
  284. | | handled in __x_do_func
  285. lea a6@(ETEMP),a0 | point a0 to sop - used in mk_norm
  286. bsrl mk_norm | go normalize - mk_norm returns:
  287. | | L_SCR1{7:5} = operand tag
  288. | |  (000 = norm, 100 = denorm)
  289. | | L_SCR1{4} = fpte15 or ete15
  290. | |  0 = exp >  0x3fff
  291. | |  1 = exp <= 0x3fff
  292. | | and puts the normalized num back
  293. | | on the fsave stack
  294. |
  295. moveb a6@(L_SCR1),a6@(STAG) | write the new tag # ete15
  296. rts | end_getop
  298. |
  299. | At this point, only single or double denorms are possible.
  300. | If the inst is not fmove, normalize the source.  If it is,
  301. | do nothing to the input.
  302. |
  303. src_sd_dnrm:
  304. btst #4,a6@(CMDREG1B) | differentiate between sgl/dbl denorm
  305. jne  is_double
  306. is_single:
  307. movew #0x3f81,d1 | write bias for sgl denorm
  308. jra  common | goto the common code
  309. is_double:
  310. movew #0x3c01,d1 | write the bias for a dbl denorm
  311. common:
  312. btst #sign_bit,a6@(ETEMP_EX) | grab sign bit of mantissa
  313. jeq  pos
  314. bset #15,d1 | set sign bit because it is negative
  315. pos:
  316. movew d1,a6@(ETEMP_EX)
  317. | | put exponent on stack
  319. movew a6@(CMDREG1B),d1
  320. andw #0xe3ff,d1 | clear out source specifier
  321. orw #0x0800,d1 | set source specifier to extended prec
  322. movew d1,a6@(CMDREG1B) | write back to the command word in stack
  323. | | this is needed to fix unsupp data stack
  324. lea a6@(ETEMP),a0 | point a0 to sop
  326. bsrl mk_norm | convert sgl/dbl denorm to norm
  327. moveb a6@(L_SCR1),a6@(STAG) | put tag into source tag reg - d0
  328. rts | end_getop
  329. |
  330. | At this point, the source is definitely packed, whether
  331. | instruction is dyadic or monadic is still unknown
  332. |
  333. pack_source:
  334. movel a6@(FPTEMP_LO),a6@(ETEMP) | write ms part of packed
  335. | | number to etemp slot
  336. bsrl chk_dy_mo | set dyadic/monadic flag
  337. bsrl unpack
  339. tstb a6@(DY_MO_FLG)
  340. jeq  end_getop | if monadic, exit
  341. | | else, fix FPTEMP
  342. pack_dya:
  343. bfextu a6@(CMDREG1B){#6:#3},d0 | extract dest fp reg
  344. movel #7,d1
  345. subl d0,d1
  346. clrl d0
  347. bset d1,d0 | set up d0 as a dynamic register mask
  348. fmovemx d0,a6@(FPTEMP) | write to FPTEMP
  350. btst #7,a6@(DTAG) | check dest tag for unnorm or denorm
  351. jne  dst_ex_dnrm | else, handle the unnorm or ext denorm
  352. |
  353. | Dest is not denormalized.  Check for norm, and set fpte15
  354. | accordingly.
  355. |
  356. moveb a6@(DTAG),d0
  357. andib #0xf0,d0 | strip to only dtag:fpte15
  358. tstb d0 | check for normalized value
  359. jne  end_getop | if inf/nan/zero leave __x_get_op
  360. movew a6@(FPTEMP_EX),d0
  361. andiw #0x7fff,d0
  362. cmpiw #0x3fff,d0 | check if fpte15 needs setting
  363. jge  end_getop | if >= 0x3fff, leave fpte15=0
  364. orb #0x10,a6@(DTAG)
  365. jra  end_getop
  367. |
  368. | At this point, it is either an fmoveout packed, unnorm or denorm
  369. |
  370. opclass3:
  371. clrb a6@(DY_MO_FLG) | set dyadic/monadic flag to monadic
  372. bfextu a6@(CMDREG1B){#4:#2},d0
  373. cmpib #3,d0
  374. jne  src_ex_dnrm | if not equal, must be unnorm or denorm
  375. | | else it is a packed move out
  376. | | exit
  377. end_getop:
  378. rts
  380. |
  381. | Sets the DY_MO_FLG correctly. This is used only on if it is an
  382. | unuspported data type exception.  Set if dyadic.
  383. |
  384. chk_dy_mo:
  385. movew a6@(CMDREG1B),d0
  386. btst #5,d0 | testing extension command word
  387. jeq  set_mon | if bit 5 = 0 then monadic
  388. btst #4,d0 | know that bit 5 = 1
  389. jeq  set_dya | if bit 4 = 0 then dyadic
  390. andiw #0x007f,d0 | get rid of all but extension bits {6:0}
  391. cmpiw  #0x0038,d0 | if extension = 0x38 then fcmp (dyadic)
  392. jne  set_mon
  393. set_dya:
  394. st a6@(DY_MO_FLG) | set the inst flag type to dyadic
  395. rts
  396. set_mon:
  397. clrb a6@(DY_MO_FLG) | set the inst flag type to monadic
  398. rts
  399. |
  400. | MK_NORM
  401. |
  402. | Normalizes unnormalized numbers, sets tag to norm or denorm, sets unfl
  403. | exception if denorm.
  404. |
  405. | CASE opclass 0x0 unsupp
  406. | mk_norm till msb set
  407. | set tag = norm
  408. |
  409. | CASE opclass 0x0 unimp
  410. | mk_norm till msb set or exp = 0
  411. | if integer bit = 0
  412. |    tag = denorm
  413. | else
  414. |    tag = norm
  415. |
  416. | CASE opclass 011 unsupp
  417. | mk_norm till msb set or exp = 0
  418. | if integer bit = 0
  419. |    tag = denorm
  420. |    set unfl_nmcexe = 1
  421. | else
  422. |    tag = norm
  423. |
  424. | if exp <= 0x3fff
  425. |   set ete15 or fpte15 = 1
  426. | else set ete15 or fpte15 = 0
  428. | input:
  429. | a0 = points to operand to be normalized
  430. | output:
  431. | L_SCR1{7:5} = operand tag (000 = norm, 100 = denorm)
  432. | L_SCR1{4}   = fpte15 or ete15 (0 = exp > 0x3fff, 1 = exp <=0x3fff)
  433. | the normalized operand is placed back on the fsave stack
  434. mk_norm:
  435. clrl a6@(L_SCR1)
  436. bclr #sign_bit,a0@(LOCAL_EX)
  437. sne a0@(LOCAL_SGN) | transform into internal extended format
  439. cmpib #0x2c,a6@(1+EXC_VEC) | check if unimp
  440. jne  uns_data | branch if unsupp
  441. bsrl uni_inst | call if unimp (opclass 0x0)
  442. jra  reload
  443. uns_data:
  444. btst #direction_bit,a6@(CMDREG1B) | check transfer direction
  445. jne  bit_set | branch if set (opclass 011)
  446. bsrl uns_opx | call if opclass 0x0
  447. jra  reload
  448. bit_set:
  449. bsrl uns_op3 | opclass 011
  450. reload:
  451. cmpw #0x3fff,a0@(LOCAL_EX) | if exp > 0x3fff
  452. jgt  end_mk |    fpte15/ete15 already set to 0
  453. bset #4,a6@(L_SCR1) | else set fpte15/ete15 to 1
  454. | | calling routine actually sets the
  455. | | value on the stack (along with the
  456. /* | | tag), since this routine doesn't  */
  457. | | know if it should set ete15 or fpte15
  458. /* | | ie, it doesn't know if this is the  */
  459. | | src op or dest op.
  460. end_mk:
  461. bfclr a0@(LOCAL_SGN){#0:#8}
  462. jeq  end_mk_pos
  463. bset #sign_bit,a0@(LOCAL_EX) | convert back to IEEE format
  464. end_mk_pos:
  465. rts
  466. |
  467. |     CASE opclass 011 unsupp
  468. |
  469. uns_op3:
  470. bsrl __x_nrm_zero | normalize till msb = 1 or exp = zero
  471. btst #7,a0@(LOCAL_HI) | if msb = 1
  472. jne  no_unfl | then branch
  473. set_unfl:
  474. orw #dnrm_tag,a6@(L_SCR1) | set denorm tag
  475. bset #__x_unfl_bit,a6@(FPSR_EXCEPT) | set unfl exception bit
  476. no_unfl:
  477. rts
  478. |
  479. |     CASE opclass 0x0 unsupp
  480. |
  481. uns_opx:
  482. bsrl __x_nrm_zero | normalize the number
  483. btst #7,a0@(LOCAL_HI) | check if integer bit (j-bit) is set
  484. jeq  uns_den | if clear then now have a denorm
  485. uns_nrm:
  486. orb #__x_norm_tag,a6@(L_SCR1) | set tag to norm
  487. rts
  488. uns_den:
  489. orb #dnrm_tag,a6@(L_SCR1) | set tag to denorm
  490. rts
  491. |
  492. |     CASE opclass 0x0 unimp
  493. |
  494. uni_inst:
  495. bsrl __x_nrm_zero
  496. btst #7,a0@(LOCAL_HI) | check if integer bit (j-bit) is set
  497. jeq  uni_den | if clear then now have a denorm
  498. uni_nrm:
  499. orb #__x_norm_tag,a6@(L_SCR1) | set tag to norm
  500. rts
  501. uni_den:
  502. orb #dnrm_tag,a6@(L_SCR1) | set tag to denorm
  503. rts
  505. |
  506. | Decimal to binary conversion
  507. |
  508. | Special cases of inf and NaNs are completed outside of __x_decbin.
  509. | If the input is an snan, the snan bit is not set.
  510. |
  511. | input:
  512. | a6@(ETEMP) - points to packed decimal string in memory
  513. | output:
  514. | fp0 - contains packed string converted to extended precision
  515. | ETEMP - same as fp0
  516. unpack:
  517. movew a6@(CMDREG1B),d0 /* | examine command word, looking for fmove's */
  518. andw #0x3b,d0
  519. jeq  move_unpack | special handling for fmove: must set FPSR_CC
  521. movew a6@(ETEMP),d0 | get word with inf information
  522. bfextu d0{#20:#12},d1 | get exponent into d1
  523. cmpiw #0x0fff,d1 | test for inf or NaN
  524. jne  try_zero | if not equal, it is not special
  525. bfextu d0{#17:#3},d1 | get SE and y bits into d1
  526. cmpiw #7,d1 | SE and y bits must be on for special
  527. jne  try_zero | if not on, it is not special
  528. |input is of the special cases of inf and NaN
  529. tstl a6@(ETEMP_HI) | check ms mantissa
  530. jne  fix_nan | if non-zero, it is a NaN
  531. tstl a6@(ETEMP_LO) | check ls mantissa
  532. jne  fix_nan | if non-zero, it is a NaN
  533. jra  finish | special already on stack
  534. fix_nan:
  535. btst #signan_bit,a6@(ETEMP_HI) | test for snan
  536. jne  finish
  537. orl #__x_snaniop_mask,a6@(USER_FPSR) | always set snan if it is so
  538. jra  finish
  539. try_zero:
  540. movew a6@(ETEMP_EX+2),d0 | get word 4
  541. andiw #0x000f,d0 | clear all but last ni(y)bble
  542. tstw d0 | check for zero.
  543. jne  not_spec
  544. tstl a6@(ETEMP_HI) | check words 3 and 2
  545. jne  not_spec
  546. tstl a6@(ETEMP_LO) | check words 1 and 0
  547. jne  not_spec
  548. tstl a6@(ETEMP) | test sign of the zero
  549. jge  pos_zero
  550. movel #0x80000000,a6@(ETEMP) | write neg zero to etemp
  551. clrl a6@(ETEMP_HI)
  552. clrl a6@(ETEMP_LO)
  553. jra  finish
  554. pos_zero:
  555. clrl a6@(ETEMP)
  556. clrl a6@(ETEMP_HI)
  557. clrl a6@(ETEMP_LO)
  558. jra  finish
  560. not_spec:
  561. fmovemx fp0-fp1,a7@- | save fp0 - __x_decbin returns in it
  562. bsrl __x_decbin
  563. fmovex fp0,a6@(ETEMP) | put the unpacked sop in the fsave stack
  564. fmovemx a7@+,fp0-fp1
  565. fmovel #0,FPSR | clr fpsr from __x_decbin
  566. jra  finish
  568. |
  569. | Special handling for packed move in:  Same results as all other
  570. | packed cases, but we must set the FPSR condition codes properly.
  571. |
  572. move_unpack:
  573. movew a6@(ETEMP),d0 | get word with inf information
  574. bfextu d0{#20:#12},d1 | get exponent into d1
  575. cmpiw #0x0fff,d1 | test for inf or NaN
  576. jne  mtry_zero | if not equal, it is not special
  577. bfextu d0{#17:#3},d1 | get SE and y bits into d1
  578. cmpiw #7,d1 | SE and y bits must be on for special
  579. jne  mtry_zero | if not on, it is not special
  580. |input is of the special cases of inf and NaN
  581. tstl a6@(ETEMP_HI) | check ms mantissa
  582. jne  mfix_nan | if non-zero, it is a NaN
  583. tstl a6@(ETEMP_LO) | check ls mantissa
  584. jne  mfix_nan | if non-zero, it is a NaN
  585. |input is inf
  586. orl #inf_mask,a6@(USER_FPSR) | set I bit
  587. tstl a6@(ETEMP) | check sign
  588. jge  finish
  589. orl #neg_mask,a6@(USER_FPSR) | set N bit
  590. jra  finish | special already on stack
  591. mfix_nan:
  592. orl #nan_mask,a6@(USER_FPSR) | set NaN bit
  593. moveb #nan_tag,a6@(STAG) | set stag to NaN
  594. btst #signan_bit,a6@(ETEMP_HI) | test for snan
  595. jne  mn_snan
  596. orl #__x_snaniop_mask,a6@(USER_FPSR) | set snan bit
  597. btst #__x_snan_bit,a6@(fpcr_ENABLE) | test for snan enabled
  598. jne  mn_snan
  599. bset #signan_bit,a6@(ETEMP_HI) | force snans to qnans
  600. mn_snan:
  601. tstl a6@(ETEMP) | check for sign
  602. jge  finish | if clr, go on
  603. orl #neg_mask,a6@(USER_FPSR) | set N bit
  604. jra  finish
  606. mtry_zero:
  607. movew a6@(ETEMP_EX+2),d0 | get word 4
  608. andiw #0x000f,d0 | clear all but last ni(y)bble
  609. tstw d0 | check for zero.
  610. jne  mnot_spec
  611. tstl a6@(ETEMP_HI) | check words 3 and 2
  612. jne  mnot_spec
  613. tstl a6@(ETEMP_LO) | check words 1 and 0
  614. jne  mnot_spec
  615. tstl a6@(ETEMP) | test sign of the zero
  616. jge  mpos_zero
  617. orl #neg_mask+z_mask,a6@(USER_FPSR) | set N and Z
  618. movel #0x80000000,a6@(ETEMP) | write neg zero to etemp
  619. clrl a6@(ETEMP_HI)
  620. clrl a6@(ETEMP_LO)
  621. jra  finish
  622. mpos_zero:
  623. orl #z_mask,a6@(USER_FPSR) | set Z
  624. clrl a6@(ETEMP)
  625. clrl a6@(ETEMP_HI)
  626. clrl a6@(ETEMP_LO)
  627. jra  finish
  629. mnot_spec:
  630. fmovemx fp0-fp1,a7@- | save fp0 - __x_decbin returns in it
  631. bsrl __x_decbin
  632. fmovex fp0,a6@(ETEMP)
  633. | | put the unpacked sop in the fsave stack
  634. fmovemx a7@+,fp0-fp1
  636. finish:
  637. movew a6@(CMDREG1B),d0 | get the command word
  638. andw #0xfbff,d0 | change the source specifier field to
  639. | | extended (was packed).
  640. movew d0,a6@(CMDREG1B) | write command word back to fsave stack
  641. | | we need to do this so the 040 will
  642. | | re-execute the inst. without taking
  643. | | another packed trap.
  645. fix_stag:
  646. |Converted result is now in etemp on fsave stack, now set the source
  647. |tag (stag)
  648. | if (ete =0x7fff) then INF or NAN
  649. | if (etemp = $x.0----0) then
  650. | stag = INF
  651. | else
  652. | stag = NAN
  653. | else
  654. | if (ete = 0x0000) then
  655. | stag = ZERO
  656. | else
  657. | stag = NORM
  658. |
  659. | Note also that the etemp_15 bit (just right of the stag) must
  660. | be set accordingly.
  661. |
  662. movew a6@(ETEMP_EX),d1
  663. andiw #0x7fff,d1   | strip sign
  664. cmpw   #0x7fff,d1
  665. jne    z_or_nrm
  666. movel a6@(ETEMP_HI),d1
  667. jne  is_nan
  668. movel a6@(ETEMP_LO),d1
  669. jne  is_nan
  670. is_inf:
  671. moveb #0x40,a6@(STAG)
  672. movel #0x40,d0
  673. rts
  674. is_nan:
  675. moveb #0x60,a6@(STAG)
  676. movel #0x60,d0
  677. rts
  678. z_or_nrm:
  679. tstw d1
  680. jne  is_nrm
  681. is_zro:
  682. | For a zero, set etemp_15
  683. moveb #0x30,a6@(STAG)
  684. movel #0x20,d0
  685. rts
  686. is_nrm:
  687. | For a norm, check if the exp <= 0x3fff|  if so, set etemp_15
  688. cmpiw #0x3fff,d1
  689. jle  set_bit15
  690. moveb #0,a6@(STAG)
  691. jra  end_is_nrm
  692. set_bit15:
  693. moveb #0x10,a6@(STAG)
  694. end_is_nrm:
  695. movel #0,d0
  696. end_fix:
  697. rts
  699. end_get:
  700. rts
  701. | end