开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > 嵌入式Linux > 查看源码
blockops.S
资源名称：SBC-2410X_kernel.tar.gz　[点击查看]
上传用户：lgb322
上传日期：2013-02-24
资源大小：30529k
文件大小：11k
源码类别：

嵌入式Linux

开发平台：

Unix_Linux

blockops.S：源码内容
  1. /* $Id: blockops.S,v 1.41 2001/12/05 06:05:35 davem Exp $
  2.  * blockops.S: UltraSparc block zero optimized routines.
  3.  *
  4.  * Copyright (C) 1996, 1998, 1999, 2000 David S. Miller (davem@redhat.com)
  5.  * Copyright (C) 1997 Jakub Jelinek (jakub@redhat.com)
  6.  */
  8. #include "VIS.h"
  9. #include <asm/visasm.h>
  10. #include <asm/page.h>
  11. #include <asm/pgtable.h>
  12. #include <asm/asm_offsets.h>
  14. #define TOUCH(reg0, reg1, reg2, reg3, reg4, reg5, reg6, reg7)
  15. fmovd %reg0, %f48;  fmovd %reg1, %f50;
  16. fmovd %reg2, %f52;  fmovd %reg3, %f54;
  17. fmovd %reg4, %f56;  fmovd %reg5, %f58;
  18. fmovd %reg6, %f60;  fmovd %reg7, %f62;
  20. #define DCACHE_SIZE (PAGE_SIZE * 2)
  21. #define TLBTEMP_ENT1 (60 << 3)
  22. #define TLBTEMP_ENT2 (61 << 3)
  23. #define TLBTEMP_ENTSZ (1 << 3)
  25. #if (PAGE_SHIFT == 13) || (PAGE_SHIFT == 19)
  26. #define PAGE_SIZE_REM 0x80
  27. #elif (PAGE_SHIFT == 16) || (PAGE_SHIFT == 22)
  28. #define PAGE_SIZE_REM 0x100
  29. #else
  30. #error Wrong PAGE_SHIFT specified
  31. #endif
  33. .text
  35. .align 32
  36. .globl copy_user_page
  37. .type copy_user_page,@function
  38. copy_user_page: /* %o0=dest, %o1=src, %o2=vaddr */
  39. VISEntry
  40. sethi %hi(PAGE_SIZE), %g3
  41. sub %o0, %g4, %g1
  42. and %o2, %g3, %o0
  43. sethi %hi(TLBTEMP_BASE), %o3
  44. sethi %uhi(_PAGE_VALID | _PAGE_SZBITS), %g3
  45. sub %o1, %g4, %g2
  46. sllx %g3, 32, %g3
  47. mov TLB_TAG_ACCESS, %o2
  48. or %g3, (_PAGE_CP | _PAGE_CV | _PAGE_P | _PAGE_L | _PAGE_W), %g3
  49. sethi %hi(DCACHE_SIZE), %o1
  50. or %g1, %g3, %g1
  51. or %g2, %g3, %g2
  52. add %o0, %o3, %o0
  53. add %o0, %o1, %o1
  54. #define FIX_INSN_1 0x96102060 /* mov (12 << 3), %o3 */
  55. cheetah_patch_1:
  56. mov TLBTEMP_ENT1, %o3
  57. rdpr %pstate, %g3
  58. wrpr %g3, PSTATE_IE, %pstate
  60. /* Do this now, before loading the fixed TLB entries for copying,
  61.  * so we do not risk a multiple TLB match condition later when
  62.  * restoring those entries.
  63.  */
  64. ldub [%g6 + AOFF_task_thread + AOFF_thread_use_blkcommit], %g3
  66. /* Spitfire Errata #32 workaround */
  67. mov 0x8, %o4
  68. stxa %g0, [%o4] ASI_DMMU
  69. membar #Sync
  71. ldxa [%o3] ASI_DTLB_TAG_READ, %o4
  73. /* Spitfire Errata #32 workaround */
  74. mov 0x8, %o5
  75. stxa %g0, [%o5] ASI_DMMU
  76. membar #Sync
  78. ldxa [%o3] ASI_DTLB_DATA_ACCESS, %g0
  79. ldxa [%o3] ASI_DTLB_DATA_ACCESS, %o5
  80. stxa %o0, [%o2] ASI_DMMU
  81. stxa %g1, [%o3] ASI_DTLB_DATA_ACCESS
  82. membar #Sync
  83. add %o3, (TLBTEMP_ENTSZ), %o3
  85. /* Spitfire Errata #32 workaround */
  86. mov 0x8, %g5
  87. stxa %g0, [%g5] ASI_DMMU
  88. membar #Sync
  90. ldxa [%o3] ASI_DTLB_TAG_READ, %g5
  92. /* Spitfire Errata #32 workaround */
  93. mov 0x8, %g7
  94. stxa %g0, [%g7] ASI_DMMU
  95. membar #Sync
  97. ldxa [%o3] ASI_DTLB_DATA_ACCESS, %g0
  98. ldxa [%o3] ASI_DTLB_DATA_ACCESS, %g7
  99. stxa %o1, [%o2] ASI_DMMU
  100. stxa %g2, [%o3] ASI_DTLB_DATA_ACCESS
  101. membar #Sync
  103. cmp %g3, 0
  104. bne,pn %xcc, copy_page_using_blkcommit
  105.  nop
  107. rdpr %ver, %g3
  108. sllx %g3, 16, %g3
  109. srlx %g3, 32 + 16, %g3
  110. cmp %g3, 0x14
  111. bne,pt %icc, spitfire_copy_user_page
  112.  nop
  114. cheetah_copy_user_page:
  115. sethi %hi((PAGE_SIZE/64)-7), %o2 ! A0 Group
  116. prefetch [%o1 + 0x000], #one_read ! MS
  117. or %o2, %lo((PAGE_SIZE/64)-7), %o2 ! A1 Group
  118. prefetch [%o1 + 0x040], #one_read ! MS
  119. prefetch [%o1 + 0x080], #one_read ! MS Group
  120. prefetch [%o1 + 0x0c0], #one_read ! MS Group
  121. ldd [%o1 + 0x000], %f0 ! MS Group
  122. prefetch [%o1 + 0x100], #one_read ! MS Group
  123. ldd [%o1 + 0x008], %f2 ! AX
  124. prefetch [%o1 + 0x140], #one_read ! MS Group
  125. ldd [%o1 + 0x010], %f4 ! AX
  126. prefetch [%o1 + 0x180], #one_read ! MS Group
  127. fmovd %f0, %f32 ! FGA Group
  128. ldd [%o1 + 0x018], %f6 ! AX
  129. fmovd %f2, %f34 ! FGA Group
  130. ldd [%o1 + 0x020], %f8 ! MS
  131. fmovd %f4, %f36 ! FGA Group
  132. ldd [%o1 + 0x028], %f10 ! AX
  133. membar #StoreStore ! MS
  134. fmovd %f6, %f38 ! FGA Group
  135. ldd [%o1 + 0x030], %f12 ! MS
  136. fmovd %f8, %f40 ! FGA Group
  137. ldd [%o1 + 0x038], %f14 ! AX
  138. fmovd %f10, %f42 ! FGA Group
  139. ldd [%o1 + 0x040], %f16 ! MS
  140. 1: ldd [%o1 + 0x048], %f2 ! AX (Group)
  141. fmovd %f12, %f44 ! FGA
  142. ldd [%o1 + 0x050], %f4 ! MS
  143. fmovd %f14, %f46 ! FGA Group
  144. stda %f32, [%o0] ASI_BLK_P ! MS
  145. ldd [%o1 + 0x058], %f6 ! AX
  146. fmovd %f16, %f32 ! FGA Group (8-cycle stall)
  147. ldd [%o1 + 0x060], %f8 ! MS
  148. fmovd %f2, %f34 ! FGA Group
  149. ldd [%o1 + 0x068], %f10 ! AX
  150. fmovd %f4, %f36 ! FGA Group
  151. ldd [%o1 + 0x070], %f12 ! MS
  152. fmovd %f6, %f38 ! FGA Group
  153. ldd [%o1 + 0x078], %f14 ! AX
  154. fmovd %f8, %f40 ! FGA Group
  155. ldd [%o1 + 0x080], %f16 ! AX
  156. prefetch [%o1 + 0x180], #one_read ! MS
  157. fmovd %f10, %f42 ! FGA Group
  158. subcc %o2, 1, %o2 ! A0
  159. add %o0, 0x40, %o0 ! A1
  160. bne,pt %xcc, 1b ! BR
  161.  add %o1, 0x40, %o1 ! A0 Group
  163. mov 5, %o2 ! A0 Group
  164. 1: ldd [%o1 + 0x048], %f2 ! AX
  165. fmovd %f12, %f44 ! FGA
  166. ldd [%o1 + 0x050], %f4 ! MS
  167. fmovd %f14, %f46 ! FGA Group
  168. stda %f32, [%o0] ASI_BLK_P ! MS
  169. ldd [%o1 + 0x058], %f6 ! AX
  170. fmovd %f16, %f32 ! FGA Group (8-cycle stall)
  171. ldd [%o1 + 0x060], %f8 ! MS
  172. fmovd %f2, %f34 ! FGA Group
  173. ldd [%o1 + 0x068], %f10 ! AX
  174. fmovd %f4, %f36 ! FGA Group
  175. ldd [%o1 + 0x070], %f12 ! MS
  176. fmovd %f6, %f38 ! FGA Group
  177. ldd [%o1 + 0x078], %f14 ! AX
  178. fmovd %f8, %f40 ! FGA Group
  179. ldd [%o1 + 0x080], %f16 ! MS
  180. fmovd %f10, %f42 ! FGA Group
  181. subcc %o2, 1, %o2 ! A0
  182. add %o0, 0x40, %o0 ! A1
  183. bne,pt %xcc, 1b ! BR
  184.  add %o1, 0x40, %o1 ! A0 Group
  186. ldd [%o1 + 0x048], %f2 ! AX
  187. fmovd %f12, %f44 ! FGA
  188. ldd [%o1 + 0x050], %f4 ! MS
  189. fmovd %f14, %f46 ! FGA Group
  190. stda %f32, [%o0] ASI_BLK_P ! MS
  191. ldd [%o1 + 0x058], %f6 ! AX
  192. fmovd %f16, %f32 ! FGA Group (8-cycle stall)
  193. ldd [%o1 + 0x060], %f8 ! MS
  194. fmovd %f2, %f34 ! FGA Group
  195. ldd [%o1 + 0x068], %f10 ! AX
  196. fmovd %f4, %f36 ! FGA Group
  197. ldd [%o1 + 0x070], %f12 ! MS
  198. fmovd %f6, %f38 ! FGA Group
  199. add %o0, 0x40, %o0 ! A0
  200. ldd [%o1 + 0x078], %f14 ! AX
  201. fmovd %f8, %f40 ! FGA Group
  202. fmovd %f10, %f42 ! FGA Group
  203. fmovd %f12, %f44 ! FGA Group
  204. fmovd %f14, %f46 ! FGA Group
  205. stda %f32, [%o0] ASI_BLK_P ! MS
  206. ba,a,pt %xcc, copy_user_page_continue
  208. spitfire_copy_user_page:
  209. ldda [%o1] ASI_BLK_P, %f0
  210. add %o1, 0x40, %o1
  211. ldda [%o1] ASI_BLK_P, %f16
  212. add %o1, 0x40, %o1
  213. sethi %hi(PAGE_SIZE), %o2
  214. 1: TOUCH(f0, f2, f4, f6, f8, f10, f12, f14)
  215. ldda [%o1] ASI_BLK_P, %f32
  216. stda %f48, [%o0] ASI_BLK_P
  217. add %o1, 0x40, %o1
  218. sub %o2, 0x40, %o2
  219. add %o0, 0x40, %o0
  220. TOUCH(f16, f18, f20, f22, f24, f26, f28, f30)
  221. ldda [%o1] ASI_BLK_P, %f0
  222. stda %f48, [%o0] ASI_BLK_P
  223. add %o1, 0x40, %o1
  224. sub %o2, 0x40, %o2
  225. add %o0, 0x40, %o0
  226. TOUCH(f32, f34, f36, f38, f40, f42, f44, f46)
  227. ldda [%o1] ASI_BLK_P, %f16
  228. stda %f48, [%o0] ASI_BLK_P
  229. sub %o2, 0x40, %o2
  230. add %o1, 0x40, %o1
  231. cmp %o2, PAGE_SIZE_REM
  232. bne,pt %xcc, 1b
  233.  add %o0, 0x40, %o0
  234. #if (PAGE_SHIFT == 16) || (PAGE_SHIFT == 22)
  235. TOUCH(f0, f2, f4, f6, f8, f10, f12, f14)
  236. ldda [%o1] ASI_BLK_P, %f32
  237. stda %f48, [%o0] ASI_BLK_P
  238. add %o1, 0x40, %o1
  239. sub %o2, 0x40, %o2
  240. add %o0, 0x40, %o0
  241. TOUCH(f16, f18, f20, f22, f24, f26, f28, f30)
  242. ldda [%o1] ASI_BLK_P, %f0
  243. stda %f48, [%o0] ASI_BLK_P
  244. add %o1, 0x40, %o1
  245. sub %o2, 0x40, %o2
  246. add %o0, 0x40, %o0
  247. membar #Sync
  248. stda %f32, [%o0] ASI_BLK_P
  249. add %o0, 0x40, %o0
  250. stda %f0, [%o0] ASI_BLK_P
  251. #else
  252. membar #Sync
  253. stda %f0, [%o0] ASI_BLK_P
  254. add %o0, 0x40, %o0
  255. stda %f16, [%o0] ASI_BLK_P
  256. #endif
  257. copy_user_page_continue:
  258. membar #Sync
  259. VISExit
  261. mov TLB_TAG_ACCESS, %o2
  262. stxa %g5, [%o2] ASI_DMMU
  263. stxa %g7, [%o3] ASI_DTLB_DATA_ACCESS
  264. membar #Sync
  265. sub %o3, (TLBTEMP_ENTSZ), %o3
  266. stxa %o4, [%o2] ASI_DMMU
  267. stxa %o5, [%o3] ASI_DTLB_DATA_ACCESS
  268. membar #Sync
  269. rdpr %pstate, %g3
  270. jmpl %o7 + 0x8, %g0
  271.  wrpr %g3, PSTATE_IE, %pstate
  273. copy_page_using_blkcommit:
  274. membar #LoadStore | #StoreStore | #StoreLoad
  275. ldda [%o1] ASI_BLK_P, %f0
  276. add %o1, 0x40, %o1
  277. ldda [%o1] ASI_BLK_P, %f16
  278. add %o1, 0x40, %o1
  279. sethi %hi(PAGE_SIZE), %o2
  280. 1: TOUCH(f0, f2, f4, f6, f8, f10, f12, f14)
  281. ldda [%o1] ASI_BLK_P, %f32
  282. stda %f48, [%o0] ASI_BLK_COMMIT_P
  283. add %o1, 0x40, %o1
  284. sub %o2, 0x40, %o2
  285. add %o0, 0x40, %o0
  286. TOUCH(f16, f18, f20, f22, f24, f26, f28, f30)
  287. ldda [%o1] ASI_BLK_P, %f0
  288. stda %f48, [%o0] ASI_BLK_COMMIT_P
  289. add %o1, 0x40, %o1
  290. sub %o2, 0x40, %o2
  291. add %o0, 0x40, %o0
  292. TOUCH(f32, f34, f36, f38, f40, f42, f44, f46)
  293. ldda [%o1] ASI_BLK_P, %f16
  294. stda %f48, [%o0] ASI_BLK_COMMIT_P
  295. sub %o2, 0x40, %o2
  296. add %o1, 0x40, %o1
  297. cmp %o2, PAGE_SIZE_REM
  298. bne,pt %xcc, 1b
  299.  add %o0, 0x40, %o0
  300. #if (PAGE_SHIFT == 16) || (PAGE_SHIFT == 22)
  301. TOUCH(f0, f2, f4, f6, f8, f10, f12, f14)
  302. ldda [%o1] ASI_BLK_P, %f32
  303. stda %f48, [%o0] ASI_BLK_COMMIT_P
  304. add %o1, 0x40, %o1
  305. sub %o2, 0x40, %o2
  306. add %o0, 0x40, %o0
  307. TOUCH(f16, f18, f20, f22, f24, f26, f28, f30)
  308. ldda [%o1] ASI_BLK_P, %f0
  309. stda %f48, [%o0] ASI_BLK_COMMIT_P
  310. add %o1, 0x40, %o1
  311. sub %o2, 0x40, %o2
  312. add %o0, 0x40, %o0
  313. membar #Sync
  314. stda %f32, [%o0] ASI_BLK_COMMIT_P
  315. add %o0, 0x40, %o0
  316. ba,pt %xcc, copy_user_page_continue
  317.  stda %f0, [%o0] ASI_BLK_COMMIT_P
  318. #else
  319. membar #Sync
  320. stda %f0, [%o0] ASI_BLK_COMMIT_P
  321. add %o0, 0x40, %o0
  322. ba,pt %xcc, copy_user_page_continue
  323.  stda %f16, [%o0] ASI_BLK_COMMIT_P
  324. #endif
  326. .align 32
  327. .globl _clear_page
  328. .type _clear_page,@function
  329. _clear_page: /* %o0=dest */
  330. VISEntryHalf
  331. ba,pt %xcc, clear_page_common
  332.  clr %o4
  334. .align 32
  335. .globl clear_user_page
  336. .type clear_user_page,@function
  337. clear_user_page: /* %o0=dest, %o1=vaddr */
  338. VISEntryHalf
  339. sethi %hi(PAGE_SIZE), %g3
  340. sub %o0, %g4, %g1
  341. and %o1, %g3, %o0
  342. mov TLB_TAG_ACCESS, %o2
  343. sethi %uhi(_PAGE_VALID | _PAGE_SZBITS), %g3
  344. sethi %hi(TLBTEMP_BASE), %o3
  345. sllx %g3, 32, %g3
  346. or %g3, (_PAGE_CP | _PAGE_CV | _PAGE_P | _PAGE_L | _PAGE_W), %g3
  347. or %g1, %g3, %g1
  348. add %o0, %o3, %o0
  349. #define FIX_INSN_2 0x96102068 /* mov (13 << 3), %o3 */
  350. cheetah_patch_2:
  351. mov TLBTEMP_ENT2, %o3
  352. rdpr %pstate, %g3
  353. wrpr %g3, PSTATE_IE, %pstate
  355. /* Spitfire Errata #32 workaround */
  356. mov 0x8, %g5
  357. stxa %g0, [%g5] ASI_DMMU
  358. membar #Sync
  360. ldxa [%o3] ASI_DTLB_TAG_READ, %g5
  362. /* Spitfire Errata #32 workaround */
  363. mov 0x8, %g7
  364. stxa %g0, [%g7] ASI_DMMU
  365. membar #Sync
  367. ldxa [%o3] ASI_DTLB_DATA_ACCESS, %g0
  368. ldxa [%o3] ASI_DTLB_DATA_ACCESS, %g7
  369. stxa %o0, [%o2] ASI_DMMU
  370. stxa %g1, [%o3] ASI_DTLB_DATA_ACCESS
  371. membar #Sync
  373. mov 1, %o4
  375. clear_page_common:
  376. membar #StoreLoad | #StoreStore | #LoadStore ! LSU Group
  377. fzero %f0 ! FPA Group
  378. sethi %hi(PAGE_SIZE/256), %o1 ! IEU0
  379. fzero %f2 ! FPA Group
  380. or %o1, %lo(PAGE_SIZE/256), %o1 ! IEU0
  381. faddd %f0, %f2, %f4 ! FPA Group
  382. fmuld %f0, %f2, %f6 ! FPM
  383. faddd %f0, %f2, %f8 ! FPA Group
  384. fmuld %f0, %f2, %f10 ! FPM
  386. faddd %f0, %f2, %f12 ! FPA Group
  387. fmuld %f0, %f2, %f14 ! FPM
  388. 1: stda %f0, [%o0 + %g0] ASI_BLK_P ! Store Group
  389. add %o0, 0x40, %o0 ! IEU0
  390. stda %f0, [%o0 + %g0] ASI_BLK_P ! Store Group
  391. add %o0, 0x40, %o0 ! IEU0
  392. stda %f0, [%o0 + %g0] ASI_BLK_P ! Store Group
  394. add %o0, 0x40, %o0 ! IEU0 Group
  395. stda %f0, [%o0 + %g0] ASI_BLK_P ! Store Group
  396. subcc %o1, 1, %o1 ! IEU1
  397. bne,pt %icc, 1b ! CTI
  398.  add %o0, 0x40, %o0 ! IEU0 Group
  399. membar #Sync ! LSU Group
  400. VISExitHalf
  402. brnz,pt %o4, 1f
  403.  nop
  405. retl
  406.  nop
  408. 1: stxa %g5, [%o2] ASI_DMMU
  409. stxa %g7, [%o3] ASI_DTLB_DATA_ACCESS
  410. membar #Sync
  411. jmpl %o7 + 0x8, %g0
  412.  wrpr %g3, 0x0, %pstate
  414. .globl cheetah_patch_pgcopyops
  415. cheetah_patch_pgcopyops:
  416. sethi %hi(FIX_INSN_1), %g1
  417. or %g1, %lo(FIX_INSN_1), %g1
  418. sethi %hi(cheetah_patch_1), %g2
  419. or %g2, %lo(cheetah_patch_1), %g2
  420. stw %g1, [%g2]
  421. flush %g2
  422. sethi %hi(FIX_INSN_2), %g1
  423. or %g1, %lo(FIX_INSN_2), %g1
  424. sethi %hi(cheetah_patch_2), %g2
  425. or %g2, %lo(cheetah_patch_2), %g2
  426. stw %g1, [%g2]
  427. flush %g2
  428. retl
  429.  nop
  431. #undef FIX_INSN1
  432. #undef FIX_INSN2
  433. #undef PAGE_SIZE_REM