开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > 嵌入式Linux > 查看源码
entry.S
资源名称：SBC-2410X_kernel.tar.gz　[点击查看]
上传用户：lgb322
上传日期：2013-02-24
资源大小：30529k
文件大小：33k
源码类别：

嵌入式Linux

开发平台：

Unix_Linux

entry.S：源码内容
  1. /* $Id: entry.S,v 1.38 2002/01/16 15:15:30 bjornw Exp $
  2.  *
  3.  *  linux/arch/cris/entry.S
  4.  *
  5.  *  Copyright (C) 2000, 2001 Axis Communications AB
  6.  *
  7.  *  Authors: Bjorn Wesen (bjornw@axis.com)
  8.  *
  9.  *  $Log: entry.S,v $
  10.  *  Revision 1.38  2002/01/16 15:15:30  bjornw
  11.  *  Use a C-code compatible watchdog reset when NICE_DOGGY is enabled
  12.  *
  13.  *  Revision 1.37  2001/12/07 17:03:55  bjornw
  14.  *  Call a c-hook called watchdog_bite_hook instead of show_registers directly
  15.  *
  16.  *  Revision 1.36  2001/11/22 13:36:36  bjornw
  17.  *  * In ret_from_intr, check regs->dccr for usermode reentrance instead of
  18.  *    DCCR explicitely (because the latter might not reflect current reality)
  19.  *  * In mmu_bus_fault, set $r9 _after_ calling the C-code instead of before
  20.  *    since $r9 is call-clobbered and is potentially needed afterwards
  21.  *
  22.  *  Revision 1.35  2001/10/30 17:10:15  bjornw
  23.  *  Add some syscalls
  24.  *
  25.  *  Revision 1.34  2001/10/01 14:45:03  bjornw
  26.  *  Removed underscores and added register prefixes
  27.  *
  28.  *  Revision 1.33  2001/08/21 13:48:01  jonashg
  29.  *  Added fix by HP to avoid oops when doing a hard_reset_now.
  30.  *
  31.  *  Revision 1.32  2001/08/14 04:32:02  hp
  32.  *  In _resume, add comment why R9 is saved; don't sound like it's call-saved.
  33.  *
  34.  *  Revision 1.31  2001/07/25 16:07:42  bjornw
  35.  *  softirq_active/mask -> softirq_pending only
  36.  *
  37.  *  Revision 1.30  2001/07/05 01:03:32  hp
  38.  *  - include asm/errno.h to get ENOSYS.
  39.  *  - Use ENOSYS, not local constant LENOSYS; tweak comments.
  40.  *  - Explain why .include, not #include is used.
  41.  *  - Make oops-register-dump if watchdog bits and it's not expected.
  42.  *  - Don't jsr, use jump _hard_reset_now, and skip spurious nop.
  43.  *  - Use correct section attribute for section .rodata.
  44.  *  - Adjust sys_ni_syscall fill number.
  45.  *
  46.  *  Revision 1.29  2001/06/25 14:07:00  hp
  47.  *   Fix review comment.
  48.  *   * head.S: Use IO_STATE, IO_FIELD and IO_MASK constructs instead of
  49.  *   magic numbers.  Add comment that -traditional must not be used.
  50.  *   * entry.S (SYMBOL_NAME): Change redefinition to use ## concatenation.
  51.  *   Correct and update comment.
  52.  *   * Makefile (.S.o): Don't use -traditional.  Add comment why the
  53.  *   toplevel rule can't be used (now that there's a reason).
  54.  *
  55.  *  Revision 1.28  2001/06/21 02:00:40  hp
  56.  *   * entry.S: Include asm/unistd.h.
  57.  *   (_sys_call_table): Use section .rodata, not .data.
  58.  *   (_kernel_thread): Move from...
  59.  *   * process.c: ... here.
  60.  *   * entryoffsets.c (VAL): Break out from...
  61.  *   (OF): Use VAL.
  62.  *   (LCLONE_VM): New asmified value from CLONE_VM.
  63.  *
  64.  *  Revision 1.27  2001/05/29 11:25:27  markusl
  65.  *  In case of "spurious_interrupt", do hard_reset instead of hanging system in a loop...
  66.  *
  67.  *  Revision 1.26  2001/05/15 15:46:03  bjornw
  68.  *  Include config.h now that we use some CONFIG_ options
  69.  *
  70.  *  Revision 1.25  2001/05/15 05:38:47  hp
  71.  *  Tweaked code in _ret_from_sys_call
  72.  *
  73.  *  Revision 1.24  2001/05/15 05:27:49  hp
  74.  *  Save r9 in r1 over function call rather than on stack.
  75.  *
  76.  *  Revision 1.23  2001/05/15 05:10:00  hp
  77.  *  Generate entry.S structure offsets from C
  78.  *
  79.  *  Revision 1.22  2001/04/17 13:58:39  orjanf
  80.  *  * Renamed CONFIG_KGDB to CONFIG_ETRAX_KGDB.
  81.  *
  82.  *  Revision 1.21  2001/04/17 11:33:29  orjanf
  83.  *  Updated according to review:
  84.  *  * Included asm/sv_addr_ag.h to get macro for internal register.
  85.  *  * Corrected comment regarding system call argument passing.
  86.  *  * Removed comment about instruction being in a delay slot.
  87.  *  * Added comment about SYMBOL_NAME macro.
  88.  *
  89.  *  Revision 1.20  2001/04/12 08:51:07  hp
  90.  *  - Add entry for sys_fcntl64.  In fact copy last piece from i386 including ...
  91.  *  - .rept to fill table to safe state with sys_ni_syscall.
  92.  *
  93.  *  Revision 1.19  2001/04/04 09:43:32  orjanf
  94.  *  * Moved do_sigtrap from traps.c to entry.S.
  95.  *  * LTASK_PID need not be global anymore.
  96.  *
  97.  *  Revision 1.18  2001/03/26 09:25:02  markusl
  98.  *  Updated after review, should now handle USB interrupts correctly.
  99.  *
  100.  *  Revision 1.17  2001/03/21 16:12:55  bjornw
  101.  *  * Always make room for the cpu status record in the frame, in order to
  102.  *    use the same framelength and layout for both mmu busfaults and normal
  103.  *    irqs. No need to check for the explicit CRIS_FRAME_FIXUP type anymore.
  104.  *  * Fixed bug with using addq for popping the stack in the epilogue - it
  105.  *    destroyed the flag register. Use instructions that don't affect the
  106.  *    flag register instead.
  107.  *  * Removed write to R_PORT_PA_DATA during spurious_interrupt
  108.  *
  109.  *  Revision 1.16  2001/03/20 19:43:02  bjornw
  110.  *  * Get rid of esp0 setting
  111.  *  * Give a 7th argument to a systemcall - the stackframe
  112.  *
  113.  *  Revision 1.15  2001/03/05 13:14:30  bjornw
  114.  *  Spelling fix
  115.  *
  116.  *  Revision 1.14  2001/02/23 08:36:36  perf
  117.  *  New ABI; syscallnr=r9, arg5=mof, arg6=srp.
  118.  *  Corrected tracesys call check.
  119.  *
  120.  *  Revision 1.13  2001/02/15 08:40:55  perf
  121.  *  H-P by way of perf;
  122.  *  - (_system_call): Don't read system call function address into r1.
  123.  *  - (RBFExit): There is no such thing as a null pop.  Adjust sp by addq.
  124.  *  - (_system_call): Don't use r10 and don't save and restore it.
  125.  *  - (THREAD_ESP0): New constant.
  126.  *  - (_system_call): Inline set_esp0.
  127.  *
  128.  *  Revision 1.12  2001/01/31 17:56:25  orjanf
  129.  *  Added definition of LTASK_PID and made it global.
  130.  *
  131.  *  Revision 1.11  2001/01/10 21:13:29  bjornw
  132.  *  SYMBOL_NAME is defined incorrectly for the compiler options we currently use
  133.  *
  134.  *  Revision 1.10  2000/12/18 23:47:56  bjornw
  135.  *  * Added syscall trace support (ptrace), completely untested of course
  136.  *  * Removed redundant check for NULL entries in syscall_table
  137.  *
  138.  *  Revision 1.9  2000/11/21 16:40:51  bjornw
  139.  *  * New frame type used when an SBFS frame needs to be popped without
  140.  *    actually restarting the instruction
  141.  *  * Enable interrupts in signal_return (they did so in x86, I hope it's a good
  142.  *    idea)
  143.  *
  144.  *  Revision 1.8  2000/11/17 16:53:35  bjornw
  145.  *  Added detection of frame-type in Rexit, so that mmu_bus_fault can
  146.  *  use ret_from_intr in the return-path to check for signals (like SEGV)
  147.  *  and other foul things that might have occurred during the fault.
  148.  *
  149.  *  Revision 1.7  2000/10/06 15:04:28  bjornw
  150.  *  Include mof in register savings
  151.  *
  152.  *  Revision 1.6  2000/09/12 16:02:44  bjornw
  153.  *  Linux-2.4.0-test7 derived updates
  154.  *
  155.  *  Revision 1.5  2000/08/17 15:35:15  bjornw
  156.  *  2.4.0-test6 changed local_irq_count and friends API
  157.  *
  158.  *  Revision 1.4  2000/08/02 13:59:30  bjornw
  159.  *  Removed olduname and uname from the syscall list
  160.  *
  161.  *  Revision 1.3  2000/07/31 13:32:58  bjornw
  162.  *  * Export ret_from_intr
  163.  *  * _resume updated (prev/last tjohejsan)
  164.  *  * timer_interrupt obsolete
  165.  *  * SIGSEGV detection in mmu_bus_fault temporarily disabled
  166.  *
  167.  *
  168.  */
  170. /*
  171.  * entry.S contains the system-call and fault low-level handling routines.
  172.  *
  173.  * NOTE: This code handles signal-recognition, which happens every time
  174.  * after a timer-interrupt and after each system call.
  175.  *
  176.  * Stack layout in 'ret_from_system_call':
  177.  *  ptrace needs to have all regs on the stack.
  178.  * if the order here is changed, it needs to be 
  179.  * updated in fork.c:copy_process, signal.c:do_signal,
  180.  * ptrace.c and ptrace.h
  181.  *
  182.  */
  184. #include <linux/config.h>
  185. #include <linux/linkage.h>
  186. #include <linux/sys.h>
  187. #include <asm/unistd.h>
  188. #include <asm/sv_addr_ag.h>
  189. #include <asm/errno.h>
  191. ;; functions exported from this file
  193. .globl system_call
  194. .globl ret_from_intr
  195. .globl ret_from_sys_call
  196. .globl resume
  197. .globl multiple_interrupt
  198. .globl hwbreakpoint
  199. .globl IRQ1_interrupt
  200. .globl timer_interrupt
  201. .globl timer_shortcut
  202. .globl spurious_interrupt
  203. .globl hw_bp_trigs
  204. .globl mmu_bus_fault
  205. .globl do_sigtrap
  206. .globl gdb_handle_breakpoint
  208. .globl sys_call_table
  210. ;; Get values and offsets into various structs.  The file isn't
  211. ;; suitable for consumption by the preprocessor, so don't use
  212. ;; #include.
  213. .include "entryoffsets.s"
  215. ;; process bits for ptrace.  FIXME: Should be in a header file.
  217. PT_TRACESYS_BIT   = 1
  219. ;; below are various parts of system_call which are not in the fast-path
  221. ;; handle software irqs
  223. _handle_softirq:
  224. move.d $r9, $r1
  225. jsr do_softirq ; call the C routine for softirq handling
  226. move.d $r1, $r9
  228. ;; fall-through
  230. ret_from_intr:
  231. ;; check for resched only if we're going back to user-mode
  232. ;; this test matches the user_regs(regs) macro
  233. ;; we cannot simply test $dccr, because that does not necessarily
  234. ;; reflect what mode we'll return into.
  236. move.d [$sp + LDCCR], $r0; regs->dccr
  237. btstq 8, $r0 ; U-flag
  238. bpl _Rexit ; go back directly
  239. nop
  240. ba _ret_with_reschedule  ; go back but check schedule and signals first 
  241. nop
  243. _reschedule:
  244. ;; keep r9 intact
  245. move.d $r9, $r1
  246. jsr schedule
  247. ba ret_from_sys_call
  248. move.d $r1, $r9
  250. ;; return but call do_signal first
  251. _signal_return:
  252. ei ; we can get here from an interrupt
  253. move.d $r9, $r10 ; do_signals syscall/irq param
  254. moveq 0, $r11 ; oldset param - 0 in this case
  255. move.d $sp, $r12 ; another argument to do_signal (the regs param)
  256. jsr do_signal ; arch/cris/kernel/signal.c
  257. ba _Rexit
  258. nop
  260. ;; The system_call is called by a BREAK instruction, which works like
  261. ;; an interrupt call but it stores the return PC in BRP instead of IRP.
  262. ;; Since we dont really want to have two epilogues (one for system calls
  263. ;; and one for interrupts) we push the contents of BRP instead of IRP in the
  264. ;; system call prologue, to make it look like an ordinary interrupt on the
  265. ;; stackframe.
  266. ;;
  267. ;; Since we can't have system calls inside interrupts, it should not matter
  268. ;; that we don't stack IRP.
  269. ;; 
  270. ;; In r9 we have the wanted syscall number. Arguments come in r10,r11,r12,r13,mof,srp
  271. ;;
  272. ;; This function looks on the _surface_ like spaghetti programming, but it's
  273. ;; really designed so that the fast-path does not force cache-loading of non-used
  274. ;; instructions. Only the non-common cases cause the outlined code to run..
  276. system_call:
  277. ;; stack-frame similar to the irq heads, which is reversed in ret_from_sys_call
  278. move $brp,[$sp=$sp-16]; instruction pointer and room for a fake SBFS frame
  279. push $srp
  280. push $dccr
  281. push $mof
  282. subq 14*4, $sp ; make room for r0-r13
  283. movem $r13, [$sp] ; push r0-r13
  284. push $r10 ; push orig_r10
  285. clear.d [$sp=$sp-4] ; frametype == 0, normal stackframe
  287. movs.w -ENOSYS, $r0
  288. move.d $r0, [$sp+LR10] ; put the default return value in r10 in the frame
  290. ;; check if this process is syscall-traced
  292. movs.w -8192, $r0 ; THREAD_SIZE == 8192
  293. and.d $sp, $r0
  295. move.d [$r0+LTASK_PTRACE], $r0
  296. btstq PT_TRACESYS_BIT, $r0
  297. bmi _tracesys
  298. nop
  300. ;; check for sanity in the requested syscall number
  302. cmpu.w NR_syscalls, $r9
  303. bcc ret_from_sys_call
  304. lslq 2, $r9 ;  multiply by 4, in the delay slot
  306. ;; as a bonus 7th parameter, we give the location on the stack
  307. ;; of the register structure itself. some syscalls need this.
  309. push $sp
  311. ;; the parameter carrying registers r10, r11, r12 and 13 are intact.
  312. ;; the fifth and sixth parameters (if any) was in mof and srp 
  313. ;; respectively, and we need to put them on the stack.
  315. push $srp
  316. push $mof
  318. jsr [$r9+sys_call_table] ; actually do the system call
  319. addq 3*4, $sp ; pop the mof, srp and regs parameters
  320. move.d $r10, [$sp+LR10] ; save the return value
  322. moveq 1, $r9 ; "parameter" to ret_from_sys_call to show it was a sys call
  324. ;; fall through into ret_from_sys_call to return
  326. ret_from_sys_call:
  327. ;; r9 is a parameter - if 1, we came from a syscall, if 0, from an irq
  329. ;; check if any bottom halves need service
  331. test.d [irq_stat]        ; softirq_pending
  332. bne _handle_softirq
  333. nop
  335. _ret_with_reschedule:
  336. ;; first get the current task-struct pointer (see top for defs)
  338. move.d $sp, $r0
  339. and.d -8192, $r0 ; THREAD_SIZE == 8192
  341. ;; see if we want to reschedule into another process
  343. test.d [$r0+LTASK_NEEDRESCHED]
  344. bne _reschedule
  345. nop
  347. ;; see if we need to run signal checks (important that r9 is intact here)
  349. test.d [$r0+LTASK_SIGPENDING]
  350. bne _signal_return
  351. nop
  353. _Rexit:
  354. ;; this epilogue MUST match the prologues in multiple_interrupt, irq.h and ptregs.h
  355. pop $r10 ; frametype
  356. bne _RBFexit ; was not CRIS_FRAME_NORMAL, handle otherwise
  357. addq 4, $sp ; skip orig_r10, in delayslot
  358. movem [$sp+], $r13 ; registers r0-r13
  359. pop $mof ; multiply overflow register 
  360. pop $dccr ; condition codes
  361. pop $srp ; subroutine return pointer
  362. ;; now we have a 4-word SBFS frame which we do not want to restore
  363. ;; using RBF since it was not stacked with SBFS. instead we would like to
  364. ;; just get the PC value to restart it with, and skip the rest of
  365. ;; the frame.
  366. ;; Also notice that it's important to use instructions here that
  367. ;; keep the interrupts disabled (since we've already popped DCCR)
  368. move [$sp=$sp+16], $p8; pop the SBFS frame from the sp
  369. jmpu [$sp-16] ; return through the irp field in the sbfs frame
  371. _RBFexit:
  372. movem [$sp+], $r13 ; registers r0-r13, in delay slot
  373. pop $mof ; multiply overflow register 
  374. pop $dccr ; condition codes
  375. pop $srp ; subroutine return pointer
  376. rbf [$sp+] ; return by popping the CPU status
  378. _tracesys:
  379. ;; this first invocation of syscall_trace _requires_ that
  380. ;; LR10 in the frame contains -ENOSYS (as is set in the beginning
  381. ;; of system_call).
  383. jsr syscall_trace
  385. ;; now we should more or less do the same things as in the system_call
  386. ;; but since our argument regs got clobbered during syscall_trace and
  387. ;; because syscall_trace might want to alter them, we need to reload them
  388. ;; from the stack-frame as we use them.
  390. ;; check for sanity in the requested syscall number
  392. move.d [$sp+LR9], $r9
  393. movs.w -ENOSYS, $r10
  394. cmpu.w NR_syscalls, $r9
  395. bcc 1f
  396. lslq 2, $r9 ;  multiply by 4, in the delay slot
  398. ;; read the system call vector entry into r9
  400. move.d [$r9+sys_call_table], $r9
  402. ;; restore r10, r11, r12, r13, mof and srp into the needed registers
  404. move.d [$sp+LORIG_R10], $r10  ; LR10 is already filled with -ENOSYS.
  405. move.d [$sp+LR11],      $r11
  406. move.d [$sp+LR12],      $r12
  407. move.d [$sp+LR13],      $r13
  408. move [$sp+LMOF],      $mof
  409. move [$sp+LSRP],      $srp
  411. ;; as a bonus 7th parameter, we give the location on the stack
  412. ;; of the register structure itself. some syscalls need this.
  414. push $sp
  416. ;; the fifth and sixth parameters needs to be put on the stack for
  417. ;; the system call to find them
  419. push $srp
  420. push $mof
  422. jsr $r9 ; actually call the system-call
  423. addq 3*4, $sp ; pop the srp, mof and regs parameters
  425. 1: move.d $r10, [$sp+LR10]; save the return value
  427. ;; second call of syscall_trace, to let it grab the results
  429. jsr syscall_trace
  431. moveq 1, $r9 ; "parameter" to ret_from_sys_call to show it was a sys call
  432. ba ret_from_sys_call
  433. nop
  435. ;; resume performs the actual task-switching, by switching stack pointers
  436. ;; input arguments: r10 = prev, r11 = next, r12 = thread offset in task struct
  437. ;; returns old current in r10
  438. ;;
  439. ;; TODO:  see the i386 version. The switch_to which calls resume in our version
  440. ;;        could really be an inline asm of this.
  442. resume:
  443. push $srp          ; we keep the old/new PC on the stack 
  444. add.d $r12, $r10  ; r10 = current tasks tss
  445. move $dccr, [$r10+LTHREAD_DCCR] ; save irq enable state
  446. di
  448. move $usp, [$r10+LTHREAD_USP] ; save user-mode stackpointer
  450. ;; See copy_thread for the reason why register R9 is saved.
  451. subq 10*4, $sp
  452. movem $r9, [$sp]  ; save non-scratch registers and R9.
  454. move.d $sp, [$r10+LTHREAD_KSP]  ; save the kernel stack pointer for the old task
  455. move.d $sp, $r10  ; return last running task in r10
  456. and.d   -8192, $r10          ; get task ptr from stackpointer
  457. add.d $r12, $r11  ; find the new tasks tss
  458. move.d [$r11+LTHREAD_KSP], $sp  ; switch into the new stackframe by restoring kernel sp
  460. movem [$sp+], $r9  ; restore non-scratch registers and R9.
  462. move [$r11+LTHREAD_USP], $usp ; restore user-mode stackpointer
  464. move [$r11+LTHREAD_DCCR], $dccr ; restore irq enable status
  465. jump [$sp+]          ; restore PC
  467. ;; This is the MMU bus fault handler.
  468. ;; It needs to stack the CPU status and overall is different
  469. ;; from the other interrupt handlers.
  471. mmu_bus_fault:
  472. sbfs [$sp=$sp-16] ; push the internal CPU status
  473. ;; the first longword in the sbfs frame was the interrupted PC
  474. ;; which fits nicely with the "IRP" slot in pt_regs normally used to
  475. ;; contain the return address. used by Oops to print kernel errors..
  476. push $srp ; make a stackframe similar to pt_regs
  477. push $dccr
  478. push $mof
  479. di
  480. subq 14*4, $sp
  481. movem $r13, [$sp]
  482. push $r10 ; dummy orig_r10
  483. moveq 1, $r10
  484. push $r10 ; frametype == 1, BUSFAULT frame type
  486. move.d $sp, $r10 ; pt_regs argument to handle_mmu_bus_fault
  488. jsr handle_mmu_bus_fault  ; in arch/cris/mm/fault.c
  490. ;; now we need to return through the normal path, we cannot just
  491. ;; do the RBFexit since we might have killed off the running
  492. ;; process due to a SEGV, scheduled due to a page blocking or
  493. ;; whatever.
  495. moveq 0, $r9 ; busfault is equivalent to an irq
  497. ba ret_from_intr
  498. nop
  500. ;; special handlers for breakpoint and NMI
  501. #if 0
  502. hwbreakpoint:
  503. push $dccr
  504. di
  505. push $r10
  506. push $r11
  507. push $r12
  508. push $r13
  509. clearf b
  510. move $brp,$r11
  511. move.d [hw_bp_msg],$r10
  512. jsr printk
  513. setf b
  514. pop $r13
  515. pop $r12
  516. pop $r11
  517. pop $r10
  518. pop $dccr
  519. retb
  520. nop
  521. #else
  522. hwbreakpoint:
  523. push $dccr
  524. di
  525. #if 1
  526. push $r10
  527. push $r11
  528. move.d [hw_bp_trig_ptr],$r10
  529. move.d [$r10],$r11
  530. cmp.d 42,$r11
  531. beq 1f
  532. nop
  533. move $brp,$r11
  534. move.d $r11,[$r10+]
  535. move.d $r10,[hw_bp_trig_ptr]
  536. 1: pop $r11
  537. pop $r10
  538. #endif
  539. pop $dccr
  540. retb
  541. nop
  542. #endif
  544. IRQ1_interrupt:
  546. #if defined(CONFIG_ETRAX_WATCHDOG) && !defined(CONFIG_SVINTO_SIM)
  547. ;; If we receive a watchdog interrupt while it is not expected, then set
  548. ;; up a canonical frame and dump register contents before dying.
  550. ;; this prologue MUST match the one in irq.h and the struct in ptregs.h!!!
  551. move $brp,[$sp=$sp-16]; instruction pointer and room for a fake SBFS frame
  552. push $srp
  553. push $dccr
  554. push $mof
  555. di
  556. subq 14*4, $sp
  557. movem $r13, [$sp]
  558. push $r10 ; push orig_r10
  559. clear.d [$sp=$sp-4] ; frametype == 0, normal frame
  561. ;; We don't check that we actually were bit by the watchdog as opposed to
  562. ;; an external NMI, since there is currently no handler for external NMI.
  564. ;; Check if we're waiting for reset to happen, as signalled by
  565. ;; hard_reset_now setting cause_of_death to a magic value.  If so, just
  566. ;; get stuck until reset happens.
  567. .comm cause_of_death, 4 ;; Don't declare this anywhere.
  568. move.d [cause_of_death], $r10
  569. cmp.d 0xbedead, $r10
  570. _killed_by_death:
  571. beq _killed_by_death
  572. nop
  574. ;; We'll see this in ksymoops dumps.
  575. Watchdog_bite:
  577. #ifdef CONFIG_ETRAX_WATCHDOG_NICE_DOGGY
  578. ;; We just restart the watchdog here to be sure we dont get
  579. ;; hit while printing the watchdogmsg below
  580. ;; This restart is compatible with the rest of the C-code, so
  581. ;; the C-code can keep restarting the watchdog after this point.
  582. ;; The non-NICE_DOGGY code below though, disables the possibility
  583. ;; to restart since it changes the watchdog key, to avoid any
  584. ;; buggy loops etc. keeping the watchdog alive after this.
  585. jsr reset_watchdog
  586. #else
  587. ;; We need to extend the 3.3ms after the NMI at watchdog bite, so we have
  588. ;; time for an oops-dump over a 115k2 serial wire.  Another 100ms should do.
  590. ;; Change the watchdog key to an arbitrary 3-bit value and restart the
  591. ;; watchdog.
  592. #define WD_INIT 2
  593. moveq   IO_FIELD (R_WATCHDOG, key, WD_INIT), $r10
  594. move.d R_WATCHDOG, $r11
  596. move.d $r10, [$r11]
  597. moveq   IO_FIELD (R_WATCHDOG, key,
  598.     IO_EXTRACT (R_WATCHDOG, key,
  599. IO_MASK (R_WATCHDOG, key))
  600.     ^ WD_INIT)
  601. | IO_STATE (R_WATCHDOG, enable, start), $r10
  602. move.d $r10, [$r11]
  603. #endif
  605. ;; Note that we don't do "setf m" here (or after two necessary NOPs),
  606. ;; since *not* doing that saves us from re-entrancy checks.  We don't want
  607. ;; to get here again due to possible subsequent NMIs; we want the watchdog
  608. ;; to reset us.
  610. move.d _watchdogmsg,$r10
  611. jsr printk
  613. move.d $sp, $r10
  614. jsr watchdog_bite_hook
  616. ;; This nop is here so we see the "Watchdog_bite" label in ksymoops dumps
  617. ;; rather than "spurious_interrupt".
  618. nop
  619. ;; At this point we drop down into spurious_interrupt, which will do a
  620. ;; hard reset.
  622. .section .rodata,"a"
  623. _watchdogmsg:
  624. .ascii "Oops: bitten by watchdogn"
  625. .previous
  627. #endif /* CONFIG_ETRAX_WATCHDOG and not CONFIG_SVINTO_SIM */
  629. spurious_interrupt:
  630. di
  631. jump hard_reset_now
  633. ;; this handles the case when multiple interrupts arrive at the same time
  634. ;; we jump to the first set interrupt bit in a priority fashion
  635. ;; the hardware will call the unserved interrupts after the handler finishes
  637. multiple_interrupt:
  638. ;; this prologue MUST match the one in irq.h and the struct in ptregs.h!!!
  639. move $irp,[$sp=$sp-16]; instruction pointer and room for a fake SBFS frame
  640. push $srp
  641. push $dccr
  642. push $mof
  643. di
  644. subq 14*4, $sp
  645. movem $r13, [$sp]
  646. push $r10 ; push orig_r10
  647. clear.d [$sp=$sp-4] ; frametype == 0, normal frame
  649. move.d irq_shortcuts + 8, $r1
  650. moveq 2, $r2 ; first bit we care about is the timer0 irq
  651. move.d [R_VECT_MASK_RD], $r0; read the irq bits that triggered the multiple irq
  652. 1:
  653. btst $r2, $r0 ; check for the irq given by bit r2
  654. bmi _do_shortcut ; actually do the shortcut
  655. nop
  656. addq 1, $r2 ; next vector bit
  657. addq 4, $r1 ; next vector
  658. cmp.b 32, $r2
  659. bne 1b ; process all irq's up to and including number 31
  660. nop
  662. ;; strange, we didn't get any set vector bits.. oh well, just return
  664. ba _Rexit
  665. nop
  667. _do_shortcut:
  668. test.d [$r1]
  669. beq _Rexit
  670. nop
  671. jump [$r1] ; jump to the irq handlers shortcut
  673. do_sigtrap:
  674. ;; 
  675. ;; SIGTRAP the process that executed the break instruction.
  676. ;; Make a frame that Rexit in entry.S expects.
  677. ;;
  678. move $brp, [$sp=$sp-16] ; Push BRP while faking a cpu status record.
  679. push $srp ; Push subroutine return pointer.
  680. push $dccr ; Push condition codes.
  681. push $mof ; Push multiply overflow reg.
  682. di ; Need to disable irq's at this point.
  683. subq 14*4, $sp ; Make room for r0-r13.
  684. movem $r13, [$sp] ; Push the r0-r13 registers.
  685. push $r10 ; Push orig_r10.
  686. clear.d [$sp=$sp-4] ; Frametype - this is a normal stackframe.
  688. movs.w -8192,$r9 ; THREAD_SIZE == 8192
  689. and.d $sp, $r9
  690. move.d [$r9+LTASK_PID], $r10 ; current->pid as arg1.
  691. moveq 5, $r11 ; SIGTRAP as arg2.
  692. jsr sys_kill       
  693. jump ret_from_intr ; Use the return routine for interrupts.
  695. gdb_handle_breakpoint:
  696. push $dccr
  697. push $r0
  698. #ifdef CONFIG_ETRAX_KGDB
  699. move $dccr, $r0 ; U-flag not affected by previous insns. 
  700. btstq 8, $r0 ; Test the U-flag.
  701. bmi _ugdb_handle_breakpoint ; Go to user mode debugging. 
  702. nop ; Empty delay slot (cannot pop r0 here). 
  703. pop $r0 ; Restore r0.
  704. ba kgdb_handle_breakpoint ; Go to kernel debugging. 
  705. pop $dccr ; Restore dccr in delay slot.
  706. #endif
  708. _ugdb_handle_breakpoint:
  709. move $brp, $r0 ; Use r0 temporarily for calculation.
  710. subq 2, $r0 ; Set to address of previous instruction.
  711. move $r0, $brp
  712. pop $r0 ; Restore r0. 
  713. ba do_sigtrap ; SIGTRAP the offending process. 
  714. pop $dccr ; Restore dccr in delay slot.
  716. .data
  718. hw_bp_trigs:
  719. .space 64*4
  720. hw_bp_trig_ptr:
  721. .dword hw_bp_trigs
  723. /*
  724.  * This is the mechanism for creating a new kernel thread.
  725.  *
  726.  * NOTE! Only a kernel-only process (i.e. the swapper or direct descendants
  727.  * who haven't done an "execve()") should use this: it will work within
  728.  * a system call from a "real" process, but the process memory space will
  729.  * not be free'd until both the parent and the child have exited.
  730.  *
  731.  * This *can* be done in C with an single-asm-wrapped-in-a-function, but you
  732.  * get more or less gross code.  The safer you make the asm-constraints,
  733.  * the grosser the code, at least with the gcc version in cris-dist-1.13.
  734.  */
  736. /* int kernel_thread(int (*fn)(void *), void * arg, unsigned long flags) */
  737. /*                   r10                r11         r12  */
  739. .text
  740. .global kernel_thread
  741. kernel_thread:
  743. /* Save ARG for later.  */
  744. move.d $r11, $r13
  746. /* r11 is argument 2 to clone, the flags */
  747. move.d  $r12, $r11
  748. or.w LCLONE_VM, $r11
  750. /* Save FN for later.  */
  751. move.d $r10, $r12
  753. /* r9 contains syscall number, to sys_clone */
  754. movu.w __NR_clone, $r9
  756. /* r10 is argument 1 to clone */
  757. clear.d $r10
  759. /* call sys_clone, this will fork */
  760. break 13
  762. /* parent or child? child returns 0 here. */
  763. test.d $r10
  765. /* jump if parent */
  766. bne 1f
  767. nop              /* delay slot */
  769. /* set argument to function to call */
  770. move.d $r13, $r10
  772. /* call specified function */
  773. jsr $r12
  774. /* If we ever return from the function, something bad has happened.  */
  776. /* r9 is sys_exit syscall number */
  777. movu.w __NR_exit, $r9
  779. /* Give a really bad exit-value */
  780. moveq -1, $r10
  782. /* call sys_exit, killing the child */
  783. break 13
  784. 1:
  785. ret
  786. nop              /* delay slot */
  788. .section .rodata,"a"
  789. sys_call_table:
  790. .long SYMBOL_NAME(sys_ni_syscall) /* 0  -  old "setup()" system call*/
  791. .long SYMBOL_NAME(sys_exit)
  792. .long SYMBOL_NAME(sys_fork)
  793. .long SYMBOL_NAME(sys_read)
  794. .long SYMBOL_NAME(sys_write)
  795. .long SYMBOL_NAME(sys_open) /* 5 */
  796. .long SYMBOL_NAME(sys_close)
  797. .long SYMBOL_NAME(sys_waitpid)
  798. .long SYMBOL_NAME(sys_creat)
  799. .long SYMBOL_NAME(sys_link)
  800. .long SYMBOL_NAME(sys_unlink) /* 10 */
  801. .long SYMBOL_NAME(sys_execve)
  802. .long SYMBOL_NAME(sys_chdir)
  803. .long SYMBOL_NAME(sys_time)
  804. .long SYMBOL_NAME(sys_mknod)
  805. .long SYMBOL_NAME(sys_chmod) /* 15 */
  806. .long SYMBOL_NAME(sys_lchown16)
  807. .long SYMBOL_NAME(sys_ni_syscall) /* old break syscall holder */
  808. .long SYMBOL_NAME(sys_stat)
  809. .long SYMBOL_NAME(sys_lseek)
  810. .long SYMBOL_NAME(sys_getpid) /* 20 */
  811. .long SYMBOL_NAME(sys_mount)
  812. .long SYMBOL_NAME(sys_oldumount)
  813. .long SYMBOL_NAME(sys_setuid16)
  814. .long SYMBOL_NAME(sys_getuid16)
  815. .long SYMBOL_NAME(sys_stime) /* 25 */
  816. .long SYMBOL_NAME(sys_ptrace)
  817. .long SYMBOL_NAME(sys_alarm)
  818. .long SYMBOL_NAME(sys_fstat)
  819. .long SYMBOL_NAME(sys_pause)
  820. .long SYMBOL_NAME(sys_utime) /* 30 */
  821. .long SYMBOL_NAME(sys_ni_syscall) /* old stty syscall holder */
  822. .long SYMBOL_NAME(sys_ni_syscall) /* old gtty syscall holder */
  823. .long SYMBOL_NAME(sys_access)
  824. .long SYMBOL_NAME(sys_nice)
  825. .long SYMBOL_NAME(sys_ni_syscall) /* 35  old ftime syscall holder */
  826. .long SYMBOL_NAME(sys_sync)
  827. .long SYMBOL_NAME(sys_kill)
  828. .long SYMBOL_NAME(sys_rename)
  829. .long SYMBOL_NAME(sys_mkdir)
  830. .long SYMBOL_NAME(sys_rmdir) /* 40 */
  831. .long SYMBOL_NAME(sys_dup)
  832. .long SYMBOL_NAME(sys_pipe)
  833. .long SYMBOL_NAME(sys_times)
  834. .long SYMBOL_NAME(sys_ni_syscall) /* old prof syscall holder */
  835. .long SYMBOL_NAME(sys_brk) /* 45 */
  836. .long SYMBOL_NAME(sys_setgid16)
  837. .long SYMBOL_NAME(sys_getgid16)
  838. .long SYMBOL_NAME(sys_signal)
  839. .long SYMBOL_NAME(sys_geteuid16)
  840. .long SYMBOL_NAME(sys_getegid16) /* 50 */
  841. .long SYMBOL_NAME(sys_acct)
  842. .long SYMBOL_NAME(sys_umount) /* recycled never used phys() */
  843. .long SYMBOL_NAME(sys_ni_syscall) /* old lock syscall holder */
  844. .long SYMBOL_NAME(sys_ioctl)
  845. .long SYMBOL_NAME(sys_fcntl) /* 55 */
  846. .long SYMBOL_NAME(sys_ni_syscall) /* old mpx syscall holder */
  847. .long SYMBOL_NAME(sys_setpgid)
  848. .long SYMBOL_NAME(sys_ni_syscall) /* old ulimit syscall holder */
  849. .long SYMBOL_NAME(sys_ni_syscall)       /* old sys_olduname holder */
  850. .long SYMBOL_NAME(sys_umask) /* 60 */
  851. .long SYMBOL_NAME(sys_chroot)
  852. .long SYMBOL_NAME(sys_ustat)
  853. .long SYMBOL_NAME(sys_dup2)
  854. .long SYMBOL_NAME(sys_getppid)
  855. .long SYMBOL_NAME(sys_getpgrp) /* 65 */
  856. .long SYMBOL_NAME(sys_setsid)
  857. .long SYMBOL_NAME(sys_sigaction)
  858. .long SYMBOL_NAME(sys_sgetmask)
  859. .long SYMBOL_NAME(sys_ssetmask)
  860. .long SYMBOL_NAME(sys_setreuid16) /* 70 */
  861. .long SYMBOL_NAME(sys_setregid16)
  862. .long SYMBOL_NAME(sys_sigsuspend)
  863. .long SYMBOL_NAME(sys_sigpending)
  864. .long SYMBOL_NAME(sys_sethostname)
  865. .long SYMBOL_NAME(sys_setrlimit) /* 75 */
  866. .long SYMBOL_NAME(sys_old_getrlimit)
  867. .long SYMBOL_NAME(sys_getrusage)
  868. .long SYMBOL_NAME(sys_gettimeofday)
  869. .long SYMBOL_NAME(sys_settimeofday)
  870. .long SYMBOL_NAME(sys_getgroups16) /* 80 */
  871. .long SYMBOL_NAME(sys_setgroups16)
  872. .long SYMBOL_NAME(sys_select)           /* was old_select in Linux/E100 */
  873. .long SYMBOL_NAME(sys_symlink)
  874. .long SYMBOL_NAME(sys_lstat)
  875. .long SYMBOL_NAME(sys_readlink) /* 85 */
  876. .long SYMBOL_NAME(sys_uselib)
  877. .long SYMBOL_NAME(sys_swapon)
  878. .long SYMBOL_NAME(sys_reboot)
  879. .long SYMBOL_NAME(old_readdir)
  880. .long SYMBOL_NAME(old_mmap) /* 90 */
  881. .long SYMBOL_NAME(sys_munmap)
  882. .long SYMBOL_NAME(sys_truncate)
  883. .long SYMBOL_NAME(sys_ftruncate)
  884. .long SYMBOL_NAME(sys_fchmod)
  885. .long SYMBOL_NAME(sys_fchown16) /* 95 */
  886. .long SYMBOL_NAME(sys_getpriority)
  887. .long SYMBOL_NAME(sys_setpriority)
  888. .long SYMBOL_NAME(sys_ni_syscall) /* old profil syscall holder */
  889. .long SYMBOL_NAME(sys_statfs)
  890. .long SYMBOL_NAME(sys_fstatfs) /* 100 */
  891. .long SYMBOL_NAME(sys_ni_syscall)       /* sys_ioperm in i386 */
  892. .long SYMBOL_NAME(sys_socketcall)
  893. .long SYMBOL_NAME(sys_syslog)
  894. .long SYMBOL_NAME(sys_setitimer)
  895. .long SYMBOL_NAME(sys_getitimer) /* 105 */
  896. .long SYMBOL_NAME(sys_newstat)
  897. .long SYMBOL_NAME(sys_newlstat)
  898. .long SYMBOL_NAME(sys_newfstat)
  899. .long SYMBOL_NAME(sys_ni_syscall) /* old sys_uname holder */
  900. .long SYMBOL_NAME(sys_ni_syscall) /* sys_iopl in i386 */
  901. .long SYMBOL_NAME(sys_vhangup)
  902. .long SYMBOL_NAME(sys_ni_syscall) /* old "idle" system call */
  903. .long SYMBOL_NAME(sys_ni_syscall) /* vm86old in i386 */
  904. .long SYMBOL_NAME(sys_wait4)
  905. .long SYMBOL_NAME(sys_swapoff) /* 115 */
  906. .long SYMBOL_NAME(sys_sysinfo)
  907. .long SYMBOL_NAME(sys_ipc)
  908. .long SYMBOL_NAME(sys_fsync)
  909. .long SYMBOL_NAME(sys_sigreturn)
  910. .long SYMBOL_NAME(sys_clone) /* 120 */
  911. .long SYMBOL_NAME(sys_setdomainname)
  912. .long SYMBOL_NAME(sys_newuname)
  913. .long SYMBOL_NAME(sys_ni_syscall) /* TODO sys_modify_ldt - do something ?*/
  914. .long SYMBOL_NAME(sys_adjtimex)
  915. .long SYMBOL_NAME(sys_mprotect) /* 125 */
  916. .long SYMBOL_NAME(sys_sigprocmask)
  917. .long SYMBOL_NAME(sys_create_module)
  918. .long SYMBOL_NAME(sys_init_module)
  919. .long SYMBOL_NAME(sys_delete_module)
  920. .long SYMBOL_NAME(sys_get_kernel_syms) /* 130 */
  921. .long SYMBOL_NAME(sys_quotactl)
  922. .long SYMBOL_NAME(sys_getpgid)
  923. .long SYMBOL_NAME(sys_fchdir)
  924. .long SYMBOL_NAME(sys_bdflush)
  925. .long SYMBOL_NAME(sys_sysfs) /* 135 */
  926. .long SYMBOL_NAME(sys_personality)
  927. .long SYMBOL_NAME(sys_ni_syscall) /* for afs_syscall */
  928. .long SYMBOL_NAME(sys_setfsuid16)
  929. .long SYMBOL_NAME(sys_setfsgid16)
  930. .long SYMBOL_NAME(sys_llseek) /* 140 */
  931. .long SYMBOL_NAME(sys_getdents)
  932. .long SYMBOL_NAME(sys_select)
  933. .long SYMBOL_NAME(sys_flock)
  934. .long SYMBOL_NAME(sys_msync)
  935. .long SYMBOL_NAME(sys_readv) /* 145 */
  936. .long SYMBOL_NAME(sys_writev)
  937. .long SYMBOL_NAME(sys_getsid)
  938. .long SYMBOL_NAME(sys_fdatasync)
  939. .long SYMBOL_NAME(sys_sysctl)
  940. .long SYMBOL_NAME(sys_mlock) /* 150 */
  941. .long SYMBOL_NAME(sys_munlock)
  942. .long SYMBOL_NAME(sys_mlockall)
  943. .long SYMBOL_NAME(sys_munlockall)
  944. .long SYMBOL_NAME(sys_sched_setparam)
  945. .long SYMBOL_NAME(sys_sched_getparam)   /* 155 */
  946. .long SYMBOL_NAME(sys_sched_setscheduler)
  947. .long SYMBOL_NAME(sys_sched_getscheduler)
  948. .long SYMBOL_NAME(sys_sched_yield)
  949. .long SYMBOL_NAME(sys_sched_get_priority_max)
  950. .long SYMBOL_NAME(sys_sched_get_priority_min)  /* 160 */
  951. .long SYMBOL_NAME(sys_sched_rr_get_interval)
  952. .long SYMBOL_NAME(sys_nanosleep)
  953. .long SYMBOL_NAME(sys_mremap)
  954. .long SYMBOL_NAME(sys_setresuid16)
  955. .long SYMBOL_NAME(sys_getresuid16) /* 165 */
  956. .long SYMBOL_NAME(sys_ni_syscall) /* sys_vm86 */
  957. .long SYMBOL_NAME(sys_query_module)
  958. .long SYMBOL_NAME(sys_poll)
  959. .long SYMBOL_NAME(sys_nfsservctl)
  960. .long SYMBOL_NAME(sys_setresgid16) /* 170 */
  961. .long SYMBOL_NAME(sys_getresgid16)
  962. .long SYMBOL_NAME(sys_prctl)
  963. .long SYMBOL_NAME(sys_rt_sigreturn)
  964. .long SYMBOL_NAME(sys_rt_sigaction)
  965. .long SYMBOL_NAME(sys_rt_sigprocmask) /* 175 */
  966. .long SYMBOL_NAME(sys_rt_sigpending)
  967. .long SYMBOL_NAME(sys_rt_sigtimedwait)
  968. .long SYMBOL_NAME(sys_rt_sigqueueinfo)
  969. .long SYMBOL_NAME(sys_rt_sigsuspend)
  970. .long SYMBOL_NAME(sys_pread) /* 180 */
  971. .long SYMBOL_NAME(sys_pwrite)
  972. .long SYMBOL_NAME(sys_chown16)
  973. .long SYMBOL_NAME(sys_getcwd)
  974. .long SYMBOL_NAME(sys_capget)
  975. .long SYMBOL_NAME(sys_capset)           /* 185 */
  976. .long SYMBOL_NAME(sys_sigaltstack)
  977. .long SYMBOL_NAME(sys_sendfile)
  978. .long SYMBOL_NAME(sys_ni_syscall) /* streams1 */
  979. .long SYMBOL_NAME(sys_ni_syscall) /* streams2 */
  980. .long SYMBOL_NAME(sys_vfork)            /* 190 */
  981. .long SYMBOL_NAME(sys_getrlimit)
  982. .long SYMBOL_NAME(sys_mmap2)
  983. .long SYMBOL_NAME(sys_truncate64)
  984. .long SYMBOL_NAME(sys_ftruncate64)
  985. .long SYMBOL_NAME(sys_stat64) /* 195 */
  986. .long SYMBOL_NAME(sys_lstat64)
  987. .long SYMBOL_NAME(sys_fstat64)
  988. .long SYMBOL_NAME(sys_lchown)
  989. .long SYMBOL_NAME(sys_getuid)
  990. .long SYMBOL_NAME(sys_getgid) /* 200 */
  991. .long SYMBOL_NAME(sys_geteuid)
  992. .long SYMBOL_NAME(sys_getegid)
  993. .long SYMBOL_NAME(sys_setreuid)
  994. .long SYMBOL_NAME(sys_setregid)
  995. .long SYMBOL_NAME(sys_getgroups) /* 205 */
  996. .long SYMBOL_NAME(sys_setgroups)
  997. .long SYMBOL_NAME(sys_fchown)
  998. .long SYMBOL_NAME(sys_setresuid)
  999. .long SYMBOL_NAME(sys_getresuid)
  1000. .long SYMBOL_NAME(sys_setresgid) /* 210 */
  1001. .long SYMBOL_NAME(sys_getresgid)
  1002. .long SYMBOL_NAME(sys_chown)
  1003. .long SYMBOL_NAME(sys_setuid)
  1004. .long SYMBOL_NAME(sys_setgid)
  1005. .long SYMBOL_NAME(sys_setfsuid) /* 215 */
  1006. .long SYMBOL_NAME(sys_setfsgid)
  1007. .long SYMBOL_NAME(sys_pivot_root)
  1008. .long SYMBOL_NAME(sys_mincore)
  1009. .long SYMBOL_NAME(sys_madvise)
  1010. .long SYMBOL_NAME(sys_getdents64)       /* 220 */
  1011. .long SYMBOL_NAME(sys_fcntl64)
  1012. .long SYMBOL_NAME(sys_ni_syscall) /* reserved for TUX */
  1013.         .long SYMBOL_NAME(sys_ni_syscall)       /* Reserved for Security */
  1014.         .long SYMBOL_NAME(sys_gettid)
  1015.         .long SYMBOL_NAME(sys_readahead)        /* 225 */
  1017.         /*
  1018.          * NOTE!! This doesn't have to be exact - we just have
  1019.          * to make sure we have _enough_ of the "sys_ni_syscall"
  1020.          * entries. Don't panic if you notice that this hasn't
  1021.          * been shrunk every time we add a new system call.
  1022.          */
  1024. .rept NR_syscalls-(.-sys_call_table)/4
  1025. .long SYMBOL_NAME(sys_ni_syscall)
  1026. .endr