开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > VxWorks > 查看源码
do_func.s
资源名称：vxwork_src.rar　[点击查看]
上传用户：nvosite88
上传日期：2007-01-17
资源大小：4983k
文件大小：15k
源码类别：

VxWorks

开发平台：

C/C++

do_func.s：源码内容
  1. /* do_func.s - Motorola 68040 FP routine jump table (EXC) */
  3. /* Copyright 1991-1993 Wind River Systems, Inc. */
  4. .data
  5. .globl _copyright_wind_river
  6. .long _copyright_wind_river
  8. /*
  9. modification history
  10. --------------------
  11. 01g,31may96,ms   updated to mototorola version 2.3
  12. 01f,14jun95,tpr  changed fbxx to fbxxl.
  13. 01e,21jul93,kdl  added .text (SPR #2372).
  14. 01d,23aug92,jcf  changed bxxx to jxx.
  15. 01c,26may92,rrr  the tree shuffle
  16. 01b,10jan92,kdl  added modification history; general cleanup.
  17. 01a,15aug91,kdl  original version, from Motorola FPSP v2.0.
  18. */
  20. /*
  21. DESCRIPTION
  24. do_funcsa 3.4 2/18/91
  26. Do_func performs the unimplemented operation.  The operation
  27. to be performed is determined from the lower 7 bits of the
  28. extension word (except in the case of fmovecr and fsincos).
  29. The opcode and tag bits form an index into a jump table in
  30. tbldosa.  Cases of zero, infinity and NaN are handled in
  31. __x_do_func by forcing the default result.  Normalized and
  32. denormalized (there are no unnormalized numbers at this
  33. point) are passed onto the emulation code.
  35. CMDREG1B and STAG are extracted from the fsave frame
  36. and combined to form the table index.  The function called
  37. will start with a0 pointing to the ETEMP operand.  Dyadic
  38. functions can find FPTEMP at a0@(-12).
  40. Called functions return their result in fp0.  Sincos returns
  41. sin(x) in fp0 and cos(x) in fp1.
  44. Copyright (C) Motorola, Inc. 1990
  45. All Rights Reserved
  47. THIS IS UNPUBLISHED PROPRIETARY SOURCE CODE OF MOTOROLA
  48. The copyright notice above does not evidence any
  49. actual or intended publication of such source code.
  51. DO_FUNC idnt    2,1 Motorola 040 Floating Point Software Package
  53. section 8
  55. NOMANUAL
  56. */
  58. #include "fpsp040E.h"
  60. | xref __x_t_dz2
  61. | xref __x_t_operr
  62. | xref __x_t_inx2
  63. | xref  __x_t_resdnrm
  64. | xref __x_dst_nan
  65. | xref __x_src_nan
  66. | xref __x_nrm_set
  67. | xref __x_sto_cos
  69. | xref __x_tblpre
  70. | xref __x_slognp1,__x_slogn,__x_slog10,__x_slog2
  71. | xref __x_slognd,__x_slog10d,__x_slog2d
  72. | xref __x_smod,__x_srem
  73. | xref __x_sscale
  74. | xref __x_smovcr
  76. PONE: .long 0x3fff0000,0x80000000,0x00000000 | +1
  77. MONE: .long 0xbfff0000,0x80000000,0x00000000 | -1
  78. PZERO: .long 0x00000000,0x00000000,0x00000000 | +0
  79. MZERO: .long 0x80000000,0x00000000,0x00000000 | -0
  80. PINF: .long 0x7fff0000,0x00000000,0x00000000 | +inf
  81. MINF: .long 0xffff0000,0x00000000,0x00000000 | -inf
  82. QNAN: .long 0x7fff0000,0xffffffff,0xffffffff | non-signaling nan
  83. PPIBY2:  .long 0x3FFF0000,0xC90FDAA2,0x2168C235 | +PI/2
  84. MPIBY2:  .long 0xbFFF0000,0xC90FDAA2,0x2168C235 | -PI/2
  86. .globl __x_do_func
  88. .text
  90. __x_do_func:
  91. clrb a6@(CU_ONLY)
  92. |
  93. | Check for fmovecr.  It does not follow the format of fp gen
  94. | unimplemented instructions.  The test is on the upper 6 bits|
  95. | if they are 0x17, the inst is fmovecr.  Call entry __x_smovcr
  96. | directly.
  97. |
  98. bfextu a6@(CMDREG1B){#0:#6},d0 | get opclass and src fields
  99. cmpil #0x17,d0 | if op class and size fields are 0x17,
  100. | | it is FMOVECR|  if not, continue
  101. jne  not_fmovecr
  102. jmp __x_smovcr | fmovecr|  jmp directly to emulation
  104. not_fmovecr:
  105. movew a6@(CMDREG1B),d0
  106. andl #0x7F,d0
  107. cmpil #0x38,d0 | if the extension is >= 0x38,
  108. jge  __x_serror | it is illegal
  109. bfextu a6@(STAG){#0:#3},d1
  110. lsll #3,d0 | make room for STAG
  111. addl d1,d0 | combine for final index into table
  112. lea __x_tblpre,a1 | start of monster jump table
  113. movel a1@(d0:w:4),a1 | real target address
  114. lea a6@(ETEMP),a0 | a0 is pointer to src op
  115. movel a6@(USER_FPCR),d1
  116. andl #0xFF,d1 |  discard all but rounding mode/prec
  117. fmovel #0,fpcr
  118. jmp a1@
  119. |
  120. | ERROR
  121. |
  122. .globl __x_serror
  123. __x_serror:
  124. st a6@(STORE_FLG)
  125. rts
  126. |
  127. | These routines load forced values into fp0.  They are called
  128. | by index into tbldo.
  129. |
  130. | Load a signed zero to fp0 and set inex2/ainex
  131. |
  132. .globl __x_snzrinx
  133. __x_snzrinx:
  134. btst #sign_bit,a0@(LOCAL_EX) | get sign of source operand
  135. jne  ld_mzinx | if negative, branch
  136. bsrl __x_ld_pzero | bsr so we can return and set inx
  137. jra  __x_t_inx2 | now, set the inx for the next inst
  138. ld_mzinx:
  139. bsrl __x_ld_mzero | if neg, load neg zero, return here
  140. jra  __x_t_inx2 | now, set the inx for the next inst
  141. |
  142. | Load a signed zero to fp0|  do not set inex2/ainex
  143. |
  144. .globl __x_szero
  145. __x_szero:
  146. btst #sign_bit,a0@(LOCAL_EX) | get sign of source operand
  147. jne  __x_ld_mzero | if neg, load neg zero
  148. jra  __x_ld_pzero | load positive zero
  149. |
  150. | Load a signed infinity to fp0|  do not set inex2/ainex
  151. |
  152. .globl __x_sinf
  153. __x_sinf:
  154. btst #sign_bit,a0@(LOCAL_EX) | get sign of source operand
  155. jne  __x_ld_minf | if negative branch
  156. jra  __x_ld_pinf
  157. |
  158. | Load a signed one to fp0|  do not set inex2/ainex
  159. |
  160. .globl __x_sone
  161. __x_sone:
  162. btst #sign_bit,a0@(LOCAL_EX) | check sign of source
  163. jne  __x_ld_mone
  164. jra  __x_ld_pone
  165. |
  166. | Load a signed pi/2 to fp0|  do not set inex2/ainex
  167. |
  168. .globl __x_spi_2
  169. __x_spi_2:
  170. btst #sign_bit,a0@(LOCAL_EX) | check sign of source
  171. jne  __x_ld_mpi2
  172. jra  __x_ld_ppi2
  173. |
  174. | Load either a +0 or +inf for plus/minus operand
  175. |
  176. .globl __x_szr_inf
  177. __x_szr_inf:
  178. btst #sign_bit,a0@(LOCAL_EX) | check sign of source
  179. jne  __x_ld_pzero
  180. jra  __x_ld_pinf
  181. |
  182. | Result is either an operr or +inf for plus/minus operand
  183. | [Used by __x_slogn, __x_slognp1, __x_slog10, and __x_slog2]
  184. |
  185. .globl __x_sopr_inf
  186. __x_sopr_inf:
  187. btst #sign_bit,a0@(LOCAL_EX) | check sign of source
  188. jne  __x_t_operr
  189. jra  __x_ld_pinf
  190. |
  191. | FLOGNP1
  192. |
  193. .globl __x_sslognp1
  194. __x_sslognp1:
  195. fmovemx a0@,fp0-fp0
  196. fcmpb #-1,fp0
  197. fbgtl __x_slognp1
  198. fbeql __x_t_dz2 | if = -1, divide by zero exception
  199. fmovel #0,FPSR | clr N flag
  200. jra  __x_t_operr | take care of operands < -1
  201. |
  202. | FETOXM1
  203. |
  204. .globl __x_setoxm1i
  205. __x_setoxm1i:
  206. btst #sign_bit,a0@(LOCAL_EX) | check sign of source
  207. jne  __x_ld_mone
  208. jra  __x_ld_pinf
  209. |
  210. | FLOGN
  211. |
  212. | Test for 1.0 as an input argument, returning +zero.  Also check
  213. | the sign and return operr if negative.
  214. |
  215. .globl __x_sslogn
  216. __x_sslogn:
  217. btst #sign_bit,a0@(LOCAL_EX)
  218. jne  __x_t_operr | take care of operands < 0
  219. cmpiw #0x3fff,a0@(LOCAL_EX)  | test for 1.0 input
  220. jne  __x_slogn
  221. cmpil #0x80000000,a0@(LOCAL_HI)
  222. jne  __x_slogn
  223. tstl a0@(LOCAL_LO)
  224. jne  __x_slogn
  225. fmovex PZERO,fp0
  226. rts
  228. .globl __x_sslognd
  229. __x_sslognd:
  230. btst #sign_bit,a0@(LOCAL_EX)
  231. jeq  __x_slognd
  232. jra  __x_t_operr | take care of operands < 0
  234. |
  235. | FLOG10
  236. |
  237. .globl __x_sslog10
  238. __x_sslog10:
  239. btst #sign_bit,a0@(LOCAL_EX)
  240. jne  __x_t_operr | take care of operands < 0
  241. cmpiw #0x3fff,a0@(LOCAL_EX)  | test for 1.0 input
  242. jne  __x_slog10
  243. cmpil #0x80000000,a0@(LOCAL_HI)
  244. jne  __x_slog10
  245. tstl a0@(LOCAL_LO)
  246. jne  __x_slog10
  247. fmovex PZERO,fp0
  248. rts
  250. .globl __x_sslog10d
  251. __x_sslog10d:
  252. btst #sign_bit,a0@(LOCAL_EX)
  253. jeq  __x_slog10d
  254. jra  __x_t_operr | take care of operands < 0
  256. |
  257. | FLOG2
  258. |
  259. .globl __x_sslog2
  260. __x_sslog2:
  261. btst #sign_bit,a0@(LOCAL_EX)
  262. jne  __x_t_operr | take care of operands < 0
  263. cmpiw #0x3fff,a0@(LOCAL_EX)  | test for 1.0 input
  264. jne  __x_slog2
  265. cmpil #0x80000000,a0@(LOCAL_HI)
  266. jne  __x_slog2
  267. tstl a0@(LOCAL_LO)
  268. jne  __x_slog2
  269. fmovex PZERO,fp0
  270. rts
  272. .globl __x_sslog2d
  273. __x_sslog2d:
  274. btst #sign_bit,a0@(LOCAL_EX)
  275. jeq  __x_slog2d
  276. jra  __x_t_operr | take care of operands < 0
  278. |
  279. | FMOD
  280. |
  281. __x_pmodt:
  282. | | 0x21 fmod
  283. | | dtag,stag
  284. .long __x_smod |   00,00  norm,norm = normal
  285. .long __x_smod_oper |   00,01  norm,zero = nan with operr
  286. .long __x_smod_fpn |   00,10  norm,inf  = fpn
  287. .long __x_smod_snan |   00,11  norm,nan  = nan
  288. .long __x_smod_zro |   01,00  zero,norm = +-zero
  289. .long __x_smod_oper |   01,01  zero,zero = nan with operr
  290. .long __x_smod_zro |   01,10  zero,inf  = +-zero
  291. .long __x_smod_snan |   01,11  zero,nan  = nan
  292. .long __x_smod_oper |   10,00  inf,norm  = nan with operr
  293. .long __x_smod_oper |   10,01  inf,zero  = nan with operr
  294. .long __x_smod_oper |   10,10  inf,inf   = nan with operr
  295. .long __x_smod_snan |   10,11  inf,nan   = nan
  296. .long __x_smod_dnan |   11,00  nan,norm  = nan
  297. .long __x_smod_dnan |   11,01  nan,zero  = nan
  298. .long __x_smod_dnan |   11,10  nan,inf   = nan
  299. .long __x_smod_dnan |   11,11  nan,nan   = nan
  301. .globl __x_pmod
  302. __x_pmod:
  303. clr.b FPSR_QBYTE(a6)      | clear quotient field
  304. bfextu a6@(STAG){#0:#3},d0 | stag = d0
  305. bfextu a6@(DTAG){#0:#3},d1 | dtag = d1
  307. |
  308. | Alias extended denorms to norms for the jump table.
  309. |
  310. bclr #2,d0
  311. bclr #2,d1
  313. lslb #2,d1
  314. orb d0,d1 | d1{3:2} = dtag, d1{1:0} = stag
  315. | | Tag values:
  316. | | 00 = norm or denorm
  317. | | 01 = zero
  318. | | 10 = inf
  319. | | 11 = nan
  320. lea __x_pmodt,a1
  321. movel a1@(d1:w:4),a1
  322. jmp a1@
  324. __x_smod_snan:
  325. jra  __x_src_nan
  326. __x_smod_dnan:
  327. jra  __x_dst_nan
  328. __x_smod_oper:
  329. jra  __x_t_operr
  330. __x_smod_zro:
  331. moveb a6@(ETEMP),d1 | get sign of src op
  332. moveb a6@(FPTEMP),d0 | get sign of dst op
  333. eorb d0,d1 | get exor of sign bits
  334. btst #7,d1 | test for sign
  335. jeq  __x_smod_zsn | if clr, do not set sign big
  336. bset #q_sn_bit,a6@(FPSR_QBYTE) | set q-byte sign bit
  337. __x_smod_zsn:
  338. btst #7,d0 | test if + or -
  339. jeq  __x_ld_pzero | if pos then load +0
  340. jra  __x_ld_mzero | else neg load -0
  342. __x_smod_fpn:
  343. moveb a6@(ETEMP),d1 | get sign of src op
  344. moveb a6@(FPTEMP),d0 | get sign of dst op
  345. eorb d0,d1 | get exor of sign bits
  346. btst #7,d1 | test for sign
  347. jeq  __x_smod_fsn | if clr, do not set sign big
  348. bset #q_sn_bit,a6@(FPSR_QBYTE) | set q-byte sign bit
  349. __x_smod_fsn:
  350. tstb a6@(DTAG) | filter out denormal destination case
  351. jpl  __x_smod_nrm |
  352. lea a6@(FPTEMP),a0 | a0<- addr(FPTEMP)
  353. jra  __x_t_resdnrm | force UNFL(but exact) result
  354. __x_smod_nrm:
  355. fmovel a6@(USER_FPCR),fpcr /* | use user's rmode and precision */
  356. fmovex a6@(FPTEMP),fp0 | return dest to fp0
  357. rts
  359. |
  360. | FREM
  361. |
  362. __x_premt:
  363. | | 0x25 frem
  364. | | dtag,stag
  365. .long __x_srem |   00,00  norm,norm = normal
  366. .long __x_srem_oper |   00,01  norm,zero = nan with operr
  367. .long __x_srem_fpn |   00,10  norm,inf  = fpn
  368. .long __x_srem_snan |   00,11  norm,nan  = nan
  369. .long __x_srem_zro |   01,00  zero,norm = +-zero
  370. .long __x_srem_oper |   01,01  zero,zero = nan with operr
  371. .long __x_srem_zro |   01,10  zero,inf  = +-zero
  372. .long __x_srem_snan |   01,11  zero,nan  = nan
  373. .long __x_srem_oper |   10,00  inf,norm  = nan with operr
  374. .long __x_srem_oper |   10,01  inf,zero  = nan with operr
  375. .long __x_srem_oper |   10,10  inf,inf   = nan with operr
  376. .long __x_srem_snan |   10,11  inf,nan   = nan
  377. .long __x_srem_dnan |   11,00  nan,norm  = nan
  378. .long __x_srem_dnan |   11,01  nan,zero  = nan
  379. .long __x_srem_dnan |   11,10  nan,inf   = nan
  380. .long __x_srem_dnan |   11,11  nan,nan   = nan
  382. .globl __x_prem
  383. __x_prem:
  384. clr.b FPSR_QBYTE(a6)      | clear quotient field
  385. bfextu a6@(STAG){#0:#3},d0 | stag = d0
  386. bfextu a6@(DTAG){#0:#3},d1 | dtag = d1
  387. |
  388. | Alias extended denorms to norms for the jump table.
  389. |
  390. bclr #2,d0
  391. bclr #2,d1
  393. lslb #2,d1
  394. orb d0,d1 | d1{3:2} = dtag, d1{1:0} = stag
  395. | | Tag values:
  396. | | 00 = norm or denorm
  397. | | 01 = zero
  398. | | 10 = inf
  399. | | 11 = nan
  400. lea __x_premt,a1
  401. movel a1@(d1:w:4),a1
  402. jmp a1@
  404. __x_srem_snan:
  405. jra  __x_src_nan
  406. __x_srem_dnan:
  407. jra  __x_dst_nan
  408. __x_srem_oper:
  409. jra  __x_t_operr
  410. __x_srem_zro:
  411. moveb a6@(ETEMP),d1 | get sign of src op
  412. moveb a6@(FPTEMP),d0 | get sign of dst op
  413. eorb d0,d1 | get exor of sign bits
  414. btst #7,d1 | test for sign
  415. jeq  __x_srem_zsn | if clr, do not set sign big
  416. bset #q_sn_bit,a6@(FPSR_QBYTE) | set q-byte sign bit
  417. __x_srem_zsn:
  418. btst #7,d0 | test if + or -
  419. jeq  __x_ld_pzero | if pos then load +0
  420. jra  __x_ld_mzero | else neg load -0
  422. __x_srem_fpn:
  423. moveb a6@(ETEMP),d1 | get sign of src op
  424. moveb a6@(FPTEMP),d0 | get sign of dst op
  425. eorb d0,d1 | get exor of sign bits
  426. btst #7,d1 | test for sign
  427. jeq  __x_srem_fsn | if clr, do not set sign big
  428. bset #q_sn_bit,a6@(FPSR_QBYTE) | set q-byte sign bit
  429. __x_srem_fsn:
  430. tstb a6@(DTAG) | filter out denormal destination case
  431. jpl  __x_srem_nrm |
  432. lea a6@(FPTEMP),a0 | a0<- addr(FPTEMP)
  433. jra  __x_t_resdnrm | force UNFL(but exact) result
  434. __x_srem_nrm:
  435. fmovel a6@(USER_FPCR),fpcr /* | use user's rmode and precision */
  436. fmovex a6@(FPTEMP),fp0 | return dest to fp0
  437. rts
  438. |
  439. | FSCALE
  440. |
  441. __x_pscalet:
  442. | | 0x26 fscale
  443. | | dtag,stag
  444. .long __x_sscale |   00,00  norm,norm = result
  445. .long __x_sscale |   00,01  norm,zero = fpn
  446. .long scl_opr |   00,10  norm,inf  = nan with operr
  447. .long scl_snan |   00,11  norm,nan  = nan
  448. .long scl_zro |   01,00  zero,norm = +-zero
  449. .long scl_zro |   01,01  zero,zero = +-zero
  450. .long scl_opr |   01,10  zero,inf  = nan with operr
  451. .long scl_snan |   01,11  zero,nan  = nan
  452. .long scl_inf |   10,00  inf,norm  = +-inf
  453. .long scl_inf |   10,01  inf,zero  = +-inf
  454. .long scl_opr |   10,10  inf,inf   = nan with operr
  455.   .long scl_snan |   10,11  inf,nan   = nan
  456.   .long scl_dnan |   11,00  nan,norm  = nan
  457.   .long scl_dnan |   11,01  nan,zero  = nan
  458.   .long scl_dnan |   11,10  nan,inf   = nan
  459. .long scl_dnan |   11,11  nan,nan   = nan
  461. .globl __x_pscale
  462. __x_pscale:
  463. bfextu a6@(STAG){#0:#3},d0 | stag in d0
  464. bfextu a6@(DTAG){#0:#3},d1 | dtag in d1
  465. bclr #2,d0 | alias  denorm into norm
  466. bclr #2,d1 | alias  denorm into norm
  467. lslb #2,d1
  468. orb d0,d1 | d1{4:2} = dtag, d1{1:0} = stag
  469. | | dtag values     stag values:
  470. | | 000 = norm      00 = norm
  471. | | 001 = zero  01 = zero
  472. | | 010 = inf  10 = inf
  473. | | 011 = nan  11 = nan
  474. | | 100 = dnrm
  475. |
  476. |
  477. lea __x_pscalet,a1 | load start of jump table
  478. movel a1@(d1:w:4),a1 | load a1 with label depending on tag
  479. jmp a1@ | go to the routine
  481. scl_opr:
  482. jra  __x_t_operr
  484. scl_dnan:
  485. jra  __x_dst_nan
  487. scl_zro:
  488. btst #sign_bit,a6@(FPTEMP_EX) | test if + or -
  489. jeq  __x_ld_pzero | if pos then load +0
  490. jra  __x_ld_mzero | if neg then load -0
  491. scl_inf:
  492. btst #sign_bit,a6@(FPTEMP_EX) | test if + or -
  493. jeq  __x_ld_pinf | if pos then load +inf
  494. jra  __x_ld_minf | else neg load -inf
  495. scl_snan:
  496. jra  __x_src_nan
  497. |
  498. | FSINCOS
  499. |
  500. .globl __x_ssincosz
  501. __x_ssincosz:
  502. btst #sign_bit,a6@(ETEMP) | get sign
  503. jeq  sincosp
  504. fmovex MZERO,fp0
  505. jra  sincoscom
  506. sincosp:
  507. fmovex PZERO,fp0
  508. sincoscom:
  509.    fmovemx PONE,fp1-fp1 | do not allow FPSR to be affected
  510. jra  __x_sto_cos | store cosine result
  512. .globl __x_ssincosi
  513. __x_ssincosi:
  514. fmovex QNAN,fp1 | load NAN
  515. bsrl __x_sto_cos | store cosine result
  516. fmovex QNAN,fp0 | load NAN
  517. jra  __x_t_operr
  519. .globl __x_ssincosnan
  520. __x_ssincosnan:
  521. movel a6@(ETEMP_EX),a6@(FP_SCR1)
  522. movel a6@(ETEMP_HI),a6@(FP_SCR1+4)
  523. movel a6@(ETEMP_LO),a6@(FP_SCR1+8)
  524. bset #signan_bit,a6@(FP_SCR1+4)
  525. fmovemx a6@(FP_SCR1),fp1-fp1
  526. bsrl __x_sto_cos
  527. jra  __x_src_nan
  528. |
  529. | This code forces default values for the zero, inf, and nan cases
  530. | in the transcendentals code.  The CC bits must be set in the
  531. | stacked FPSR to be correctly reported.
  532. |
  533. |**Returns +PI/2
  534. .globl __x_ld_ppi2
  535. __x_ld_ppi2:
  536. fmovex PPIBY2,fp0 | load +pi/2
  537. jra  __x_t_inx2 | set inex2 exc
  539. |**Returns -PI/2
  540. .globl __x_ld_mpi2
  541. __x_ld_mpi2:
  542. fmovex MPIBY2,fp0 | load -pi/2
  543. orl #neg_mask,a6@(USER_FPSR) | set N bit
  544. jra  __x_t_inx2 | set inex2 exc
  546. |**Returns +inf
  547. .globl __x_ld_pinf
  548. __x_ld_pinf:
  549. fmovex PINF,fp0 | load +inf
  550. orl #inf_mask,a6@(USER_FPSR) | set I bit
  551. rts
  553. |**Returns -inf
  554. .globl __x_ld_minf
  555. __x_ld_minf:
  556. fmovex MINF,fp0 | load -inf
  557. orl #neg_mask+inf_mask,a6@(USER_FPSR) | set N and I bits
  558. rts
  560. |**Returns +1
  561. .globl __x_ld_pone
  562. __x_ld_pone:
  563. fmovex PONE,fp0 | load +1
  564. rts
  566. |**Returns -1
  567. .globl __x_ld_mone
  568. __x_ld_mone:
  569. fmovex MONE,fp0 | load -1
  570. orl #neg_mask,a6@(USER_FPSR) | set N bit
  571. rts
  573. |**Returns +0
  574. .globl __x_ld_pzero
  575. __x_ld_pzero:
  576. fmovex PZERO,fp0 | load +0
  577. orl #z_mask,a6@(USER_FPSR) | set Z bit
  578. rts
  580. |**Returns -0
  581. .globl __x_ld_mzero
  582. __x_ld_mzero:
  583. fmovex MZERO,fp0 | load -0
  584. orl #neg_mask+z_mask,a6@(USER_FPSR) | set N and Z bits
  585. rts
  587. | end