开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > 嵌入式Linux > 查看源码
ip22-irq.S
资源名称：SBC-2410X_kernel.tar.gz　[点击查看]
上传用户：lgb322
上传日期：2013-02-24
资源大小：30529k
文件大小：3k
源码类别：

嵌入式Linux

开发平台：

Unix_Linux

ip22-irq.S：源码内容
  1. /*
  2.  * This file is subject to the terms and conditions of the GNU General Public
  3.  * License.  See the file "COPYING" in the main directory of this archive
  4.  * for more details.
  5.  *
  6.  * indyIRQ.S: Interrupt exception dispatch code for FullHouse and
  7.  *            Guiness.
  8.  *
  9.  * Copyright (C) 1996 David S. Miller (dm@engr.sgi.com)
  10.  */
  11. #include <asm/asm.h>
  12. #include <asm/mipsregs.h>
  13. #include <asm/regdef.h>
  14. #include <asm/stackframe.h>
  16. /* A lot of complication here is taken away because:
  17.  *
  18.  * 1) We handle one interrupt and return, sitting in a loop and moving across
  19.  *    all the pending IRQ bits in the cause register is _NOT_ the answer, the
  20.  *    common case is one pending IRQ so optimize in that direction.
  21.  *
  22.  * 2) We need not check against bits in the status register IRQ mask, that
  23.  *    would make this routine slow as hell.
  24.  *
  25.  * 3) Linux only thinks in terms of all IRQs on or all IRQs off, nothing in
  26.  *    between like BSD spl() brain-damage.
  27.  *
  28.  * Furthermore, the IRQs on the INDY look basically (barring software IRQs
  29.  * which we don't use at all) like:
  30.  *
  31.  * MIPS IRQ Source
  32.  *      --------        ------
  33.  *             0 Software (ignored)
  34.  *             1        Software (ignored)
  35.  *             2        Local IRQ level zero
  36.  *             3        Local IRQ level one
  37.  *             4        8254 Timer zero
  38.  *             5        8254 Timer one
  39.  *             6        Bus Error
  40.  *             7        R4k timer (what we use)
  41.  *
  42.  * We handle the IRQ according to _our_ priority which is:
  43.  *
  44.  * Highest ----     R4k Timer
  45.  *                  Local IRQ zero
  46.  *                  Local IRQ one
  47.  *                  Bus Error
  48.  *                  8254 Timer zero
  49.  * Lowest  ----     8254 Timer one
  50.  *
  51.  * then we just return, if multiple IRQs are pending then we will just take
  52.  * another exception, big deal.
  53.  */
  55. .text
  56. .set noreorder
  57. .set noat
  58. .align 5
  59. NESTED(indyIRQ, PT_SIZE, sp)
  60. SAVE_ALL
  61. CLI
  62. .set at
  63. mfc0 s0, CP0_CAUSE # get irq mask
  65. /* First we check for r4k counter/timer IRQ. */
  66. andi a0, s0, CAUSEF_IP7
  67. beq a0, zero, 1f
  68.  andi a0, s0, CAUSEF_IP2 # delay slot, check local level zero
  70. /* Wheee, a timer interrupt. */
  71. move a0, sp
  72. jal indy_timer_interrupt
  73.  nop # delay slot
  75. j ret_from_irq
  76.  nop # delay slot
  78. 1:
  79. beq a0, zero, 1f
  80.  andi a0, s0, CAUSEF_IP3 # delay slot, check local level one
  82. /* Wheee, local level zero interrupt. */
  83. jal indy_local0_irqdispatch
  84.  move a0, sp # delay slot
  86. j ret_from_irq
  87.  nop # delay slot
  89. 1:
  90. beq a0, zero, 1f
  91.  andi a0, s0, CAUSEF_IP6 # delay slot, check bus error
  93. /* Wheee, local level one interrupt. */
  94. move a0, sp
  95. jal indy_local1_irqdispatch
  96.  nop
  98. j ret_from_irq
  99.  nop
  101. 1:
  102. beq a0, zero, 1f
  103.  nop
  105. /* Wheee, an asynchronous bus error... */
  106. move a0, sp
  107. jal indy_buserror_irq
  108.  nop
  110. j ret_from_irq
  111.  nop
  113. 1:
  114. /* Here by mistake?  This is possible, what can happen
  115.  * is that by the time we take the exception the IRQ
  116.  * pin goes low, so just leave if this is the case.
  117.  */
  118. andi a0, s0, (CAUSEF_IP4 | CAUSEF_IP5)
  119. beq a0, zero, 1f
  121. /* Must be one of the 8254 timers... */
  122. move a0, sp
  123. jal indy_8254timer_irq
  124.  nop
  125. 1:
  126. j ret_from_irq
  127.  nop
  128. END(indyIRQ)