开通博客赚积分
发布资源赚积分
分类

源码开发语言/平台
当前位置：首页 > 源码/资料 > 嵌入式/单片机编程 > 嵌入式Linux > 查看源码
entry.S
资源名称：SBC-2410X_kernel.tar.gz　[点击查看]
上传用户：lgb322
上传日期：2013-02-24
资源大小：30529k
文件大小：33k
源码类别：

嵌入式Linux

开发平台：

Unix_Linux

entry.S：源码内容
  1. /*
  2.  *  arch/s390/kernel/entry.S
  3.  *    S390 low-level entry points.
  4.  *
  5.  *  S390 version
  6.  *    Copyright (C) 1999,2000 IBM Deutschland Entwicklung GmbH, IBM Corporation
  7.  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
  8.  *               Hartmut Penner (hp@de.ibm.com),
  9.  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
  10.  */
  12. #include <linux/sys.h>
  13. #include <linux/linkage.h>
  14. #include <linux/config.h>
  15. #include <asm/cache.h>
  16. #include <asm/lowcore.h>
  17. #include <asm/errno.h>
  18. #include <asm/smp.h>
  19. #include <asm/ptrace.h>
  21. /*
  22.  * Stack layout for the system_call stack entry.
  23.  * The first few entries are identical to the user_regs_struct.
  24.  */
  25. SP_PTREGS    =  STACK_FRAME_OVERHEAD 
  26. SP_PSW       =  STACK_FRAME_OVERHEAD + PT_PSWMASK
  27. SP_R0        =  STACK_FRAME_OVERHEAD + PT_GPR0
  28. SP_R1        =  STACK_FRAME_OVERHEAD + PT_GPR1
  29. SP_R2        =  STACK_FRAME_OVERHEAD + PT_GPR2
  30. SP_R3        =  STACK_FRAME_OVERHEAD + PT_GPR3
  31. SP_R4        =  STACK_FRAME_OVERHEAD + PT_GPR4
  32. SP_R5        =  STACK_FRAME_OVERHEAD + PT_GPR5
  33. SP_R6        =  STACK_FRAME_OVERHEAD + PT_GPR6
  34. SP_R7        =  STACK_FRAME_OVERHEAD + PT_GPR7
  35. SP_R8        =  STACK_FRAME_OVERHEAD + PT_GPR8
  36. SP_R9        =  STACK_FRAME_OVERHEAD + PT_GPR9
  37. SP_R10       =  STACK_FRAME_OVERHEAD + PT_GPR10
  38. SP_R11       =  STACK_FRAME_OVERHEAD + PT_GPR11
  39. SP_R12       =  STACK_FRAME_OVERHEAD + PT_GPR12
  40. SP_R13       =  STACK_FRAME_OVERHEAD + PT_GPR13
  41. SP_R14       =  STACK_FRAME_OVERHEAD + PT_GPR14
  42. SP_R15       =  STACK_FRAME_OVERHEAD + PT_GPR15
  43. SP_AREGS     =  STACK_FRAME_OVERHEAD + PT_ACR0
  44. SP_ORIG_R2   =  STACK_FRAME_OVERHEAD + PT_ORIGGPR2
  45. /* Now the additional entries */
  46. SP_TRAP      =  (SP_ORIG_R2+GPR_SIZE)
  47. #if CONFIG_REMOTE_DEBUG
  48. SP_CRREGS    =  (SP_TRAP+4)
  49. /* fpu registers are saved & restored by the gdb stub itself */
  50. SP_FPC       =  (SP_CRREGS+(NUM_CRS*CR_SIZE))
  51. SP_FPRS      =  (SP_FPC+FPC_SIZE+FPC_PAD_SIZE)
  52. SP_PGM_OLD_ILC= (SP_FPRS+(NUM_FPRS*FPR_SIZE))
  53. #else
  54. SP_PGM_OLD_ILC= (SP_TRAP+4)
  55. #endif
  56. SP_SIZE      =  (SP_PGM_OLD_ILC+4)
  57. /*
  58.  * these defines are offsets into the thread_struct
  59.  */
  60. _TSS_PTREGS  = 0
  61. _TSS_FPRS    = (_TSS_PTREGS+8)
  62. _TSS_AR2     = (_TSS_FPRS+136)
  63. _TSS_AR4     = (_TSS_AR2+4)
  64. _TSS_KSP     = (_TSS_AR4+4)
  65. _TSS_USERSEG = (_TSS_KSP+4)
  66. _TSS_ERROR   = (_TSS_USERSEG+4)
  67. _TSS_PROT    = (_TSS_ERROR+4)
  68. _TSS_TRAP    = (_TSS_PROT+4)
  69. _TSS_MM      = (_TSS_TRAP+4)
  70. _TSS_PER     = (_TSS_MM+8)
  71. _TSS_IEEE    = (_TSS_PER+36)
  72. _TSS_FLAGS   = (_TSS_IEEE+4)
  74. /*
  75.  * these are offsets into the task-struct.
  76.  */
  77. state        =  0
  78. flags        =  4
  79. sigpending   =  8
  80. need_resched = 24
  81. tsk_ptrace   = 28
  82. processor    = 52
  84. /*
  85.  * Base Address of this Module --- saved in __LC_ENTRY_BASE
  86.  */
  87.        .globl entry_base
  88. entry_base:
  90. #define BASED(name) name-entry_base(%r13)
  92. /*
  93.  * Register usage in interrupt handlers:
  94.  *    R9  - pointer to current task structure
  95.  *    R13 - pointer to literal pool
  96.  *    R14 - return register for function calls
  97.  *    R15 - kernel stack pointer
  98.  */
  100.         .macro  SAVE_ALL psworg,sync      # system entry macro
  101.         stm     %r13,%r15,__LC_SAVE_AREA
  102.         basr    %r13,0                    #  temp base pointer
  103.         l       %r13,.Lentry_base-.(%r13) # load &entry_base to %r13 
  104.         tm      psworg+1,0x01            # test problem state bit
  105.         stam    %a2,%a4,__LC_SAVE_AREA+12
  106. .if sync
  107.         bz      BASED(1f)                 # skip stack setup save
  108. .else
  109.         bnz     BASED(0f)                 # from user -> load kernel stack
  110. l %r14,__LC_ASYNC_STACK   # are we already on the async stack ?
  111. slr     %r14,%r15
  112. sra %r14,13
  113. be BASED(1f)
  114.         l       %r15,__LC_ASYNC_STACK     # load async. stack
  115. b BASED(1f)
  116. .endif
  117. 0:      l       %r15,__LC_KERNEL_STACK    # problem state -> load ksp
  118. lam %a2,%a4,BASED(.Lc_ac)   # set ac.reg. 2 to primary space
  119.   # and ac.reg. 4 to home space
  120. 1:      s       %r15,BASED(.Lc_spsize)    # make room for registers & psw
  121.         n       %r15,BASED(.Lc0xfffffff8) # align stack pointer to 8
  122.         stm     %r0,%r12,SP_R0(%r15)      # store gprs 0-12 to kernel stack
  123.         st      %r2,SP_ORIG_R2(%r15)      # store original content of gpr 2
  124.         mvc     SP_R13(12,%r15),__LC_SAVE_AREA  # move R13-R15 to stack
  125.         stam    %a0,%a15,SP_AREGS(%r15)   # store access registers to kst.
  126.         mvc     SP_AREGS+8(12,%r15),__LC_SAVE_AREA+12 # store ac. regs
  127.         mvc     SP_PSW(8,%r15),psworg    # move user PSW to stack
  128.         la      %r0,psworg               # store trap indication
  129.         st      %r0,SP_TRAP(%r15)
  130.         xc      0(4,%r15),0(%r15)         # clear back chain
  131.         .endm
  133.         .macro  RESTORE_ALL sync          # system exit macro
  134.         mvc     __LC_RETURN_PSW(8),SP_PSW(%r15)  # move user PSW to lowcore
  135.         lam     %a0,%a15,SP_AREGS(%r15)   # load the access registers
  136.         lm      %r0,%r15,SP_R0(%r15)      # load gprs 0-15 of user
  137.         ni      __LC_RETURN_PSW+1,0xfd    # clear wait state bit
  138.         lpsw    __LC_RETURN_PSW           # back to caller
  139.         .endm
  141.         .macro  GET_CURRENT
  142. l %r9,BASED(.Lc0xffffe000)  # load pointer to task_struct to %r9
  143. al %r9,__LC_KERNEL_STACK
  144.         .endm
  147. /*
  148.  * Scheduler resume function, called by switch_to
  149.  *  grp2 = (thread_struct *) prev->tss
  150.  *  grp3 = (thread_struct *) next->tss
  151.  * Returns:
  152.  *  gpr2 = prev
  153.  */
  154.         .globl  resume
  155. resume:
  156.         basr    %r1,0
  157. resume_base:
  158.         l       %r4,_TSS_PTREGS(%r3)
  159.         tm      SP_PSW-SP_PTREGS(%r4),0x40 # is the new process using per ?
  160.         bz      resume_noper-resume_base(%r1) # if not we're fine
  161.         stctl   %c9,%c11,24(%r15)             # We are using per stuff
  162.         clc     _TSS_PER(12,%r3),24(%r15)
  163.         be      resume_noper-resume_base(%r1) # we got away w/o bashing TLB's
  164.         lctl    %c9,%c11,_TSS_PER(%r3)        # Nope we didn't
  165. resume_noper:
  166.         stm     %r6,%r15,24(%r15)       # store resume registers of prev task
  167.         st      %r15,_TSS_KSP(%r2) # store kernel stack ptr to prev->tss.ksp
  168.         lr      %r0,%r15
  169.         n       %r0,.Lc0xffffe000-resume_base(%r1)
  170.         l       %r15,_TSS_KSP(%r3) # load kernel stack ptr from next->tss.ksp
  171.         l       %r1,.Lc8191-resume_base(%r1)
  172.         or      %r1,%r15
  173.         la      %r1,1(%r1)
  174.         st      %r1,__LC_KERNEL_STACK   # __LC_KERNEL_STACK = new kernel stack
  175.         stam    %a2,%a2,_TSS_AR2(%r2)   # store kernel access reg. 2
  176.         stam    %a4,%a4,_TSS_AR4(%r2)   # store kernel access reg. 4
  177.         lam     %a2,%a2,_TSS_AR2(%r3)   # load kernel access reg. 2
  178.         lam     %a4,%a4,_TSS_AR4(%r3)   # load kernel access reg. 4
  179.         lr      %r2,%r0                 # return task_struct of last task
  180.         lm      %r6,%r15,24(%r15)       # load resume registers of next task
  181.         br      %r14
  183. /*
  184.  * do_softirq calling function. We want to run the softirq functions on the
  185.  * asynchronous interrupt stack.
  186.  */
  187. .global do_call_softirq
  188. do_call_softirq:
  189. stm %r12,%r15,24(%r15)
  190. lr %r12,%r15
  191.         basr    %r13,0
  192. do_call_base:
  193. l %r0,__LC_ASYNC_STACK
  194. slr     %r0,%r15
  195. sra %r0,13
  196. be 0f-do_call_base(%r13)
  197. l %r15,__LC_ASYNC_STACK
  198. 0: sl %r15,.Lc_overhead-do_call_base(%r13)
  199.         st %r12,0(%r15) # store backchain
  200. l %r1,.Ldo_softirq-do_call_base(%r13)
  201. basr %r14,%r1
  202. lm %r12,%r15,24(%r12)
  203. br %r14
  205. /*
  206.  * SVC interrupt handler routine. System calls are synchronous events and
  207.  * are executed with interrupts enabled.
  208.  */
  210. .globl  system_call
  211. system_call:
  212.         SAVE_ALL __LC_SVC_OLD_PSW,1
  213. mvi     SP_PGM_OLD_ILC(%r15),1  # mark PGM_OLD_ILC as invalid
  214. pgm_system_call:
  215.         GET_CURRENT               # load pointer to task_struct to R9
  216.         slr     %r8,%r8           # gpr 8 is call save (-> tracesys)
  217.         ic      %r8,0x8B          # get svc number from lowcore
  218.         stosm   24(%r15),0x03     # reenable interrupts
  219.         sll     %r8,2
  220.         l       %r8,sys_call_table-entry_base(8,%r13) # get address of system call
  221.         tm      tsk_ptrace+3(%r9),0x02 # PT_TRACESYS
  222.         bnz     BASED(sysc_tracesys)
  223.         basr    %r14,%r8          # call sys_xxxx
  224.         st      %r2,SP_R2(%r15)   # store return value (change R2 on stack)
  225.                                   # ATTENTION: check sys_execve_glue before
  226.                                   # changing anything here !!
  228. sysc_return:
  229.         tm      SP_PSW+1(%r15),0x01 # returning to user ?
  230.         bno     BASED(sysc_leave) # no-> skip resched & signal
  231. #
  232. # check, if reschedule is needed
  233. #
  234.         icm     %r0,15,need_resched(%r9) # get need_resched from task_struct
  235.         bnz     BASED(sysc_reschedule)
  236.         icm     %r0,15,sigpending(%r9)   # get sigpending from task_struct
  237.         bnz     BASED(sysc_signal_return)
  238. sysc_leave:
  239. tm      SP_PGM_OLD_ILC(%r15),0xff
  240.         bz      BASED(pgm_svcret)
  241. stnsm   24(%r15),0xfc            # disable I/O and ext. interrupts
  242.         RESTORE_ALL 1
  244. #
  245. # call do_signal before return
  246. #
  247. sysc_signal_return:     
  248.         la      %r2,SP_PTREGS(%r15) # load pt_regs
  249.         sr      %r3,%r3           # clear *oldset
  250.         l       %r1,BASED(.Ldo_signal)
  251. la      %r14,BASED(sysc_leave)
  252.         br      %r1               # return point is sysc_leave
  254. #
  255. # call trace before and after sys_call
  256. #
  257. sysc_tracesys:
  258.         l       %r1,BASED(.Ltrace)
  259. l       %r7,BASED(.Lc_ENOSYS)
  260. st      %r7,SP_R2(%r15)   # give sysc_trace an -ENOSYS retval
  261.         basr    %r14,%r1
  262. l       %r2,SP_R2(%r15)
  263. cr      %r2,%r7 # compare with saved -ENOSYS
  264. be      BASED(sysc_tracesys_dn1)
  265. # strace wants to change the syscall
  266. sll     %r2,24
  267. srl     %r2,22
  268.         l       %r8,sys_call_table-entry_base(2,%r13) # get address of system call    
  269. sysc_tracesys_dn1:
  270. lm      %r3,%r6,SP_R3(%r15)
  271. l       %r2,SP_ORIG_R2(%r15)
  272.         basr    %r14,%r8          # call sys_xxx
  273.         st      %r2,SP_R2(%r15)   # store return value
  274.         l       %r1,BASED(.Ltrace)
  275. la      %r14,BASED(sysc_return)
  276.         br      %r1               # return point is sysc_return
  279. #
  280. # call schedule with sysc_return as return-address
  281. #
  282. sysc_reschedule:        
  283.         l       %r1,BASED(.Lschedule)
  284. la      %r14,BASED(sysc_return)
  285.         br      %r1               # call scheduler, return to sysc_return
  287. #
  288. # a new process exits the kernel with ret_from_fork
  289. #
  290.         .globl  ret_from_fork
  291. ret_from_fork:  
  292.         basr    %r13,0
  293.         l       %r13,.Lentry_base-.(%r13)  # setup base pointer to &entry_base
  294.         GET_CURRENT               # load pointer to task_struct to R9
  295.         stosm   24(%r15),0x03     # reenable interrupts
  296.         sr      %r0,%r0           # child returns 0
  297.         st      %r0,SP_R2(%r15)   # store return value (change R2 on stack)
  298. #ifdef CONFIG_SMP
  299.         l       %r1,BASED(.Lschedtail)
  300. la      %r14,BASED(sysc_return)
  301.         br      %r1               # call schedule_tail, return to sysc_return
  302. #else
  303.         b       BASED(sysc_return)
  304. #endif
  306. #
  307. # clone, fork, vfork, exec and sigreturn need glue,
  308. # because they all expect pt_regs as parameter,
  309. # but are called with different parameter.
  310. # return-address is set up above
  311. #
  312. sys_clone_glue: 
  313.         la      %r2,SP_PTREGS(%r15)    # load pt_regs
  314.         l       %r1,BASED(.Lclone)
  315.         br      %r1                   # branch to sys_clone
  317. sys_fork_glue:  
  318.         la      %r2,SP_PTREGS(%r15)    # load pt_regs
  319.         l       %r1,BASED(.Lfork)
  320.         br      %r1                   # branch to sys_fork
  322. sys_vfork_glue: 
  323.         la      %r2,SP_PTREGS(%r15)    # load pt_regs
  324.         l       %r1,BASED(.Lvfork)
  325.         br      %r1                   # branch to sys_vfork
  327. sys_execve_glue:        
  328.         la      %r2,SP_PTREGS(%r15)   # load pt_regs
  329.         l       %r1,BASED(.Lexecve)
  330. lr      %r12,%r14             # save return address
  331.         basr    %r14,%r1              # call sys_execve
  332.         ltr     %r2,%r2               # check if execve failed
  333.         bnz     0(%r12)               # it did fail -> store result in gpr2
  334.         b       4(%r12)               # SKIP ST 2,SP_R2(15) after BASR 14,8
  335.                                       # in system_call/sysc_tracesys
  337. sys_sigreturn_glue:     
  338.         la      %r2,SP_PTREGS(%r15)   # load pt_regs as parameter
  339.         l       %r1,BASED(.Lsigreturn)
  340.         br      %r1                   # branch to sys_sigreturn
  342. sys_rt_sigreturn_glue:     
  343.         la      %r2,SP_PTREGS(%r15)   # load pt_regs as parameter
  344.         l       %r1,BASED(.Lrt_sigreturn)
  345.         br      %r1                   # branch to sys_sigreturn
  347. #
  348. # sigsuspend and rt_sigsuspend need pt_regs as an additional
  349. # parameter and they have to skip the store of %r2 into the
  350. # user register %r2 because the return value was set in 
  351. # sigsuspend and rt_sigsuspend already and must not be overwritten!
  352. #
  354. sys_sigsuspend_glue:    
  355.         lr      %r5,%r4               # move mask back
  356.         lr      %r4,%r3               # move history1 parameter
  357.         lr      %r3,%r2               # move history0 parameter
  358.         la      %r2,SP_PTREGS(%r15)   # load pt_regs as first parameter
  359.         l       %r1,BASED(.Lsigsuspend)
  360. la      %r14,4(%r14)          # skip store of return value
  361.         br      %r1                   # branch to sys_sigsuspend
  363. sys_rt_sigsuspend_glue: 
  364.         lr      %r4,%r3               # move sigsetsize parameter
  365.         lr      %r3,%r2               # move unewset parameter
  366.         la      %r2,SP_PTREGS(%r15)   # load pt_regs as first parameter
  367.         l       %r1,BASED(.Lrt_sigsuspend)
  368. la      %r14,4(%r14)          # skip store of return value
  369.         br      %r1                   # branch to sys_rt_sigsuspend
  371. sys_sigaltstack_glue:
  372.         la      %r4,SP_PTREGS(%r15)   # load pt_regs as parameter
  373.         l       %r1,BASED(.Lsigaltstack)
  374.         br      %r1                   # branch to sys_sigreturn
  376. .globl  sys_call_table
  377. sys_call_table:
  378.         .long  sys_ni_syscall            /* 0 */
  379.         .long  sys_exit
  380.         .long  sys_fork_glue
  381.         .long  sys_read
  382.         .long  sys_write
  383.         .long  sys_open                  /* 5 */
  384.         .long  sys_close
  385.         .long  sys_ni_syscall           /* old waitpid syscall holder */
  386.         .long  sys_creat
  387.         .long  sys_link
  388.         .long  sys_unlink                /* 10 */
  389.         .long  sys_execve_glue
  390.         .long  sys_chdir
  391.         .long  sys_time
  392.         .long  sys_mknod
  393.         .long  sys_chmod                /* 15 */
  394.         .long  sys_lchown16
  395.         .long  sys_ni_syscall           /* old break syscall holder */
  396.         .long  sys_ni_syscall           /* old stat syscall holder */
  397.         .long  sys_lseek
  398.         .long  sys_getpid               /* 20 */
  399.         .long  sys_mount
  400.         .long  sys_oldumount
  401.         .long  sys_setuid16
  402.         .long  sys_getuid16
  403.         .long  sys_stime                /* 25 */
  404.         .long  sys_ptrace
  405.         .long  sys_alarm
  406.         .long  sys_ni_syscall           /* old fstat syscall holder */
  407.         .long  sys_pause
  408.         .long  sys_utime                /* 30 */
  409.         .long  sys_ni_syscall           /* old stty syscall holder */
  410.         .long  sys_ni_syscall           /* old gtty syscall holder */
  411.         .long  sys_access
  412.         .long  sys_nice
  413.         .long  sys_ni_syscall           /* 35 */  /* old ftime syscall holder */
  414.         .long  sys_sync
  415.         .long  sys_kill
  416.         .long  sys_rename
  417.         .long  sys_mkdir
  418.         .long  sys_rmdir                /* 40 */
  419.         .long  sys_dup
  420.         .long  sys_pipe
  421.         .long  sys_times
  422.         .long  sys_ni_syscall           /* old prof syscall holder */
  423.         .long  sys_brk                  /* 45 */
  424.         .long  sys_setgid16
  425.         .long  sys_getgid16
  426.         .long  sys_signal
  427.         .long  sys_geteuid16
  428.         .long  sys_getegid16            /* 50 */
  429.         .long  sys_acct
  430.         .long  sys_umount
  431.         .long  sys_ni_syscall           /* old lock syscall holder */
  432.         .long  sys_ioctl
  433.         .long  sys_fcntl                /* 55 */
  434.         .long  sys_ni_syscall           /* old mpx syscall holder */
  435.         .long  sys_setpgid
  436.         .long  sys_ni_syscall           /* old ulimit syscall holder */
  437.         .long  sys_ni_syscall           /* old uname syscall holder */
  438.         .long  sys_umask                /* 60 */
  439.         .long  sys_chroot
  440.         .long  sys_ustat
  441.         .long  sys_dup2
  442.         .long  sys_getppid
  443.         .long  sys_getpgrp              /* 65 */
  444.         .long  sys_setsid
  445.         .long  sys_sigaction
  446.         .long  sys_ni_syscall           /* old sgetmask syscall holder */
  447.         .long  sys_ni_syscall           /* old ssetmask syscall holder */
  448.         .long  sys_setreuid16           /* 70 */
  449.         .long  sys_setregid16
  450.         .long  sys_sigsuspend_glue
  451.         .long  sys_sigpending
  452.         .long  sys_sethostname
  453.         .long  sys_setrlimit            /* 75 */
  454.         .long  sys_old_getrlimit
  455.         .long  sys_getrusage
  456.         .long  sys_gettimeofday
  457.         .long  sys_settimeofday
  458.         .long  sys_getgroups16          /* 80 */
  459.         .long  sys_setgroups16
  460.         .long  sys_ni_syscall           /* old select syscall holder */
  461.         .long  sys_symlink
  462.         .long  sys_ni_syscall           /* old lstat syscall holder */
  463.         .long  sys_readlink             /* 85 */
  464.         .long  sys_uselib
  465.         .long  sys_swapon
  466.         .long  sys_reboot
  467.         .long  sys_ni_syscall           /* old readdir syscall holder */
  468.         .long  old_mmap                 /* 90 */
  469.         .long  sys_munmap
  470.         .long  sys_truncate
  471.         .long  sys_ftruncate
  472.         .long  sys_fchmod
  473.         .long  sys_fchown16              /* 95 */
  474.         .long  sys_getpriority
  475.         .long  sys_setpriority
  476.         .long  sys_ni_syscall            /* old profil syscall holder */
  477.         .long  sys_statfs
  478.         .long  sys_fstatfs               /* 100 */
  479.         .long  sys_ioperm
  480.         .long  sys_socketcall
  481.         .long  sys_syslog
  482.         .long  sys_setitimer
  483.         .long  sys_getitimer             /* 105 */
  484.         .long  sys_newstat
  485.         .long  sys_newlstat
  486.         .long  sys_newfstat
  487.         .long  sys_ni_syscall            /* old uname syscall holder */
  488.         .long  sys_ni_syscall            /* 110 */ /* iopl for i386 */
  489.         .long  sys_vhangup
  490.         .long  sys_ni_syscall            /* old "idle" system call */
  491.         .long  sys_ni_syscall            /* vm86old for i386 */
  492.         .long  sys_wait4
  493.         .long  sys_swapoff               /* 115 */
  494.         .long  sys_sysinfo
  495.         .long  sys_ipc
  496.         .long  sys_fsync
  497.         .long  sys_sigreturn_glue
  498.         .long  sys_clone_glue            /* 120 */
  499.         .long  sys_setdomainname
  500.         .long  sys_newuname
  501.         .long  sys_ni_syscall            /* modify_ldt for i386 */
  502.         .long  sys_adjtimex
  503.         .long  sys_mprotect              /* 125 */
  504.         .long  sys_sigprocmask
  505.         .long  sys_create_module
  506.         .long  sys_init_module
  507.         .long  sys_delete_module
  508.         .long  sys_get_kernel_syms       /* 130 */
  509.         .long  sys_quotactl
  510.         .long  sys_getpgid
  511.         .long  sys_fchdir
  512.         .long  sys_bdflush
  513.         .long  sys_sysfs                 /* 135 */
  514.         .long  sys_personality
  515.         .long  sys_ni_syscall            /* for afs_syscall */
  516.         .long  sys_setfsuid16
  517.         .long  sys_setfsgid16
  518.         .long  sys_llseek                /* 140 */
  519.         .long  sys_getdents
  520.         .long  sys_select
  521.         .long  sys_flock
  522.         .long  sys_msync
  523.         .long  sys_readv                 /* 145 */
  524.         .long  sys_writev
  525.         .long  sys_getsid
  526.         .long  sys_fdatasync
  527.         .long  sys_sysctl
  528.         .long  sys_mlock                 /* 150 */
  529.         .long  sys_munlock
  530.         .long  sys_mlockall
  531.         .long  sys_munlockall
  532.         .long  sys_sched_setparam
  533.         .long  sys_sched_getparam        /* 155 */
  534.         .long  sys_sched_setscheduler
  535.         .long  sys_sched_getscheduler
  536.         .long  sys_sched_yield
  537.         .long  sys_sched_get_priority_max
  538.         .long  sys_sched_get_priority_min  /* 160 */
  539.         .long  sys_sched_rr_get_interval
  540.         .long  sys_nanosleep
  541.         .long  sys_mremap
  542.         .long  sys_setresuid16
  543.         .long  sys_getresuid16           /* 165 */
  544.         .long  sys_ni_syscall            /* for vm86 */
  545.         .long  sys_query_module
  546.         .long  sys_poll
  547.         .long  sys_nfsservctl
  548.         .long  sys_setresgid16           /* 170 */
  549.         .long  sys_getresgid16
  550.         .long  sys_prctl
  551.         .long  sys_rt_sigreturn_glue
  552.         .long  sys_rt_sigaction
  553.         .long  sys_rt_sigprocmask        /* 175 */
  554.         .long  sys_rt_sigpending
  555.         .long  sys_rt_sigtimedwait
  556.         .long  sys_rt_sigqueueinfo
  557.         .long  sys_rt_sigsuspend_glue
  558.         .long  sys_pread                 /* 180 */
  559.         .long  sys_pwrite
  560.         .long  sys_chown16
  561.         .long  sys_getcwd
  562.         .long  sys_capget
  563.         .long  sys_capset                /* 185 */
  564.         .long  sys_sigaltstack_glue
  565.         .long  sys_sendfile
  566.         .long  sys_ni_syscall            /* streams1 */
  567.         .long  sys_ni_syscall            /* streams2 */
  568.         .long  sys_vfork_glue            /* 190 */
  569.         .long  sys_getrlimit
  570. .long  sys_mmap2
  571.         .long  sys_truncate64
  572.         .long  sys_ftruncate64
  573.         .long  sys_stat64                /* 195 */
  574.         .long  sys_lstat64
  575.         .long  sys_fstat64
  576. .long  sys_lchown
  577. .long  sys_getuid
  578. .long  sys_getgid  /* 200 */
  579. .long  sys_geteuid
  580. .long  sys_getegid
  581. .long  sys_setreuid
  582. .long  sys_setregid
  583. .long  sys_getgroups             /* 205 */
  584. .long  sys_setgroups
  585. .long  sys_fchown
  586. .long  sys_setresuid
  587. .long  sys_getresuid
  588. .long  sys_setresgid             /* 210 */
  589. .long  sys_getresgid
  590. .long  sys_chown
  591. .long  sys_setuid
  592. .long  sys_setgid
  593. .long  sys_setfsuid              /* 215 */
  594. .long  sys_setfsgid
  595.         .long  sys_pivot_root
  596.         .long  sys_mincore
  597.         .long  sys_madvise
  598. .long  sys_getdents64  /* 220 */
  599.         .long  sys_fcntl64 
  600. .long  sys_ni_syscall  /* 222 - reserved for posix_acl */
  601. .long  sys_ni_syscall  /* 223 - reserved for posix_acl */
  602. .long  sys_ni_syscall  /* 224 - reserved for posix_acl */
  603. .rept  255-224
  604. .long  sys_ni_syscall
  605. .endr
  607. /*
  608.  * Program check handler routine
  609.  */
  611.         .globl  pgm_check_handler
  612. pgm_check_handler:
  613. /*
  614.  * First we need to check for a special case:
  615.  * Single stepping an instruction that disables the PER event mask will
  616.  * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
  617.  * For a single stepped SVC the program check handler gets control after
  618.  * the SVC new PSW has been loaded. But we want to execute the SVC first and
  619.  * then handle the PER event. Therefore we update the SVC old PSW to point
  620.  * to the pgm_check_handler and branch to the SVC handler after we checked
  621.  * if we have to load the kernel stack register.
  622.  * For every other possible cause for PER event without the PER mask set
  623.  * we just ignore the PER event (FIXME: is there anything we have to do
  624.  * for LPSW?).
  625.  */
  626. stm     %r13,%r15,__LC_SAVE_AREA
  627. basr    %r13,0                   # temp base pointer
  628. l       %r13,.Lentry_base-.(%r13)# load &entry_base to %r13
  629.         tm      __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
  630. stam    %a2,%a4,__LC_SAVE_AREA+12
  631.         bz      BASED(pgm_sv)            # skip if not
  632.         tm      __LC_PGM_OLD_PSW,0x40    # test if per event recording is on
  633.         bnz     BASED(pgm_sv)            # skip if it is
  634. # ok its one of the special cases, now we need to find out which one
  635.         clc     __LC_PGM_OLD_PSW(8),__LC_SVC_NEW_PSW
  636.         be      BASED(pgm_svcper)
  637. # no interesting special case, ignore PER event
  638.         lm      %r13,%r15,__LC_SAVE_AREA
  639. lpsw    0x28
  640. # it was a single stepped SVC that is causing all the trouble
  641. pgm_svcper:
  642.         tm      0x21,0x01                # test problem state bit
  643. bz BASED(.+12)              # skip stack & access regs setup
  644. l %r15,__LC_KERNEL_STACK   # problem state -> load ksp
  645. lam     %a2,%a4,BASED(.Lc_ac)    # set ac.reg. 2 to primary space
  646.                                          # and access reg. 4 to home space
  647. s       %r15,BASED(.Lc_spsize)   # make room for registers & psw
  648.         n       %r15,BASED(.Lc0xfffffff8) # align stack pointer to 8
  649.         stm     %r0,%r12,SP_R0(%r15)     # store gprs 0-12 to kernel stack
  650.         st      %r2,SP_ORIG_R2(%r15)     # store original content of gpr 2
  651.         mvc     SP_R13(12,%r15),__LC_SAVE_AREA # move R13-R15 to stack
  652.         stam    %a0,%a15,SP_AREGS(%r15)  # store access registers to kst.
  653. mvc     SP_AREGS+8(12,%r15),__LC_SAVE_AREA+12 # store ac. regs
  654.         mvc     SP_PSW(8,%r15),0x20      # move user PSW to stack
  655.         la      %r0,0x20                 # store trap indication
  656.         st      %r0,SP_TRAP(%r15)
  657.         xc      0(4,%r15),0(%r15)        # clear back chain
  658.         mvc     SP_PGM_OLD_ILC(4,%r15),__LC_PGM_ILC # save program check information
  659.         b       BASED(pgm_system_call)   # now do the svc
  660. pgm_svcret:
  661.         mvi     SP_TRAP+3(%r15),0x28     # set trap indication back to pgm_chk
  662.         lh      %r7,SP_PGM_OLD_ILC(%r15) # get ilc from stack
  663. mvi     SP_PGM_OLD_ILC(%r15),1   # mark PGM_OLD_ILC as invalid
  664. b       BASED(pgm_no_sv)
  665. pgm_sv:
  666.         tm      0x29,0x01                # test problem state bit
  667. bz BASED(.+12)              # skip stack & access regs setup
  668. l %r15,__LC_KERNEL_STACK   # problem state -> load ksp
  669. lam     %a2,%a4,BASED(.Lc_ac)    # set ac.reg. 2 to primary space
  670.                                          # and access reg. 4 to home space
  671. s       %r15,BASED(.Lc_spsize)   # make room for registers & psw
  672.         n       %r15,BASED(.Lc0xfffffff8) # align stack pointer to 8
  673.         stm     %r0,%r12,SP_R0(%r15)     # store gprs 0-12 to kernel stack
  674.         st      %r2,SP_ORIG_R2(%r15)     # store original content of gpr 2
  675.         mvc     SP_R13(12,%r15),__LC_SAVE_AREA # move R13-R15 to stack
  676.         stam    %a0,%a15,SP_AREGS(%r15)  # store access registers to kst.
  677. mvc     SP_AREGS+8(12,%r15),__LC_SAVE_AREA+12 # store ac. regs
  678.         mvc     SP_PSW(8,%r15),0x28      # move user PSW to stack
  679.         la      %r0,0x28                 # store trap indication
  680.         st      %r0,SP_TRAP(%r15)
  681.         xc      0(4,%r15),0(%r15)        # clear back chain
  682. mvi     SP_PGM_OLD_ILC(%r15),1   # mark PGM_OLD_ILC as invalid
  683.         lh      %r7,__LC_PGM_ILC         # load instruction length
  684. GET_CURRENT
  685. pgm_no_sv:
  686. la %r3,0x7f
  687.         lh      %r8,__LC_PGM_INT_CODE  # N.B. saved int code used later KEEP it
  688. nr      %r3,%r8           # reload & clear per-event-bit
  689.         be      BASED(pgm_dn)     # none of Martins exceptions occurred bypass
  690.         l       %r1,BASED(.Ljump_table)
  691.         sll     %r3,2
  692.         l       %r1,0(%r3,%r1)    # load address of handler routine
  693.         la      %r2,SP_PTREGS(%r15) # address of register-save area
  694.         srl     %r3,2
  695.         cl      %r3,BASED(.Lc4)   # protection-exception ?
  696.         bne     BASED(pgm_per)    # if not,
  697.         l       %r5,SP_PSW+4(15)  # load psw addr
  698.         sr      %r5,%r7           # substract ilc from psw
  699.         st      %r5,SP_PSW+4(15)  # store corrected psw addr
  700. pgm_per:basr    %r14,%r1          # branch to interrupt-handler
  701. pgm_dn: n %r8,BASED(.Lc128) # check for per excepton
  702.         be      BASED(pgm_return)
  703.         la      %r2,SP_PTREGS(15) # address of register-save area
  704.         l       %r1,BASED(.Lhandle_per) # load adr. of per handler
  705.         la      %r14,BASED(sysc_return) # load adr. of system return
  706.         br      %r1               # branch to handle_per_exception
  708. #
  709. # the backend code is the same as for sys-call
  710. #
  711. pgm_return:
  712.         b       BASED(sysc_return)
  714. /*
  715.  * IO interrupt handler routine
  716.  */
  718.         .globl io_int_handler
  719. io_int_handler:
  720.         SAVE_ALL __LC_IO_OLD_PSW,0
  721.         GET_CURRENT               # load pointer to task_struct to R9
  722.         la      %r2,SP_PTREGS(%r15) # address of register-save area
  723.         sr      %r3,%r3
  724.         icm     %r3,%r3,__LC_SUBCHANNEL_NR # load subchannel nr & extend to int
  725.         l       %r4,__LC_IO_INT_PARM       # load interuption parm
  726. l       %r5,__LC_IO_INT_WORD       # load interuption word
  727.         l       %r1,BASED(.Ldo_IRQ)        # load address of do_IRQ
  728.         basr    %r14,%r1          # branch to standard irq handler
  730. io_return:
  731. #
  732. # check, if bottom-half has to be done
  733. #
  734.         l       %r1,processor(%r9)    # get cpu number from task struture
  735.         sll     %r1,L1_CACHE_SHIFT
  736.         al      %r1,BASED(.Lirq_stat) # get address of irq_stat
  737.         icm     %r0,15,0(%r1)         # test irq_stat[#cpu].__softirq_pending
  738.         bnz     BASED(io_handle_bottom_half)
  739. io_return_bh:
  741.         tm      SP_PSW+1(%r15),0x01 # returning to user ?
  742.         bno     BASED(io_leave)   # no-> skip resched & signal
  743.         stosm   24(%r15),0x03     # reenable interrupts
  744. #
  745. # check, if reschedule is needed
  746. #
  747.         icm     %r0,15,need_resched(%r9) # get need_resched from task_struct
  748.         bnz     BASED(io_reschedule)
  749.         icm     %r0,15,sigpending(%r9)   # get sigpending from task_struct
  750.         bnz     BASED(io_signal_return)
  751. io_leave:
  752.         stnsm   24(%r15),0xfc            # disable I/O and ext. interrupts
  753.         RESTORE_ALL 0
  755. #
  756. # call do_softirq
  757. #
  758. io_handle_bottom_half:
  759.         l       %r1,BASED(.Ldo_softirq)
  760.         la      %r14,BASED(io_return_bh)
  761.         br      %r1               # call do_softirq
  763. #
  764. # call schedule with io_return as return-address
  765. #
  766. io_reschedule:        
  767.         l       %r1,BASED(.Lschedule)
  768. la      %r14,BASED(io_return)
  769.         br      %r1               # call scheduler, return to io_return
  771. #
  772. # call do_signal before return
  773. #
  774. io_signal_return:     
  775.         la      %r2,SP_PTREGS(%r15) # load pt_regs
  776.         sr      %r3,%r3           # clear *oldset
  777.         l       %r1,BASED(.Ldo_signal)
  778. la      %r14,BASED(io_leave)
  779.         br      %r1               # return point is io_leave
  781. /*
  782.  * External interrupt handler routine
  783.  */
  785.         .globl  ext_int_handler
  786. ext_int_handler:
  787.         SAVE_ALL __LC_EXT_OLD_PSW,0
  788.         GET_CURRENT                    # load pointer to task_struct to R9
  789.         la      %r2,SP_PTREGS(%r15)    # address of register-save area
  790.         lh      %r3,__LC_EXT_INT_CODE  # error code
  791.         lr      %r1,%r3                # calculate index = code & 0xff
  792.         n       %r1,BASED(.Lc0xff)
  793.         sll     %r1,2
  794.         l       %r4,BASED(.Lext_hash)
  795.         l       %r4,0(%r1,%r4)         # get first list entry for hash value
  796.         ltr     %r4,%r4                # == NULL ?
  797.         bz      BASED(io_return)       # yes, nothing to do, exit
  798. ext_int_loop:
  799.         ch      %r3,8(%r4)             # compare external interrupt code
  800.         be      BASED(ext_int_found)
  801.         icm     %r4,15,0(%r4)          # next list entry
  802.         bnz     BASED(ext_int_loop)
  803.         b       BASED(io_return)
  804. ext_int_found:
  805.         l       %r4,4(%r4)             # get handler address
  806.         la      %r14,BASED(io_return)
  807.         br      %r4                    # branch to ext call handler
  809. /*
  810.  * Machine check handler routines
  811.  */
  813.         .globl mcck_int_handler
  814. mcck_int_handler:
  815.         SAVE_ALL __LC_MCK_OLD_PSW,0
  816. l       %r1,BASED(.Ls390_mcck)
  817. basr    %r14,%r1   # call machine check handler
  818. mcck_return:
  819.         RESTORE_ALL 0
  821. #ifdef CONFIG_SMP
  822. /*
  823.  * Restart interruption handler, kick starter for additional CPUs
  824.  */
  825.         .globl restart_int_handler
  826. restart_int_handler:
  827.         l       %r15,__LC_SAVE_AREA+60 # load ksp
  828.         lctl    %c0,%c15,__LC_CREGS_SAVE_AREA # get new ctl regs
  829.         lam     %a0,%a15,__LC_AREGS_SAVE_AREA
  830.         stosm   0(%r15),0x04           # now we can turn dat on
  831.         lm      %r6,%r15,24(%r15)      # load registers from clone
  832.         basr    %r14,0
  833.         l       %r14,restart_addr-.(%r14)
  834.         br      %r14                   # branch to start_secondary
  835. restart_addr:
  836.         .long   start_secondary
  837. #else
  838. /*
  839.  * If we do not run with SMP enabled, let the new CPU crash ...
  840.  */
  841.         .globl restart_int_handler
  842. restart_int_handler:
  843.         basr    %r1,0
  844. restart_base:
  845.         lpsw    restart_crash-restart_base(%r1)
  846.         .align 8
  847. restart_crash:
  848.         .long  0x000a0000,0x00000000
  849. restart_go:
  850. #endif
  852. /*
  853.  * Integer constants
  854.  */
  855.                .align 4
  856. .Lc0xfffffff8: .long  -8           # to align stack pointer to 8
  857. .Lc0xffffe000: .long  -8192        # to round stack pointer to &task_struct
  858. .Lc8191:       .long  8191
  859. .Lc_spsize:    .long  SP_SIZE
  860. .Lc_overhead:  .long  STACK_FRAME_OVERHEAD
  861. .Lc_ac:        .long  0,0,1
  862. .Lc_ENOSYS:    .long  -ENOSYS
  863. .Lc4:          .long  4
  864. .Lc20:         .long  20
  865. .Lc0x1202:     .long  0x1202
  866. .Lc0x1004:     .long  0x1004
  867. .Lc0x2401:     .long  0x2401
  868. .Lc0x4000:     .long  0x4000
  869. .Lc0xff:       .long  0xff
  870. .Lc128:        .long  128
  872. /*
  873.  * Symbol constants
  874.  */
  875. .Ls390_mcck:   .long  s390_do_machine_check
  876. .Ldo_IRQ:      .long  do_IRQ
  877. .Ldo_signal:   .long  do_signal
  878. .Ldo_softirq:  .long  do_softirq
  879. .Lentry_base:  .long  entry_base
  880. .Lext_hash:    .long  ext_int_hash
  881. .Lhandle_per:  .long  handle_per_exception
  882. .Lirq_stat:    .long  irq_stat
  883. .Ljump_table:  .long  pgm_check_table
  884. .Lschedule:    .long  schedule
  885. .Lclone:       .long  sys_clone
  886. .Lexecve:      .long  sys_execve
  887. .Lfork:        .long  sys_fork
  888. .Lrt_sigreturn:.long  sys_rt_sigreturn
  889. .Lrt_sigsuspend:
  890.                .long  sys_rt_sigsuspend
  891. .Lsigreturn:   .long  sys_sigreturn
  892. .Lsigsuspend:  .long  sys_sigsuspend
  893. .Lsigaltstack: .long  sys_sigaltstack
  894. .Ltrace:       .long  syscall_trace
  895. .Lvfork:       .long  sys_vfork
  897. #ifdef CONFIG_SMP
  898. .Lschedtail:   .long  schedule_tail
  899. #endif