开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > 嵌入式Linux > 查看源码
entry.S
资源名称：SBC-2410X_kernel.tar.gz　[点击查看]
上传用户：lgb322
上传日期：2013-02-24
资源大小：30529k
文件大小：41k
源码类别：

嵌入式Linux

开发平台：

Unix_Linux

entry.S：源码内容
  1. /* $Id: entry.S,v 1.170 2001/11/13 00:57:05 davem Exp $
  2.  * arch/sparc/kernel/entry.S:  Sparc trap low-level entry points.
  3.  *
  4.  * Copyright (C) 1995 David S. Miller (davem@caip.rutgers.edu)
  5.  * Copyright (C) 1996 Eddie C. Dost   (ecd@skynet.be)
  6.  * Copyright (C) 1996 Miguel de Icaza (miguel@nuclecu.unam.mx)
  7.  * Copyright (C) 1996-1999 Jakub Jelinek   (jj@sunsite.mff.cuni.cz)
  8.  * Copyright (C) 1997 Anton Blanchard (anton@progsoc.uts.edu.au)
  9.  */
  11. #include <linux/config.h>
  12. #include <linux/errno.h>
  14. #include <asm/head.h>
  15. #include <asm/asi.h>
  16. #include <asm/smp.h>
  17. #include <asm/kgdb.h>
  18. #include <asm/contregs.h>
  19. #include <asm/ptrace.h>
  20. #include <asm/psr.h>
  21. #include <asm/cprefix.h>
  22. #include <asm/vaddrs.h>
  23. #include <asm/memreg.h>
  24. #include <asm/page.h>
  25. #ifdef CONFIG_SUN4
  26. #include <asm/pgtsun4.h>
  27. #else
  28. #include <asm/pgtsun4c.h>
  29. #endif
  30. #include <asm/winmacro.h>
  31. #include <asm/signal.h>
  32. #include <asm/obio.h>
  33. #include <asm/mxcc.h>
  35. #include <asm/asmmacro.h>
  37. #define curptr      g6
  39. #define NR_SYSCALLS 256      /* Each OS is different... */
  41. /* First, KGDB low level things.  This is a rewrite
  42.  * of the routines found in the sparc-stub.c asm() statement
  43.  * from the gdb distribution.  This is also dual-purpose
  44.  * as a software trap for userlevel programs.
  45.  */
  46. .data
  47. .align 4
  49. in_trap_handler:
  50. .word 0
  52. .text
  53. .align 4
  55. ! This function is called when any SPARC trap (except window overflow or
  56. ! underflow) occurs.  It makes sure that the invalid register window is still
  57. ! available before jumping into C code.  It will also restore the world if you
  58. ! return from handle_exception.
  60. .globl C_LABEL(trap_low)
  61. C_LABEL(trap_low):
  62. rd %wim, %l3
  63. SAVE_ALL
  65. sethi %hi(in_trap_handler), %l4
  66. ld [%lo(in_trap_handler) + %l4], %l5
  67. inc %l5
  68. st %l5, [%lo(in_trap_handler) + %l4]
  70. /* Make sure kgdb sees the same state we just saved. */
  71. LOAD_PT_GLOBALS(sp)
  72. LOAD_PT_INS(sp)
  73. ld [%sp + REGWIN_SZ + PT_Y], %l4
  74. ld [%sp + REGWIN_SZ + PT_WIM], %l3
  75. ld [%sp + REGWIN_SZ + PT_PSR], %l0
  76. ld [%sp + REGWIN_SZ + PT_PC], %l1
  77. ld [%sp + REGWIN_SZ + PT_NPC], %l2
  78. rd %tbr, %l5 /* Never changes... */
  80. /* Make kgdb exception frame. */
  81. sub %sp,(16+1+6+1+72)*4,%sp ! Make room for input & locals
  82.   ! + hidden arg + arg spill
  83. ! + doubleword alignment
  84. ! + registers[72] local var
  85. SAVE_KGDB_GLOBALS(sp)
  86. SAVE_KGDB_INS(sp)
  87. SAVE_KGDB_SREGS(sp, l4, l0, l3, l5, l1, l2)
  89. /* We are increasing PIL, so two writes. */
  90. or %l0, PSR_PIL, %l0
  91. wr %l0, 0, %psr
  92. WRITE_PAUSE
  93. wr %l0, PSR_ET, %psr
  94. WRITE_PAUSE
  96. call C_LABEL(handle_exception)
  97.  add %sp, REGWIN_SZ, %o0 ! Pass address of registers
  99. /* Load new kgdb register set. */
  100. LOAD_KGDB_GLOBALS(sp)
  101. LOAD_KGDB_INS(sp)
  102. LOAD_KGDB_SREGS(sp, l4, l0, l3, l5, l1, l2)
  103. wr      %l4, 0x0, %y
  105. sethi %hi(in_trap_handler), %l4
  106. ld [%lo(in_trap_handler) + %l4], %l5
  107. dec %l5
  108. st %l5, [%lo(in_trap_handler) + %l4]
  110. add %sp,(16+1+6+1+72)*4,%sp ! Undo the kgdb trap frame.
  112. /* Now take what kgdb did and place it into the pt_regs
  113.  * frame which SparcLinux RESTORE_ALL understands.,
  114.  */
  115. STORE_PT_INS(sp)
  116. STORE_PT_GLOBALS(sp)
  117. STORE_PT_YREG(sp, g2)
  118. STORE_PT_PRIV(sp, l0, l1, l2)
  120. RESTORE_ALL
  123. #ifdef CONFIG_BLK_DEV_FD
  124. .text
  125. .align 4
  126. .globl C_LABEL(floppy_hardint)
  127. C_LABEL(floppy_hardint):
  128. /*
  129.  * This code cannot touch registers %l0 %l1 and %l2
  130.  * because SAVE_ALL depends on their values. It depends
  131.  * on %l3 also, but we regenerate it before a call.
  132.  * Other registers are:
  133.  * %l3 -- base address of fdc registers
  134.  * %l4 -- pdma_vaddr
  135.  * %l5 -- scratch for ld/st address
  136.  * %l6 -- pdma_size
  137.  * %l7 -- scratch [floppy byte, ld/st address, aux. data]
  138.  */
  140. /* Do we have work to do? */
  141. sethi %hi(C_LABEL(doing_pdma)), %l7
  142. ld [%l7 + %lo(C_LABEL(doing_pdma))], %l7
  143. cmp %l7, 0
  144. be floppy_dosoftint
  145.  nop
  147. /* Load fdc register base */
  148. sethi %hi(C_LABEL(fdc_status)), %l3
  149. ld [%l3 + %lo(C_LABEL(fdc_status))], %l3
  151. /* Setup register addresses */
  152. sethi %hi(C_LABEL(pdma_vaddr)), %l5 ! transfer buffer
  153. ld [%l5 + %lo(C_LABEL(pdma_vaddr))], %l4
  154. sethi %hi(C_LABEL(pdma_size)), %l5 ! bytes to go
  155. ld [%l5 + %lo(C_LABEL(pdma_size))], %l6
  156. next_byte:
  157.    ldub [%l3], %l7
  159. andcc %l7, 0x80, %g0 ! Does fifo still have data
  160. bz floppy_fifo_emptied ! fifo has been emptied...
  161.  andcc %l7, 0x20, %g0 ! in non-dma mode still?
  162. bz floppy_overrun ! nope, overrun
  163.  andcc %l7, 0x40, %g0 ! 0=write 1=read
  164. bz floppy_write
  165.  sub %l6, 0x1, %l6
  167. /* Ok, actually read this byte */
  168. ldub [%l3 + 1], %l7
  169. orcc %g0, %l6, %g0
  170. stb %l7, [%l4]
  171. bne next_byte
  172.  add %l4, 0x1, %l4
  174. b floppy_tdone
  175.  nop
  177. floppy_write:
  178. /* Ok, actually write this byte */
  179. ldub [%l4], %l7
  180. orcc %g0, %l6, %g0
  181. stb %l7, [%l3 + 1]
  182. bne next_byte
  183.  add %l4, 0x1, %l4
  185. /* fall through... */
  186. floppy_tdone:
  187. sethi %hi(C_LABEL(pdma_vaddr)), %l5
  188. st %l4, [%l5 + %lo(C_LABEL(pdma_vaddr))]
  189. sethi %hi(C_LABEL(pdma_size)), %l5
  190. st %l6, [%l5 + %lo(C_LABEL(pdma_size))]
  191. /* Flip terminal count pin */
  192. set C_LABEL(auxio_register), %l7
  193. ld [%l7], %l7
  195. set C_LABEL(sparc_cpu_model), %l5
  196. ld [%l5], %l5
  197. subcc   %l5, 1, %g0 /* enum { sun4c = 1 }; */
  198. be 1f
  199.  ldub [%l7], %l5
  201. or %l5, 0xc2, %l5
  202. stb %l5, [%l7]
  203. andn    %l5, 0x02, %l5
  204. b 2f
  205.  nop
  207. 1:
  208. or      %l5, 0xf4, %l5
  209. stb     %l5, [%l7]
  210. andn    %l5, 0x04, %l5
  212. 2:
  213. /* Kill some time so the bits set */
  214. WRITE_PAUSE
  215. WRITE_PAUSE
  217. stb     %l5, [%l7]
  219. /* Prevent recursion */
  220. sethi %hi(C_LABEL(doing_pdma)), %l7
  221. b floppy_dosoftint
  222.  st %g0, [%l7 + %lo(C_LABEL(doing_pdma))]
  224. /* We emptied the FIFO, but we haven't read everything
  225.  * as of yet.  Store the current transfer address and
  226.  * bytes left to read so we can continue when the next
  227.  * fast IRQ comes in.
  228.  */
  229. floppy_fifo_emptied:
  230. sethi %hi(C_LABEL(pdma_vaddr)), %l5
  231. st %l4, [%l5 + %lo(C_LABEL(pdma_vaddr))]
  232. sethi %hi(C_LABEL(pdma_size)), %l7
  233. st %l6, [%l7 + %lo(C_LABEL(pdma_size))]
  235. /* Restore condition codes */
  236. wr %l0, 0x0, %psr
  237. WRITE_PAUSE
  239. jmp %l1
  240. rett %l2
  242. floppy_overrun:
  243. sethi %hi(C_LABEL(pdma_vaddr)), %l5
  244. st %l4, [%l5 + %lo(C_LABEL(pdma_vaddr))]
  245. sethi %hi(C_LABEL(pdma_size)), %l5
  246. st %l6, [%l5 + %lo(C_LABEL(pdma_size))]
  247. /* Prevent recursion */
  248. sethi %hi(C_LABEL(doing_pdma)), %l7
  249. st %g0, [%l7 + %lo(C_LABEL(doing_pdma))]
  251. /* fall through... */
  252. floppy_dosoftint:
  253. rd %wim, %l3
  254. SAVE_ALL
  256. /* Set all IRQs off. */
  257. or %l0, PSR_PIL, %l4
  258. wr %l4, 0x0, %psr
  259. WRITE_PAUSE
  260. wr %l4, PSR_ET, %psr
  261. WRITE_PAUSE
  263. mov 11, %o0 ! floppy irq level (unused anyway)
  264. mov %g0, %o1 ! devid is not used in fast interrupts
  265. call C_LABEL(sparc_floppy_irq)
  266.  add %sp, REGWIN_SZ, %o2 ! struct pt_regs *regs
  268. RESTORE_ALL
  270. #endif /* (CONFIG_BLK_DEV_FD) */
  272. /* Bad trap handler */
  273. .globl bad_trap_handler
  274. bad_trap_handler:
  275. SAVE_ALL
  277. wr %l0, PSR_ET, %psr
  278. WRITE_PAUSE
  280. mov %l7, %o0 ! trap number
  281. mov %l0, %o1 ! psr
  282. call C_LABEL(do_hw_interrupt)
  283.  mov %l1, %o2 ! pc
  285. RESTORE_ALL
  287. /* For now all IRQ's not registered get sent here. handler_irq() will
  288.  * see if a routine is registered to handle this interrupt and if not
  289.  * it will say so on the console.
  290.  */
  292. .align 4
  293. .globl real_irq_entry, patch_handler_irq
  294. real_irq_entry:
  295. SAVE_ALL
  297. #ifdef CONFIG_SMP
  298. .globl patchme_maybe_smp_msg
  300. cmp %l7, 12
  301. patchme_maybe_smp_msg:
  302. bgu maybe_smp4m_msg
  303.  nop
  304. #endif
  306. real_irq_continue:
  307. or %l0, PSR_PIL, %g2
  308. wr %g2, 0x0, %psr
  309. WRITE_PAUSE
  310. wr %g2, PSR_ET, %psr
  311. WRITE_PAUSE
  312. mov %l7, %o0 ! irq level
  313. patch_handler_irq:
  314. call C_LABEL(handler_irq)
  315.  add %sp, REGWIN_SZ, %o1 ! pt_regs ptr
  316. or %l0, PSR_PIL, %g2 ! restore PIL after handler_irq
  317. wr %g2, PSR_ET, %psr ! keep ET up
  318. WRITE_PAUSE
  320. RESTORE_ALL
  322. #ifdef CONFIG_SMP
  323. /* SMP per-cpu ticker interrupts are handled specially. */
  324. smp4m_ticker:
  325. bne real_irq_continue+4
  326.  or %l0, PSR_PIL, %g2
  327. wr %g2, 0x0, %psr
  328. WRITE_PAUSE
  329. wr %g2, PSR_ET, %psr
  330. WRITE_PAUSE
  331. call C_LABEL(smp4m_percpu_timer_interrupt)
  332.  add %sp, REGWIN_SZ, %o0
  333. wr %l0, PSR_ET, %psr
  334. WRITE_PAUSE
  335. RESTORE_ALL
  337. /* Here is where we check for possible SMP IPI passed to us
  338.  * on some level other than 15 which is the NMI and only used
  339.  * for cross calls.  That has a separate entry point below.
  340.  */
  341. maybe_smp4m_msg:
  342. GET_PROCESSOR_MID(o3, o2)
  343. set C_LABEL(sun4m_interrupts), %l5
  344. ld [%l5], %o5
  345. sethi %hi(0x60000000), %o4
  346. sll %o3, 12, %o3
  347. ld [%o5 + %o3], %o1
  348. andcc %o1, %o4, %g0
  349. be,a smp4m_ticker
  350.  cmp %l7, 14
  351. cmp %l7, 13
  352. add %o5, %o3, %o5
  353. bne,a 1f
  354.  sethi %hi(0x40000000), %o2
  355. sethi %hi(0x20000000), %o2
  356. 1:
  357. st %o2, [%o5 + 0x4]
  358. WRITE_PAUSE
  359. ld [%o5], %g0
  360. WRITE_PAUSE
  361. or %l0, PSR_PIL, %l4
  362. wr %l4, 0x0, %psr
  363. WRITE_PAUSE
  364. wr %l4, PSR_ET, %psr
  365. WRITE_PAUSE
  366. cmp %l7, 13
  367. bne 2f
  368.  nop
  369. call C_LABEL(smp_reschedule_irq)
  370.  add %o7, 8, %o7
  371. 2:
  372. call C_LABEL(smp_stop_cpu_irq)
  373.  nop
  374. RESTORE_ALL
  376. .align 4
  377. .globl linux_trap_ipi15_sun4m
  378. linux_trap_ipi15_sun4m:
  379. SAVE_ALL
  380. sethi %hi(0x80000000), %o2
  381. GET_PROCESSOR_MID(o0, o1)
  382. set C_LABEL(sun4m_interrupts), %l5
  383. ld [%l5], %o5
  384. sll %o0, 12, %o0
  385. add %o5, %o0, %o5
  386. ld [%o5], %o3
  387. andcc %o3, %o2, %g0
  388. be 1f ! Must be an NMI async memory error
  389.  st %o2, [%o5 + 4]
  390. WRITE_PAUSE
  391. ld [%o5], %g0
  392. WRITE_PAUSE
  393. or %l0, PSR_PIL, %l4
  394. wr %l4, 0x0, %psr
  395. WRITE_PAUSE
  396. wr %l4, PSR_ET, %psr
  397. WRITE_PAUSE
  398. call C_LABEL(smp4m_cross_call_irq)
  399.  nop
  400. b ret_trap_lockless_ipi
  401.  clr %l6
  402. 1:
  403. /* NMI async memory error handling. */
  404. sethi %hi(0x80000000), %l4
  405. sethi %hi(0x4000), %o3
  406. sub %o5, %o0, %o5
  407. add %o5, %o3, %l5
  408. st %l4, [%l5 + 0xc]
  409. WRITE_PAUSE
  410. ld [%l5], %g0
  411. WRITE_PAUSE
  412. or %l0, PSR_PIL, %l4
  413. wr %l4, 0x0, %psr
  414. WRITE_PAUSE
  415. wr %l4, PSR_ET, %psr
  416. WRITE_PAUSE
  417. call C_LABEL(sun4m_nmi)
  418.  nop
  419. st %l4, [%l5 + 0x8]
  420. WRITE_PAUSE
  421. ld [%l5], %g0
  422. WRITE_PAUSE
  423. RESTORE_ALL
  425. .globl smp4d_ticker
  426. /* SMP per-cpu ticker interrupts are handled specially. */
  427. smp4d_ticker:
  428. SAVE_ALL
  429. or %l0, PSR_PIL, %g2
  430. sethi %hi(CC_ICLR), %o0
  431. sethi %hi(1 << 14), %o1
  432. or %o0, %lo(CC_ICLR), %o0
  433. stha %o1, [%o0] ASI_M_MXCC /* Clear PIL 14 in MXCC's ICLR */
  434. wr %g2, 0x0, %psr
  435. WRITE_PAUSE
  436. wr %g2, PSR_ET, %psr
  437. WRITE_PAUSE
  438. call C_LABEL(smp4d_percpu_timer_interrupt)
  439.  add %sp, REGWIN_SZ, %o0
  440. wr %l0, PSR_ET, %psr
  441. WRITE_PAUSE
  442. RESTORE_ALL
  444. .align 4
  445. .globl linux_trap_ipi15_sun4d
  446. linux_trap_ipi15_sun4d:
  447. SAVE_ALL
  448. sethi %hi(CC_BASE), %o4
  449. sethi %hi(MXCC_ERR_ME|MXCC_ERR_PEW|MXCC_ERR_ASE|MXCC_ERR_PEE), %o2
  450. or %o4, (CC_EREG - CC_BASE), %o0
  451. ldda [%o0] ASI_M_MXCC, %o0
  452. andcc %o0, %o2, %g0
  453. bne 1f
  454.  sethi %hi(BB_STAT2), %o2
  455. lduba [%o2] ASI_M_CTL, %o2
  456. andcc %o2, BB_STAT2_MASK, %g0
  457. bne 2f
  458.  or %o4, (CC_ICLR - CC_BASE), %o0
  459. sethi %hi(1 << 15), %o1
  460. stha %o1, [%o0] ASI_M_MXCC /* Clear PIL 15 in MXCC's ICLR */
  461. or %l0, PSR_PIL, %l4
  462. wr %l4, 0x0, %psr
  463. WRITE_PAUSE
  464. wr %l4, PSR_ET, %psr
  465. WRITE_PAUSE
  466. call C_LABEL(smp4d_cross_call_irq)
  467.  nop
  468. b ret_trap_lockless_ipi
  469.  clr %l6
  471. 1: /* MXCC error */
  472. 2: /* BB error */
  473. /* Disable PIL 15 */
  474. set CC_IMSK, %l4
  475. lduha [%l4] ASI_M_MXCC, %l5
  476. sethi %hi(1 << 15), %l7
  477. or %l5, %l7, %l5
  478. stha %l5, [%l4] ASI_M_MXCC
  479. /* FIXME */
  480. 1: b,a 1b
  482. #endif /* CONFIG_SMP */
  484. /* This routine handles illegal instructions and privileged
  485.  * instruction attempts from user code.
  486.  */
  487. .align 4
  488. .globl bad_instruction
  489. bad_instruction:
  490. sethi %hi(0xc1f80000), %l4
  491. ld [%l1], %l5
  492. sethi %hi(0x81d80000), %l7
  493. and %l5, %l4, %l5
  494. cmp %l5, %l7
  495. be 1f
  496. SAVE_ALL
  498. wr %l0, PSR_ET, %psr ! re-enable traps
  499. WRITE_PAUSE
  501. add %sp, REGWIN_SZ, %o0
  502. mov %l1, %o1
  503. mov %l2, %o2
  504. call C_LABEL(do_illegal_instruction)
  505.  mov %l0, %o3
  507. RESTORE_ALL
  509. 1: /* unimplemented flush - just skip */
  510. jmpl %l2, %g0
  511.  rett %l2 + 4
  513. .align 4
  514. .globl priv_instruction
  515. priv_instruction:
  516. SAVE_ALL
  518. wr %l0, PSR_ET, %psr
  519. WRITE_PAUSE
  521. add %sp, REGWIN_SZ, %o0
  522. mov %l1, %o1
  523. mov %l2, %o2
  524. call C_LABEL(do_priv_instruction)
  525.  mov %l0, %o3
  527. RESTORE_ALL
  529. /* This routine handles unaligned data accesses. */
  530. .align 4
  531. .globl mna_handler
  532. mna_handler:
  533. andcc %l0, PSR_PS, %g0
  534. be mna_fromuser
  535.  nop
  537. SAVE_ALL
  539. wr %l0, PSR_ET, %psr
  540. WRITE_PAUSE
  542. ld [%l1], %o1
  543. call C_LABEL(kernel_unaligned_trap)
  544.  add %sp, REGWIN_SZ, %o0
  546. RESTORE_ALL
  548. mna_fromuser:
  549. SAVE_ALL
  551. wr %l0, PSR_ET, %psr ! re-enable traps
  552. WRITE_PAUSE
  554. ld [%l1], %o1
  555. call C_LABEL(user_unaligned_trap)
  556.  add %sp, REGWIN_SZ, %o0
  558. RESTORE_ALL
  560. /* This routine handles floating point disabled traps. */
  561. .align 4
  562. .globl fpd_trap_handler
  563. fpd_trap_handler:
  564. SAVE_ALL
  566. wr %l0, PSR_ET, %psr ! re-enable traps
  567. WRITE_PAUSE
  569. add %sp, REGWIN_SZ, %o0
  570. mov %l1, %o1
  571. mov %l2, %o2
  572. call C_LABEL(do_fpd_trap)
  573.  mov %l0, %o3
  575. RESTORE_ALL
  577. /* This routine handles Floating Point Exceptions. */
  578. .align 4
  579. .globl fpe_trap_handler
  580. fpe_trap_handler:
  581. set fpsave_magic, %l5
  582. cmp %l1, %l5
  583. be 1f
  584.  sethi %hi(C_LABEL(fpsave)), %l5
  585. or %l5, %lo(C_LABEL(fpsave)), %l5
  586. cmp %l1, %l5
  587. bne 2f
  588.  sethi %hi(fpsave_catch2), %l5
  589. or %l5, %lo(fpsave_catch2), %l5
  590. wr %l0, 0x0, %psr
  591. WRITE_PAUSE
  592. jmp %l5
  593.  rett %l5 + 4
  594. 1:
  595. sethi %hi(fpsave_catch), %l5
  596. or %l5, %lo(fpsave_catch), %l5
  597. wr %l0, 0x0, %psr
  598. WRITE_PAUSE
  599. jmp %l5
  600.  rett %l5 + 4
  602. 2:
  603. SAVE_ALL
  605. wr %l0, PSR_ET, %psr ! re-enable traps
  606. WRITE_PAUSE
  608. add %sp, REGWIN_SZ, %o0
  609. mov %l1, %o1
  610. mov %l2, %o2
  611. call C_LABEL(do_fpe_trap)
  612.  mov %l0, %o3
  614. RESTORE_ALL
  616. /* This routine handles Tag Overflow Exceptions. */
  617. .align 4
  618. .globl do_tag_overflow
  619. do_tag_overflow:
  620. SAVE_ALL
  622. wr %l0, PSR_ET, %psr ! re-enable traps
  623. WRITE_PAUSE
  625. add %sp, REGWIN_SZ, %o0
  626. mov %l1, %o1
  627. mov %l2, %o2
  628. call C_LABEL(handle_tag_overflow)
  629.  mov %l0, %o3
  631. RESTORE_ALL
  633. /* This routine handles Watchpoint Exceptions. */
  634. .align 4
  635. .globl do_watchpoint
  636. do_watchpoint:
  637. SAVE_ALL
  639. wr %l0, PSR_ET, %psr ! re-enable traps
  640. WRITE_PAUSE
  642. add %sp, REGWIN_SZ, %o0
  643. mov %l1, %o1
  644. mov %l2, %o2
  645. call C_LABEL(handle_watchpoint)
  646.  mov %l0, %o3
  648. RESTORE_ALL
  650. /* This routine handles Register Access Exceptions. */
  651. .align 4
  652. .globl do_reg_access
  653. do_reg_access:
  654. SAVE_ALL
  656. wr %l0, PSR_ET, %psr ! re-enable traps
  657. WRITE_PAUSE
  659. add %sp, REGWIN_SZ, %o0
  660. mov %l1, %o1
  661. mov %l2, %o2
  662. call C_LABEL(handle_reg_access)
  663.  mov %l0, %o3
  665. RESTORE_ALL
  667. /* This routine handles Co-Processor Disabled Exceptions. */
  668. .align 4
  669. .globl do_cp_disabled
  670. do_cp_disabled:
  671. SAVE_ALL
  673. wr %l0, PSR_ET, %psr ! re-enable traps
  674. WRITE_PAUSE
  676. add %sp, REGWIN_SZ, %o0
  677. mov %l1, %o1
  678. mov %l2, %o2
  679. call C_LABEL(handle_cp_disabled)
  680.  mov %l0, %o3
  682. RESTORE_ALL
  684. /* This routine handles Co-Processor Exceptions. */
  685. .align 4
  686. .globl do_cp_exception
  687. do_cp_exception:
  688. SAVE_ALL
  690. wr %l0, PSR_ET, %psr ! re-enable traps
  691. WRITE_PAUSE
  693. add %sp, REGWIN_SZ, %o0
  694. mov %l1, %o1
  695. mov %l2, %o2
  696. call C_LABEL(handle_cp_exception)
  697.  mov %l0, %o3
  699. RESTORE_ALL
  701. /* This routine handles Hardware Divide By Zero Exceptions. */
  702. .align 4
  703. .globl do_hw_divzero
  704. do_hw_divzero:
  705. SAVE_ALL
  707. wr %l0, PSR_ET, %psr ! re-enable traps
  708. WRITE_PAUSE
  710. add %sp, REGWIN_SZ, %o0
  711. mov %l1, %o1
  712. mov %l2, %o2
  713. call C_LABEL(handle_hw_divzero)
  714.  mov %l0, %o3
  716. RESTORE_ALL
  718. .align 4
  719. .globl do_flush_windows
  720. do_flush_windows:
  721. SAVE_ALL
  723. wr %l0, PSR_ET, %psr
  724. WRITE_PAUSE
  726. andcc %l0, PSR_PS, %g0
  727. bne dfw_kernel
  728.  nop
  730. call C_LABEL(flush_user_windows)
  731.  nop
  733. /* Advance over the trap instruction. */
  734. ld [%sp + REGWIN_SZ + PT_NPC], %l1
  735. add %l1, 0x4, %l2
  736. st %l1, [%sp + REGWIN_SZ + PT_PC]
  737. st %l2, [%sp + REGWIN_SZ + PT_NPC]
  739. RESTORE_ALL
  741. .globl flush_patch_one
  743. /* We get these for debugging routines using __builtin_return_address() */
  744. dfw_kernel:
  745. flush_patch_one:
  746. FLUSH_ALL_KERNEL_WINDOWS
  748. /* Advance over the trap instruction. */
  749. ld [%sp + REGWIN_SZ + PT_NPC], %l1
  750. add %l1, 0x4, %l2
  751. st %l1, [%sp + REGWIN_SZ + PT_PC]
  752. st %l2, [%sp + REGWIN_SZ + PT_NPC]
  754. RESTORE_ALL
  756. /* The getcc software trap.  The user wants the condition codes from
  757.  * the %psr in register %g1.
  758.  */
  760. .align 4
  761. .globl getcc_trap_handler
  762. getcc_trap_handler:
  763. srl %l0, 20, %g1 ! give user
  764. and %g1, 0xf, %g1 ! only ICC bits in %psr
  765. jmp %l2 ! advance over trap instruction
  766. rett %l2 + 0x4 ! like this...
  768. /* The setcc software trap.  The user has condition codes in %g1
  769.  * that it would like placed in the %psr.  Be careful not to flip
  770.  * any unintentional bits!
  771.  */
  773. .align 4
  774. .globl setcc_trap_handler
  775. setcc_trap_handler:
  776. sll %g1, 0x14, %l4
  777. set PSR_ICC, %l5
  778. andn %l0, %l5, %l0 ! clear ICC bits in %psr
  779. and %l4, %l5, %l4 ! clear non-ICC bits in user value
  780. or %l4, %l0, %l4 ! or them in... mix mix mix
  782. wr %l4, 0x0, %psr ! set new %psr
  783. WRITE_PAUSE ! TI scumbags...
  785. jmp %l2 ! advance over trap instruction
  786. rett %l2 + 0x4 ! like this...
  788. .align 4
  789. .globl linux_trap_nmi_sun4c
  790. linux_trap_nmi_sun4c:
  791. SAVE_ALL
  793. /* Ugh, we need to clear the IRQ line.  This is now
  794.  * a very sun4c specific trap handler...
  795.  */
  796. sethi %hi(C_LABEL(interrupt_enable)), %l5
  797. ld [%l5 + %lo(C_LABEL(interrupt_enable))], %l5
  798. ldub [%l5], %l6
  799. andn %l6, INTS_ENAB, %l6
  800. stb %l6, [%l5]
  802. /* Now it is safe to re-enable traps without recursion. */
  803. or %l0, PSR_PIL, %l0
  804. wr %l0, PSR_ET, %psr
  805. WRITE_PAUSE
  807. /* Now call the c-code with the pt_regs frame ptr and the
  808.  * memory error registers as arguments.  The ordering chosen
  809.  * here is due to unlatching semantics.
  810.  */
  811. sethi %hi(AC_SYNC_ERR), %o0
  812. add %o0, 0x4, %o0
  813. lda [%o0] ASI_CONTROL, %o2 ! sync vaddr
  814. sub %o0, 0x4, %o0
  815. lda [%o0] ASI_CONTROL, %o1 ! sync error
  816. add %o0, 0xc, %o0
  817. lda [%o0] ASI_CONTROL, %o4 ! async vaddr
  818. sub %o0, 0x4, %o0
  819. lda [%o0] ASI_CONTROL, %o3 ! async error
  820. call C_LABEL(sparc_lvl15_nmi)
  821.  add %sp, REGWIN_SZ, %o0
  823. RESTORE_ALL
  825. .align 4
  826. .globl C_LABEL(invalid_segment_patch1_ff)
  827. .globl C_LABEL(invalid_segment_patch2_ff)
  828. C_LABEL(invalid_segment_patch1_ff): cmp %l4, 0xff
  829. C_LABEL(invalid_segment_patch2_ff): mov 0xff, %l3
  831. .align 4
  832. .globl C_LABEL(invalid_segment_patch1_1ff)
  833. .globl C_LABEL(invalid_segment_patch2_1ff)
  834. C_LABEL(invalid_segment_patch1_1ff): cmp %l4, 0x1ff
  835. C_LABEL(invalid_segment_patch2_1ff): mov 0x1ff, %l3
  837. .align 4
  838. .globl C_LABEL(num_context_patch1_16), C_LABEL(num_context_patch2_16)
  839. C_LABEL(num_context_patch1_16): mov 0x10, %l7
  840. C_LABEL(num_context_patch2_16): mov 0x10, %l7
  842. .align 4
  843. .globl C_LABEL(vac_linesize_patch_32)
  844. C_LABEL(vac_linesize_patch_32): subcc %l7, 32, %l7
  846. .align 4
  847. .globl C_LABEL(vac_hwflush_patch1_on), C_LABEL(vac_hwflush_patch2_on)
  849. /*
  850.  * Ugly, but we cant use hardware flushing on the sun4 and we'd require
  851.  * two instructions (Anton)
  852.  */
  853. #ifdef CONFIG_SUN4
  854. C_LABEL(vac_hwflush_patch1_on): nop
  855. #else
  856. C_LABEL(vac_hwflush_patch1_on): addcc %l7, -PAGE_SIZE, %l7
  857. #endif
  859. C_LABEL(vac_hwflush_patch2_on): sta %g0, [%l3 + %l7] ASI_HWFLUSHSEG
  861. .globl C_LABEL(invalid_segment_patch1), C_LABEL(invalid_segment_patch2)
  862. .globl C_LABEL(num_context_patch1), C_LABEL(num_context_patch2)
  863. .globl C_LABEL(vac_linesize_patch), C_LABEL(vac_hwflush_patch1)
  864. .globl C_LABEL(vac_hwflush_patch2)
  866. .align 4
  867. .globl sun4c_fault
  869. ! %l0 = %psr
  870. ! %l1 = %pc
  871. ! %l2 = %npc
  872. ! %l3 = %wim
  873. ! %l7 = 1 for textfault
  874. ! We want error in %l5, vaddr in %l6
  875. sun4c_fault:
  876. #ifdef CONFIG_SUN4
  877. sethi %hi(C_LABEL(sun4c_memerr_reg)), %l4
  878. ld [%l4+%lo(C_LABEL(sun4c_memerr_reg))], %l4  ! memerr ctrl reg addr
  879. ld [%l4], %l6 ! memerr ctrl reg
  880. ld [%l4 + 4], %l5 ! memerr vaddr reg
  881. andcc %l6, 0x80, %g0 ! check for error type
  882. st %g0, [%l4 + 4] ! clear the error
  883. be 0f ! normal error
  884.  sethi %hi(AC_BUS_ERROR), %l4 ! bus err reg addr
  886. call C_LABEL(prom_halt) ! something weird happened
  887. ! what exactly did happen?
  888. ! what should we do here?
  890. 0: or %l4, %lo(AC_BUS_ERROR), %l4 ! bus err reg addr
  891. lduba [%l4] ASI_CONTROL, %l6 ! bus err reg
  893. cmp    %l7, 1 ! text fault?
  894. be 1f ! yes
  895.  nop
  897. ld     [%l1], %l4 ! load instruction that caused fault
  898. srl %l4, 21, %l4
  899. andcc %l4, 1, %g0 ! store instruction?
  901. be 1f ! no
  902.  sethi %hi(SUN4C_SYNC_BADWRITE), %l4 ! yep
  903. ! %lo(SUN4C_SYNC_BADWRITE) = 0
  904. or %l4, %l6, %l6 ! set write bit to emulate sun4c
  905. 1:
  906. #else
  907. sethi %hi(AC_SYNC_ERR), %l4
  908. add %l4, 0x4, %l6 ! AC_SYNC_VA in %l6
  909. lda [%l6] ASI_CONTROL, %l5 ! Address
  910. lda [%l4] ASI_CONTROL, %l6 ! Error, retained for a bit
  911. #endif
  913. andn %l5, 0xfff, %l5 ! Encode all info into l7
  914. srl %l6, 14, %l4
  916. and %l4, 2, %l4
  917. or %l5, %l4, %l4
  919. or %l4, %l7, %l7 ! l7 = [addr,write,txtfault]
  921. andcc %l0, PSR_PS, %g0
  922. be sun4c_fault_fromuser
  923.  andcc %l7, 1, %g0 ! Text fault?
  925. be 1f
  926.  sethi %hi(KERNBASE), %l4
  928. mov %l1, %l5 ! PC
  930. 1:
  931. cmp %l5, %l4
  932. blu sun4c_fault_fromuser
  933.  sethi %hi(~((1 << SUN4C_REAL_PGDIR_SHIFT) - 1)), %l4
  935. /* If the kernel references a bum kernel pointer, or a pte which
  936.  * points to a non existant page in ram, we will run this code
  937.  * _forever_ and lock up the machine!!!!! So we must check for
  938.  * this condition, the AC_SYNC_ERR bits are what we must examine.
  939.  * Also a parity error would make this happen as well.  So we just
  940.  * check that we are in fact servicing a tlb miss and not some
  941.  * other type of fault for the kernel.
  942.  */
  943. andcc %l6, 0x80, %g0
  944. be sun4c_fault_fromuser
  945.  and %l5, %l4, %l5
  947. /* Test for NULL pte_t * in vmalloc area. */
  948. sethi   %hi(VMALLOC_START), %l4
  949. cmp     %l5, %l4
  950. blu,a   C_LABEL(invalid_segment_patch1)
  951.  lduXa [%l5] ASI_SEGMAP, %l4
  953. sethi   %hi(C_LABEL(swapper_pg_dir)), %l4
  954. srl     %l5, SUN4C_PGDIR_SHIFT, %l6
  955. or      %l4, %lo(C_LABEL(swapper_pg_dir)), %l4
  956. sll     %l6, 2, %l6
  957. ld      [%l4 + %l6], %l4
  958. #ifdef CONFIG_SUN4
  959. sethi %hi(PAGE_MASK), %l6
  960. andcc %l4, %l6, %g0
  961. #else
  962. andcc   %l4, PAGE_MASK, %g0
  963. #endif
  964. be      sun4c_fault_fromuser
  965.  lduXa  [%l5] ASI_SEGMAP, %l4
  967. C_LABEL(invalid_segment_patch1):
  968. cmp %l4, 0x7f
  969. bne 1f
  970.  sethi %hi(C_LABEL(sun4c_kfree_ring)), %l4
  971. or %l4, %lo(C_LABEL(sun4c_kfree_ring)), %l4
  972. ld [%l4 + 0x18], %l3
  973. deccc %l3 ! do we have a free entry?
  974. bcs,a 2f ! no, unmap one.
  975.  sethi %hi(C_LABEL(sun4c_kernel_ring)), %l4
  977. st %l3, [%l4 + 0x18] ! sun4c_kfree_ring.num_entries--
  979. ld [%l4 + 0x00], %l6 ! entry = sun4c_kfree_ring.ringhd.next
  980. st %l5, [%l6 + 0x08] ! entry->vaddr = address
  982. ld [%l6 + 0x00], %l3 ! next = entry->next
  983. ld [%l6 + 0x04], %l7 ! entry->prev
  985. st %l7, [%l3 + 0x04] ! next->prev = entry->prev
  986. st %l3, [%l7 + 0x00] ! entry->prev->next = next
  988. sethi %hi(C_LABEL(sun4c_kernel_ring)), %l4
  989. or %l4, %lo(C_LABEL(sun4c_kernel_ring)), %l4
  990. ! head = &sun4c_kernel_ring.ringhd
  992. ld [%l4 + 0x00], %l7 ! head->next
  994. st %l4, [%l6 + 0x04] ! entry->prev = head
  995. st %l7, [%l6 + 0x00] ! entry->next = head->next
  996. st %l6, [%l7 + 0x04] ! head->next->prev = entry
  998. st %l6, [%l4 + 0x00] ! head->next = entry
  1000. ld [%l4 + 0x18], %l3
  1001. inc %l3 ! sun4c_kernel_ring.num_entries++
  1002. st %l3, [%l4 + 0x18]
  1003. b 4f
  1004.  ld [%l6 + 0x08], %l5
  1006. 2:
  1007. or %l4, %lo(C_LABEL(sun4c_kernel_ring)), %l4
  1008. ! head = &sun4c_kernel_ring.ringhd
  1010. ld [%l4 + 0x04], %l6 ! entry = head->prev
  1012. ld [%l6 + 0x08], %l3 ! tmp = entry->vaddr
  1014. ! Flush segment from the cache.
  1015. #ifdef CONFIG_SUN4
  1016. sethi %hi((128 * 1024)), %l7
  1017. #else
  1018. sethi %hi((64 * 1024)), %l7
  1019. #endif
  1020. 9:
  1021. C_LABEL(vac_hwflush_patch1):
  1022. C_LABEL(vac_linesize_patch):
  1023. subcc %l7, 16, %l7
  1024. bne 9b
  1025. C_LABEL(vac_hwflush_patch2):
  1026.  sta %g0, [%l3 + %l7] ASI_FLUSHSEG
  1028. st %l5, [%l6 + 0x08] ! entry->vaddr = address
  1030. ld [%l6 + 0x00], %l5 ! next = entry->next
  1031. ld [%l6 + 0x04], %l7 ! entry->prev
  1033. st %l7, [%l5 + 0x04] ! next->prev = entry->prev
  1034. st %l5, [%l7 + 0x00] ! entry->prev->next = next
  1035. st %l4, [%l6 + 0x04] ! entry->prev = head
  1037. ld [%l4 + 0x00], %l7 ! head->next
  1039. st %l7, [%l6 + 0x00] ! entry->next = head->next
  1040. st %l6, [%l7 + 0x04] ! head->next->prev = entry
  1041. st %l6, [%l4 + 0x00] ! head->next = entry
  1043. mov %l3, %l5 ! address = tmp
  1045. 4:
  1046. C_LABEL(num_context_patch1):
  1047. mov 0x08, %l7
  1049. ld [%l6 + 0x08], %l4
  1050. ldub [%l6 + 0x0c], %l3
  1051. or %l4, %l3, %l4 ! encode new vaddr/pseg into l4
  1053. sethi %hi(AC_CONTEXT), %l3
  1054. lduba [%l3] ASI_CONTROL, %l6
  1056. /* Invalidate old mapping, instantiate new mapping,
  1057.  * for each context.  Registers l6/l7 are live across
  1058.  * this loop.
  1059.  */
  1060. 3: deccc %l7
  1061. sethi %hi(AC_CONTEXT), %l3
  1062. stba %l7, [%l3] ASI_CONTROL
  1063. C_LABEL(invalid_segment_patch2):
  1064. mov 0x7f, %l3
  1065. stXa %l3, [%l5] ASI_SEGMAP
  1066. andn %l4, 0x1ff, %l3
  1067. bne 3b
  1068.  stXa %l4, [%l3] ASI_SEGMAP
  1070. sethi %hi(AC_CONTEXT), %l3
  1071. stba %l6, [%l3] ASI_CONTROL
  1073. andn %l4, 0x1ff, %l5
  1075. 1:
  1076. sethi %hi(VMALLOC_START), %l4
  1077. cmp %l5, %l4
  1079. bgeu 1f
  1080.  mov 1 << (SUN4C_REAL_PGDIR_SHIFT - PAGE_SHIFT), %l7
  1082. sethi %hi(KERNBASE), %l6
  1084. sub %l5, %l6, %l4
  1085. srl %l4, PAGE_SHIFT, %l4
  1086. sethi %hi((SUN4C_PAGE_KERNEL & 0xf4000000)), %l3
  1087. or %l3, %l4, %l3
  1089. sethi %hi(PAGE_SIZE), %l4
  1091. 2:
  1092. sta %l3, [%l5] ASI_PTE
  1093. deccc %l7
  1094. inc %l3
  1095. bne 2b
  1096.  add %l5, %l4, %l5
  1098. b 7f
  1099.  sethi %hi(C_LABEL(sun4c_kernel_faults)), %l4
  1101. 1:
  1102. srl %l5, SUN4C_PGDIR_SHIFT, %l3
  1103. sethi %hi(C_LABEL(swapper_pg_dir)), %l4
  1104. or %l4, %lo(C_LABEL(swapper_pg_dir)), %l4
  1105. sll %l3, 2, %l3
  1106. ld [%l4 + %l3], %l4
  1107. #ifndef CONFIG_SUN4
  1108. and %l4, PAGE_MASK, %l4
  1109. #else
  1110. sethi %hi(PAGE_MASK), %l6
  1111. and %l4, %l6, %l4
  1112. #endif
  1114. srl %l5, (PAGE_SHIFT - 2), %l6
  1115. and %l6, ((SUN4C_PTRS_PER_PTE - 1) << 2), %l6
  1116. add %l6, %l4, %l6
  1118. sethi %hi(PAGE_SIZE), %l4
  1120. 2:
  1121. ld [%l6], %l3
  1122. deccc %l7
  1123. sta %l3, [%l5] ASI_PTE
  1124. add %l6, 0x4, %l6
  1125. bne 2b
  1126.  add %l5, %l4, %l5
  1128. sethi %hi(C_LABEL(sun4c_kernel_faults)), %l4
  1129. 7:
  1130. ld [%l4 + %lo(C_LABEL(sun4c_kernel_faults))], %l3
  1131. inc %l3
  1132. st %l3, [%l4 + %lo(C_LABEL(sun4c_kernel_faults))]
  1134. /* Restore condition codes */
  1135. wr %l0, 0x0, %psr
  1136. WRITE_PAUSE
  1137. jmp %l1
  1138.  rett %l2
  1140. sun4c_fault_fromuser:
  1141. SAVE_ALL
  1142.  nop
  1144. mov %l7, %o1 ! Decode the info from %l7
  1145. mov %l7, %o2
  1146. and %o1, 1, %o1 ! arg2 = text_faultp
  1147. mov %l7, %o3
  1148. and %o2, 2, %o2 ! arg3 = writep
  1149. andn %o3, 0xfff, %o3 ! arg4 = faulting address
  1151. wr %l0, PSR_ET, %psr
  1152. WRITE_PAUSE
  1154. call C_LABEL(do_sun4c_fault)
  1155.  add %sp, REGWIN_SZ, %o0 ! arg1 = pt_regs ptr
  1157. RESTORE_ALL
  1159. .align 4
  1160. .globl C_LABEL(srmmu_fault)
  1161. C_LABEL(srmmu_fault):
  1162. mov 0x400, %l5
  1163. mov 0x300, %l4
  1165. lda [%l5] ASI_M_MMUREGS, %l6 ! read sfar first
  1166. lda [%l4] ASI_M_MMUREGS, %l5 ! read sfsr last
  1168. andn %l6, 0xfff, %l6
  1169. srl %l5, 6, %l5 ! and encode all info into l7
  1171. and %l5, 2, %l5
  1172. or %l5, %l6, %l6
  1174. or %l6, %l7, %l7 ! l7 = [addr,write,txtfault]
  1176. SAVE_ALL
  1178. mov %l7, %o1
  1179. mov %l7, %o2
  1180. and %o1, 1, %o1 ! arg2 = text_faultp
  1181. mov %l7, %o3
  1182. and %o2, 2, %o2 ! arg3 = writep
  1183. andn %o3, 0xfff, %o3 ! arg4 = faulting address
  1185. wr %l0, PSR_ET, %psr
  1186. WRITE_PAUSE
  1188. call C_LABEL(do_sparc_fault)
  1189.  add %sp, REGWIN_SZ, %o0 ! arg1 = pt_regs ptr
  1191. RESTORE_ALL
  1193. #ifdef CONFIG_SUNOS_EMUL
  1194. /* SunOS uses syscall zero as the 'indirect syscall' it looks
  1195.  * like indir_syscall(scall_num, arg0, arg1, arg2...);  etc.
  1196.  * This is complete brain damage.
  1197.  */
  1198. .globl C_LABEL(sunos_indir)
  1199. C_LABEL(sunos_indir):
  1200. mov %o7, %l4
  1201. cmp %o0, NR_SYSCALLS
  1202. blu,a 1f
  1203.  sll %o0, 0x2, %o0
  1205. sethi %hi(C_LABEL(sunos_nosys)), %l6
  1206. b 2f
  1207.  or %l6, %lo(C_LABEL(sunos_nosys)), %l6
  1209. 1:
  1210. set C_LABEL(sunos_sys_table), %l7
  1211. ld [%l7 + %o0], %l6
  1213. 2:
  1214. mov %o1, %o0
  1215. mov %o2, %o1
  1216. mov %o3, %o2
  1217. mov %o4, %o3
  1218. mov %o5, %o4
  1219. call %l6
  1220.  mov %l4, %o7
  1221. #endif
  1223. .align 4
  1224. .globl C_LABEL(sys_nis_syscall)
  1225. C_LABEL(sys_nis_syscall):
  1226. mov %o7, %l5
  1227. add %sp, REGWIN_SZ, %o0 ! pt_regs *regs arg
  1228. call C_LABEL(c_sys_nis_syscall)
  1229.  mov %l5, %o7
  1231. .align 4
  1232. .globl C_LABEL(sys_ptrace)
  1233. C_LABEL(sys_ptrace):
  1234. call C_LABEL(do_ptrace)
  1235.  add %sp, REGWIN_SZ, %o0
  1237. ld [%curptr + AOFF_task_ptrace], %l5
  1238. andcc %l5, 0x02, %g0
  1239. be 1f
  1240.  nop
  1242. call C_LABEL(syscall_trace)
  1243.  nop
  1245. 1:
  1246. RESTORE_ALL
  1248. .align 4
  1249. .globl C_LABEL(sys_execve)
  1250. C_LABEL(sys_execve):
  1251. mov %o7, %l5
  1252. add %sp, REGWIN_SZ, %o0 ! pt_regs *regs arg
  1253. call C_LABEL(sparc_execve)
  1254.  mov %l5, %o7
  1256. .align 4
  1257. .globl C_LABEL(sys_pipe)
  1258. C_LABEL(sys_pipe):
  1259. mov %o7, %l5
  1260. add %sp, REGWIN_SZ, %o0 ! pt_regs *regs arg
  1261. call C_LABEL(sparc_pipe)
  1262.  mov %l5, %o7
  1264. .align 4
  1265. .globl C_LABEL(sys_sigaltstack)
  1266. C_LABEL(sys_sigaltstack):
  1267. mov %o7, %l5
  1268. mov %fp, %o2
  1269. call C_LABEL(do_sigaltstack)
  1270.  mov %l5, %o7
  1272. .align 4
  1273. .globl C_LABEL(sys_sigstack)
  1274. C_LABEL(sys_sigstack):
  1275. mov %o7, %l5
  1276. mov %fp, %o2
  1277. call C_LABEL(do_sys_sigstack)
  1278.  mov %l5, %o7
  1280. .align 4
  1281. .globl C_LABEL(sys_sigpause)
  1282. C_LABEL(sys_sigpause):
  1283. /* Note: %o0 already has correct value... */
  1284. call C_LABEL(do_sigpause)
  1285.  add %sp, REGWIN_SZ, %o1
  1287. ld [%curptr + AOFF_task_ptrace], %l5
  1288. andcc %l5, 0x02, %g0
  1289. be 1f
  1290.  nop
  1292. call C_LABEL(syscall_trace)
  1293.  nop
  1295. 1:
  1296. /* We are returning to a signal handler. */
  1297. RESTORE_ALL
  1299. .align 4
  1300. .globl C_LABEL(sys_sigsuspend)
  1301. C_LABEL(sys_sigsuspend):
  1302. call C_LABEL(do_sigsuspend)
  1303.  add %sp, REGWIN_SZ, %o0
  1305. ld [%curptr + AOFF_task_ptrace], %l5
  1306. andcc %l5, 0x02, %g0
  1307. be 1f
  1308.  nop
  1310. call C_LABEL(syscall_trace)
  1311.  nop
  1313. 1:
  1314. /* We are returning to a signal handler. */
  1315. RESTORE_ALL
  1317. .align 4
  1318. .globl C_LABEL(sys_rt_sigsuspend)
  1319. C_LABEL(sys_rt_sigsuspend):
  1320. /* Note: %o0, %o1 already have correct value... */
  1321. call C_LABEL(do_rt_sigsuspend)
  1322.  add %sp, REGWIN_SZ, %o2
  1324. ld [%curptr + AOFF_task_ptrace], %l5
  1325. andcc %l5, 0x02, %g0
  1326. be 1f
  1327.  nop
  1329. call C_LABEL(syscall_trace)
  1330.  nop
  1332. 1:
  1333. /* We are returning to a signal handler. */
  1334. RESTORE_ALL
  1336. .align 4
  1337. .globl C_LABEL(sys_sigreturn)
  1338. C_LABEL(sys_sigreturn):
  1339. call C_LABEL(do_sigreturn)
  1340.  add %sp, REGWIN_SZ, %o0
  1342. ld [%curptr + AOFF_task_ptrace], %l5
  1343. andcc %l5, 0x02, %g0
  1344. be 1f
  1345.  nop
  1347. call C_LABEL(syscall_trace)
  1348.  nop
  1350. 1:
  1351. /* We don't want to muck with user registers like a
  1352.  * normal syscall, just return.
  1353.  */
  1354. RESTORE_ALL
  1356. .align 4
  1357. .globl C_LABEL(sys_rt_sigreturn)
  1358. C_LABEL(sys_rt_sigreturn):
  1359. call C_LABEL(do_rt_sigreturn)
  1360.  add %sp, REGWIN_SZ, %o0
  1362. ld [%curptr + AOFF_task_ptrace], %l5
  1363. andcc %l5, 0x02, %g0
  1364. be 1f
  1365.  nop
  1367. call C_LABEL(syscall_trace)
  1368.  nop
  1370. 1:
  1371. /* We are returning to a signal handler. */
  1372. RESTORE_ALL
  1374. /* Now that we have a real sys_clone, sys_fork() is
  1375.  * implemented in terms of it.  Our _real_ implementation
  1376.  * of SunOS vfork() will use sys_vfork().
  1377.  *
  1378.  * XXX These three should be consolidated into mostly shared
  1379.  * XXX code just like on sparc64... -DaveM
  1380.  */
  1381. .align 4
  1382. .globl C_LABEL(sys_fork), flush_patch_two
  1383. C_LABEL(sys_fork):
  1384. mov %o7, %l5
  1385. flush_patch_two:
  1386. FLUSH_ALL_KERNEL_WINDOWS;
  1387. rd %psr, %g4
  1388. WRITE_PAUSE
  1389. mov SIGCHLD, %o0 ! arg0: clone flags
  1390. rd %wim, %g5
  1391. WRITE_PAUSE
  1392. mov %fp, %o1 ! arg1: usp
  1393. std %g4, [%curptr + AOFF_task_thread + AOFF_thread_fork_kpsr]
  1394. add %sp, REGWIN_SZ, %o2 ! arg2: pt_regs ptr
  1395. mov 0, %o3
  1396. call C_LABEL(do_fork)
  1397.  mov %l5, %o7
  1399. /* Whee, kernel threads! */
  1400. .globl C_LABEL(sys_clone), flush_patch_three
  1401. C_LABEL(sys_clone):
  1402. mov %o7, %l5
  1403. flush_patch_three:
  1404. FLUSH_ALL_KERNEL_WINDOWS;
  1405. rd %psr, %g4
  1406. WRITE_PAUSE
  1408. /* arg0,1: flags,usp  -- loaded already */
  1409. cmp %o1, 0x0 ! Is new_usp NULL?
  1410. rd %wim, %g5
  1411. WRITE_PAUSE
  1412. be,a 1f
  1413.  mov %fp, %o1 ! yes, use callers usp
  1414. andn %o1, 7, %o1 ! no, align to 8 bytes
  1415. 1:
  1416. std %g4, [%curptr + AOFF_task_thread + AOFF_thread_fork_kpsr]
  1417. add %sp, REGWIN_SZ, %o2 ! arg2: pt_regs ptr
  1418. mov 0, %o3
  1419. call C_LABEL(do_fork)
  1420.  mov %l5, %o7
  1422. /* Whee, real vfork! */
  1423. .globl C_LABEL(sys_vfork), flush_patch_four
  1424. C_LABEL(sys_vfork):
  1425. flush_patch_four:
  1426. FLUSH_ALL_KERNEL_WINDOWS;
  1427. rd %psr, %g4
  1428. WRITE_PAUSE
  1429. rd %wim, %g5
  1430. WRITE_PAUSE
  1431. std %g4, [%curptr + AOFF_task_thread + AOFF_thread_fork_kpsr]
  1432. sethi %hi(0x4000 | 0x0100 | SIGCHLD), %o0
  1433. mov %fp, %o1
  1434. or %o0, %lo(0x4000 | 0x0100 | SIGCHLD), %o0
  1435. sethi %hi(C_LABEL(do_fork)), %l1
  1436. mov 0, %o3
  1437. jmpl %l1 + %lo(C_LABEL(do_fork)), %g0
  1438.  add %sp, REGWIN_SZ, %o2
  1440.         .align  4
  1441. linux_sparc_ni_syscall:
  1442. sethi   %hi(C_LABEL(sys_ni_syscall)), %l7
  1443. b       syscall_is_too_hard
  1444.  or     %l7, %lo(C_LABEL(sys_ni_syscall)), %l7
  1446. linux_fast_syscall:
  1447. andn %l7, 3, %l7
  1448. mov %i0, %o0
  1449. mov %i1, %o1
  1450. mov  %i2, %o2
  1451. jmpl %l7 + %g0, %g0
  1452.  mov %i3, %o3
  1454. linux_syscall_trace:
  1455. call C_LABEL(syscall_trace)
  1456.  nop
  1457. mov %i0, %o0
  1458. mov %i1, %o1
  1459. mov %i2, %o2
  1460. mov %i3, %o3
  1461. b 2f
  1462.  mov %i4, %o4
  1464. .globl C_LABEL(ret_from_fork)
  1465. C_LABEL(ret_from_fork):
  1466. call schedule_tail
  1467.  mov %g3, %o0
  1468. b C_LABEL(ret_sys_call)
  1469.  ld [%sp + REGWIN_SZ + PT_I0], %o0
  1471. /* Linux native and SunOS system calls enter here... */
  1472. .align 4
  1473. .globl linux_sparc_syscall
  1474. linux_sparc_syscall:
  1475. /* Direct access to user regs, must faster. */
  1476. cmp %g1, NR_SYSCALLS
  1477. bgeu linux_sparc_ni_syscall
  1478.  sll %g1, 2, %l4
  1479. ld [%l7 + %l4], %l7
  1480. andcc %l7, 1, %g0
  1481. bne linux_fast_syscall
  1482.  /* Just do first insn from SAVE_ALL in the delay slot */
  1484. .globl syscall_is_too_hard
  1485. syscall_is_too_hard:
  1486. SAVE_ALL_HEAD
  1487.  rd %wim, %l3
  1489. wr %l0, PSR_ET, %psr
  1490. mov %i0, %o0
  1491. mov %i1, %o1
  1492. mov %i2, %o2
  1494. ld [%curptr + AOFF_task_ptrace], %l5
  1495. mov %i3, %o3
  1496. andcc %l5, 0x02, %g0
  1497. mov %i4, %o4
  1498. bne linux_syscall_trace
  1499.  mov %i0, %l5
  1500. 2:
  1501. call %l7
  1502.  mov %i5, %o5
  1504. st %o0, [%sp + REGWIN_SZ + PT_I0]
  1506. .globl C_LABEL(ret_sys_call)
  1507. C_LABEL(ret_sys_call):
  1508. ld [%curptr + AOFF_task_ptrace], %l6
  1509. cmp %o0, -ENOIOCTLCMD
  1510. ld [%sp + REGWIN_SZ + PT_PSR], %g3
  1511. set PSR_C, %g2
  1512. bgeu 1f
  1513.  andcc %l6, 0x02, %l6
  1515. /* System call success, clear Carry condition code. */
  1516. andn %g3, %g2, %g3
  1517. clr %l6
  1518. st %g3, [%sp + REGWIN_SZ + PT_PSR]
  1519. bne linux_syscall_trace2
  1520.  ld [%sp + REGWIN_SZ + PT_NPC], %l1 /* pc = npc */
  1521. add %l1, 0x4, %l2 /* npc = npc+4 */
  1522. st %l1, [%sp + REGWIN_SZ + PT_PC]
  1523. b ret_trap_entry
  1524.  st %l2, [%sp + REGWIN_SZ + PT_NPC]
  1525. 1:
  1526. /* System call failure, set Carry condition code.
  1527.  * Also, get abs(errno) to return to the process.
  1528.  */
  1529. sub %g0, %o0, %o0
  1530. or %g3, %g2, %g3
  1531. st %o0, [%sp + REGWIN_SZ + PT_I0]
  1532. mov 1, %l6
  1533. st %g3, [%sp + REGWIN_SZ + PT_PSR]
  1534. bne linux_syscall_trace2
  1535.  ld [%sp + REGWIN_SZ + PT_NPC], %l1 /* pc = npc */
  1536. add %l1, 0x4, %l2 /* npc = npc+4 */
  1537. st %l1, [%sp + REGWIN_SZ + PT_PC]
  1538. b ret_trap_entry
  1539.  st %l2, [%sp + REGWIN_SZ + PT_NPC]
  1541. linux_syscall_trace2:
  1542. call C_LABEL(syscall_trace)
  1543.  add %l1, 0x4, %l2 /* npc = npc+4 */
  1544. st %l1, [%sp + REGWIN_SZ + PT_PC]
  1545. b ret_trap_entry
  1546.  st %l2, [%sp + REGWIN_SZ + PT_NPC]
  1549. /*
  1550.  * Solaris system calls and indirect system calls enter here.
  1551.          *
  1552.  * I have named the solaris indirect syscalls like that because
  1553.  * it seems like Solaris has some fast path syscalls that can
  1554.  * be handled as indirect system calls. - mig
  1555.  */
  1557. linux_syscall_for_solaris:
  1558. sethi %hi(sys_call_table), %l7
  1559. b linux_sparc_syscall
  1560.  or %l7, %lo(sys_call_table), %l7
  1562. .align 4
  1563. .globl solaris_syscall
  1564. solaris_syscall:
  1565. cmp %g1,59
  1566. be linux_syscall_for_solaris
  1567.  cmp %g1,2
  1568. be linux_syscall_for_solaris
  1569.  cmp    %g1,42
  1570. be      linux_syscall_for_solaris
  1571.  cmp %g1,119
  1572. be,a linux_syscall_for_solaris
  1573.  mov 2, %g1
  1574. 1:
  1575. SAVE_ALL_HEAD
  1576.  rd %wim, %l3
  1578. wr %l0, PSR_ET, %psr
  1579. nop
  1580. nop
  1581. mov %i0, %l5
  1583. call C_LABEL(do_solaris_syscall)
  1584.  add %sp, REGWIN_SZ, %o0
  1586. st %o0, [%sp + REGWIN_SZ + PT_I0]
  1587. set PSR_C, %g2
  1588. cmp %o0, -ENOIOCTLCMD
  1589. bgeu 1f
  1590.  ld [%sp + REGWIN_SZ + PT_PSR], %g3
  1592. /* System call success, clear Carry condition code. */
  1593. andn %g3, %g2, %g3
  1594. clr %l6
  1595. b 2f
  1596.  st %g3, [%sp + REGWIN_SZ + PT_PSR]
  1598. 1:
  1599. /* System call failure, set Carry condition code.
  1600.  * Also, get abs(errno) to return to the process.
  1601.  */
  1602. sub %g0, %o0, %o0
  1603. mov 1, %l6
  1604. st %o0, [%sp + REGWIN_SZ + PT_I0]
  1605. or %g3, %g2, %g3
  1606. st %g3, [%sp + REGWIN_SZ + PT_PSR]
  1608. /* Advance the pc and npc over the trap instruction.
  1609.  * If the npc is unaligned (has a 1 in the lower byte), it means
  1610.  * the kernel does not want us to play magic (ie, skipping over
  1611.  * traps).  Mainly when the Solaris code wants to set some PC and
  1612.  * nPC (setcontext).
  1613.  */
  1614. 2:
  1615. ld [%sp + REGWIN_SZ + PT_NPC], %l1 /* pc  = npc   */
  1616. andcc %l1, 1, %g0
  1617. bne 1f
  1618.  add %l1, 0x4, %l2 /* npc = npc+4 */
  1619. st %l1, [%sp + REGWIN_SZ + PT_PC]
  1620. b ret_trap_entry
  1621.  st %l2, [%sp + REGWIN_SZ + PT_NPC]
  1623. /* kernel knows what it is doing, fixup npc and continue */
  1624. 1:
  1625. sub %l1, 1, %l1
  1626.   b ret_trap_entry
  1627.  st %l1, [%sp + REGWIN_SZ + PT_NPC]
  1629. #ifndef CONFIG_SUNOS_EMUL
  1630. .align 4
  1631. .globl sunos_syscall
  1632. sunos_syscall:
  1633. SAVE_ALL_HEAD
  1634.  rd %wim, %l3
  1635. wr %l0, PSR_ET, %psr
  1636. nop
  1637. nop
  1638. mov %i0, %l5
  1639. call C_LABEL(do_sunos_syscall)
  1640.  add %sp, REGWIN_SZ, %o0
  1641. #endif
  1643. /* {net, open}bsd system calls enter here... */
  1644. .align 4
  1645. .globl bsd_syscall
  1646. bsd_syscall:
  1647. /* Direct access to user regs, must faster. */
  1648. cmp %g1, NR_SYSCALLS
  1649. blu,a 1f
  1650.  sll %g1, 2, %l4
  1652. set C_LABEL(sys_ni_syscall), %l7
  1653. b bsd_is_too_hard
  1654.  nop
  1656. 1:
  1657. ld [%l7 + %l4], %l7
  1659. .globl bsd_is_too_hard
  1660. bsd_is_too_hard:
  1661. rd %wim, %l3
  1662. SAVE_ALL
  1664. wr %l0, PSR_ET, %psr
  1665. WRITE_PAUSE
  1667. 2:
  1668. mov %i0, %o0
  1669. mov %i1, %o1
  1670. mov %i2, %o2
  1671. mov %i0, %l5
  1672. mov %i3, %o3
  1673. mov %i4, %o4
  1674. call %l7
  1675.  mov %i5, %o5
  1677. st %o0, [%sp + REGWIN_SZ + PT_I0]
  1678. set PSR_C, %g2
  1679. cmp %o0, -ENOIOCTLCMD
  1680. bgeu 1f
  1681.  ld [%sp + REGWIN_SZ + PT_PSR], %g3
  1683. /* System call success, clear Carry condition code. */
  1684. andn %g3, %g2, %g3
  1685. clr %l6
  1686. b 2f
  1687.  st %g3, [%sp + REGWIN_SZ + PT_PSR]
  1689. 1:
  1690. /* System call failure, set Carry condition code.
  1691.  * Also, get abs(errno) to return to the process.
  1692.  */
  1693. sub %g0, %o0, %o0
  1694. #if 0 /* XXX todo XXX */
  1695. sethi %hi(C_LABEL(bsd_xlatb_rorl), %o3
  1696. or %o3, %lo(C_LABEL(bsd_xlatb_rorl)), %o3
  1697. sll %o0, 2, %o0
  1698. ld [%o3 + %o0], %o0
  1699. #endif
  1700. mov 1, %l6
  1701. st %o0, [%sp + REGWIN_SZ + PT_I0]
  1702. or %g3, %g2, %g3
  1703. st %g3, [%sp + REGWIN_SZ + PT_PSR]
  1705. /* Advance the pc and npc over the trap instruction. */
  1706. 2:
  1707. ld [%sp + REGWIN_SZ + PT_NPC], %l1 /* pc  = npc   */
  1708. add %l1, 0x4, %l2 /* npc = npc+4 */
  1709. st %l1, [%sp + REGWIN_SZ + PT_PC]
  1710. b ret_trap_entry
  1711.  st %l2, [%sp + REGWIN_SZ + PT_NPC]
  1713. /* Saving and restoring the FPU state is best done from lowlevel code.
  1714.  *
  1715.  * void fpsave(unsigned long *fpregs, unsigned long *fsr,
  1716.  *             void *fpqueue, unsigned long *fpqdepth)
  1717.  */
  1719. .globl C_LABEL(fpsave)
  1720. C_LABEL(fpsave):
  1721. st %fsr, [%o1] ! this can trap on us if fpu is in bogon state
  1722. ld [%o1], %g1
  1723. set 0x2000, %g4
  1724. andcc %g1, %g4, %g0
  1725. be 2f
  1726.  mov 0, %g2
  1728. /* We have an fpqueue to save. */
  1729. 1:
  1730. std %fq, [%o2]
  1731. fpsave_magic:
  1732. st %fsr, [%o1]
  1733. ld [%o1], %g3
  1734. andcc %g3, %g4, %g0
  1735. add %g2, 1, %g2
  1736. bne 1b
  1737.  add %o2, 8, %o2
  1739. 2:
  1740. st %g2, [%o3]
  1742. std %f0, [%o0 + 0x00]
  1743. std %f2, [%o0 + 0x08]
  1744. std %f4, [%o0 + 0x10]
  1745. std %f6, [%o0 + 0x18]
  1746. std %f8, [%o0 + 0x20]
  1747. std %f10, [%o0 + 0x28]
  1748. std %f12, [%o0 + 0x30]
  1749. std %f14, [%o0 + 0x38]
  1750. std %f16, [%o0 + 0x40]
  1751. std %f18, [%o0 + 0x48]
  1752. std %f20, [%o0 + 0x50]
  1753. std %f22, [%o0 + 0x58]
  1754. std %f24, [%o0 + 0x60]
  1755. std %f26, [%o0 + 0x68]
  1756. std %f28, [%o0 + 0x70]
  1757. retl
  1758.  std %f30, [%o0 + 0x78]
  1760. /* Thanks for Theo Deraadt and the authors of the Sprite/netbsd/openbsd
  1761.  * code for pointing out this possible deadlock, while we save state
  1762.  * above we could trap on the fsr store so our low level fpu trap
  1763.  * code has to know how to deal with this.
  1764.  */
  1765. fpsave_catch:
  1766. b fpsave_magic + 4
  1767.  st %fsr, [%o1]
  1769. fpsave_catch2:
  1770. b C_LABEL(fpsave) + 4
  1771.  st %fsr, [%o1]
  1773. /* void fpload(unsigned long *fpregs, unsigned long *fsr); */
  1775. .globl C_LABEL(fpload)
  1776. C_LABEL(fpload):
  1777. ldd [%o0 + 0x00], %f0
  1778. ldd [%o0 + 0x08], %f2
  1779. ldd [%o0 + 0x10], %f4
  1780. ldd [%o0 + 0x18], %f6
  1781. ldd [%o0 + 0x20], %f8
  1782. ldd [%o0 + 0x28], %f10
  1783. ldd [%o0 + 0x30], %f12
  1784. ldd [%o0 + 0x38], %f14
  1785. ldd [%o0 + 0x40], %f16
  1786. ldd [%o0 + 0x48], %f18
  1787. ldd [%o0 + 0x50], %f20
  1788. ldd [%o0 + 0x58], %f22
  1789. ldd [%o0 + 0x60], %f24
  1790. ldd [%o0 + 0x68], %f26
  1791. ldd [%o0 + 0x70], %f28
  1792. ldd [%o0 + 0x78], %f30
  1793. ld [%o1], %fsr
  1794. retl
  1795.  nop
  1797. .globl C_LABEL(udelay)
  1798. C_LABEL(udelay):
  1799. save %sp, -REGWIN_SZ, %sp
  1800. mov %i0, %o0
  1801. sethi %hi(0x10c6), %o1
  1802. call .umul
  1803.  or %o1, %lo(0x10c6), %o1
  1804. #ifndef CONFIG_SMP
  1805. sethi %hi(C_LABEL(loops_per_jiffy)), %o3
  1806. call .umul
  1807.  ld [%o3 + %lo(C_LABEL(loops_per_jiffy))], %o1
  1808. #else
  1809. GET_PROCESSOR_OFFSET(o4, o2)
  1810. set C_LABEL(cpu_data), %o3
  1811. call .umul
  1812.  ld [%o3 + %o4], %o1
  1813. #endif
  1814. call .umul
  1815.  mov 100, %o0
  1817. cmp %o0, 0x0
  1818. 1:
  1819. bne 1b
  1820.  subcc %o0, 1, %o0
  1822. ret
  1823. restore
  1825. /* Handle a software breakpoint */
  1826. /* We have to inform parent that child has stopped */
  1827. .align 4
  1828. .globl breakpoint_trap
  1829. breakpoint_trap:
  1830. rd %wim,%l3
  1831. SAVE_ALL
  1832. wr  %l0, PSR_ET, %psr
  1833. WRITE_PAUSE
  1835. st %i0, [%sp + REGWIN_SZ + PT_G0] ! for restarting syscalls
  1836. call C_LABEL(sparc_breakpoint)
  1837.  add %sp, REGWIN_SZ, %o0
  1839. RESTORE_ALL
  1841. .align 4
  1842. .globl C_LABEL(__handle_exception), flush_patch_exception
  1843. C_LABEL(__handle_exception):
  1844. flush_patch_exception:
  1845. FLUSH_ALL_KERNEL_WINDOWS;
  1846. ldd [%o0], %o6
  1847. jmpl %o7 + 0xc, %g0 ! see asm-sparc/processor.h
  1848.  mov 1, %g1 ! signal EFAULT condition
  1850. .align 4
  1851. .globl C_LABEL(kill_user_windows), kuw_patch1_7win
  1852. .globl kuw_patch1
  1853. kuw_patch1_7win: sll %o3, 6, %o3
  1855. /* No matter how much overhead this routine has in the worst
  1856.  * case scenerio, it is several times better than taking the
  1857.  * traps with the old method of just doing flush_user_windows().
  1858.  */
  1859. C_LABEL(kill_user_windows):
  1860. ld [%g6 + AOFF_task_thread + AOFF_thread_uwinmask], %o0 ! get current umask
  1861. orcc %g0, %o0, %g0 ! if no bits set, we are done
  1862. be 3f ! nothing to do
  1863.  rd %psr, %o5 ! must clear interrupts
  1864. or %o5, PSR_PIL, %o4 ! or else that could change
  1865. wr %o4, 0x0, %psr ! the uwinmask state
  1866. WRITE_PAUSE ! burn them cycles
  1867. 1:
  1868. ld [%g6 + AOFF_task_thread + AOFF_thread_uwinmask], %o0 ! get consistant state
  1869. orcc %g0, %o0, %g0 ! did an interrupt come in?
  1870. be 4f ! yep, we are done
  1871.  rd %wim, %o3 ! get current wim
  1872. srl %o3, 1, %o4 ! simulate a save
  1873. kuw_patch1:
  1874. sll %o3, 7, %o3 ! compute next wim
  1875. or %o4, %o3, %o3 ! result
  1876. andncc %o0, %o3, %o0 ! clean this bit in umask
  1877. bne kuw_patch1 ! not done yet
  1878.  srl %o3, 1, %o4 ! begin another save simulation
  1879. wr %o3, 0x0, %wim ! set the new wim
  1880. st %g0, [%g6 + AOFF_task_thread + AOFF_thread_uwinmask] ! clear uwinmask
  1881. 4:
  1882. wr %o5, 0x0, %psr ! re-enable interrupts
  1883. WRITE_PAUSE ! burn baby burn
  1884. 3:
  1885. retl ! return
  1886.  st %g0, [%g6 + AOFF_task_thread + AOFF_thread_w_saved] ! no windows saved
  1888. .align 4
  1889. .globl C_LABEL(restore_current)
  1890. C_LABEL(restore_current):
  1891. LOAD_CURRENT(g6, o0)
  1892. retl
  1893.  nop
  1895. #ifdef CONFIG_PCI
  1896. #include <asm/pcic.h>
  1898. .align 4
  1899. .globl linux_trap_ipi15_pcic
  1900. linux_trap_ipi15_pcic:
  1901. rd %wim, %l3
  1902. SAVE_ALL
  1904. /*
  1905.  * First deactivate NMI
  1906.  * or we cannot drop ET, cannot get window spill traps.
  1907.  * The busy loop is necessary because the PIO error
  1908.  * sometimes does not go away quickly and we trap again.
  1909.  */
  1910. sethi %hi(C_LABEL(pcic_regs)), %o1
  1911. ld [%o1 + %lo(C_LABEL(pcic_regs))], %o2
  1913. ! Get pending status for printouts later.
  1914. ld [%o2 + PCI_SYS_INT_PENDING], %o0
  1916. mov PCI_SYS_INT_PENDING_CLEAR_ALL, %o1
  1917. stb %o1, [%o2 + PCI_SYS_INT_PENDING_CLEAR]
  1918. 1:
  1919. ld [%o2 + PCI_SYS_INT_PENDING], %o1
  1920. andcc %o1, ((PCI_SYS_INT_PENDING_PIO|PCI_SYS_INT_PENDING_PCI)>>24), %g0
  1921. bne 1b
  1922.  nop
  1924. or %l0, PSR_PIL, %l4
  1925. wr %l4, 0x0, %psr
  1926. WRITE_PAUSE
  1927. wr %l4, PSR_ET, %psr
  1928. WRITE_PAUSE
  1930. call C_LABEL(pcic_nmi)
  1931.  add %sp, REGWIN_SZ, %o1 ! struct pt_regs *regs
  1932. RESTORE_ALL
  1934. .globl C_LABEL(pcic_nmi_trap_patch)
  1935. C_LABEL(pcic_nmi_trap_patch):
  1936. sethi %hi(linux_trap_ipi15_pcic), %l3
  1937. jmpl %l3 + %lo(linux_trap_ipi15_pcic), %g0
  1938.  rd %psr, %l0
  1939. .word 0
  1941. #endif /* CONFIG_PCI */
  1943. /* End of entry.S */