开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 多媒体 > DVD > 查看源码
idct_block_mmx.S
资源名称：dvd-munitions.tar.gz　[点击查看]
上传用户：aoeyumen
上传日期：2007-01-06
资源大小：3329k
文件大小：20k
源码类别：

DVD

开发平台：

Unix_Linux

idct_block_mmx.S：源码内容
  1. /*
  2.  * the input data is tranposed and each 16 bit element in the 8x8 matrix
  3.  * is left aligned:
  4.  * for example in 11...1110000 format
  5.  * If the iDCT is of I macroblock then 0.5 needs to be added to the;DC Component
  6.  * (element[0][0] of the matrix)
  7.  */
  11. .text
  12. .align 4
  13. .globl idct_block_mmx 
  14. .type  idct_block_mmx,@function
  15. idct_block_mmx:
  16. pushl  %ebp
  17. movl  %esp,%ebp
  18. pushl  %esi
  19. leal  preSC, %ecx
  20. movl  8(%ebp),%esi /* source matrix */
  22. /* 
  23.  * column 0: even part
  24.  *  use V4, V12, V0, V8 to produce V22..V25
  25.  */
  26. movq 8*12(%ecx), %mm0 /* maybe the first mul can be done together */
  27. /* with the dequantization in iHuff module */
  28. pmulhw  8*12(%esi), %mm0 /* V12 */
  29. movq 8*4(%ecx), %mm1
  30. pmulhw  8*4(%esi), %mm1 /* V4 */
  31. movq  (%ecx), %mm3
  32. psraw $1, %mm0 /* t64=t66 */
  33. pmulhw (%esi), %mm3 /* V0 */
  34. movq 8*8(%ecx), %mm5 /* duplicate V4 */
  35. movq %mm1, %mm2 /* added 11/1/96 */
  36. pmulhw 8*8(%esi),%mm5 /* V8 */
  37. psubsw %mm0, %mm1 /* V16 */
  38. pmulhw x5a825a825a825a82, %mm1 /* 23170 ->V18 */
  39. paddsw %mm0, %mm2 /* V17 */
  40. movq %mm2, %mm0 /* duplicate V17 */
  41. psraw $1, %mm2 /* t75=t82 */
  42. psraw $2, %mm0 /* t72 */
  43. movq %mm3, %mm4 /* duplicate V0 */
  44. paddsw %mm5, %mm3 /* V19 */
  45. psubsw %mm5, %mm4 /* V20 ;mm5 free */
  46. /* moved from the block below */
  47. movq 8*10(%ecx), %mm7
  48. psraw $1, %mm3 /* t74=t81 */
  49. movq %mm3, %mm6 /* duplicate t74=t81 */
  50. psraw $2, %mm4 /* t77=t79 */
  51. psubsw %mm0, %mm1 /* V21 ; mm0 free */
  52. paddsw %mm2, %mm3 /* V22 */
  53. movq %mm1, %mm5 /* duplicate V21 */
  54. paddsw %mm4, %mm1 /* V23 */
  55. movq %mm3, 8*4(%esi) /* V22 */
  56. psubsw %mm5, %mm4 /* V24; mm5 free */
  57. movq %mm1, 8*12(%esi) /* V23 */
  58. psubsw %mm2, %mm6 /* V25; mm2 free */
  59. movq %mm4, (%esi) /* V24 */
  60. /* keep mm6 alive all along the next block */
  61. /* movq %mm6, 8*8(%esi)  V25 */
  62. /* column 0: odd part
  63.  * use V2, V6, V10, V14 to produce V31, V39, V40, V41
  64.  */
  65. /* moved above: movq 8*10(%ecx), %mm7 */
  67. pmulhw 8*10(%esi), %mm7 /* V10 */
  68. movq 8*6(%ecx), %mm0
  69. pmulhw 8*6(%esi), %mm0 /* V6 */
  70. movq 8*2(%ecx), %mm5
  71. movq %mm7, %mm3 /* duplicate V10 */
  72. pmulhw 8*2(%esi), %mm5 /* V2 */
  73. movq 8*14(%ecx), %mm4
  74. psubsw %mm0, %mm7 /* V26 */
  75. pmulhw 8*14(%esi), %mm4 /* V14 */
  76. paddsw %mm0, %mm3 /* V29 ; free mm0 */
  77. movq %mm7, %mm1 /* duplicate V26 */
  78. psraw $1, %mm3 /* t91=t94 */
  79. pmulhw x539f539f539f539f,%mm7 /* V33 */
  80. psraw $1, %mm1 /* t96 */
  81. movq %mm5, %mm0 /* duplicate V2 */
  82. psraw $2, %mm4 /* t85=t87 */
  83. paddsw %mm4,%mm5 /* V27 */
  84. psubsw %mm4, %mm0 /* V28 ; free mm4 */
  85. movq %mm0, %mm2 /* duplicate V28 */
  86. psraw $1, %mm5 /* t90=t93 */
  87. pmulhw x4546454645464546,%mm0 /* V35 */
  88. psraw $1, %mm2 /* t97 */
  89. movq %mm5, %mm4 /* duplicate t90=t93 */
  90. psubsw %mm2, %mm1 /* V32 ; free mm2 */
  91. pmulhw x61f861f861f861f8,%mm1 /* V36 */
  92. psllw $1, %mm7 /* t107 */
  93. paddsw %mm3, %mm5 /* V31 */
  94. psubsw %mm3, %mm4 /* V30 ; free mm3 */
  95. pmulhw x5a825a825a825a82,%mm4 /* V34 */
  96. nop
  97. psubsw %mm1, %mm0 /* V38 */
  98. psubsw %mm7, %mm1 /* V37 ; free mm7 */
  99. psllw $1, %mm1 /* t114 */
  100. /* move from the next block */
  101. movq %mm6, %mm3 /* duplicate V25 */
  102. /* move from the next block */
  103. movq 8*4(%esi), %mm7 /* V22 */
  104. psllw $1, %mm0 /* t110 */
  105. psubsw %mm5, %mm0 /* V39 (mm5 needed for next block) */
  106. psllw $2, %mm4 /* t112 */
  107. /* moved from the next block */
  108. movq 8*12(%esi), %mm2 /* V23 */
  109. psubsw %mm0, %mm4 /* V40 */
  110. paddsw %mm4, %mm1 /* V41; free mm0 */
  111. /* moved from the next block */
  112. psllw $1, %mm2 /* t117=t125 */
  113. /* column 0: output butterfly */
  114. /* moved above:
  115.  * movq %mm6, %mm3 duplicate V25
  116.  * movq 8*4(%esi), %mm7 V22
  117.  * movq 8*12(%esi), %mm2 V23
  118.  * psllw $1, %mm2 t117=t125
  119.  */
  120. psubsw %mm1, %mm6 /* tm6 */
  121. paddsw %mm1, %mm3 /* tm8; free mm1 */
  122. movq %mm7, %mm1 /* duplicate V22 */
  123. paddsw %mm5, %mm7 /* tm0 */
  124. movq %mm3, 8*8(%esi) /* tm8; free mm3 */
  125. psubsw %mm5, %mm1 /* tm14; free mm5 */
  126. movq %mm6, 8*6(%esi) /* tm6; free mm6 */
  127. movq %mm2, %mm3 /* duplicate t117=t125 */
  128. movq (%esi), %mm6 /* V24 */
  129. paddsw %mm0, %mm2 /* tm2 */
  130. movq %mm7, (%esi) /* tm0; free mm7 */
  131. psubsw %mm0, %mm3 /* tm12; free mm0 */
  132. movq %mm1, 8*14(%esi) /* tm14; free mm1 */
  133. psllw $1, %mm6 /* t119=t123 */
  134. movq %mm2, 8*2(%esi) /* tm2; free mm2 */
  135. movq %mm6, %mm0 /* duplicate t119=t123 */
  136. movq %mm3, 8*12(%esi) /* tm12; free mm3 */
  137. paddsw %mm4, %mm6 /* tm4 */
  138. /* moved from next block */
  139. movq 8*5(%ecx), %mm1
  140. psubsw %mm4, %mm0 /* tm10; free mm4 */
  141. /* moved from next block */
  142. pmulhw 8*5(%esi), %mm1 /* V5 */
  143. movq %mm6, 8*4(%esi) /* tm4; free mm6 */
  144. movq %mm0, 8*10(%esi) /* tm10; free mm0 */
  145. /* column 1: even part
  146.  * use V5, V13, V1, V9 to produce V56..V59
  147.  */
  148. /* moved to prev block:
  149.  * movq 8*5(%ecx), %mm1
  150.  * pmulhw 8*5(%esi), %mm1  V5
  151.  */
  152. movq 8*13(%ecx), %mm7
  153. psllw $1, %mm1 /* t128=t130 */
  154. pmulhw 8*13(%esi), %mm7 /* V13 */
  155. movq %mm1, %mm2 /* duplicate t128=t130 */
  156. movq 8(%ecx), %mm3
  157. pmulhw 8(%esi), %mm3 /* V1 */
  158. movq 8*9(%ecx), %mm5
  159. psubsw %mm7, %mm1 /* V50 */
  160. pmulhw 8*9(%esi), %mm5 /* V9 */
  161. paddsw %mm7, %mm2 /* V51 */
  162. pmulhw x5a825a825a825a82, %mm1 /* 23170 ->V52 */
  163. movq %mm2, %mm6 /* duplicate V51 */
  164. psraw $1, %mm2 /* t138=t144 */
  165. movq %mm3, %mm4 /* duplicate V1 */
  166. psraw $2, %mm6 /* t136 */
  167. paddsw %mm5, %mm3 /* V53 */
  168. psubsw %mm5, %mm4 /* V54 ;mm5 free */
  169. movq %mm3, %mm7 /* duplicate V53 */
  170. /* moved from next block */
  171. movq 8*11(%ecx), %mm0
  172. psraw $1, %mm4 /* t140=t142 */
  173. psubsw %mm6, %mm1 /* V55 ; mm6 free */
  174. paddsw %mm2, %mm3 /* V56 */
  175. movq %mm4, %mm5 /* duplicate t140=t142 */
  176. paddsw %mm1, %mm4 /* V57 */
  177. movq %mm3, 8*5(%esi) /* V56 */
  178. psubsw %mm1, %mm5 /* V58; mm1 free */
  179. movq %mm4, 8*13(%esi) /* V57 */
  180. psubsw %mm2, %mm7 /* V59; mm2 free */
  181. movq %mm5, 8*9(%esi) /* V58 */
  182. /* keep mm7 alive all along the next block
  183.  * movq %mm7, 8(%esi) V59
  184.  * moved above
  185.  * movq 8*11(%ecx), %mm0
  186.  */
  187. pmulhw 8*11(%esi), %mm0 /* V11 */
  188. movq 8*7(%ecx), %mm6
  189. pmulhw 8*7(%esi), %mm6 /* V7 */
  190. movq 8*15(%ecx), %mm4
  191. movq %mm0, %mm3 /* duplicate V11 */
  192. pmulhw 8*15(%esi), %mm4 /* V15 */
  193. movq 8*3(%ecx), %mm5
  194. psllw $1, %mm6 /* t146=t152 */
  195. pmulhw 8*3(%esi), %mm5 /* V3 */
  196. paddsw %mm6, %mm0 /* V63 */
  197. /* note that V15 computation has a correction step: 
  198.  * this is a 'magic' constant that rebiases the results to be closer to the
  199.  * expected result.  this magic constant can be refined to reduce the error
  200.  * even more by doing the correction step in a later stage when the number
  201.  * is actually multiplied by 16
  202.  */
  203. paddw x0005000200010001, %mm4
  204. psubsw %mm6, %mm3 /* V60 ; free mm6 */
  205. psraw $1, %mm0 /* t154=t156 */
  206. movq %mm3, %mm1 /* duplicate V60 */
  207. pmulhw x539f539f539f539f, %mm1 /* V67 */
  208. movq %mm5, %mm6 /* duplicate V3 */
  209. psraw $2, %mm4 /* t148=t150 */
  210. paddsw %mm4, %mm5 /* V61 */
  211. psubsw %mm4, %mm6 /* V62 ; free mm4 */
  212. movq %mm5, %mm4 /* duplicate V61 */
  213. psllw $1, %mm1 /* t169 */
  214. paddsw %mm0, %mm5 /* V65 -> result */
  215. psubsw %mm0, %mm4 /* V64 ; free mm0 */
  216. pmulhw x5a825a825a825a82, %mm4 /* V68 */
  217. psraw $1, %mm3 /* t158 */
  218. psubsw %mm6, %mm3 /* V66 */
  219. movq %mm5, %mm2 /* duplicate V65 */
  220. pmulhw x61f861f861f861f8, %mm3 /* V70 */
  221. psllw $1, %mm6 /* t165 */
  222. pmulhw x4546454645464546, %mm6 /* V69 */
  223. psraw $1, %mm2 /* t172 */
  224. /* moved from next block */
  225. movq 8*5(%esi), %mm0 /* V56 */
  226. psllw $1, %mm4 /* t174 */
  227. /* moved from next block */
  228. psraw $1, %mm0 /* t177=t188 */
  229. nop
  230. psubsw %mm3, %mm6 /* V72 */
  231. psubsw %mm1, %mm3 /* V71 ; free mm1 */
  232. psubsw %mm2, %mm6 /* V73 ; free mm2 */
  233. /* moved from next block */
  234. psraw $1, %mm5 /* t178=t189 */
  235. psubsw %mm6, %mm4 /* V74 */
  236. /* moved from next block */
  237. movq %mm0, %mm1 /* duplicate t177=t188 */
  238. paddsw %mm4, %mm3 /* V75 */
  239. /* moved from next block */
  240. paddsw %mm5, %mm0 /* tm1 */
  241. /* location
  242.  *  5 - V56
  243.  * 13 - V57
  244.  *  9 - V58
  245.  *  X - V59, mm7
  246.  *  X - V65, mm5
  247.  *  X - V73, mm6
  248.  *  X - V74, mm4
  249.  *  X - V75, mm3
  250.  * free mm0, mm1 & mm2
  251.  * moved above
  252.  * movq 8*5(%esi), %mm0 V56
  253.  * psllw $1, %mm0 t177=t188 ! new !!
  254.  * psllw $1, %mm5 t178=t189 ! new !!
  255.  * movq %mm0, %mm1 duplicate t177=t188
  256.  * paddsw %mm5, %mm0 tm1
  257.  */
  258. movq 8*13(%esi), %mm2 /* V57 */
  259. psubsw %mm5, %mm1 /* tm15; free mm5 */
  260. movq %mm0, 8(%esi) /* tm1; free mm0 */
  261. psraw $1, %mm7 /* t182=t184 ! new !! */
  262. /* save the store as used directly in the transpose
  263.  * movq %mm1, 120(%esi) tm15; free mm1
  264.  */
  265. movq %mm7, %mm5 /* duplicate t182=t184 */
  266. psubsw %mm3, %mm7 /* tm7 */
  267. paddsw %mm3, %mm5 /* tm9; free mm3 */
  268. movq 8*9(%esi), %mm0 /* V58 */
  269. movq %mm2, %mm3 /* duplicate V57 */
  270. movq %mm7, 8*7(%esi) /* tm7; free mm7 */
  271. psubsw %mm6, %mm3 /* tm13 */
  272. paddsw %mm6, %mm2 /* tm3 ; free mm6 */
  273. /* moved up from the transpose */
  274. movq %mm3, %mm7
  275. /* moved up from the transpose */
  276. punpcklwd %mm1, %mm3
  277. movq %mm0, %mm6 /* duplicate V58 */
  278. movq %mm2, 8*3(%esi) /* tm3; free mm2 */
  279. paddsw %mm4, %mm0 /* tm5 */
  280. psubsw %mm4, %mm6 /* tm11; free mm4 */
  281. /* moved up from the transpose */
  282. punpckhwd %mm1, %mm7
  283. movq %mm0, 8*5(%esi) /* tm5; free mm0 */
  284. /* moved up from the transpose */
  285. movq %mm5, %mm2
  286. /* transpose - M4 part
  287.  *  ---------       ---------
  288.  * | M1 | M2 |     | M1'| M3'|
  289.  *  ---------  -->  ---------
  290.  * | M3 | M4 |     | M2'| M4'|
  291.  *  ---------       ---------
  292.  * Two alternatives: use full mmword approach so the following code can be
  293.  * scheduled before the transpose is done without stores, or use the faster
  294.  * half mmword stores (when possible)
  295.  */
  296. movd %mm3, 8*9+4(%esi) /* MS part of tmt9 */
  297. punpcklwd %mm6, %mm5
  298. movd %mm7, 8*13+4(%esi) /* MS part of tmt13 */
  299. punpckhwd %mm6, %mm2
  300. movd %mm5, 8*9(%esi) /* LS part of tmt9 */
  301. punpckhdq %mm3, %mm5 /* free mm3 */
  302. movd %mm2, 8*13(%esi) /* LS part of tmt13 */
  303. punpckhdq %mm7, %mm2 /* free mm7 */
  304. /* moved up from the M3 transpose */
  305. movq 8*8(%esi), %mm0
  306. /* moved up from the M3 transpose */
  307. movq 8*10(%esi), %mm1
  308. /* moved up from the M3 transpose */
  309. movq %mm0, %mm3
  310. /* shuffle the rest of the data, and write it with 2 mmword writes */
  311. movq %mm5, 8*11(%esi) /* tmt11 */
  312. /* moved up from the M3 transpose */
  313. punpcklwd %mm1, %mm0
  314. movq %mm2, 8*15(%esi) /* tmt15 */
  315. /* moved up from the M3 transpose */
  316. punpckhwd %mm1, %mm3
  317. /* transpose - M3 part
  318.  * moved up to previous code section
  319.  * movq 8*8(%esi), %mm0
  320.  * movq 8*10(%esi), %mm1
  321.  * movq %mm0, %mm3
  322.  * punpcklwd %mm1, %mm0
  323.  * punpckhwd %mm1, %mm3
  324.  */
  325. movq 8*12(%esi), %mm6
  326. movq 8*14(%esi), %mm4
  327. movq %mm6, %mm2
  328. /* shuffle the data and write the lower parts of the transposed in 4 dwords */
  329. punpcklwd %mm4, %mm6
  330. movq %mm0, %mm1
  331. punpckhdq %mm6, %mm1
  332. movq %mm3, %mm7
  333. punpckhwd %mm4, %mm2 /* free mm4 */
  334. punpckldq %mm6, %mm0 /* free mm6 */
  335. /* moved from next block */
  336. movq 8*13(%esi), %mm4 /* tmt13 */
  337. punpckldq %mm2, %mm3
  338. punpckhdq %mm2, %mm7 /* free mm2 */
  339. /* moved from next block */
  340. movq %mm3, %mm5 /* duplicate tmt5 */
  341. /* column 1: even part (after transpose)
  342. * moved above
  343. * movq %mm3, %mm5 duplicate tmt5
  344. * movq 8*13(%esi), %mm4 tmt13
  345. */
  346. psubsw %mm4, %mm3 /* V134 */
  347. pmulhw x5a825a825a825a82, %mm3 /* 23170 ->V136 */
  348. movq 8*9(%esi), %mm6 /* tmt9 */
  349. paddsw %mm4, %mm5 /* V135 ; mm4 free */
  350. movq %mm0, %mm4 /* duplicate tmt1 */
  351. paddsw %mm6, %mm0 /* V137 */
  352. psubsw %mm6, %mm4 /* V138 ; mm6 free */
  353. psllw $2, %mm3 /* t290 */
  354. psubsw %mm5, %mm3 /* V139 */
  355. movq %mm0, %mm6 /* duplicate V137 */
  356. paddsw %mm5, %mm0 /* V140 */
  357. movq %mm4, %mm2 /* duplicate V138 */
  358. paddsw %mm3, %mm2 /* V141 */
  359. psubsw %mm3, %mm4 /* V142 ; mm3 free */
  360. movq %mm0, 8*9(%esi) /* V140 */
  361. psubsw %mm5, %mm6 /* V143 ; mm5 free */
  362. /* moved from next block */
  363. movq 8*11(%esi), %mm0 /* tmt11 */
  364. movq %mm2, 8*13(%esi) /* V141 */
  365. /* moved from next block */
  366. movq %mm0, %mm2 /* duplicate tmt11 */
  367. /* column 1: odd part (after transpose) */
  368. /* moved up to the prev block
  369.  * movq 8*11(%esi), %mm0 tmt11
  370.  * movq %mm0, %mm2 duplicate tmt11
  371.  */
  372. movq 8*15(%esi), %mm5 /* tmt15 */
  373. psubsw %mm7, %mm0 /* V144 */
  374. movq %mm0, %mm3 /* duplicate V144 */
  375. paddsw %mm7, %mm2 /* V147 ; free mm7 */
  376. pmulhw x539f539f539f539f, %mm0 /* 21407-> V151 */
  377. movq %mm1, %mm7 /* duplicate tmt3 */
  378. paddsw %mm5, %mm7 /* V145 */
  379. psubsw %mm5, %mm1 /* V146 ; free mm5 */
  380. psubsw %mm1, %mm3 /* V150 */
  381. movq %mm7, %mm5 /* duplicate V145 */
  382. pmulhw x4546454645464546, %mm1 /* 17734-> V153 */
  383. psubsw %mm2, %mm5 /* V148 */
  384. pmulhw x61f861f861f861f8, %mm3 /* 25080-> V154 */
  385. psllw $2, %mm0 /* t311 */
  386. pmulhw x5a825a825a825a82, %mm5 /* 23170-> V152 */
  387. paddsw %mm2, %mm7 /* V149 ; free mm2 */
  388. psllw $1, %mm1 /* t313 */
  389. nop /* without the nop - freeze here for one clock */
  390. movq %mm3, %mm2 /* duplicate V154 */
  391. psubsw %mm0, %mm3 /* V155 ; free mm0 */
  392. psubsw %mm2, %mm1 /* V156 ; free mm2 */
  393. /* moved from the next block */
  394. movq %mm6, %mm2 /* duplicate V143 */
  395. /* moved from the next block */
  396. movq 8*13(%esi), %mm0 /* V141 */
  397. psllw $1, %mm1 /* t315 */
  398. psubsw %mm7, %mm1 /* V157 (keep V149) */
  399. psllw $2, %mm5 /* t317 */
  400. psubsw %mm1, %mm5 /* V158 */
  401. psllw $1, %mm3 /* t319 */
  402. paddsw %mm5, %mm3 /* V159 */
  403. /* column 1: output butterfly (after transform)
  404.  * moved to the prev block
  405.  * movq %mm6, %mm2 duplicate V143
  406.  * movq 8*13(%esi), %mm0 V141
  407.  */
  408. psubsw %mm3, %mm2 /* V163 */
  409. paddsw %mm3, %mm6 /* V164 ; free mm3 */
  410. movq %mm4, %mm3 /* duplicate V142 */
  411. psubsw %mm5, %mm4 /* V165 ; free mm5 */
  412. movq %mm2, scratch7 /* out7 */
  413. psraw $4, %mm6
  414. psraw $4, %mm4
  415. paddsw %mm5, %mm3 /* V162 */
  416. movq 8*9(%esi), %mm2 /* V140 */
  417. movq %mm0, %mm5 /* duplicate V141 */
  418. /* in order not to perculate this line up,
  419.  * we read 72(%esi) very near to this location
  420.  */
  421. movq %mm6, 8*9(%esi) /* out9 */
  422. paddsw %mm1, %mm0 /* V161 */
  423. movq %mm3, scratch5 /* out5 */
  424. psubsw %mm1, %mm5 /* V166 ; free mm1 */
  425. movq %mm4, 8*11(%esi) /* out11 */
  426. psraw $4, %mm5
  427. movq %mm0, scratch3 /* out3 */
  428. movq %mm2, %mm4 /* duplicate V140 */
  429. movq %mm5, 8*13(%esi) /* out13 */
  430. paddsw %mm7, %mm2 /* V160 */
  431. /* moved from the next block */
  432. movq 8(%esi), %mm0
  433. psubsw %mm7, %mm4 /* V167 ; free mm7 */
  434. /* moved from the next block */
  435. movq 8*3(%esi), %mm7
  436. psraw $4, %mm4
  437. movq %mm2, scratch1 /* out1 */
  438. /* moved from the next block */
  439. movq %mm0, %mm1
  440. movq %mm4, 8*15(%esi) /* out15 */
  441. /* moved from the next block */
  442. punpcklwd %mm7, %mm0
  443. /* transpose - M2 parts
  444.  * moved up to the prev block
  445.  * movq 8(%esi), %mm0
  446.  * movq 8*3(%esi), %mm7
  447.  * movq %mm0, %mm1
  448.  * punpcklwd %mm7, %mm0
  449.  */
  450. movq 8*5(%esi), %mm5
  451. punpckhwd %mm7, %mm1
  452. movq 8*7(%esi), %mm4
  453. movq %mm5, %mm3
  454. /* shuffle the data and write the lower parts of the trasposed in 4 dwords */
  455. movd %mm0, 8*8(%esi) /* LS part of tmt8 */
  456. punpcklwd %mm4, %mm5
  457. movd %mm1, 8*12(%esi) /* LS part of tmt12 */
  458. punpckhwd %mm4, %mm3
  459. movd %mm5, 8*8+4(%esi) /* MS part of tmt8 */
  460. punpckhdq %mm5, %mm0 /* tmt10 */
  461. movd %mm3, 8*12+4(%esi) /* MS part of tmt12 */
  462. punpckhdq %mm3, %mm1 /* tmt14 */
  463. /* transpose - M1 parts */
  464. movq (%esi), %mm7
  465. movq 8*2(%esi), %mm2
  466. movq %mm7, %mm6
  467. movq 8*4(%esi), %mm5
  468. punpcklwd %mm2, %mm7
  469. movq 8*6(%esi), %mm4
  470. punpckhwd %mm2, %mm6 /* free mm2 */
  471. movq %mm5, %mm3
  472. punpcklwd %mm4, %mm5
  473. punpckhwd %mm4, %mm3 /* free mm4 */
  474. movq %mm7, %mm2
  475. movq %mm6, %mm4
  476. punpckldq %mm5, %mm7 /* tmt0 */
  477. punpckhdq %mm5, %mm2 /* tmt2 ; free mm5 */
  478. /* shuffle the rest of the data, and write it with 2 mmword writes */
  479. punpckldq %mm3, %mm6 /* tmt4 */
  480. /* moved from next block */
  481. movq %mm2, %mm5 /* duplicate tmt2 */
  482. punpckhdq %mm3, %mm4 /* tmt6 ; free mm3 */
  483. /* moved from next block */
  484. movq %mm0, %mm3 /* duplicate tmt10 */
  485. /* column 0: odd part (after transpose)
  486.  *moved up to prev block
  487.  * movq %mm0, %mm3 duplicate tmt10
  488.  * movq %mm2, %mm5 duplicate tmt2
  489.  */
  490. psubsw %mm4, %mm0 /* V110 */
  491. paddsw %mm4, %mm3 /* V113 ; free mm4 */
  492. movq %mm0, %mm4 /* duplicate V110 */
  493. paddsw %mm1, %mm2 /* V111 */
  494. pmulhw x539f539f539f539f, %mm0 /* 21407-> V117 */
  495. psubsw %mm1, %mm5 /* V112 ; free mm1 */
  496. psubsw %mm5, %mm4 /* V116 */
  497. movq %mm2, %mm1 /* duplicate V111 */
  498. pmulhw x4546454645464546, %mm5 /* 17734-> V119 */
  499. psubsw %mm3, %mm2 /* V114 */
  500. pmulhw x61f861f861f861f8, %mm4 /* 25080-> V120 */
  501. paddsw %mm3, %mm1 /* V115 ; free mm3 */
  502. pmulhw x5a825a825a825a82, %mm2 /* 23170-> V118 */
  503. psllw $2, %mm0 /* t266 */
  504. movq %mm1, (%esi) /* save V115 */
  505. psllw $1, %mm5 /* t268 */
  506. psubsw %mm4, %mm5 /* V122 */
  507. psubsw %mm0, %mm4 /* V121 ; free mm0 */
  508. psllw $1, %mm5 /* t270 */
  509. psubsw %mm1, %mm5 /* V123 ; free mm1 */
  510. psllw $2, %mm2 /* t272 */
  511. psubsw %mm5, %mm2 /* V124 (keep V123) */
  512. psllw $1, %mm4 /* t274 */
  513. movq %mm5, 8*2(%esi) /* save V123 ; free mm5 */
  514. paddsw %mm2, %mm4 /* V125 (keep V124) */
  515. /* column 0: even part (after transpose) */
  516. movq 8*12(%esi), %mm0 /* tmt12 */
  517. movq %mm6, %mm3 /* duplicate tmt4 */
  518. psubsw %mm0, %mm6 /* V100 */
  519. paddsw %mm0, %mm3 /* V101 ; free mm0 */
  520. pmulhw x5a825a825a825a82, %mm6 /* 23170 ->V102 */
  521. movq %mm7, %mm5 /* duplicate tmt0 */
  522. movq 8*8(%esi), %mm1 /* tmt8 */
  523. paddsw %mm1, %mm7 /* V103 */
  524. psubsw %mm1, %mm5 /* V104 ; free mm1 */
  525. movq %mm7, %mm0 /* duplicate V103 */
  526. psllw $2, %mm6 /* t245 */
  527. paddsw %mm3, %mm7 /* V106 */
  528. movq %mm5, %mm1 /* duplicate V104 */
  529. psubsw %mm3, %mm6 /* V105 */
  530. psubsw %mm3, %mm0 /* V109; free mm3 */
  531. paddsw %mm6, %mm5 /* V107 */
  532. psubsw %mm6, %mm1 /* V108 ; free mm6 */
  533. /* column 0: output butterfly (after transform) */
  534. movq %mm1, %mm3 /* duplicate V108 */
  535. paddsw %mm2, %mm1 /* out4 */
  536. psraw $4, %mm1
  537. psubsw %mm2, %mm3 /* out10 ; free mm2 */
  538. psraw $4, %mm3
  539. movq %mm0, %mm6 /* duplicate V109 */
  540. movq %mm1, 8*4(%esi) /* out4 ; free mm1 */
  541. psubsw %mm4, %mm0 /* out6 */
  542. movq %mm3, 8*10(%esi) /* out10 ; free mm3 */
  543. psraw $4, %mm0
  544. paddsw %mm4, %mm6 /* out8 ; free mm4 */
  545. movq %mm7, %mm1 /* duplicate V106 */
  546. movq %mm0, 8*6(%esi) /* out6 ; free mm0 */
  547. psraw $4, %mm6
  548. movq (%esi), %mm4 /* V115 */
  549. movq %mm6, 8*8(%esi) /* out8 ; free mm6 */
  550. movq %mm5, %mm2 /* duplicate V107 */
  551. movq 8*2(%esi), %mm3 /* V123 */
  552. paddsw %mm4, %mm7 /* out0 */
  553. /* moved up from next block */
  554. movq scratch3, %mm0
  555. psraw $4, %mm7
  556. /* moved up from next block */
  557. movq scratch5, %mm6 
  558. psubsw %mm4, %mm1 /* out14 ; free mm4 */
  559. paddsw %mm3, %mm5 /* out2 */
  560. psraw $4, %mm1
  561. movq %mm7, (%esi) /* out0 ; free mm7 */
  562. psraw $4, %mm5
  563. movq %mm1, 8*14(%esi) /* out14 ; free mm1 */
  564. psubsw %mm3, %mm2 /* out12 ; free mm3 */
  565. movq %mm5, 8*2(%esi) /* out2 ; free mm5 */
  566. psraw $4, %mm2
  567. /* moved up to the prev block */
  568. movq scratch7, %mm4
  569. /* moved up to the prev block */
  570. psraw $4, %mm0
  571. movq %mm2, 8*12(%esi) /* out12 ; free mm2 */
  572. /* moved up to the prev block */
  573. psraw $4, %mm6
  574. /* move back the data to its correct place
  575. * moved up to the prev block
  576.  * movq scratch3, %mm0
  577.  * movq scratch5, %mm6
  578.  * movq scratch7, %mm4
  579.  * psraw $4, %mm0
  580.  * psraw $4, %mm6
  581. */
  582. movq scratch1, %mm1
  583. psraw $4, %mm4
  584. movq %mm0, 8*3(%esi) /* out3 */
  585. psraw $4, %mm1
  586. movq %mm6, 8*5(%esi) /* out5 */
  587. movq %mm4, 8*7(%esi) /* out7 */
  588. movq %mm1, 8(%esi) /* out1 */
  589. popl %esi
  590. popl %ebp
  591. ret
  594. .data
  595. .align 16
  596. .type  preSC,@object
  597. preSC:  .short  16384,22725,21407,19266,16384,12873,8867,4520
  598.         .short  22725,31521,29692,26722,22725,17855,12299,6270
  599.         .short  21407,29692,27969,25172,21407,16819,11585,5906
  600.         .short  19266,26722,25172,22654,19266,15137,10426,5315
  601.         .short  16384,22725,21407,19266,16384,12873,8867,4520
  602.         .short  12873,17855,16819,15137,25746,20228,13933,7103
  603.         .short  17734,24598,23170,20853,17734,13933,9597,4892
  604.         .short  18081,25080,23624,21261,18081,14206,9785,4988
  605. .size  preSC,128
  606. .align 8
  607. .type x0005000200010001,@object
  608. .size x0005000200010001,8
  609. x0005000200010001:
  610. .long 0x00010001,0x00050002
  611. .align 8
  612. .type x0040000000000000,@object
  613. .size x0040000000000000,8
  614. x0040000000000000:
  615. .long 0, 0x00400000
  616. .align 8
  617. .type x5a825a825a825a82,@object
  618. .size x5a825a825a825a82,8
  619. x5a825a825a825a82:
  620. .long 0x5a825a82, 0x5a825a82
  621. .align 8
  622. .type x539f539f539f539f,@object
  623. .size x539f539f539f539f,8
  624. x539f539f539f539f:
  625. .long 0x539f539f,0x539f539f
  626. .align 8
  627. .type x4546454645464546,@object
  628. .size x4546454645464546,8
  629. x4546454645464546:
  630. .long 0x45464546,0x45464546
  631. .align 8
  632. .type x61f861f861f861f8,@object
  633. .size x61f861f861f861f8,8
  634. x61f861f861f861f8:
  635. .long 0x61f861f8,0x61f861f8
  636. .align 8
  637. .type  scratch1,@object
  638. .size  scratch1,8
  639. scratch1:
  640. .long 0,0
  641. .align 8
  642. .type  scratch3,@object
  643. .size  scratch3,8
  644. scratch3:
  645. .long 0,0
  646. .align 8
  647. .type  scratch5,@object
  648. .size  scratch5,8
  649. scratch5:
  650. .long 0,0
  651. .align 8
  652. .type  scratch7,@object
  653. .size  scratch7,8
  654. scratch7:
  655. .long 0,0
  656. .type  x0,@object
  657. .size  x0,8
  658. x0:
  659. .long 0,0
  660. .align 8