开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > 嵌入式Linux > 查看源码
U3memcpy.S
资源名称：SBC-2410X_kernel.tar.gz　[点击查看]
上传用户：lgb322
上传日期：2013-02-24
资源大小：30529k
文件大小：12k
源码类别：

嵌入式Linux

开发平台：

Unix_Linux

U3memcpy.S：源码内容
  1. /* $Id: U3memcpy.S,v 1.2 2000/11/01 09:29:19 davem Exp $
  2.  * U3memcpy.S: UltraSparc-III optimized memcpy.
  3.  *
  4.  * Copyright (C) 1999, 2000 David S. Miller (davem@redhat.com)
  5.  */
  7. #ifdef __KERNEL__
  8. #include <asm/visasm.h>
  9. #include <asm/asi.h>
  10. #undef SMALL_COPY_USES_FPU
  11. #else
  12. #define ASI_BLK_P 0xf0
  13. #define FPRS_FEF  0x04
  14. #define VISEntryHalf rd %fprs, %o5; wr %g0, FPRS_FEF, %fprs
  15. #define VISExitHalf and %o5, FPRS_FEF, %o5; wr %o5, 0x0, %fprs
  16. #define SMALL_COPY_USES_FPU
  17. #endif
  19. /* Special/non-trivial issues of this code:
  20.  *
  21.  * 1) %o5 is preserved from VISEntryHalf to VISExitHalf
  22.  * 2) Only low 32 FPU registers are used so that only the
  23.  *    lower half of the FPU register set is dirtied by this
  24.  *    code.  This is especially important in the kernel.
  25.  * 3) This code never prefetches cachelines past the end
  26.  *    of the source buffer.
  27.  */
  29. .text
  30. .align 32
  32. /* The cheetah's flexible spine, oversized liver, enlarged heart,
  33.  * slender muscular body, and claws make it the swiftest hunter
  34.  * in Africa and the fastest animal on land.  Can reach speeds
  35.  * of up to 2.4GB per second.
  36.  */
  38. .globl U3memcpy
  39. U3memcpy: /* %o0=dst, %o1=src, %o2=len */
  40. #ifndef __KERNEL__
  41. /* Save away original 'dst' for memcpy return value. */
  42. mov %o0, %g3 ! A0 Group
  43. #endif
  44. /* Anything to copy at all? */
  45. cmp %o2, 0 ! A1
  46. ble,pn %icc, U3memcpy_short_ret ! BR
  48. /* Extremely small copy? */
  49.  cmp %o2, 31 ! A0 Group
  50. ble,pn %icc, U3memcpy_short ! BR
  52. /* Large enough to use unrolled prefetch loops? */
  53.  cmp %o2, 0x100 ! A1
  54. bge,a,pt %icc, U3memcpy_enter ! BR Group
  55.  andcc %o0, 0x3f, %g2 ! A0
  57. ba,pt %xcc, U3memcpy_toosmall ! BR Group
  58.  andcc %o0, 0x7, %g2 ! A0
  60. .align 32
  61. U3memcpy_short:
  62. /* Copy %o2 bytes from src to dst, one byte at a time. */
  63. ldub [%o1 + 0x00], %o3 ! MS Group
  64. add %o1, 0x1, %o1 ! A0
  65. add %o0, 0x1, %o0 ! A1
  66. subcc %o2, 1, %o2 ! A0 Group
  68. bg,pt %icc, U3memcpy_short ! BR
  69.  stb %o3, [%o0 + -1] ! MS Group (1-cycle stall)
  71. U3memcpy_short_ret:
  72. #ifdef __KERNEL__
  73. retl ! BR Group (0-4 cycle stall)
  74.  clr %o0 ! A0
  75. #else
  76. retl ! BR Group (0-4 cycle stall)
  77.  mov %g3, %o0 ! A0
  78. #endif
  80. /* Here len >= (6 * 64) and condition codes reflect execution
  81.  * of "andcc %o0, 0x7, %g2", done by caller.
  82.  */
  83. .align 64
  84. U3memcpy_enter:
  85. /* Is 'dst' already aligned on an 64-byte boundary? */
  86. be,pt %xcc, 2f ! BR
  88. /* Compute abs((dst & 0x3f) - 0x40) into %g2.  This is the number
  89.  * of bytes to copy to make 'dst' 64-byte aligned.  We pre-
  90.  * subtract this from 'len'.
  91.  */
  92.  sub %g2, 0x40, %g2 ! A0 Group
  93. sub %g0, %g2, %g2 ! A0 Group
  94. sub %o2, %g2, %o2 ! A0 Group
  96. /* Copy %g2 bytes from src to dst, one byte at a time. */
  97. 1: ldub [%o1 + 0x00], %o3 ! MS (Group)
  98. add %o1, 0x1, %o1 ! A1
  99. add %o0, 0x1, %o0 ! A0 Group
  100. subcc %g2, 0x1, %g2 ! A1
  102. bg,pt %icc, 1b ! BR Group
  103.  stb %o3, [%o0 + -1] ! MS Group
  105. 2: VISEntryHalf ! MS+MS
  106. and %o1, 0x7, %g1 ! A1
  107. ba,pt %xcc, U3memcpy_begin ! BR
  108.  alignaddr %o1, %g0, %o1 ! MS       (Break-after)
  110. .align 64
  111. U3memcpy_begin:
  112. prefetch [%o1 + 0x000], #one_read ! MS Group1
  113. prefetch [%o1 + 0x040], #one_read ! MS Group2
  114. andn %o2, (0x40 - 1), %o4 ! A0
  115. prefetch [%o1 + 0x080], #one_read ! MS Group3
  116. cmp %o4, 0x140 ! A0
  117. prefetch [%o1 + 0x0c0], #one_read ! MS Group4
  118. ldd [%o1 + 0x000], %f0 ! MS Group5 (%f0 results at G8)
  119. bge,a,pt %icc, 1f ! BR
  121.  prefetch [%o1 + 0x100], #one_read ! MS Group6
  122. 1: ldd [%o1 + 0x008], %f2 ! AX        (%f2 results at G9)
  123. cmp %o4, 0x180 ! A1
  124. bge,a,pt %icc, 1f ! BR
  125.  prefetch [%o1 + 0x140], #one_read ! MS Group7
  126. 1: ldd [%o1 + 0x010], %f4 ! AX        (%f4 results at G10)
  127. cmp %o4, 0x1c0 ! A1
  128. bge,a,pt %icc, 1f ! BR
  130.  prefetch [%o1 + 0x180], #one_read ! MS Group8
  131. 1: faligndata %f0, %f2, %f16 ! FGA Group9 (%f16 at G12)
  132. ldd [%o1 + 0x018], %f6 ! AX        (%f6 results at G12)
  133. faligndata %f2, %f4, %f18 ! FGA Group10 (%f18 results at G13)
  134. ldd [%o1 + 0x020], %f8 ! MS         (%f8 results at G13)
  135. faligndata %f4, %f6, %f20 ! FGA Group12 (1-cycle stall,%f20 at G15)
  136. ldd [%o1 + 0x028], %f10 ! MS (%f10 results at G15)
  137. faligndata %f6, %f8, %f22 ! FGA Group13 (%f22 results at G16)
  139. ldd [%o1 + 0x030], %f12 ! MS (%f12 results at G16)
  140. faligndata %f8, %f10, %f24 ! FGA Group15 (1-cycle stall,%f24 at G18)
  141. ldd [%o1 + 0x038], %f14 ! MS (%f14 results at G18)
  142. faligndata %f10, %f12, %f26 ! FGA Group16 (%f26 results at G19)
  143. ldd [%o1 + 0x040], %f0 ! MS (%f0 results at G19)
  145. /* We only use the first loop if len > (7 * 64). */
  146. subcc %o4, 0x1c0, %o4 ! A0 Group17
  147. bg,pt %icc, U3memcpy_loop1 ! BR
  148.  add %o1, 0x40, %o1 ! A1
  150. add %o4, 0x140, %o4 ! A0 Group18
  151. ba,pt %xcc, U3memcpy_loop2 ! BR
  152.  srl %o4, 6, %o3 ! A0 Group19
  153. nop
  154. nop
  155. nop
  156. nop
  157. nop
  159. nop
  160. nop
  162. /* This loop performs the copy and queues new prefetches.
  163.  * We drop into the second loop when len <= (5 * 64).  Note
  164.  * that this (5 * 64) factor has been subtracted from len
  165.  * already.
  166.  */
  167. U3memcpy_loop1:
  168. ldd [%o1 + 0x008], %f2 ! MS Group2 (%f2 results at G5)
  169. faligndata %f12, %f14, %f28 ! FGA (%f28 results at G5)
  170. ldd [%o1 + 0x010], %f4 ! MS Group3 (%f4 results at G6)
  171. faligndata %f14, %f0, %f30 ! FGA Group4 (1-cycle stall, %f30 at G7)
  172. stda %f16, [%o0] ASI_BLK_P ! MS
  173. ldd [%o1 + 0x018], %f6 ! AX (%f6 results at G7)
  175. faligndata %f0, %f2, %f16 ! FGA Group12 (7-cycle stall)
  176. ldd [%o1 + 0x020], %f8 ! MS         (%f8 results at G15)
  177. faligndata %f2, %f4, %f18 ! FGA Group13 (%f18 results at G16)
  178. ldd [%o1 + 0x028], %f10 ! MS (%f10 results at G16)
  179. faligndata %f4, %f6, %f20 ! FGA Group14 (%f20 results at G17)
  180. ldd [%o1 + 0x030], %f12 ! MS (%f12 results at G17)
  181. faligndata %f6, %f8, %f22 ! FGA Group15 (%f22 results at G18)
  182. ldd [%o1 + 0x038], %f14 ! MS (%f14 results at G18)
  184. faligndata %f8, %f10, %f24 ! FGA Group16 (%f24 results at G19)
  185. ldd [%o1 + 0x040], %f0 ! AX (%f0 results at G19)
  186. prefetch [%o1 + 0x180], #one_read ! MS
  187. faligndata %f10, %f12, %f26 ! FGA Group17 (%f26 results at G20)
  188. subcc %o4, 0x40, %o4 ! A0
  189. add %o1, 0x40, %o1 ! A1
  190. bg,pt %xcc, U3memcpy_loop1 ! BR
  191.  add %o0, 0x40, %o0 ! A0 Group18
  193. U3memcpy_loop2_enter:
  194. mov 5, %o3 ! A1
  196. /* This loop performs on the copy, no new prefetches are
  197.  * queued.  We do things this way so that we do not perform
  198.  * any spurious prefetches past the end of the src buffer.
  199.  */
  200. U3memcpy_loop2:
  201. ldd [%o1 + 0x008], %f2 ! MS
  202. faligndata %f12, %f14, %f28 ! FGA Group2
  203. ldd [%o1 + 0x010], %f4 ! MS
  204. faligndata %f14, %f0, %f30 ! FGA Group4 (1-cycle stall)
  205. stda %f16, [%o0] ASI_BLK_P ! MS
  206. ldd [%o1 + 0x018], %f6 ! AX
  207. faligndata %f0, %f2, %f16 ! FGA Group12 (7-cycle stall)
  209. ldd [%o1 + 0x020], %f8 ! MS
  210. faligndata %f2, %f4, %f18 ! FGA Group13
  211. ldd [%o1 + 0x028], %f10 ! MS
  212. faligndata %f4, %f6, %f20 ! FGA Group14
  213. ldd [%o1 + 0x030], %f12 ! MS
  214. faligndata %f6, %f8, %f22 ! FGA Group15
  215. ldd [%o1 + 0x038], %f14 ! MS
  216. faligndata %f8, %f10, %f24 ! FGA Group16
  218. ldd [%o1 + 0x040], %f0 ! AX
  219. faligndata %f10, %f12, %f26 ! FGA Group17
  220. subcc %o3, 0x01, %o3 ! A0
  221. add %o1, 0x40, %o1 ! A1
  222. bg,pt %xcc, U3memcpy_loop2 ! BR
  223.  add %o0, 0x40, %o0 ! A0 Group18
  225. /* Finally we copy the last full 64-byte block. */
  226. U3memcpy_loopfini:
  227. ldd [%o1 + 0x008], %f2 ! MS
  228. faligndata %f12, %f14, %f28 ! FGA
  229. ldd [%o1 + 0x010], %f4 ! MS Group19
  230. faligndata %f14, %f0, %f30 ! FGA
  231. stda %f16, [%o0] ASI_BLK_P ! MS Group20
  232. ldd [%o1 + 0x018], %f6 ! AX
  233. faligndata %f0, %f2, %f16 ! FGA Group11 (7-cycle stall)
  234. ldd [%o1 + 0x020], %f8 ! MS
  235. faligndata %f2, %f4, %f18 ! FGA Group12
  236. ldd [%o1 + 0x028], %f10 ! MS
  237. faligndata %f4, %f6, %f20 ! FGA Group13
  238. ldd [%o1 + 0x030], %f12 ! MS
  239. faligndata %f6, %f8, %f22 ! FGA Group14
  240. ldd [%o1 + 0x038], %f14 ! MS
  241. faligndata %f8, %f10, %f24 ! FGA Group15
  242. cmp %g1, 0 ! A0
  243. be,pt %icc, 1f ! BR
  244.  add %o0, 0x40, %o0 ! A1
  245. ldd [%o1 + 0x040], %f0 ! MS
  246. 1: faligndata %f10, %f12, %f26 ! FGA Group16
  247. faligndata %f12, %f14, %f28 ! FGA Group17
  248. faligndata %f14, %f0, %f30 ! FGA Group18
  249. stda %f16, [%o0] ASI_BLK_P ! MS
  250. add %o0, 0x40, %o0 ! A0
  251. add %o1, 0x40, %o1 ! A1
  252. membar #Sync ! MS Group26 (7-cycle stall)
  254. /* Now we copy the (len modulo 64) bytes at the end.
  255.  * Note how we borrow the %f0 loaded above.
  256.  *
  257.  * Also notice how this code is careful not to perform a
  258.  * load past the end of the src buffer just like similar
  259.  * code found in U3memcpy_toosmall processing.
  260.  */
  261. U3memcpy_loopend:
  262. and %o2, 0x3f, %o2 ! A0 Group
  263. andcc %o2, 0x38, %g2 ! A0 Group
  264. be,pn %icc, U3memcpy_endcruft ! BR
  265.  subcc %g2, 0x8, %g2 ! A1
  266. be,pn %icc, U3memcpy_endcruft ! BR Group
  267.  cmp %g1, 0 ! A0
  269. be,a,pt %icc, 1f ! BR Group
  270.  ldd [%o1 + 0x00], %f0 ! MS
  272. 1: ldd [%o1 + 0x08], %f2 ! MS Group
  273. add %o1, 0x8, %o1 ! A0
  274. sub %o2, 0x8, %o2 ! A1
  275. subcc %g2, 0x8, %g2 ! A0 Group
  276. faligndata %f0, %f2, %f8 ! FGA Group
  277. std %f8, [%o0 + 0x00] ! MS (XXX does it stall here? XXX)
  278. be,pn %icc, U3memcpy_endcruft ! BR
  279.  add %o0, 0x8, %o0 ! A0
  280. ldd [%o1 + 0x08], %f0 ! MS Group
  281. add %o1, 0x8, %o1 ! A0
  282. sub %o2, 0x8, %o2 ! A1
  283. subcc %g2, 0x8, %g2 ! A0 Group
  284. faligndata %f2, %f0, %f8 ! FGA
  285. std %f8, [%o0 + 0x00] ! MS (XXX does it stall here? XXX)
  286. bne,pn %icc, 1b ! BR
  287.  add %o0, 0x8, %o0 ! A0 Group
  289. /* If anything is left, we copy it one byte at a time.
  290.  * Note that %g1 is (src & 0x3) saved above before the
  291.  * alignaddr was performed.
  292.  */
  293. U3memcpy_endcruft:
  294. cmp %o2, 0
  295. add %o1, %g1, %o1
  296. VISExitHalf
  297. be,pn %icc, U3memcpy_short_ret
  298.  nop
  299. ba,a,pt %xcc, U3memcpy_short
  301. /* If we get here, then 32 <= len < (6 * 64) */
  302. U3memcpy_toosmall:
  304. #ifdef SMALL_COPY_USES_FPU
  306. /* Is 'dst' already aligned on an 8-byte boundary? */
  307. be,pt %xcc, 2f ! BR Group
  309. /* Compute abs((dst & 7) - 8) into %g2.  This is the number
  310.  * of bytes to copy to make 'dst' 8-byte aligned.  We pre-
  311.  * subtract this from 'len'.
  312.  */
  313.  sub %g2, 0x8, %g2 ! A0
  314. sub %g0, %g2, %g2 ! A0 Group (reg-dep)
  315. sub %o2, %g2, %o2 ! A0 Group (reg-dep)
  317. /* Copy %g2 bytes from src to dst, one byte at a time. */
  318. 1: ldub [%o1 + 0x00], %o3 ! MS (Group) (%o3 in 3 cycles)
  319. add %o1, 0x1, %o1 ! A1
  320. add %o0, 0x1, %o0 ! A0 Group
  321. subcc %g2, 0x1, %g2 ! A1
  323. bg,pt %icc, 1b ! BR Group
  324.  stb %o3, [%o0 + -1] ! MS Group
  326. 2: VISEntryHalf ! MS+MS
  328. /* Compute (len - (len % 8)) into %g2.  This is guarenteed
  329.  * to be nonzero.
  330.  */
  331. andn %o2, 0x7, %g2 ! A0 Group
  333. /* You may read this and believe that it allows reading
  334.  * one 8-byte longword past the end of src.  It actually
  335.  * does not, as %g2 is subtracted as loads are done from
  336.  * src, so we always stop before running off the end.
  337.  * Also, we are guarenteed to have at least 0x10 bytes
  338.  * to move here.
  339.  */
  340. sub %g2, 0x8, %g2 ! A0 Group (reg-dep)
  341. alignaddr %o1, %g0, %g1 ! MS       (Break-after)
  342. ldd [%g1 + 0x00], %f0 ! MS Group (1-cycle stall)
  343. add %g1, 0x8, %g1 ! A0
  345. 1: ldd [%g1 + 0x00], %f2 ! MS Group
  346. add %g1, 0x8, %g1 ! A0
  347. sub %o2, 0x8, %o2 ! A1
  348. subcc %g2, 0x8, %g2 ! A0 Group
  350. faligndata %f0, %f2, %f8 ! FGA Group (1-cycle stall)
  351. std %f8, [%o0 + 0x00] ! MS Group (2-cycle stall)
  352. add %o1, 0x8, %o1 ! A0
  353. be,pn %icc, 2f ! BR
  355.  add %o0, 0x8, %o0 ! A1
  356. ldd [%g1 + 0x00], %f0 ! MS Group
  357. add %g1, 0x8, %g1 ! A0
  358. sub %o2, 0x8, %o2 ! A1
  360. subcc %g2, 0x8, %g2 ! A0 Group
  361. faligndata %f2, %f0, %f8 ! FGA Group (1-cycle stall)
  362. std %f8, [%o0 + 0x00] ! MS Group (2-cycle stall)
  363. add %o1, 0x8, %o1 ! A0
  365. bne,pn %icc, 1b ! BR
  366.  add %o0, 0x8, %o0 ! A1
  368. /* Nothing left to copy? */
  369. 2: cmp %o2, 0 ! A0 Group
  370. VISExitHalf ! A0+MS
  371. be,pn %icc, U3memcpy_short_ret ! BR Group
  372.  nop ! A0
  373. ba,a,pt %xcc, U3memcpy_short ! BR Group
  375. #else /* !(SMALL_COPY_USES_FPU) */
  377. xor %o1, %o0, %g2
  378. andcc %g2, 0x7, %g0
  379. bne,pn %icc, U3memcpy_short
  380.  andcc %o1, 0x7, %g2
  382. be,pt %xcc, 2f
  383.  sub %g2, 0x8, %g2
  384. sub %g0, %g2, %g2
  385. sub %o2, %g2, %o2
  387. 1: ldub [%o1 + 0x00], %o3
  388. add %o1, 0x1, %o1
  389. add %o0, 0x1, %o0
  390. subcc %g2, 0x1, %g2
  391. bg,pt %icc, 1b
  392.  stb %o3, [%o0 + -1]
  394. 2: andn %o2, 0x7, %g2
  395. sub %o2, %g2, %o2
  397. 3: ldx [%o1 + 0x00], %o3
  398. add %o1, 0x8, %o1
  399. add %o0, 0x8, %o0
  400. subcc %g2, 0x8, %g2
  401. bg,pt %icc, 3b
  402.  stx %o3, [%o0 + -8]
  404. cmp %o2, 0
  405. bne,pn %icc, U3memcpy_short
  406.  nop
  407. ba,a,pt %xcc, U3memcpy_short_ret
  409. #endif /* !(SMALL_COPY_USES_FPU) */