开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > 嵌入式Linux > 查看源码
head.S
资源名称：SBC-2410X_kernel.tar.gz　[点击查看]
上传用户：lgb322
上传日期：2013-02-24
资源大小：30529k
文件大小：17k
源码类别：

嵌入式Linux

开发平台：

Unix_Linux

head.S：源码内容
  1. /* $Id: head.S,v 1.86 2001/12/05 01:02:16 davem Exp $
  2.  * head.S: Initial boot code for the Sparc64 port of Linux.
  3.  *
  4.  * Copyright (C) 1996,1997 David S. Miller (davem@caip.rutgers.edu)
  5.  * Copyright (C) 1996 David Sitsky (David.Sitsky@anu.edu.au)
  6.  * Copyright (C) 1997,1998 Jakub Jelinek (jj@sunsite.mff.cuni.cz)
  7.  * Copyright (C) 1997 Miguel de Icaza (miguel@nuclecu.unam.mx)
  8.  */
  10. #include <linux/config.h>
  11. #include <linux/version.h>
  12. #include <linux/errno.h>
  13. #include <asm/asm_offsets.h>
  14. #include <asm/asi.h>
  15. #include <asm/pstate.h>
  16. #include <asm/ptrace.h>
  17. #include <asm/spitfire.h>
  18. #include <asm/page.h>
  19. #include <asm/pgtable.h>
  20. #include <asm/errno.h>
  21. #include <asm/signal.h>
  22. #include <asm/processor.h>
  23. #include <asm/lsu.h>
  24. #include <asm/dcr.h>
  25. #include <asm/dcu.h>
  26. #include <asm/head.h>
  27. #include <asm/ttable.h>
  29. /* This section from from _start to sparc64_boot_end should fit into
  30.  * 0x0000.0000.0040.4000 to 0x0000.0000.0040.8000 and will be sharing space
  31.  * with bootup_user_stack, which is from 0x0000.0000.0040.4000 to
  32.  * 0x0000.0000.0040.6000 and empty_bad_page, which is from
  33.  * 0x0000.0000.0040.6000 to 0x0000.0000.0040.8000. 
  34.  */
  36. .text
  37. .globl start, _start, stext, _stext
  38. _start:
  39. start:
  40. _stext:
  41. stext:
  42. bootup_user_stack:
  43. ! 0x0000000000404000
  44. b sparc64_boot
  45.  flushw /* Flush register file.      */
  47. /* This stuff has to be in sync with SILO and other potential boot loaders
  48.  * Fields should be kept upward compatible and whenever any change is made,
  49.  * HdrS version should be incremented.
  50.  */
  51.         .global root_flags, ram_flags, root_dev
  52.         .global sparc_ramdisk_image, sparc_ramdisk_size
  53. .globl silo_args
  55.         .ascii  "HdrS"
  56.         .word   LINUX_VERSION_CODE
  57.         .half   0x0203          /* HdrS version */
  58. root_flags:
  59.         .half   1
  60. root_dev:
  61.         .half   0
  62. ram_flags:
  63.         .half   0
  64. sparc_ramdisk_image:
  65.         .word   0
  66. sparc_ramdisk_size:
  67.         .word   0
  68.         .xword  reboot_command
  69. .xword bootstr_len
  70. .word _end
  72. /* We must be careful, 32-bit OpenBOOT will get confused if it
  73.  * tries to save away a register window to a 64-bit kernel
  74.  * stack address.  Flush all windows, disable interrupts,
  75.  * remap if necessary, jump onto kernel trap table, then kernel
  76.  * stack, or else we die.
  77.  *
  78.  * PROM entry point is on %o4
  79.  */
  80. sparc64_boot:
  81. rdpr %ver, %g1
  82. sethi %hi(0x003e0014), %g5
  83. srlx %g1, 32, %g1
  84. or %g5, %lo(0x003e0014), %g5
  85. cmp %g1, %g5
  86. bne,pt %icc, spitfire_boot
  87.  nop
  89. cheetah_boot:
  90. mov DCR_BPE | DCR_RPE | DCR_SI | DCR_IFPOE | DCR_MS, %g1
  91. wr %g1, %asr18
  93. sethi %uhi(DCU_ME | DCU_RE | /*DCU_PE |*/ DCU_HPE | DCU_SPE | DCU_SL | DCU_WE), %g5
  94. or %g5, %ulo(DCU_ME | DCU_RE | /*DCU_PE |*/ DCU_HPE | DCU_SPE | DCU_SL | DCU_WE), %g5
  95. sllx %g5, 32, %g5
  96. or %g5, DCU_DM | DCU_IM | DCU_DC | DCU_IC, %g5
  97. stxa %g5, [%g0] ASI_DCU_CONTROL_REG
  98. membar #Sync
  100. mov TSB_EXTENSION_P, %g3
  101. stxa %g0, [%g3] ASI_DMMU
  102. stxa %g0, [%g3] ASI_IMMU
  103. membar #Sync
  105. mov TSB_EXTENSION_S, %g3
  106. stxa %g0, [%g3] ASI_DMMU
  107. membar #Sync
  109. mov TSB_EXTENSION_N, %g3
  110. stxa %g0, [%g3] ASI_DMMU
  111. stxa %g0, [%g3] ASI_IMMU
  112. membar #Sync
  114. wrpr    %g0, (PSTATE_PRIV|PSTATE_PEF|PSTATE_IE), %pstate
  115. wr %g0, 0, %fprs
  117. /* Just like for Spitfire, we probe itlb-2 for a mapping which
  118.  * matches our current %pc.  We take the physical address in
  119.  * that mapping and use it to make our own.
  120.  */
  122. /* %g5 holds the tlb data */
  123.         sethi   %uhi(_PAGE_VALID | _PAGE_SZ4MB), %g5
  124.         sllx    %g5, 32, %g5
  125.         or      %g5, (_PAGE_CP | _PAGE_CV | _PAGE_P | _PAGE_L | _PAGE_W | _PAGE_G), %g5
  127. /* Put PADDR tlb data mask into %g3. */
  128. sethi %uhi(_PAGE_PADDR), %g3
  129. or %g3, %ulo(_PAGE_PADDR), %g3
  130. sllx %g3, 32, %g3
  131. sethi %hi(_PAGE_PADDR), %g7
  132. or %g7, %lo(_PAGE_PADDR), %g7
  133. or %g3, %g7, %g3
  135. set 2 << 16, %l0 /* TLB entry walker. */
  136. set 0x1fff, %l2 /* Page mask. */
  137. rd %pc, %l3
  138. andn %l3, %l2, %g2 /* vaddr comparator */
  140. 1: ldxa [%l0] ASI_ITLB_TAG_READ, %g1
  141. membar #Sync
  142. andn %g1, %l2, %g1
  143. cmp %g1, %g2
  144. be,pn %xcc, cheetah_got_tlbentry
  145.  nop
  146. and %l0, (127 << 3), %g1
  147. cmp %g1, (127 << 3)
  148. blu,pt %xcc, 1b
  149.  add %l0, (1 << 3), %l0
  151. cheetah_got_tlbentry:
  152. ldxa [%l0] ASI_ITLB_DATA_ACCESS, %g1
  153. membar #Sync
  154. and %g1, %g3, %g1
  155. sub %g1, %g2, %g1
  156. or %g5, %g1, %g5
  158. /* Clear out any KERNBASE area entries. */
  159. set 2 << 16, %l0
  160. sethi %hi(KERNBASE), %g3
  161. sethi %hi(KERNBASE<<1), %g7
  162. mov TLB_TAG_ACCESS, %l7
  164. /* First, check ITLB */
  165. 1: ldxa [%l0] ASI_ITLB_TAG_READ, %g1
  166. membar #Sync
  167. andn %g1, %l2, %g1
  168. cmp %g1, %g3
  169. blu,pn %xcc, 2f
  170.  cmp %g1, %g7
  171. bgeu,pn %xcc, 2f
  172.  nop
  173. stxa %g0, [%l7] ASI_IMMU
  174. membar #Sync
  175. stxa %g0, [%l0] ASI_ITLB_DATA_ACCESS
  176. membar #Sync
  178. 2: and %l0, (127 << 3), %g1
  179. cmp %g1, (127 << 3)
  180. blu,pt %xcc, 1b
  181.  add %l0, (1 << 3), %l0
  183. /* Next, check DTLB */
  184. set 2 << 16, %l0
  185. 1: ldxa [%l0] ASI_DTLB_TAG_READ, %g1
  186. membar #Sync
  187. andn %g1, %l2, %g1
  188. cmp %g1, %g3
  189. blu,pn %xcc, 2f
  190.  cmp %g1, %g7
  191. bgeu,pn %xcc, 2f
  192.  nop
  193. stxa %g0, [%l7] ASI_DMMU
  194. membar #Sync
  195. stxa %g0, [%l0] ASI_DTLB_DATA_ACCESS
  196. membar #Sync
  198. 2: and %l0, (511 << 3), %g1
  199. cmp %g1, (511 << 3)
  200. blu,pt %xcc, 1b
  201.  add %l0, (1 << 3), %l0
  203. /* Now lock the TTE we created into ITLB-0 and DTLB-0,
  204.  * entry 15 (and maybe 14 too).
  205.  */
  206. sethi %hi(KERNBASE), %g3
  207. set (0 << 16) | (15 << 3), %g7
  208. stxa %g3, [%l7] ASI_DMMU
  209. membar #Sync
  210. stxa %g5, [%g7] ASI_DTLB_DATA_ACCESS
  211. membar #Sync
  212. stxa %g3, [%l7] ASI_IMMU
  213. membar #Sync
  214. stxa %g5, [%g7] ASI_ITLB_DATA_ACCESS
  215. membar #Sync
  216. flush %g3
  217. membar #Sync
  218. sethi %hi(_end), %g3 /* Check for bigkernel case */
  219. or %g3, %lo(_end), %g3
  220. srl %g3, 23, %g3 /* Check if _end > 8M */
  221. brz,pt %g3, 1f
  222.  sethi %hi(KERNBASE), %g3 /* Restore for fixup code below */
  223. sethi %hi(0x400000), %g3
  224. or %g3, %lo(0x400000), %g3
  225. add %g5, %g3, %g5 /* New tte data */
  226. andn %g5, (_PAGE_G), %g5
  227. sethi %hi(KERNBASE+0x400000), %g3
  228. or %g3, %lo(KERNBASE+0x400000), %g3
  229. set (0 << 16) | (14 << 3), %g7
  230. stxa %g3, [%l7] ASI_DMMU
  231. membar #Sync
  232. stxa %g5, [%g7] ASI_DTLB_DATA_ACCESS
  233. membar #Sync
  234. stxa %g3, [%l7] ASI_IMMU
  235. membar #Sync
  236. stxa %g5, [%g7] ASI_ITLB_DATA_ACCESS
  237. membar #Sync
  238. flush %g3
  239. membar #Sync
  240. sethi %hi(KERNBASE), %g3 /* Restore for fixup code below */
  241. ba,pt %xcc, 1f
  242.  nop
  244. 1: set sun4u_init, %g2
  245. jmpl    %g2 + %g0, %g0
  246.  nop
  248. spitfire_boot:
  249. /* Typically PROM has already enabled both MMU's and both on-chip
  250.  * caches, but we do it here anyway just to be paranoid.
  251.  */
  252. mov (LSU_CONTROL_IC|LSU_CONTROL_DC|LSU_CONTROL_IM|LSU_CONTROL_DM), %g1
  253. stxa %g1, [%g0] ASI_LSU_CONTROL
  254. membar #Sync
  256. /*
  257.  * Make sure we are in privileged mode, have address masking,
  258.          * using the ordinary globals and have enabled floating
  259.          * point.
  260.  *
  261.  * Again, typically PROM has left %pil at 13 or similar, and
  262.  * (PSTATE_PRIV | PSTATE_PEF | PSTATE_IE) in %pstate.
  263.          */
  264. wrpr    %g0, (PSTATE_PRIV|PSTATE_PEF|PSTATE_IE), %pstate
  265. wr %g0, 0, %fprs
  267. spitfire_create_mappings:
  268. /* %g5 holds the tlb data */
  269.         sethi   %uhi(_PAGE_VALID | _PAGE_SZ4MB), %g5
  270.         sllx    %g5, 32, %g5
  271.         or      %g5, (_PAGE_CP | _PAGE_CV | _PAGE_P | _PAGE_L | _PAGE_W | _PAGE_G), %g5
  273. /* Base of physical memory cannot reliably be assumed to be
  274.  * at 0x0!  Figure out where it happens to be. -DaveM
  275.  */
  277. /* Put PADDR tlb data mask into %g3. */
  278. sethi %uhi(_PAGE_PADDR_SF), %g3
  279. or %g3, %ulo(_PAGE_PADDR_SF), %g3
  280. sllx %g3, 32, %g3
  281. sethi %hi(_PAGE_PADDR_SF), %g7
  282. or %g7, %lo(_PAGE_PADDR_SF), %g7
  283. or %g3, %g7, %g3
  285. /* Walk through entire ITLB, looking for entry which maps
  286.  * our %pc currently, stick PADDR from there into %g5 tlb data.
  287.  */
  288. clr %l0 /* TLB entry walker. */
  289. set 0x1fff, %l2 /* Page mask. */
  290. rd %pc, %l3
  291. andn %l3, %l2, %g2 /* vaddr comparator */
  292. 1:
  293. /* Yes, the nops seem to be necessary for now, don't ask me why. -DaveM */
  294. ldxa [%l0] ASI_ITLB_TAG_READ, %g1
  295. nop
  296. nop
  297. nop
  298. andn %g1, %l2, %g1 /* Get vaddr */
  299. cmp %g1, %g2
  300. be,a,pn %xcc, spitfire_got_tlbentry
  301.  ldxa [%l0] ASI_ITLB_DATA_ACCESS, %g1
  302. cmp %l0, (63 << 3)
  303. blu,pt %xcc, 1b
  304.  add %l0, (1 << 3), %l0
  306. spitfire_got_tlbentry:
  307. /* Nops here again, perhaps Cheetah/Blackbird are better behaved... */
  308. nop
  309. nop
  310. nop
  311. and %g1, %g3, %g1 /* Mask to just get paddr bits.       */
  312. sub %g1, %g2, %g1 /* Get rid of %pc offset to get base. */
  314. /* NOTE: We hold on to %g1 paddr base as we need it below to lock
  315.  * NOTE: the PROM cif code into the TLB.
  316.  */
  318. or %g5, %g1, %g5 /* Or it into TAG being built.        */
  320. clr %l0 /* TLB entry walker. */
  321. sethi %hi(KERNBASE), %g3 /* 4M lower limit */
  322. sethi %hi(KERNBASE<<1), %g7 /* 8M upper limit */
  323. mov TLB_TAG_ACCESS, %l7
  324. 1:
  325. /* Yes, the nops seem to be necessary for now, don't ask me why. -DaveM */
  326. ldxa [%l0] ASI_ITLB_TAG_READ, %g1
  327. nop
  328. nop
  329. nop
  330. andn %g1, %l2, %g1 /* Get vaddr */
  331. cmp %g1, %g3
  332. blu,pn %xcc, 2f
  333.  cmp %g1, %g7
  334. bgeu,pn %xcc, 2f
  335.  nop
  336. stxa %g0, [%l7] ASI_IMMU
  337. stxa %g0, [%l0] ASI_ITLB_DATA_ACCESS
  338. membar #Sync
  339. 2:
  340. cmp %l0, (63 << 3)
  341. blu,pt %xcc, 1b
  342.  add %l0, (1 << 3), %l0
  344. nop; nop; nop
  346. clr %l0 /* TLB entry walker. */
  347. 1:
  348. /* Yes, the nops seem to be necessary for now, don't ask me why. -DaveM */
  349. ldxa [%l0] ASI_DTLB_TAG_READ, %g1
  350. nop
  351. nop
  352. nop
  353. andn %g1, %l2, %g1 /* Get vaddr */
  354. cmp %g1, %g3
  355. blu,pn %xcc, 2f
  356.  cmp %g1, %g7
  357. bgeu,pn %xcc, 2f
  358.  nop
  359. stxa %g0, [%l7] ASI_DMMU
  360. stxa %g0, [%l0] ASI_DTLB_DATA_ACCESS
  361. membar #Sync
  362. 2:
  363. cmp %l0, (63 << 3)
  364. blu,pt %xcc, 1b
  365.  add %l0, (1 << 3), %l0
  367. nop; nop; nop
  370. /* PROM never puts any TLB entries into the MMU with the lock bit
  371.  * set.  So we gladly use tlb entry 63 for KERNBASE. And maybe 62 too.
  372.  */
  374. sethi %hi(KERNBASE), %g3
  375. mov (63 << 3), %g7
  376. stxa %g3, [%l7] ASI_DMMU /* KERNBASE into TLB TAG */
  377. stxa %g5, [%g7] ASI_DTLB_DATA_ACCESS /* TTE into TLB DATA */
  378. membar #Sync
  379. stxa %g3, [%l7] ASI_IMMU /* KERNBASE into TLB TAG */
  380. stxa %g5, [%g7] ASI_ITLB_DATA_ACCESS /* TTE into TLB DATA */
  381. membar #Sync
  382. flush %g3
  383. membar #Sync
  384. sethi %hi(_end), %g3 /* Check for bigkernel case */
  385. or %g3, %lo(_end), %g3
  386. srl %g3, 23, %g3 /* Check if _end > 8M */
  387. brz,pt %g3, 2f
  388.  sethi %hi(KERNBASE), %g3 /* Restore for fixup code below */
  389. sethi %hi(0x400000), %g3
  390. or %g3, %lo(0x400000), %g3
  391. add %g5, %g3, %g5 /* New tte data */
  392. andn %g5, (_PAGE_G), %g5
  393. sethi %hi(KERNBASE+0x400000), %g3
  394. or %g3, %lo(KERNBASE+0x400000), %g3
  395. mov (62 << 3), %g7
  396. stxa %g3, [%l7] ASI_DMMU
  397. stxa %g5, [%g7] ASI_DTLB_DATA_ACCESS
  398. membar #Sync
  399. stxa %g3, [%l7] ASI_IMMU
  400. stxa %g5, [%g7] ASI_ITLB_DATA_ACCESS
  401. membar #Sync
  402. flush %g3
  403. membar #Sync
  404. sethi %hi(KERNBASE), %g3 /* Restore for fixup code below */
  405. 2: ba,pt %xcc, 1f
  406.  nop
  407. 1:
  408. set sun4u_init, %g2
  409. jmpl    %g2 + %g0, %g0
  410.  nop
  412. sun4u_init:
  413. /* Set ctx 0 */
  414. mov PRIMARY_CONTEXT, %g7
  415. stxa %g0, [%g7] ASI_DMMU
  416. membar #Sync
  418. mov SECONDARY_CONTEXT, %g7
  419. stxa %g0, [%g7] ASI_DMMU
  420. membar #Sync
  422. sethi %uhi(PAGE_OFFSET), %g4
  423. sllx %g4, 32, %g4
  425. /* We are now safely (we hope) in Nucleus context (0), rewrite
  426.  * the KERNBASE TTE's so they no longer have the global bit set.
  427.  * Don't forget to setup TAG_ACCESS first 8-)
  428.  */
  429. mov TLB_TAG_ACCESS, %g2
  430. stxa %g3, [%g2] ASI_IMMU
  431. stxa %g3, [%g2] ASI_DMMU
  432. membar #Sync
  434. rdpr %ver, %g1
  435. sethi %hi(0x003e0014), %g5
  436. srlx %g1, 32, %g1
  437. or %g5, %lo(0x003e0014), %g5
  438. cmp %g1, %g5
  439. bne,pt %icc, spitfire_tlb_fixup
  440.  nop
  442. cheetah_tlb_fixup:
  443. set (0 << 16) | (15 << 3), %g7
  444. ldxa [%g7] ASI_ITLB_DATA_ACCESS, %g1
  445. andn %g1, (_PAGE_G), %g1
  446. stxa %g1, [%g7] ASI_ITLB_DATA_ACCESS
  447. membar #Sync
  449. ldxa [%g7] ASI_DTLB_DATA_ACCESS, %g1
  450. andn %g1, (_PAGE_G), %g1
  451. stxa %g1, [%g7] ASI_DTLB_DATA_ACCESS
  452. membar #Sync
  454. /* Kill instruction prefetch queues. */
  455. flush %g3
  456. membar #Sync
  458. /* Set TLB type to cheetah. */
  459. mov 1, %g2
  460. sethi %hi(tlb_type), %g5
  461. stw %g2, [%g5 + %lo(tlb_type)]
  463. /* Patch copy/page operations to cheetah optimized versions. */
  464. call cheetah_patch_copyops
  465.  nop
  466. call cheetah_patch_pgcopyops
  467.  nop
  469. ba,pt %xcc, tlb_fixup_done
  470.  nop
  472. spitfire_tlb_fixup:
  473. mov (63 << 3), %g7
  474. ldxa [%g7] ASI_ITLB_DATA_ACCESS, %g1
  475. andn %g1, (_PAGE_G), %g1
  476. stxa %g1, [%g7] ASI_ITLB_DATA_ACCESS
  477. membar #Sync
  479. ldxa [%g7] ASI_DTLB_DATA_ACCESS, %g1
  480. andn %g1, (_PAGE_G), %g1
  481. stxa %g1, [%g7] ASI_DTLB_DATA_ACCESS
  482. membar #Sync
  484. /* Kill instruction prefetch queues. */
  485. flush %g3
  486. membar #Sync
  488. /* Set TLB type to spitfire. */
  489. mov 0, %g2
  490. sethi %hi(tlb_type), %g5
  491. stw %g2, [%g5 + %lo(tlb_type)]
  493. tlb_fixup_done:
  494. sethi %hi(init_task_union), %g6
  495. or %g6, %lo(init_task_union), %g6
  496. mov %sp, %l6
  497. mov %o4, %l7
  499. #if 0 /* We don't do it like this anymore, but for historical hack value
  500.  * I leave this snippet here to show how crazy we can be sometimes. 8-)
  501.  */
  503. /* Setup "Linux Current Register", thanks Sun 8-) */
  504. wr %g0, 0x1, %pcr
  506. /* Blackbird errata workaround.  See commentary in
  507.  * smp.c:smp_percpu_timer_interrupt() for more
  508.  * information.
  509.  */
  510. ba,pt %xcc, 99f
  511.  nop
  512. .align 64
  513. 99: wr %g6, %g0, %pic
  514. rd %pic, %g0
  515. #endif
  517. wr %g0, ASI_P, %asi
  518. mov 1, %g5
  519. sllx %g5, THREAD_SHIFT, %g5
  520. sub %g5, (REGWIN_SZ + STACK_BIAS), %g5
  521. add %g6, %g5, %sp
  522. mov 0, %fp
  524. wrpr %g0, 0, %wstate
  525. wrpr %g0, 0x0, %tl
  527. /* Clear the bss */
  528. sethi %hi(__bss_start), %o0
  529. or %o0, %lo(__bss_start), %o0
  530. sethi %hi(_end), %o1
  531. or %o1, %lo(_end), %o1
  532. call __bzero
  533.  sub %o1, %o0, %o1
  535. mov %l6, %o1 ! OpenPROM stack
  536. call prom_init
  537.  mov %l7, %o0 ! OpenPROM cif handler
  539. /* Off we go.... */
  540. call start_kernel
  541.  nop
  542. /* Not reached... */
  544. /* IMPORTANT NOTE: Whenever making changes here, check
  545.  * trampoline.S as well. -jj */
  546. .globl setup_tba
  547. setup_tba: /* i0 = is_starfire */
  548. save %sp, -160, %sp
  550. rdpr %tba, %g7
  551. sethi %hi(prom_tba), %o1
  552. or %o1, %lo(prom_tba), %o1
  553. stx %g7, [%o1]
  555. /* Setup "Linux" globals 8-) */
  556. rdpr %pstate, %o1
  557. mov %g6, %o2
  558. wrpr %o1, (PSTATE_AG|PSTATE_IE), %pstate
  559. sethi %hi(sparc64_ttable_tl0), %g5
  560. wrpr %g5, %tba
  561. mov %o2, %g6
  563. /* Set up MMU globals */
  564. wrpr %o1, (PSTATE_MG|PSTATE_IE), %pstate
  566. /* Set fixed globals used by dTLB miss handler. */
  567. #define KERN_HIGHBITS ((_PAGE_VALID|_PAGE_SZ4MB)^0xfffff80000000000)
  568. #define KERN_LOWBITS (_PAGE_CP | _PAGE_CV | _PAGE_P | _PAGE_W)
  570. #define VPTE_BASE_SPITFIRE 0xfffffffe00000000
  571. #if 1
  572. #define VPTE_BASE_CHEETAH VPTE_BASE_SPITFIRE
  573. #else
  574. #define VPTE_BASE_CHEETAH 0xffe0000000000000
  575. #endif
  577. mov TSB_REG, %g1
  578. stxa %g0, [%g1] ASI_DMMU
  579. membar #Sync
  580. mov TLB_SFSR, %g1
  581. sethi %uhi(KERN_HIGHBITS), %g2
  582. or %g2, %ulo(KERN_HIGHBITS), %g2
  583. sllx %g2, 32, %g2
  584. or %g2, KERN_LOWBITS, %g2
  586. rdpr %ver, %g3
  587. sethi %hi(0x003e0014), %g7
  588. srlx %g3, 32, %g3
  589. or %g7, %lo(0x003e0014), %g7
  590. cmp %g3, %g7
  591. bne,pt %icc, 1f
  592.  nop
  594. sethi %uhi(VPTE_BASE_CHEETAH), %g3
  595. or %g3, %ulo(VPTE_BASE_CHEETAH), %g3
  596. ba,pt %xcc, 2f
  597.  sllx %g3, 32, %g3
  598. 1:
  599. sethi %uhi(VPTE_BASE_SPITFIRE), %g3
  600. or %g3, %ulo(VPTE_BASE_SPITFIRE), %g3
  601. sllx %g3, 32, %g3
  603. 2:
  604. clr %g7
  605. #undef KERN_HIGHBITS
  606. #undef KERN_LOWBITS
  607. #undef VPTE_BASE_SPITFIRE
  608. #undef VPTE_BASE_CHEETAH
  610. /* Setup Interrupt globals */
  611. wrpr %o1, (PSTATE_IG|PSTATE_IE), %pstate
  612. #ifndef CONFIG_SMP
  613. sethi %hi(__up_workvec), %g5
  614. or %g5, %lo(__up_workvec), %g6
  615. #else
  616. /* By definition of where we are, this is boot_cpu. */
  617. brz,pt %i0, not_starfire
  618.  sethi %hi(0x1fff4000), %g1
  619. or %g1, %lo(0x1fff4000), %g1
  620. sllx %g1, 12, %g1
  621. or %g1, 0xd0, %g1
  622. lduwa [%g1] ASI_PHYS_BYPASS_EC_E, %g1
  623. b,pt %xcc, set_worklist
  624.  nop
  626. not_starfire:
  627. rdpr %ver, %g1
  628. sethi %hi(0x003e0014), %g5
  629. srlx %g1, 32, %g1
  630. or %g7, %lo(0x003e0014), %g5
  631. cmp %g1, %g5
  632. bne,pt %icc, not_cheetah
  633.  nop
  635. ldxa [%g0] ASI_SAFARI_CONFIG, %g1
  636. srlx %g1, 17, %g1
  637. ba,pt %xcc, set_worklist
  638.  and %g1, 0x3ff, %g1 ! 10bit Safari Agent ID
  640. not_cheetah:
  641. ldxa [%g0] ASI_UPA_CONFIG, %g1
  642. srlx %g1, 17, %g1
  643. and %g1, 0x1f, %g1
  645. /* In theory this is: &(cpu_data[boot_cpu_id].irq_worklists[0]) */
  646. set_worklist:
  647. sethi %hi(cpu_data), %g5
  648. or %g5, %lo(cpu_data), %g5
  649. sllx %g1, 7, %g1
  650. add %g5, %g1, %g5
  651. add %g5, 64, %g6
  652. #endif
  654. /* Kill PROM timer */
  655. wr %g0, 0, %tick_cmpr
  657. rdpr %ver, %g1
  658. sethi %hi(0x003e0014), %g5
  659. srlx %g1, 32, %g1
  660. or %g7, %lo(0x003e0014), %g5
  661. cmp %g1, %g5
  662. bne,pt %icc, 1f
  663.  nop
  665. /* Disable STICK_INT interrupts. */
  666. sethi %hi(0x80000000), %g1
  667. sllx %g1, 32, %g1
  668. wr %g1, %asr25
  670. /* Ok, we're done setting up all the state our trap mechanims needs,
  671.  * now get back into normal globals and let the PROM know what is up.
  672.  */
  673. 1:
  674. wrpr %g0, %g0, %wstate
  675. wrpr %o1, PSTATE_IE, %pstate
  677. sethi %hi(sparc64_ttable_tl0), %g5
  678. call prom_set_trap_table
  679.  mov %g5, %o0
  681. rdpr %pstate, %o1
  682. or %o1, PSTATE_IE, %o1
  683. wrpr %o1, 0, %pstate
  685. ret
  686.  restore
  688. /*
  689.  * The following skips make sure the trap table in ttable.S is aligned
  690.  * on a 32K boundary as required by the v9 specs for TBA register.
  691.  */
  692. sparc64_boot_end:
  693. .skip 0x2000 + _start - sparc64_boot_end
  694. bootup_user_stack_end:
  695. .skip 0x2000
  697. #ifdef CONFIG_SBUS
  698. /* This is just a hack to fool make depend config.h discovering
  699.    strategy: As the .S files below need config.h, but
  700.    make depend does not find it for them, we include config.h
  701.    in head.S */
  702. #endif
  704. ! 0x0000000000408000
  706. #include "ttable.S"
  707. #include "systbls.S"
  709. .align 1024
  710. .globl swapper_pg_dir
  711. swapper_pg_dir:
  712. .word 0
  714. #include "etrap.S"
  715. #include "rtrap.S"
  716. #include "winfixup.S"
  717. #include "entry.S"
  719. /* This is just anal retentiveness on my part... */
  720. .align 16384
  722. .data
  723. .align 8
  724. .globl prom_tba
  725. prom_tba: .xword 0
  726. .section ".fixup",#alloc,#execinstr
  727. .globl __ret_efault
  728. __ret_efault:
  729. ret
  730.  restore %g0, -EFAULT, %o0