WEB邮件程序

开发平台：

C/C++

configure.in：源码内容

							dnl Process this file with autoconf to produce a configure script.
dnl $Id: configure.in,v 1.10 2000/07/01 22:36:34 mrsam Exp $
dnl
dnl Copyright 1998 - 1999 Double Precision, Inc.  See COPYING for
dnl distribution information.
AC_INIT(bdbobj.h)
AM_INIT_AUTOMAKE(bdbobj, 0.10, 0)
AM_CONFIG_HEADER(config.h)
dnl Checks for programs.
AC_PROG_AWK
AC_PROG_CC
AC_PROG_CXX
AC_PROG_RANLIB
AC_ISC_POSIX
AC_AIX
AC_MINIX
dnl Checks for libraries.
saveLIBS="$LIBS"
AC_CHECK_LIB(db, dbopen, [ LIBDB=-ldb ; LIBS="-ldb $LIBS" ],
	AC_CHECK_LIB(db, db_open, [ LIBDB=-ldb ; LIBS="-ldb $LIBS"],
	AC_CHECK_LIB(db, db_env_create, [ LIBDB=-ldb; LIBS="-ldb $LIBS"])
	))
FOUND_DB=0
AC_CHECK_FUNC(dbopen, FOUND_DB=1)
AC_CHECK_FUNC(db_open, FOUND_DB=1)
AC_CHECK_FUNC(db_env_create, FOUND_DB=1)
LIBS="$saveLIBS"
AC_SUBST(LIBDB)
AM_CONDITIONAL(FOUND_DB, test "$FOUND_DB" != 0)
dnl Checks for header files.
AC_CHECK_HEADERS(limits.h fcntl.h unistd.h)
dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_SIZE_T
AC_LANG_CPLUSPLUS
AC_CACHE_CHECK([if the C++ compiler needs -fhandle-exceptions],
	ac_cxx_need_handlexceptions,
AC_TRY_COMPILE([],
[
throw;
], ac_cxx_need_handlexceptions=no,
ac_cxx_need_handlexceptions=yes)
)
if test "$ac_cxx_need_handlexceptions" = "yes"
then
	case "$CXXFLAGS" in
	*handle-exceptions*)
		;;
	*)
		CXXFLAGS="-fhandle-exceptions $CXXFLAGS"
		CXXFLAGS=`echo "$CXXFLAGS" | sed 's/-O2//'`
		;;
	esac
fi
if test "$GCC" = "yes"
then
	CFLAGS="-Wall $CFLAGS"
fi
AC_OUTPUT(Makefile)

						