开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 多媒体 > DVD > 查看源码
mmxidct.S
资源名称：dvd-munitions.tar.gz　[点击查看]
上传用户：aoeyumen
上传日期：2007-01-06
资源大小：3329k
文件大小：21k
源码类别：

DVD

开发平台：

Unix_Linux

mmxidct.S：源码内容
  1. /*
  2.  * the input data is tranposed and each 16 bit element in the 8x8 matrix
  3.  * is left aligned:
  4.  * for example in 11...1110000 format
  5.  * If the iDCT is of I macroblock then 0.5 needs to be added to the;DC Component
  6.  * (element[0][0] of the matrix)
  7.  */
  9. /* extrn re_matrix */
  11. .data
  12. .align 16
  13. .type  preSC,@object
  14. preSC:  .short  16384,22725,21407,19266,16384,12873,8867,4520
  15.         .short  22725,31521,29692,26722,22725,17855,12299,6270
  16.         .short  21407,29692,27969,25172,21407,16819,11585,5906
  17.         .short  19266,26722,25172,22654,19266,15137,10426,5315
  18.         .short  16384,22725,21407,19266,16384,12873,8867,4520
  19.         .short  12873,17855,16819,15137,25746,20228,13933,7103
  20.         .short  17734,24598,23170,20853,17734,13933,9597,4892
  21.         .short  18081,25080,23624,21261,18081,14206,9785,4988
  22. .size  preSC,128
  23. .align 8
  24. .type x0005000200010001,@object
  25. .size x0005000200010001,8
  26. x0005000200010001:
  27. .long 0x00010001,0x00050002
  28. .align 8
  29. .type x0040000000000000,@object
  30. .size x0040000000000000,8
  31. x0040000000000000:
  32. .long 0, 0x00400000
  33. .align 8
  34. .type x5a825a825a825a82,@object
  35. .size x5a825a825a825a82,8
  36. x5a825a825a825a82:
  37. .long 0x5a825a82, 0x5a825a82
  38. .align 8
  39. .type x539f539f539f539f,@object
  40. .size x539f539f539f539f,8
  41. x539f539f539f539f:
  42. .long 0x539f539f,0x539f539f
  43. .align 8
  44. .type x4546454645464546,@object
  45. .size x4546454645464546,8
  46. x4546454645464546:
  47. .long 0x45464546,0x45464546
  48. .align 8
  49. .type x61f861f861f861f8,@object
  50. .size x61f861f861f861f8,8
  51. x61f861f861f861f8:
  52. .long 0x61f861f8,0x61f861f8
  53. .align 8
  54. .type  scratch1,@object
  55. .size  scratch1,8
  56. scratch1:
  57. .long 0,0
  58. .align 8
  59. .type  scratch3,@object
  60. .size  scratch3,8
  61. scratch3:
  62. .long 0,0
  63. .align 8
  64. .type  scratch5,@object
  65. .size  scratch5,8
  66. scratch5:
  67. .long 0,0
  68. .align 8
  69. .type  scratch7,@object
  70. .size  scratch7,8
  71. scratch7:
  72. .long 0,0
  73. .type  x0,@object
  74. .size  x0,8
  75. x0:
  76. .long 0,0
  77. .align 8
  78. .text
  79. .align 4
  80. .globl IDCT_mmx
  81. .type  IDCT_mmx,@function
  82. IDCT_mmx:
  83. pushl %ebp
  84. movl %esp,%ebp
  85. pushl %ebx
  86. pushl %ecx
  87. pushl %edx
  88. pushl %esi
  89. pushl %edi
  90. movl 8(%ebp),%esi /* source matrix */
  91. #if 0
  92. movq (%esi), %mm0
  93. movq 8(%esi), %mm1
  94. psllw $4, %mm0
  95. movq 16(%esi), %mm2
  96. psllw $4, %mm1
  97. movq 24(%esi), %mm3
  98. psllw $4, %mm2
  99. movq 32(%esi), %mm4
  100. psllw $4, %mm3
  101. movq 40(%esi), %mm5
  102. psllw $4, %mm4
  103. movq 48(%esi), %mm6
  104. psllw $4, %mm5
  105. movq 56(%esi), %mm7
  106. psllw $4, %mm6
  107. psllw $4, %mm7
  108. movq %mm0,  (%esi)
  109. movq %mm1, 8(%esi)
  110. movq %mm2,16(%esi)
  111. movq %mm3,24(%esi)
  112. movq %mm4,32(%esi)
  113. movq %mm5,40(%esi)
  114. movq %mm6,48(%esi)
  115. movq %mm7,56(%esi)
  116. movq 64(%esi), %mm0
  117. movq 72(%esi), %mm1
  118. psllw $4, %mm0
  119. movq 80(%esi), %mm2
  120. psllw $4, %mm1
  121. movq 88(%esi), %mm3
  122. psllw $4, %mm2
  123. movq 96(%esi), %mm4
  124. psllw $4, %mm3
  125. movq 104(%esi), %mm5
  126. psllw $4, %mm4
  127. movq 112(%esi), %mm6
  128. psllw $4, %mm5
  129. movq 120(%esi), %mm7
  130. psllw $4, %mm6
  131. psllw $4, %mm7
  132. movq %mm0,64(%esi)
  133. movq %mm1,72(%esi)
  134. movq %mm2,80(%esi)
  135. movq %mm3,88(%esi)
  136. movq %mm4,96(%esi)
  137. movq %mm5,104(%esi)
  138. movq %mm6,112(%esi)
  139. movq %mm7,120(%esi)
  140. #endif
  141. leal preSC, %ecx
  142. /* column 0: even part
  143.  * use V4, V12, V0, V8 to produce V22..V25
  144.  */
  145. movq 8*12(%ecx), %mm0 /* maybe the first mul can be done together */
  146. /* with the dequantization in iHuff module */
  147. pmulhw 8*12(%esi), %mm0 /* V12 */
  148. movq 8*4(%ecx), %mm1
  149. pmulhw 8*4(%esi), %mm1 /* V4 */
  150. movq (%ecx), %mm3
  151. psraw $1, %mm0 /* t64=t66 */
  152. pmulhw (%esi), %mm3 /* V0 */
  153. movq 8*8(%ecx), %mm5 /* duplicate V4 */
  154. movq %mm1, %mm2 /* added 11/1/96 */
  155. pmulhw 8*8(%esi),%mm5 /* V8 */
  156. psubsw %mm0, %mm1 /* V16 */
  157. pmulhw x5a825a825a825a82, %mm1 /* 23170 ->V18 */
  158. paddsw %mm0, %mm2 /* V17 */
  159. movq %mm2, %mm0 /* duplicate V17 */
  160. psraw $1, %mm2 /* t75=t82 */
  161. psraw $2, %mm0 /* t72 */
  162. movq %mm3, %mm4 /* duplicate V0 */
  163. paddsw %mm5, %mm3 /* V19 */
  164. psubsw %mm5, %mm4 /* V20 ;mm5 free */
  165. /* moved from the block below */
  166. movq 8*10(%ecx), %mm7
  167. psraw $1, %mm3 /* t74=t81 */
  168. movq %mm3, %mm6 /* duplicate t74=t81 */
  169. psraw $2, %mm4 /* t77=t79 */
  170. psubsw %mm0, %mm1 /* V21 ; mm0 free */
  171. paddsw %mm2, %mm3 /* V22 */
  172. movq %mm1, %mm5 /* duplicate V21 */
  173. paddsw %mm4, %mm1 /* V23 */
  174. movq %mm3, 8*4(%esi) /* V22 */
  175. psubsw %mm5, %mm4 /* V24; mm5 free */
  176. movq %mm1, 8*12(%esi) /* V23 */
  177. psubsw %mm2, %mm6 /* V25; mm2 free */
  178. movq %mm4, (%esi) /* V24 */
  179. /* keep mm6 alive all along the next block */
  180. /* movq %mm6, 8*8(%esi)  V25 */
  181. /* column 0: odd part
  182.  * use V2, V6, V10, V14 to produce V31, V39, V40, V41
  183.  */
  184. /* moved above: movq 8*10(%ecx), %mm7 */
  186. pmulhw 8*10(%esi), %mm7 /* V10 */
  187. movq 8*6(%ecx), %mm0
  188. pmulhw 8*6(%esi), %mm0 /* V6 */
  189. movq 8*2(%ecx), %mm5
  190. movq %mm7, %mm3 /* duplicate V10 */
  191. pmulhw 8*2(%esi), %mm5 /* V2 */
  192. movq 8*14(%ecx), %mm4
  193. psubsw %mm0, %mm7 /* V26 */
  194. pmulhw 8*14(%esi), %mm4 /* V14 */
  195. paddsw %mm0, %mm3 /* V29 ; free mm0 */
  196. movq %mm7, %mm1 /* duplicate V26 */
  197. psraw $1, %mm3 /* t91=t94 */
  198. pmulhw x539f539f539f539f,%mm7 /* V33 */
  199. psraw $1, %mm1 /* t96 */
  200. movq %mm5, %mm0 /* duplicate V2 */
  201. psraw $2, %mm4 /* t85=t87 */
  202. paddsw %mm4,%mm5 /* V27 */
  203. psubsw %mm4, %mm0 /* V28 ; free mm4 */
  204. movq %mm0, %mm2 /* duplicate V28 */
  205. psraw $1, %mm5 /* t90=t93 */
  206. pmulhw x4546454645464546,%mm0 /* V35 */
  207. psraw $1, %mm2 /* t97 */
  208. movq %mm5, %mm4 /* duplicate t90=t93 */
  209. psubsw %mm2, %mm1 /* V32 ; free mm2 */
  210. pmulhw x61f861f861f861f8,%mm1 /* V36 */
  211. psllw $1, %mm7 /* t107 */
  212. paddsw %mm3, %mm5 /* V31 */
  213. psubsw %mm3, %mm4 /* V30 ; free mm3 */
  214. pmulhw x5a825a825a825a82,%mm4 /* V34 */
  215. nop
  216. psubsw %mm1, %mm0 /* V38 */
  217. psubsw %mm7, %mm1 /* V37 ; free mm7 */
  218. psllw $1, %mm1 /* t114 */
  219. /* move from the next block */
  220. movq %mm6, %mm3 /* duplicate V25 */
  221. /* move from the next block */
  222. movq 8*4(%esi), %mm7 /* V22 */
  223. psllw $1, %mm0 /* t110 */
  224. psubsw %mm5, %mm0 /* V39 (mm5 needed for next block) */
  225. psllw $2, %mm4 /* t112 */
  226. /* moved from the next block */
  227. movq 8*12(%esi), %mm2 /* V23 */
  228. psubsw %mm0, %mm4 /* V40 */
  229. paddsw %mm4, %mm1 /* V41; free mm0 */
  230. /* moved from the next block */
  231. psllw $1, %mm2 /* t117=t125 */
  232. /* column 0: output butterfly */
  233. /* moved above:
  234.  * movq %mm6, %mm3 duplicate V25
  235.  * movq 8*4(%esi), %mm7 V22
  236.  * movq 8*12(%esi), %mm2 V23
  237.  * psllw $1, %mm2 t117=t125
  238.  */
  239. psubsw %mm1, %mm6 /* tm6 */
  240. paddsw %mm1, %mm3 /* tm8; free mm1 */
  241. movq %mm7, %mm1 /* duplicate V22 */
  242. paddsw %mm5, %mm7 /* tm0 */
  243. movq %mm3, 8*8(%esi) /* tm8; free mm3 */
  244. psubsw %mm5, %mm1 /* tm14; free mm5 */
  245. movq %mm6, 8*6(%esi) /* tm6; free mm6 */
  246. movq %mm2, %mm3 /* duplicate t117=t125 */
  247. movq (%esi), %mm6 /* V24 */
  248. paddsw %mm0, %mm2 /* tm2 */
  249. movq %mm7, (%esi) /* tm0; free mm7 */
  250. psubsw %mm0, %mm3 /* tm12; free mm0 */
  251. movq %mm1, 8*14(%esi) /* tm14; free mm1 */
  252. psllw $1, %mm6 /* t119=t123 */
  253. movq %mm2, 8*2(%esi) /* tm2; free mm2 */
  254. movq %mm6, %mm0 /* duplicate t119=t123 */
  255. movq %mm3, 8*12(%esi) /* tm12; free mm3 */
  256. paddsw %mm4, %mm6 /* tm4 */
  257. /* moved from next block */
  258. movq 8*5(%ecx), %mm1
  259. psubsw %mm4, %mm0 /* tm10; free mm4 */
  260. /* moved from next block */
  261. pmulhw 8*5(%esi), %mm1 /* V5 */
  262. movq %mm6, 8*4(%esi) /* tm4; free mm6 */
  263. movq %mm0, 8*10(%esi) /* tm10; free mm0 */
  264. /* column 1: even part
  265.  * use V5, V13, V1, V9 to produce V56..V59
  266.  */
  267. /* moved to prev block:
  268.  * movq 8*5(%ecx), %mm1
  269.  * pmulhw 8*5(%esi), %mm1  V5
  270.  */
  271. movq 8*13(%ecx), %mm7
  272. psllw $1, %mm1 /* t128=t130 */
  273. pmulhw 8*13(%esi), %mm7 /* V13 */
  274. movq %mm1, %mm2 /* duplicate t128=t130 */
  275. movq 8(%ecx), %mm3
  276. pmulhw 8(%esi), %mm3 /* V1 */
  277. movq 8*9(%ecx), %mm5
  278. psubsw %mm7, %mm1 /* V50 */
  279. pmulhw 8*9(%esi), %mm5 /* V9 */
  280. paddsw %mm7, %mm2 /* V51 */
  281. pmulhw x5a825a825a825a82, %mm1 /* 23170 ->V52 */
  282. movq %mm2, %mm6 /* duplicate V51 */
  283. psraw $1, %mm2 /* t138=t144 */
  284. movq %mm3, %mm4 /* duplicate V1 */
  285. psraw $2, %mm6 /* t136 */
  286. paddsw %mm5, %mm3 /* V53 */
  287. psubsw %mm5, %mm4 /* V54 ;mm5 free */
  288. movq %mm3, %mm7 /* duplicate V53 */
  289. /* moved from next block */
  290. movq 8*11(%ecx), %mm0
  291. psraw $1, %mm4 /* t140=t142 */
  292. psubsw %mm6, %mm1 /* V55 ; mm6 free */
  293. paddsw %mm2, %mm3 /* V56 */
  294. movq %mm4, %mm5 /* duplicate t140=t142 */
  295. paddsw %mm1, %mm4 /* V57 */
  296. movq %mm3, 8*5(%esi) /* V56 */
  297. psubsw %mm1, %mm5 /* V58; mm1 free */
  298. movq %mm4, 8*13(%esi) /* V57 */
  299. psubsw %mm2, %mm7 /* V59; mm2 free */
  300. movq %mm5, 8*9(%esi) /* V58 */
  301. /* keep mm7 alive all along the next block
  302.  * movq %mm7, 8(%esi) V59
  303.  * moved above
  304.  * movq 8*11(%ecx), %mm0
  305.  */
  306. pmulhw 8*11(%esi), %mm0 /* V11 */
  307. movq 8*7(%ecx), %mm6
  308. pmulhw 8*7(%esi), %mm6 /* V7 */
  309. movq 8*15(%ecx), %mm4
  310. movq %mm0, %mm3 /* duplicate V11 */
  311. pmulhw 8*15(%esi), %mm4 /* V15 */
  312. movq 8*3(%ecx), %mm5
  313. psllw $1, %mm6 /* t146=t152 */
  314. pmulhw 8*3(%esi), %mm5 /* V3 */
  315. paddsw %mm6, %mm0 /* V63 */
  316. /* note that V15 computation has a correction step: 
  317.  * this is a 'magic' constant that rebiases the results to be closer to the
  318.  * expected result.  this magic constant can be refined to reduce the error
  319.  * even more by doing the correction step in a later stage when the number
  320.  * is actually multiplied by 16
  321.  */
  322. paddw x0005000200010001, %mm4
  323. psubsw %mm6, %mm3 /* V60 ; free mm6 */
  324. psraw $1, %mm0 /* t154=t156 */
  325. movq %mm3, %mm1 /* duplicate V60 */
  326. pmulhw x539f539f539f539f, %mm1 /* V67 */
  327. movq %mm5, %mm6 /* duplicate V3 */
  328. psraw $2, %mm4 /* t148=t150 */
  329. paddsw %mm4, %mm5 /* V61 */
  330. psubsw %mm4, %mm6 /* V62 ; free mm4 */
  331. movq %mm5, %mm4 /* duplicate V61 */
  332. psllw $1, %mm1 /* t169 */
  333. paddsw %mm0, %mm5 /* V65 -> result */
  334. psubsw %mm0, %mm4 /* V64 ; free mm0 */
  335. pmulhw x5a825a825a825a82, %mm4 /* V68 */
  336. psraw $1, %mm3 /* t158 */
  337. psubsw %mm6, %mm3 /* V66 */
  338. movq %mm5, %mm2 /* duplicate V65 */
  339. pmulhw x61f861f861f861f8, %mm3 /* V70 */
  340. psllw $1, %mm6 /* t165 */
  341. pmulhw x4546454645464546, %mm6 /* V69 */
  342. psraw $1, %mm2 /* t172 */
  343. /* moved from next block */
  344. movq 8*5(%esi), %mm0 /* V56 */
  345. psllw $1, %mm4 /* t174 */
  346. /* moved from next block */
  347. psraw $1, %mm0 /* t177=t188 */
  348. nop
  349. psubsw %mm3, %mm6 /* V72 */
  350. psubsw %mm1, %mm3 /* V71 ; free mm1 */
  351. psubsw %mm2, %mm6 /* V73 ; free mm2 */
  352. /* moved from next block */
  353. psraw $1, %mm5 /* t178=t189 */
  354. psubsw %mm6, %mm4 /* V74 */
  355. /* moved from next block */
  356. movq %mm0, %mm1 /* duplicate t177=t188 */
  357. paddsw %mm4, %mm3 /* V75 */
  358. /* moved from next block */
  359. paddsw %mm5, %mm0 /* tm1 */
  360. /* location
  361.  *  5 - V56
  362.  * 13 - V57
  363.  *  9 - V58
  364.  *  X - V59, mm7
  365.  *  X - V65, mm5
  366.  *  X - V73, mm6
  367.  *  X - V74, mm4
  368.  *  X - V75, mm3
  369.  * free mm0, mm1 & mm2
  370.  * moved above
  371.  * movq 8*5(%esi), %mm0 V56
  372.  * psllw $1, %mm0 t177=t188 ! new !!
  373.  * psllw $1, %mm5 t178=t189 ! new !!
  374.  * movq %mm0, %mm1 duplicate t177=t188
  375.  * paddsw %mm5, %mm0 tm1
  376.  */
  377. movq 8*13(%esi), %mm2 /* V57 */
  378. psubsw %mm5, %mm1 /* tm15; free mm5 */
  379. movq %mm0, 8(%esi) /* tm1; free mm0 */
  380. psraw $1, %mm7 /* t182=t184 ! new !! */
  381. /* save the store as used directly in the transpose
  382.  * movq %mm1, 120(%esi) tm15; free mm1
  383.  */
  384. movq %mm7, %mm5 /* duplicate t182=t184 */
  385. psubsw %mm3, %mm7 /* tm7 */
  386. paddsw %mm3, %mm5 /* tm9; free mm3 */
  387. movq 8*9(%esi), %mm0 /* V58 */
  388. movq %mm2, %mm3 /* duplicate V57 */
  389. movq %mm7, 8*7(%esi) /* tm7; free mm7 */
  390. psubsw %mm6, %mm3 /* tm13 */
  391. paddsw %mm6, %mm2 /* tm3 ; free mm6 */
  392. /* moved up from the transpose */
  393. movq %mm3, %mm7
  394. /* moved up from the transpose */
  395. punpcklwd %mm1, %mm3
  396. movq %mm0, %mm6 /* duplicate V58 */
  397. movq %mm2, 8*3(%esi) /* tm3; free mm2 */
  398. paddsw %mm4, %mm0 /* tm5 */
  399. psubsw %mm4, %mm6 /* tm11; free mm4 */
  400. /* moved up from the transpose */
  401. punpckhwd %mm1, %mm7
  402. movq %mm0, 8*5(%esi) /* tm5; free mm0 */
  403. /* moved up from the transpose */
  404. movq %mm5, %mm2
  405. /* transpose - M4 part
  406.  *  ---------       ---------
  407.  * | M1 | M2 |     | M1'| M3'|
  408.  *  ---------  -->  ---------
  409.  * | M3 | M4 |     | M2'| M4'|
  410.  *  ---------       ---------
  411.  * Two alternatives: use full mmword approach so the following code can be
  412.  * scheduled before the transpose is done without stores, or use the faster
  413.  * half mmword stores (when possible)
  414.  */
  415. movd %mm3, 8*9+4(%esi) /* MS part of tmt9 */
  416. punpcklwd %mm6, %mm5
  417. movd %mm7, 8*13+4(%esi) /* MS part of tmt13 */
  418. punpckhwd %mm6, %mm2
  419. movd %mm5, 8*9(%esi) /* LS part of tmt9 */
  420. punpckhdq %mm3, %mm5 /* free mm3 */
  421. movd %mm2, 8*13(%esi) /* LS part of tmt13 */
  422. punpckhdq %mm7, %mm2 /* free mm7 */
  423. /* moved up from the M3 transpose */
  424. movq 8*8(%esi), %mm0
  425. /* moved up from the M3 transpose */
  426. movq 8*10(%esi), %mm1
  427. /* moved up from the M3 transpose */
  428. movq %mm0, %mm3
  429. /* shuffle the rest of the data, and write it with 2 mmword writes */
  430. movq %mm5, 8*11(%esi) /* tmt11 */
  431. /* moved up from the M3 transpose */
  432. punpcklwd %mm1, %mm0
  433. movq %mm2, 8*15(%esi) /* tmt15 */
  434. /* moved up from the M3 transpose */
  435. punpckhwd %mm1, %mm3
  436. /* transpose - M3 part
  437.  * moved up to previous code section
  438.  * movq 8*8(%esi), %mm0
  439.  * movq 8*10(%esi), %mm1
  440.  * movq %mm0, %mm3
  441.  * punpcklwd %mm1, %mm0
  442.  * punpckhwd %mm1, %mm3
  443.  */
  444. movq 8*12(%esi), %mm6
  445. movq 8*14(%esi), %mm4
  446. movq %mm6, %mm2
  447. /* shuffle the data and write the lower parts of the transposed in 4 dwords */
  448. punpcklwd %mm4, %mm6
  449. movq %mm0, %mm1
  450. punpckhdq %mm6, %mm1
  451. movq %mm3, %mm7
  452. punpckhwd %mm4, %mm2 /* free mm4 */
  453. punpckldq %mm6, %mm0 /* free mm6 */
  454. /* moved from next block */
  455. movq 8*13(%esi), %mm4 /* tmt13 */
  456. punpckldq %mm2, %mm3
  457. punpckhdq %mm2, %mm7 /* free mm2 */
  458. /* moved from next block */
  459. movq %mm3, %mm5 /* duplicate tmt5 */
  460. /* column 1: even part (after transpose)
  461. * moved above
  462. * movq %mm3, %mm5 duplicate tmt5
  463. * movq 8*13(%esi), %mm4 tmt13
  464. */
  465. psubsw %mm4, %mm3 /* V134 */
  466. pmulhw x5a825a825a825a82, %mm3 /* 23170 ->V136 */
  467. movq 8*9(%esi), %mm6 /* tmt9 */
  468. paddsw %mm4, %mm5 /* V135 ; mm4 free */
  469. movq %mm0, %mm4 /* duplicate tmt1 */
  470. paddsw %mm6, %mm0 /* V137 */
  471. psubsw %mm6, %mm4 /* V138 ; mm6 free */
  472. psllw $2, %mm3 /* t290 */
  473. psubsw %mm5, %mm3 /* V139 */
  474. movq %mm0, %mm6 /* duplicate V137 */
  475. paddsw %mm5, %mm0 /* V140 */
  476. movq %mm4, %mm2 /* duplicate V138 */
  477. paddsw %mm3, %mm2 /* V141 */
  478. psubsw %mm3, %mm4 /* V142 ; mm3 free */
  479. movq %mm0, 8*9(%esi) /* V140 */
  480. psubsw %mm5, %mm6 /* V143 ; mm5 free */
  481. /* moved from next block */
  482. movq 8*11(%esi), %mm0 /* tmt11 */
  483. movq %mm2, 8*13(%esi) /* V141 */
  484. /* moved from next block */
  485. movq %mm0, %mm2 /* duplicate tmt11 */
  486. /* column 1: odd part (after transpose) */
  487. /* moved up to the prev block
  488.  * movq 8*11(%esi), %mm0 tmt11
  489.  * movq %mm0, %mm2 duplicate tmt11
  490.  */
  491. movq 8*15(%esi), %mm5 /* tmt15 */
  492. psubsw %mm7, %mm0 /* V144 */
  493. movq %mm0, %mm3 /* duplicate V144 */
  494. paddsw %mm7, %mm2 /* V147 ; free mm7 */
  495. pmulhw x539f539f539f539f, %mm0 /* 21407-> V151 */
  496. movq %mm1, %mm7 /* duplicate tmt3 */
  497. paddsw %mm5, %mm7 /* V145 */
  498. psubsw %mm5, %mm1 /* V146 ; free mm5 */
  499. psubsw %mm1, %mm3 /* V150 */
  500. movq %mm7, %mm5 /* duplicate V145 */
  501. pmulhw x4546454645464546, %mm1 /* 17734-> V153 */
  502. psubsw %mm2, %mm5 /* V148 */
  503. pmulhw x61f861f861f861f8, %mm3 /* 25080-> V154 */
  504. psllw $2, %mm0 /* t311 */
  505. pmulhw x5a825a825a825a82, %mm5 /* 23170-> V152 */
  506. paddsw %mm2, %mm7 /* V149 ; free mm2 */
  507. psllw $1, %mm1 /* t313 */
  508. nop /* without the nop - freeze here for one clock */
  509. movq %mm3, %mm2 /* duplicate V154 */
  510. psubsw %mm0, %mm3 /* V155 ; free mm0 */
  511. psubsw %mm2, %mm1 /* V156 ; free mm2 */
  512. /* moved from the next block */
  513. movq %mm6, %mm2 /* duplicate V143 */
  514. /* moved from the next block */
  515. movq 8*13(%esi), %mm0 /* V141 */
  516. psllw $1, %mm1 /* t315 */
  517. psubsw %mm7, %mm1 /* V157 (keep V149) */
  518. psllw $2, %mm5 /* t317 */
  519. psubsw %mm1, %mm5 /* V158 */
  520. psllw $1, %mm3 /* t319 */
  521. paddsw %mm5, %mm3 /* V159 */
  522. /* column 1: output butterfly (after transform)
  523.  * moved to the prev block
  524.  * movq %mm6, %mm2 duplicate V143
  525.  * movq 8*13(%esi), %mm0 V141
  526.  */
  527. psubsw %mm3, %mm2 /* V163 */
  528. paddsw %mm3, %mm6 /* V164 ; free mm3 */
  529. movq %mm4, %mm3 /* duplicate V142 */
  530. psubsw %mm5, %mm4 /* V165 ; free mm5 */
  531. movq %mm2, scratch7 /* out7 */
  532. psraw $4, %mm6
  533. psraw $4, %mm4
  534. paddsw %mm5, %mm3 /* V162 */
  535. movq 8*9(%esi), %mm2 /* V140 */
  536. movq %mm0, %mm5 /* duplicate V141 */
  537. /* in order not to perculate this line up,
  538.  * we read 72(%esi) very near to this location
  539.  */
  540. movq %mm6, 8*9(%esi) /* out9 */
  541. paddsw %mm1, %mm0 /* V161 */
  542. movq %mm3, scratch5 /* out5 */
  543. psubsw %mm1, %mm5 /* V166 ; free mm1 */
  544. movq %mm4, 8*11(%esi) /* out11 */
  545. psraw $4, %mm5
  546. movq %mm0, scratch3 /* out3 */
  547. movq %mm2, %mm4 /* duplicate V140 */
  548. movq %mm5, 8*13(%esi) /* out13 */
  549. paddsw %mm7, %mm2 /* V160 */
  550. /* moved from the next block */
  551. movq 8(%esi), %mm0
  552. psubsw %mm7, %mm4 /* V167 ; free mm7 */
  553. /* moved from the next block */
  554. movq 8*3(%esi), %mm7
  555. psraw $4, %mm4
  556. movq %mm2, scratch1 /* out1 */
  557. /* moved from the next block */
  558. movq %mm0, %mm1
  559. movq %mm4, 8*15(%esi) /* out15 */
  560. /* moved from the next block */
  561. punpcklwd %mm7, %mm0
  562. /* transpose - M2 parts
  563.  * moved up to the prev block
  564.  * movq 8(%esi), %mm0
  565.  * movq 8*3(%esi), %mm7
  566.  * movq %mm0, %mm1
  567.  * punpcklwd %mm7, %mm0
  568.  */
  569. movq 8*5(%esi), %mm5
  570. punpckhwd %mm7, %mm1
  571. movq 8*7(%esi), %mm4
  572. movq %mm5, %mm3
  573. /* shuffle the data and write the lower parts of the trasposed in 4 dwords */
  574. movd %mm0, 8*8(%esi) /* LS part of tmt8 */
  575. punpcklwd %mm4, %mm5
  576. movd %mm1, 8*12(%esi) /* LS part of tmt12 */
  577. punpckhwd %mm4, %mm3
  578. movd %mm5, 8*8+4(%esi) /* MS part of tmt8 */
  579. punpckhdq %mm5, %mm0 /* tmt10 */
  580. movd %mm3, 8*12+4(%esi) /* MS part of tmt12 */
  581. punpckhdq %mm3, %mm1 /* tmt14 */
  582. /* transpose - M1 parts */
  583. movq (%esi), %mm7
  584. movq 8*2(%esi), %mm2
  585. movq %mm7, %mm6
  586. movq 8*4(%esi), %mm5
  587. punpcklwd %mm2, %mm7
  588. movq 8*6(%esi), %mm4
  589. punpckhwd %mm2, %mm6 /* free mm2 */
  590. movq %mm5, %mm3
  591. punpcklwd %mm4, %mm5
  592. punpckhwd %mm4, %mm3 /* free mm4 */
  593. movq %mm7, %mm2
  594. movq %mm6, %mm4
  595. punpckldq %mm5, %mm7 /* tmt0 */
  596. punpckhdq %mm5, %mm2 /* tmt2 ; free mm5 */
  597. /* shuffle the rest of the data, and write it with 2 mmword writes */
  598. punpckldq %mm3, %mm6 /* tmt4 */
  599. /* moved from next block */
  600. movq %mm2, %mm5 /* duplicate tmt2 */
  601. punpckhdq %mm3, %mm4 /* tmt6 ; free mm3 */
  602. /* moved from next block */
  603. movq %mm0, %mm3 /* duplicate tmt10 */
  604. /* column 0: odd part (after transpose)
  605.  *moved up to prev block
  606.  * movq %mm0, %mm3 duplicate tmt10
  607.  * movq %mm2, %mm5 duplicate tmt2
  608.  */
  609. psubsw %mm4, %mm0 /* V110 */
  610. paddsw %mm4, %mm3 /* V113 ; free mm4 */
  611. movq %mm0, %mm4 /* duplicate V110 */
  612. paddsw %mm1, %mm2 /* V111 */
  613. pmulhw x539f539f539f539f, %mm0 /* 21407-> V117 */
  614. psubsw %mm1, %mm5 /* V112 ; free mm1 */
  615. psubsw %mm5, %mm4 /* V116 */
  616. movq %mm2, %mm1 /* duplicate V111 */
  617. pmulhw x4546454645464546, %mm5 /* 17734-> V119 */
  618. psubsw %mm3, %mm2 /* V114 */
  619. pmulhw x61f861f861f861f8, %mm4 /* 25080-> V120 */
  620. paddsw %mm3, %mm1 /* V115 ; free mm3 */
  621. pmulhw x5a825a825a825a82, %mm2 /* 23170-> V118 */
  622. psllw $2, %mm0 /* t266 */
  623. movq %mm1, (%esi) /* save V115 */
  624. psllw $1, %mm5 /* t268 */
  625. psubsw %mm4, %mm5 /* V122 */
  626. psubsw %mm0, %mm4 /* V121 ; free mm0 */
  627. psllw $1, %mm5 /* t270 */
  628. psubsw %mm1, %mm5 /* V123 ; free mm1 */
  629. psllw $2, %mm2 /* t272 */
  630. psubsw %mm5, %mm2 /* V124 (keep V123) */
  631. psllw $1, %mm4 /* t274 */
  632. movq %mm5, 8*2(%esi) /* save V123 ; free mm5 */
  633. paddsw %mm2, %mm4 /* V125 (keep V124) */
  634. /* column 0: even part (after transpose) */
  635. movq 8*12(%esi), %mm0 /* tmt12 */
  636. movq %mm6, %mm3 /* duplicate tmt4 */
  637. psubsw %mm0, %mm6 /* V100 */
  638. paddsw %mm0, %mm3 /* V101 ; free mm0 */
  639. pmulhw x5a825a825a825a82, %mm6 /* 23170 ->V102 */
  640. movq %mm7, %mm5 /* duplicate tmt0 */
  641. movq 8*8(%esi), %mm1 /* tmt8 */
  642. paddsw %mm1, %mm7 /* V103 */
  643. psubsw %mm1, %mm5 /* V104 ; free mm1 */
  644. movq %mm7, %mm0 /* duplicate V103 */
  645. psllw $2, %mm6 /* t245 */
  646. paddsw %mm3, %mm7 /* V106 */
  647. movq %mm5, %mm1 /* duplicate V104 */
  648. psubsw %mm3, %mm6 /* V105 */
  649. psubsw %mm3, %mm0 /* V109; free mm3 */
  650. paddsw %mm6, %mm5 /* V107 */
  651. psubsw %mm6, %mm1 /* V108 ; free mm6 */
  652. /* column 0: output butterfly (after transform) */
  653. movq %mm1, %mm3 /* duplicate V108 */
  654. paddsw %mm2, %mm1 /* out4 */
  655. psraw $4, %mm1
  656. psubsw %mm2, %mm3 /* out10 ; free mm2 */
  657. psraw $4, %mm3
  658. movq %mm0, %mm6 /* duplicate V109 */
  659. movq %mm1, 8*4(%esi) /* out4 ; free mm1 */
  660. psubsw %mm4, %mm0 /* out6 */
  661. movq %mm3, 8*10(%esi) /* out10 ; free mm3 */
  662. psraw $4, %mm0
  663. paddsw %mm4, %mm6 /* out8 ; free mm4 */
  664. movq %mm7, %mm1 /* duplicate V106 */
  665. movq %mm0, 8*6(%esi) /* out6 ; free mm0 */
  666. psraw $4, %mm6
  667. movq (%esi), %mm4 /* V115 */
  668. movq %mm6, 8*8(%esi) /* out8 ; free mm6 */
  669. movq %mm5, %mm2 /* duplicate V107 */
  670. movq 8*2(%esi), %mm3 /* V123 */
  671. paddsw %mm4, %mm7 /* out0 */
  672. /* moved up from next block */
  673. movq scratch3, %mm0
  674. psraw $4, %mm7
  675. /* moved up from next block */
  676. movq scratch5, %mm6 
  677. psubsw %mm4, %mm1 /* out14 ; free mm4 */
  678. paddsw %mm3, %mm5 /* out2 */
  679. psraw $4, %mm1
  680. movq %mm7, (%esi) /* out0 ; free mm7 */
  681. psraw $4, %mm5
  682. movq %mm1, 8*14(%esi) /* out14 ; free mm1 */
  683. psubsw %mm3, %mm2 /* out12 ; free mm3 */
  684. movq %mm5, 8*2(%esi) /* out2 ; free mm5 */
  685. psraw $4, %mm2
  686. /* moved up to the prev block */
  687. movq scratch7, %mm4
  688. /* moved up to the prev block */
  689. psraw $4, %mm0
  690. movq %mm2, 8*12(%esi) /* out12 ; free mm2 */
  691. /* moved up to the prev block */
  692. psraw $4, %mm6
  693. /* move back the data to its correct place
  694. * moved up to the prev block
  695.  * movq scratch3, %mm0
  696.  * movq scratch5, %mm6
  697.  * movq scratch7, %mm4
  698.  * psraw $4, %mm0
  699.  * psraw $4, %mm6
  700. */
  701. movq scratch1, %mm1
  702. psraw $4, %mm4
  703. movq %mm0, 8*3(%esi) /* out3 */
  704. psraw $4, %mm1
  705. movq %mm6, 8*5(%esi) /* out5 */
  706. movq %mm4, 8*7(%esi) /* out7 */
  707. movq %mm1, 8(%esi) /* out1 */
  708. popl %edi
  709. popl %esi
  710. popl %edx
  711. popl %ecx
  712. popl %ebx
  713. movl %ebp,%esp
  714. popl %ebp
  715. ret
  716. .Lfe1:
  717. .size  IDCT_mmx,.Lfe1-IDCT_mmx