开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 操作系统开发 > 查看源码
IOCTL.A86
资源名称：drdossrc.zip　[点击查看]
上传用户：xiaogehua
上传日期：2007-01-08
资源大小：1183k
文件大小：14k
源码类别：

操作系统开发

开发平台：

Asm

IOCTL.A86：源码内容
  1. ;    File              : $IOCTL.A86$
  2. ;
  3. ;    Description       :
  4. ;
  5. ;    Original Author   : DIGITAL RESEARCH
  6. ;
  7. ;    Last Edited By    : $CALDERA$
  8. ;
  9. ;-----------------------------------------------------------------------;
  10. ;    Copyright Work of Caldera, Inc. All Rights Reserved.
  11. ;      
  12. ;    THIS WORK IS A COPYRIGHT WORK AND CONTAINS CONFIDENTIAL,
  13. ;    PROPRIETARY AND TRADE SECRET INFORMATION OF CALDERA, INC.
  14. ;    ACCESS TO THIS WORK IS RESTRICTED TO (I) CALDERA, INC. EMPLOYEES
  15. ;    WHO HAVE A NEED TO KNOW TO PERFORM TASKS WITHIN THE SCOPE OF
  16. ;    THEIR ASSIGNMENTS AND (II) ENTITIES OTHER THAN CALDERA, INC. WHO
  17. ;    HAVE ACCEPTED THE CALDERA OPENDOS SOURCE LICENSE OR OTHER CALDERA LICENSE
  18. ;    AGREEMENTS. EXCEPT UNDER THE EXPRESS TERMS OF THE CALDERA LICENSE
  19. ;    AGREEMENT NO PART OF THIS WORK MAY BE USED, PRACTICED, PERFORMED,
  20. ;    COPIED, DISTRIBUTED, REVISED, MODIFIED, TRANSLATED, ABRIDGED,
  21. ;    CONDENSED, EXPANDED, COLLECTED, COMPILED, LINKED, RECAST,
  22. ;    TRANSFORMED OR ADAPTED WITHOUT THE PRIOR WRITTEN CONSENT OF
  23. ;    CALDERA, INC. ANY USE OR EXPLOITATION OF THIS WORK WITHOUT
  24. ;    AUTHORIZATION COULD SUBJECT THE PERPETRATOR TO CRIMINAL AND
  25. ;    CIVIL LIABILITY.
  26. ;-----------------------------------------------------------------------;
  27. ;
  28. ;    *** Current Edit History ***
  29. ;    *** End of Current Edit History ***
  30. ;    $Log: $
  31. ;    IOCTL.A86 1.17 94/11/28 15:42:19 
  32. ;    f440B now does not modify net_retry if DX=0    
  33. ;    IOCTL.A86 1.16 93/11/08 19:15:18
  34. ;    SETVER to subversion 0xFF disabled int 21/4452
  35. ;    IOCTL.A86 1.15 93/07/26 18:16:16
  36. ;    add some code which disables drdos check if app is SETVER'd
  37. ;    leave said code disabled unless required
  38. ;    IOCTL.A86 1.14 93/07/22 19:29:54
  39. ;    get/set serial number now the correct way round
  40. ;    IOCTL.A86 1.11 93/06/17 22:14:34
  41. ;    support for ioctl 10/11 query ioctl support
  42. ;    ENDLOG
  43. ;
  44. ;  7 Nov 87 Removal of development flags
  45. ; 17 Dec 87 Return "Single device Supported" for IOCTL sub-functions
  46. ;           0Eh and 0Fh.
  47. ; 24 Feb 88 Return 1060h from IOCTL sub-function 51h under DOS PLUS
  48. ;           instead of the Concurrent DOS OS version.
  49. ; 24 Feb 88 Correct Generic IOCTL function and prevent the generation
  50. ;           of critical errors.
  51. ; 24 May 88 sub-function 53h returns the address of the INT24 handler
  52. ;           for the command processor.
  53. ; 01 Jun 88 Add sub-function 4454 to support setting the default password
  54. ; 03 Nov 88 Add History Buffer Sub-Command f4456 for DOSPLUS
  55. ; 02 Feb 89 Add code page switching sub-function 0Ch
  56. ; 19 Feb 89 Support Sub-Command f4457 to control SHARE
  57. ; 15 Mar 89 Do not generate critical errors from 4402 and 4403.
  58. ; 18 Apr 89 Sub-function 53 only suported for Concurrect DOS
  59. ; 19 Apr 89 Don't clobber error code on 440D and 440E (pc-cache)
  60. ; 31 May 89 New function f4458 to return pointer to private data.
  61. ; 31 May 89 f440B sets up DOS internal data
  62. ; 15 Jun 89 Don't throw away inheritance bit when masking Share Mode Flags
  63. ; 11 Oct 89 f4407/07 set AX on return, not just AL
  64. ; 26 Oct 89 for a few bytes more...
  65. ; 18 Jan 90 HILOAD interface added onto f4457
  66. ; 25 Jan 90 INT21/4458 returns a pointer to IDLE_DATA in ES:AX
  67. ; 13 Jan 90 private_data exported in CDOS for DEBUG systems
  68. ; 27 Feb 90 4459 provides Int21 function that does Int224 calls
  69. ;  7 Mar 90 Convert to register preserved function calls
  70. ; 14 Mar 90 No critical error generated in IOCTL functions
  71. ;  3 May 90 stop forcing ioctl 4403/3/4/5 errors to ED_ACCESS
  72. ;  4 Jun 90 445A provides user group support on CDOS
  73. ;  3 jun 92 Add 4456/2+3 to examine history state, toggle history enable
  74. ; 30 jul 92 HILOAD now uses official memory strategy calls
  75. ;
  76. include pcmode.equ
  77. include fdos.def
  78. include i:msdos.equ
  79. include i:mserror.equ
  80. include i:cmdline.equ
  81. include i:driver.equ
  82. include i:reqhdr.equ
  83. include i:psp.def
  85. PCM_CODE CSEG BYTE
  86. extrn os_version:word
  87. extrn patch_version:word
  89. extrn invalid_function:near
  90. extrn error_ret:near
  91. extrn fdos_nocrit:near
  92. extrn fdos_crit:near
  93. extrn fdos_ax_crit:near
  94. extrn return_AX_CLC:near
  95. extrn return_DX:near
  96. extrn return_DSBX_as_ESBX:near
  97. extrn set_retry_RF:near
  98. extrn patch_version:word
  101. ; *****************************
  102. ; ***    DOS Function 69    ***
  103. ; ***   set/get serial num  ***
  104. ; *****************************
  105. ;
  106. Public func69
  107. func69:
  108. call set_retry_RF ; Prepare for an FDOS function
  109. mov FD_FUNC,MS_X_IOCTL
  110. mov cx,866h ; assume a get serial num
  111. cmp al,1 ; check for 0/1
  112. mov al,0Dh ; ready for ioctl 0D
  113.  jb func44common ; go ahead with get serial num
  114. mov cl,46h ; maybe it's a set
  115.  je func44common ; go ahead with set serial num
  116. ; jmp invalid_function ; ah well, it's an invalid one
  117. jmps f44_30
  119. ; *****************************
  120. ; ***    DOS Function 44    ***
  121. ; ***       I/O Control     ***
  122. ; *****************************
  123. ;
  124. Public func44
  125. func44:
  126. call set_retry_RF ; Prepare for an FDOS function
  127. func44common:
  128. mov FD_IOCTLFUNC,ax ; save subfunction for FDOS
  129. mov ioctlRH,22 ; assume RH will be wanted
  130. mov ioctlRH+13,0 ;  init len and media byte
  131. mov word ptr ioctlRH+14,dx ; point at buffer segment
  132. mov word ptr ioctlRH+16,es
  133. mov word ptr ioctlRH+18,cx ; the Byte Count
  134. cmp ax,dosf44_ftl ; Check for a valid PC-DOS
  135.  jae f44_20 ; sub-functions
  136. f44_10:
  137. xchg ax,si
  138. shl si,1
  139. mov si,func44_ft[si]
  140. xchg ax,si
  141. jmp ax
  142. f44_20:
  143. sub al,52h-dosf44_ftl ; adjust to our base of 52h
  144.  jc f44_30 ; bail out if too low
  145. cmp ax,ourf44_ftl ; is it too high ?
  146.  jb f44_10
  147. f44_30:
  148. jmp invalid_function
  150. ; ***********************************************
  151. ; ***    Sub Function 00 - Get Device Info    ***
  152. ; ***********************************************
  153. f4400:
  154. call fdos_handle ; execute the function
  155. mov dx,ax ; return in DX too
  156. return_AX_and_DX:
  157. call return_DX ; return to caller in DX
  158. jmp return_AX_CLC ; return AX too
  160. ; ***********************************************
  161. ; ***    Sub Function 01 - Set Device Info    ***
  162. ; ***    Sub Function 06 - Get Input Status   ***
  163. ; ***    Sub Function 07 - Get Output Status  ***
  164. ; ***********************************************
  165. f4401:
  166. f4406:
  167. f4407:
  168. call fdos_handle ; Execute the Function
  169. jmp return_AX_CLC
  171. ; ************************************************
  172. ; ***    Sub Function 04 -  Read Blk Device    ***
  173. ; ***    Sub Function 05 -  Write Blk Device   ***
  174. ; ***    Sub Function 11 -  Query ioctl Blk    ***
  175. ; ************************************************
  176. ;
  177. f4404:
  178. f4405:
  179. f4411:
  180. xor bh,bh ; BX = drive number
  182. ; ************************************************
  183. ; ***    Sub Function 02 - Read Character Dev  ***
  184. ; ***    Sub Function 03 - Write Character Dev ***
  185. ; ***    Sub Function 10 - Query ioctl Char    ***
  186. ; ************************************************
  187. ;
  188. f4402:
  189. f4403:
  190. f4410:
  191. mov dx,DA_QUERY ; assume we will query support
  192. mov al,CMD_QUERY_IOCTL ;  and be ready to go
  193. mov cx,FD_IOCTLFUNC ; re-read the function number
  194. test cl,10h ; is it function 10 of 11?
  195.  jnz f44ioctl ; yes, we are ready
  196. mov dx,DA_IOCTL ; no, we actually want to do it
  197. mov al,CMD_INPUT_IOCTL ; even functions are input
  198. test cl,1 ; test for input functions
  199.  jz f44ioctl
  200. mov al,CMD_OUTPUT_IOCTL ; odd functions are output
  201. f44ioctl:
  202. mov FD_IOCTLSTAT,dx ; this device driver support is required
  203. mov ioctlRH+2,al ;  this is the function
  204. call fdos_handle ; Execute the Function
  205. mov ax,word ptr ioctlRH+18 ; return # xfered
  206. jmp return_AX_CLC
  208. ; *****************************
  209. ; ***    Sub Function 09    ***
  210. ; ***    Networked Media    ***
  211. ; *****************************
  212. ;
  213. f4409:
  214. call fdos_drive ; Execute the Function
  215. mov dx,ax ; Get the Return Information
  216.     mov ax,0300h            
  217. jmps return_AX_and_DX
  219. ; *****************************
  220. ; ***    Sub Function 0A    ***
  221. ; ***    Networked Handle   ***
  222. ; *****************************
  223. ;
  224. f440A:
  225. call fdos_handle ; Execute the Function
  226. mov dx,ax ; Get the Return Information
  227. jmp return_DX ;  and return in DX
  229. ; *****************************
  230. ; ***    Sub Function 0B    ***
  231. ; ***   Update Share Retry  ***
  232. ; *****************************
  233. ;
  234. ; dos_CX [1] Number of times to execute the delay loop
  235. ; which consists of xor cx,cx ! loop $
  236. ;
  237. ; dos_DX [3] Number of times to retry
  238. ;
  239. ;
  240. f440B:
  241. mov net_delay,cx
  242. test dx,dx
  243.  jz f440B_10
  244. mov net_retry,dx
  245. f440b_10:
  246. ret
  248. ; *****************************
  249. ; ***    Sub Function 0D    ***
  250. ; ***   Device Driver Req   ***
  251. ; *****************************
  252. ;
  253. f440D:
  254. xor bh,bh
  255. ; jmp f440C
  257. ; *****************************
  258. ; ***    Sub Function 0C    ***
  259. ; ***  Code Page Switching  ***
  260. ; *****************************
  261. ;
  262. f440C:
  263. mov FD_IOCTLSTAT,DA_GETSET ; device driver support required
  264. mov FD_HANDLE,bx ; Save the Handle Number
  265. mov ioctlRH,23 ; different RH length
  266. mov ioctlRH+2,CMD_GENERIC_IOCTL
  267. xchg cl,ch ; swap minor/major functions
  268. mov word ptr ioctlRH+13,cx ;  and store in request header
  269. mov word ptr ioctlRH+15,si
  270. mov word ptr ioctlRH+17,di
  271. mov word ptr ioctlRH+19,dx ; point at buffer segment
  272. mov word ptr ioctlRH+21,es
  273. call fdos_ax_crit ; Execute the Function and
  274.  jc fdos_error ; return all error codes
  275. ret
  277. ; ***********************************************
  278. ; ***    Sub Function 08 - Removable Media    ***
  279. ; ***    Sub Function 0E - Get Logical Drive  ***
  280. ; ***    Sub Function 0F - Set Logical Drive  ***
  281. ; ***********************************************
  282. ;
  283. f4408:
  284. f440E:
  285. f440F:
  286. call fdos_drive ; Execute the Function
  287. jmp return_AX_CLC ; return result in AX
  290. fdos_drive:
  291. ;----------
  292. xor bh,bh ; BX = the drive number
  293. fdos_handle:
  294. ;----------
  295. mov FD_HANDLE,bx
  296. call fdos_crit ; then execute the FDOS
  297.  jnc fdos_OK ; exit on Error
  298. add sp,WORD ; discard near return address
  299. fdos_error:
  300. jmp error_ret ; and return the error
  301. fdos_OK:
  302. mov ax,FD_IOCTLSTAT ; get the return information
  303. ret
  304. eject
  305. ; *****************************
  306. ; ***    CCP/M Extension    ***
  307. ; ***    Sub Function 52    ***
  308. ; ***  Return CCP/M Version ***
  309. ; *****************************
  310. ;
  311. f4452:
  312. if DOS5
  313. mov es,current_psp ; version is kept in the PSP
  314. cmp PSP_VERSION,0FF00h ; sub-version of 255 ?
  315.  jae f4452_10 ; then say we ain't DRDOS
  316. endif
  317. mov ax,cs:os_version ; Get OS ver number
  318. mov dx,cs:patch_version
  319. call return_DX ; return in DX
  320. jmp return_AX_CLC ; return in AX
  322. if DOS5
  323. f4452_10:
  324.     jmp invalid_function    
  325. endif
  327. if PASSWORD
  329. ; *****************************
  330. ; ***    CCP/M Extension    ***
  331. ; ***    Sub Function 54    ***
  332. ; *** Set Default PASSWORD  ***
  333. ; *****************************
  334. ;
  335. f4454:
  336. mov FD_IOCTLFUNC,0Bh ; save subfunction for FDOS
  337. jmp fdos_nocrit ; Execute the Function
  339. endif
  342. ; *****************************
  343. ; ***    CCP/M Extension    ***
  344. ; ***    Sub Function 56    ***
  345. ; *** History Buffer Cntrl  ***
  346. ; *****************************
  347. ;
  348. ; This function changes the default history buffer used for func0A:
  349. ;
  350. ; On Entry:
  351. ; DL = 0 -> Standard Process Buffer
  352. ; DL = 1 -> Command.com history Buffer
  353. ; DL = 2 -> Toggle history enable/disable
  354. ; DL = 3 -> Get current state of history buffers
  355. ; DL = 4 -> Toggle insert mode
  356. ;
  357. ; On Exit:
  358. ; AL = previous history state (Bit 0 set if history on)
  359. ; Bit 0 -> set if history enabled
  360. ; Bit 1 -> set if insert enabled
  361. ; Bit 7 -> set if command history buffer
  362. ;
  363. f4456:
  364. mov ax,cle_state ; Get the current History Status
  365. cmp dl,2 ; are we disabling/enabling ?
  366.  jb f4456_10 ; below, switch buffers
  367.  je f4456_05 ; yes, try and do it
  368. cmp dl,4 ; toggle insert state ?
  369.  jne f4456_20 ; no, return existing state
  370. xor al,RLF_INS ; toggle insert state
  371. jmps f4456_20 ;  set and return prev state
  373. f4456_05:
  374. mov cl,RLF_ENHANCED ; we are interested in enhancements
  375. test @hist_flg,cl ;  only if history possible
  376.  jz f4456_20 ; just return existing state
  377. xor al,cl ; invert current setting
  378. ; and fall thru' to enable/disable
  379. ; standard buffer (never called
  380. ; by COMMAND...)
  381. f4456_10:
  382. or al,RLF_INROOT ; assume we are in the root
  383. if IDLE_DETECT
  384. or idle_flags,IDLE_COMMAND
  385. endif
  386. test dl,1 ; Get new state and mask bit
  387.  jnz f4456_20
  388. and al,not RLF_INROOT ; we are in application buffer
  389. if IDLE_DETECT
  390. and idle_flags,not IDLE_COMMAND
  391. endif
  392. f4456_20:
  393. xchg ax,cle_state ; set state, returning old state
  394. ret
  397. ; *****************************
  398. ; ***    CCP/M Extension    ***
  399. ; ***    Sub Function 58    ***
  400. ; ***   Private Data Func   ***
  401. ; *****************************
  402. ;
  403. ; On Exit ES:BX points to our DRDOS private data.
  404. ;         ES:AX points to the IDLE Data Area
  406. f4458:
  407. mov bx,offset @private_data
  408. call return_DSBX_as_ESBX ; return ES:BX pointing to private data
  409. mov ax,offset idle_data
  410. jmp return_AX_CLC
  415. PCM_RODATA CSEG WORD
  416. ;
  417. ; PCDOS Sub-Functions Only
  418. ;
  419. func44_ft dw f4400
  420. dw f4401
  421. dw f4402
  422. dw f4403
  423. dw f4404
  424. dw f4405
  425. dw f4406
  426. dw f4407
  427. dw f4408
  428. dw f4409
  429. dw f440A
  430. dw f440B
  431. dw f440C
  432. dw f440D
  433. dw f440E
  434. dw f440F
  435. dw f4410
  436. dw f4411
  437. dosf44_ftl equ (offset $ - offset func44_ft)/2
  438. ;
  439. ; CCP/M Sub-Functions Only
  440. ;
  441. dw f4452 ; 4452 OS version no
  442. dw invalid_function ; 4453 Invalid Function
  443. if PASSWORD
  444. dw f4454 ; 4454 set default password
  445. else
  446. dw invalid_function ; 4454 was set default password
  447. endif
  448. dw invalid_function ; 4455 Invalid Function
  449. dw f4456 ; 4456 history buffer support
  450. dw invalid_function ; 4457 was share enable/disable
  451. dw f4458 ; 4458 pointer to private data
  453. ourf44_ftl equ (offset $ - offset func44_ft)/2
  455. PCMODE_DATA DSEG WORD
  456. extrn net_delay:word, net_retry:word
  457. extrn @hist_flg:byte
  458. extrn @private_data:byte
  459. if IDLE_DETECT
  460. extrn idle_data:word
  461. extrn idle_flags:word
  462. endif
  463. extrn cle_state:word
  464. extrn ioctlRH:byte
  465. extrn dos_version:word
  466. extrn current_psp:word
  468. end